home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / magazine / nan_news / toolkit / default.asm < prev    next >
Assembly Source File  |  1991-08-15  |  5KB  |  120 lines
  1. ; File......: DEFAULT.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:06:40  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/default.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   E:/nanfor/src/default.asv  $
  14. ;  
  15. ;     Rev 1.2   15 Aug 1991 23:06:40   GLENN
  16. ;  Forest Belt proofread/edited/cleaned up doc
  17. ;  
  18. ;     Rev 1.1   14 Jun 1991 19:54:22   GLENN
  19. ;  Minor edit to file header
  20. ;  
  21. ;     Rev 1.0   01 Apr 1991 01:03:12   GLENN
  22. ;  Nanforum Toolkit
  23. ;  
  24. ;
  25.  
  26.  
  27. ;  $DOC$
  28. ;  $FUNCNAME$
  29. ;     FT_DEFAULT()
  30. ;  $CATEGORY$
  31. ;     DOS/BIOS
  32. ;  $ONELINER$
  33. ;     Retrieve and optionally change the current default drive
  34. ;  $SYNTAX$
  35. ;     FT_DEFAULT( [ <cDrive> ] ) -> cDrive
  36. ;  $ARGUMENTS$
  37. ;     <cDrive> is optional, and if specified is the new default drive.
  38. ;  $RETURNS$
  39. ;     The current default drive.  If a change of default drive is requested,
  40. ;     the return value is the drive AFTER the change is made.  This allows
  41. ;     you to make sure you specified a valid drive (i.e. if you attempt to
  42. ;     change the default drive, and the function returns a different drive
  43. ;     letter than the one you specified, then the drive does not exist).
  44. ;  $DESCRIPTION$
  45. ;     Useful any time you need to know or change the default drive.
  46. ;
  47. ;     The source code is written to adhere to Turbo Assembler's IDEAL mode.
  48. ;     To use another assembler, you will need to rearrange the PROC and
  49. ;     SEGMENT directives, and also the ENDP and ENDS directives (a very
  50. ;     minor task).
  51. ;  $EXAMPLES$
  52. ;     cDrive := FT_DEFAULT()  && Get the current drive
  53. ;     FT_DEFAULT("C")         && Switch to drive C
  54. ;
  55. ;     IF FT_DEFAULT("E") != "E"
  56. ;        Qout( "Drive E does not exist!" )
  57. ;     ENDIF
  58. ;  $END$
  59. ;
  60.  
  61.          IDEAL
  62.  
  63. Public   FT_DEFAULT
  64.  
  65. Extrn    __ParInfo:Far
  66. Extrn    __ParC:Far
  67. Extrn    __RetC:Far
  68.  
  69. Drive    EQU       Word Ptr BP - 2
  70.  
  71. Segment  _NanFor   Word      Public    "CODE"
  72.          Assume    CS:_NanFor
  73.  
  74. Proc     FT_DEFAULT          Far
  75.  
  76.          Push      BP                        ; Save BP
  77.          Mov       BP,SP                     ; Set up stack reference
  78.          Sub       SP,2                      ; Allocate space for drive
  79.  
  80.          Xor       AX,AX                     ; Prepare to count params
  81.          Push      AX                        ; Save on stack
  82.          Call      __ParInfo                 ; Retrieve param count
  83.          Or        AX,AX                     ; Zero parameters passed?
  84.          JZ        GetDrive                  ; If so, don't set drive
  85.  
  86.          Mov       AX,1                      ; Specify first parameter
  87.          Push      AX                        ; Save parameter # on stack
  88.          Call      __ParInfo                 ; Get param type
  89.          Test      AX,1                      ; Parameter a character?
  90.          JZ        GetDrive                  ; If not, don't set drive
  91.  
  92.          Mov       AX,1                      ; Select parameter #1
  93.          Push      AX                        ; Save parameter # on stack
  94.          Call      __ParC                    ; Retrieve it
  95.          Mov       ES,DX                     ; Load segment value
  96.          Mov       BX,AX                     ; Load offset value
  97.          Mov       DL,[Byte Ptr ES:BX]       ; Get drive letter
  98.          And       DL,0DFh                   ; Convert to uppercase
  99.          Sub       DL,"A"                    ; ASCII to binary
  100.          Mov       AH,0Eh                    ; DOS service--set default drive
  101.          Int       21h                       ; Call DOS
  102.  
  103. GetDrive:Mov       AH,19h                    ; DOS service--get current drive
  104.          Int       21h                       ; Call DOS
  105.          Add       AL,"A"                    ; Binary to ASCII
  106.          CBW                                 ; Zero terminate string
  107.          Mov       [Drive],AX                ; Store default drive
  108.  
  109. Finish:  Push       SS                       ; Save segment on stack
  110.          LEA        AX,[BP - 2]              ; Move offset to AX
  111.          Push       AX                       ; Save offset on stack
  112.          Call      __RetC                    ; Send return value to Clipper app
  113.          Mov       SP,BP                     ; Restore SP
  114.          Pop       BP                        ; Restore BP
  115.          Ret
  116. Endp     FT_DEFAULT
  117. Ends     _NanFor
  118. End
  119.  
  120.