Usenet 1994 January/usenetsourcesnewsgroupsinfomagicjanuary1994.iso/sources/misc/volume39/elfshell/part01/.elven/csh/.cshrc.v4

Text File | 1993-08-29 | 5.3 KB | 179 lines

#=======================================================================#
#
#       File:     ~/.cshrc
#       Support:  ~/.login
#                 ~/.setheaders (support file for an alias)
#       Descrip:  (with humour:) Sample .cshrc file for new users.
#                 (works in SunView, Xwindows, console and rsh)
#       Author:   Christoph. A. North-Keys (erlkonig@snowwhite)
#       Rev:      4,0 Mittwoch.d.8.Jun.1988
#
#=======================================================================#

alias self 'source ~/.cshrc'
alias Self 'unsetenv LOGGED ; self'

if !($?LOGGED) source ~/.login

if (-e ~/.cshrc_mine) source ~/.cshrc_mine

if ($?prompt) echo 'Entering C Shell'

set history = 100 savehist = 50
set nobeep


# Set search directories

set cdpath = (. ~ ~/aux)

alias X10pathset 'set path=( ~/bin /usr/5bin /bin /usr/bin /usr/local /usr/local/bin /usr/new /usr/ucb /usr/games .) ; rehash'
alias X11pathset 'set path=( ~/bin /usr/5bin /bin /usr/bin /usr/local /usr/local/bin /usr/local/X11 /usr/new /usr/ucb /usr/games .) ; rehash'
alias X10pathsetenv 'setenv X 10 ; setenv PATH=:$HOME/bin:/usr/5bin:/bin:/usr/bin:/usr/local:/usr/local/bin:/usr/new:/usr/ucb:.:/usr/games'
alias X11pathsetenv 'setenv X 11 ; setenv PATH=:$HOME/bin:/usr/5bin:/bin:/usr/bin:/usr/local:/usr/local/bin:/usr/local/X11:/usr/new:/usr/ucb:.:/usr/games'

alias X10set 'X10pathsetenv ; X10pathset'
alias X11set 'X11pathsetenv ; X11pathset'

if (${?X}) then
    if ($X == 10) then
        X10set
    else
        X11set
    endif
else
    setenv X 11
    X11set
endif

limit coredumpsize 0

alias setheaders 'setenv HEADERS \!* ; source ~/.setheaders'

setenv TTY "`tty`"

if ($?prompt) then

    alias m '/usr/local/bin/less'
    alias pg 'pg -c -n -p " Page=(%d):"'
    alias h 'history -r | m'

    if ($TTY != '/dev/console') then
        if (($TERM == 'sun-cmd') || ($TERM == 'sun') || \
            ($term == 'sun-cmd') || ($term == 'sun')) then
            echo 'Assuming SunWindows environment.'
            setenv HEADERS "sunheaders"
        else  #Xwindows
            echo 'Assuming Xwindows environment; use noheaders to cancel.'
            setenv HEADERS "xheaders"
            setenv DISPLAYMACH $HOST
            setenv DPY "0"
            setenv SCREEN "0"
            setenv DISPLAY $DISPLAYMACH":"$DPY"."$SCREEN
            setenv RESOURCE_MANAGER "$HOME/.X11defaults"
            echo 'Assuming Xserver  '$HOST','
            echo '         Xdisplay '$DISPLAY','
            echo '         Xdpy     '$DPY','
            echo '         Xscreen  '$SCREEN', use xdisp to change.'
        endif
    else
        echo 'Assuming minimal raw terminal environment.'
        setenv HEADERS "noheaders"
    endif
    if ($term != 'sun-cmd') set filec
else
    alias mm 'cat'
    alias h 'history -r'
    alias pwd 'echo $cwd'
    alias say 'echo "\!*"'
    if ("$TTY" == "not a tty") then
        setenv HEADERS "notty"
    else
        setenv HEADERS "off"
    endif
endif

    # ...more

    setheaders $HEADERS

    # Route file to laser writer
    alias [] 'lpr -Plw\!*'

    # Queries about laser writer
    alias []? 'lpq -Plw\!*'

    # [] commands with special formatting--from usernote
    alias [m]  'ptroff -man -Plw\!*'

    # Name present directory and describe members
    alias LI    '((say listing files \!* ; ls -ClFs     \!* ; pwd) | m)'
    alias L     '(say listing files \!* ; ls -CFs     \!* ; pwd)'
    alias l     '(say listing files \!* ; ls -CFa    \!* ; pwd)'
    alias li    '(say listing files \!* ; ls -CFals \!* ; pwd)'

    alias lf    'say listing dir/file  \!* ; ls -CsldF \!* ; pwd'
    alias ]d    'pushd \!* ; l'
    alias ]dq    'pushd \!* ; pwd'
    alias [d    'popd ; l'
    alias [dq    'popd ; pwd'
    alias p     'pwd'

    # File storage management
    alias q     'say quotas for $user ; quota -v ; pwd'

    # Move to auxiliary directory and ...
    alias am    'if (-e ~/aux/\!^) set preaux = $cwd ; cd ~/aux/\!^ ; pwd'
    alias ab    'cd $preaux ; pwd'

    # Move to home (Lios) directory and list as above
    alias lios '(cd ~ ; li ; if (-e ~/aux) echo "===aux===" aux/* "========" ; if (-e ~/aux) ls -FA aux/* ; if (-e ~/aux) echo "=========" ) | less '
    alias caer 'cd ~ ; l ; if (-e ~/aux) echo "===aux===" aux/* "========" ; if (-e ~/aux) ls -FA aux/* ; if (-e ~/aux) echo "=========" '


    # Move (direct, directory) to given dir, name it and list
    alias md 'cd \!* ; l'
    alias mq 'cd \!* ; pwd'

    # Move up to parent dir, name it and ls
    alias mu 'cd .. ; l'

    # Cleanup command
    alias ~~ 'say killing files in $cwd ; rm -i .*~ .*% .*OLD .*old *~ *% *OLD *old #*# ; say done killing files in $cwd ; sleep 1 ; pwd'

    # Add ability to run direct scripts without reshell NOT COMMAND
    alias shell /bin/csh -f

    # Auto-select suntools background
    alias sunpic 'suntools -background ~/\!:1' # -toggle_enable'
    alias sunicon 'suntools -pattern ~/images/tess/\!:1.icon -background ~/rasters/\!:2.ras -toggle_enable'

    # Clear screen
    alias . 'clear ; pwd'

    # Section supporting xconq ... xinit-conquest
    alias war 'cd ~/war ; l'
    alias debugxc 'makexconq =t =w -r -or =o $cwd/obj =s $cwd +x =D ; dbx -I $cwd $obj/xconq'

    # Specialized window variations
    alias wob echo -n "\[q"
    alias bow echo -n "\[p"
    wob

    # Section concerning Xwindows
    alias xbg    'xsetroot -bitmap ~/rasters/\!*.ras'
    alias xdisp     'setenv DISPLAYMACH \!:1 ; setenv SCREEN \!:2 ; setenv DISPLAY $DISPLAYMACH":"$SCREEN'
    alias Xfd    'xfd $cwd/\!*'

    # Terminal aids
    alias rs 'resize >/dev/null'
    alias se 'tset -e'
    alias SE 'se ; rs ; clear ; pwd'

#####
    if ($?prompt) pwd


########################################### End of .cshrc #####################
alias base 'setenv COLUMNS \!:1 ; source ~/vt100_80-132c'