home *** CD-ROM | disk | FTP | other *** search
/ Audio 4.94 - Over 11,000 Files / audio-11000.iso / amiga / players / modplyrs / dstrckr2.lha / DTL / code / mJuke.S < prev    next >
Text File  |  1993-12-17  |  54KB  |  1,624 lines
  1. ;;=====================================================================;;
  2. ;;                 mJuke.S  -  Begun Wed, Jan 02, 1993                 ;;
  3. ;;                   Last Updated: Sat, Dec 18, 1993                   ;;
  4. ;;---------------------------------------------------------------------;;
  5. ;;            This is version 2.0 of the Micro-Jukebox for             ;;
  6. ;;           destracker.library release 2.0+ (lib ver 3.0+)            ;;
  7. ;;---------------------------------------------------------------------;;
  8. ;;              Designed and written by Darren E. Schebek              ;;
  9. ;;                Copyright ⌐1993  by Darren E. Schebek                ;;
  10. ;;                         All rights reserved.                        ;;
  11. ;;                This source code is NOT public domain!               ;;
  12. ;;=====================================================================;;
  13.  
  14.         INCLUDE    "dp:system.gs"        ;DevPac-specific global include.
  15.         INCLUDE    "hardware/custom.i"    ;Something DevPac forgot about.
  16.         INCLUDE    "DTLib.I"        ;DES-Tracker include file.
  17.  
  18. ;---------------------------------------------------------------
  19. ; System equates...
  20.  
  21. _SYSBase    = 4        ;Pointer to exec library base.
  22.  
  23. CHIP        = $DFF000    ;Pointer to custom chip registers.
  24.  
  25. ;---------------------------------------------------------------
  26. ; Control character equates used in text strings and in string parsing...
  27.  
  28. NULL    = 0    ;NULL
  29. TAB    = $09    ;TAB
  30. LF    = $0A    ;LineFeed
  31. CR    = $0D    ;Carriage Return
  32. ESC    = $9B    ;Control sequence introducer
  33. CEOL    = $4B    ;Clear to end of line
  34.  
  35. DQUOTE    = $22    ;Double quote
  36.  
  37. ;---------------------------------------------------------------
  38. ; Some custom macros of my own...
  39.  
  40. LOADLIB    MACRO
  41.      Move.L    _\1Base,A6
  42.     ENDM
  43.  
  44. SYS    MACRO
  45.      Jsr    _LVO\1(A6)
  46.     ENDM
  47.  
  48. BYTETAB    MACRO
  49. \1     EQU    SOFFSET
  50. SOFFSET     SET    SOFFSET+\2
  51.     ENDM
  52.  
  53. WORDTAB    MACRO
  54. \1     EQU    SOFFSET
  55. SOFFSET     SET    SOFFSET+(\2*2)
  56.     ENDM
  57.  
  58. ;---------------------------------------------------------------
  59. ; Variables used by the mJuke program...
  60.  
  61.     STRUCTURE MJUKE,0
  62.  
  63.     WORDTAB    RandTable,256    ;Prime-index table used by random number routine.
  64.     UWORD    RandIndex    ;Used by my random number routine. (r-256 alg.)
  65.  
  66.     UBYTE    DTPlayDoneSig    ;Signal bit DTLib uses to signal me.
  67.     UBYTE    DTIterDoneSig    ;Another signal bit used with destracker.
  68.     UBYTE    FadingFlag    ;Set when a song is meant to fade out at end.
  69.     UBYTE    PathnameFlag    ;Used with scripts to tell paths and files apart.
  70.     UBYTE    JukeVolume    ;Holds current global playback volume.
  71.     UBYTE    ShuffleFlag    ;1 = Shuffle filenames, 0 = don't even think about it.
  72.     UBYTE    NumTimeSpaces    ;# of spaces to print before printing elapsed time.
  73.     UBYTE    Pad
  74.  
  75.     UWORD    CurSongNum    ;Keeps track of which song I'm playing in list.
  76.     UWORD    NumIterations    ;Holds calc'ed # of iterations to play song for.
  77.  
  78.     ULONG    WaitSignals    ;Holds signal bit #'s I wait for while playing.
  79.  
  80.     APTR    ScriptAddr    ;Temporary ptr used for script processing.
  81.     APTR    MyFileHandle    ;Temporary ptr used for loading script file.
  82.     ULONG    FileSize    ;Temporary. Holds size in bytes of script file.
  83.     UWORD    NumOfFiles    ;Holds number of song files in the play list.
  84.     APTR    PtrTableAddr    ;Points to array of pointers to song filenames.
  85.     ULONG    PtrTableLen    ;Holds length of the ptr-array in bytes.
  86.     APTR    FilenameBufAddr    ;Ptr to buffer containing all song filenames.
  87.     ULONG    FilenameBufLen    ;Holds length of filename buffer in bytes.
  88.     ULONG    FilenameBufIndex ;Used for appending new song filenames to buffer.
  89.  
  90.     APTR    TaskPointer    ;Pointer to mJuke's own TCB structure.
  91.     BPTR    LockPointer    ;Holds DOS Lock required for Examine() function.
  92.     BPTR    OutputHandle    ;Holds BPTR to standard output for text output.
  93.     APTR    MyFileInfoBlock    ;Ptr to file info block struct required by DOS.
  94.     APTR    DosBase        ;Pointer to DOS library base structure.
  95.     APTR    DTBase        ;Pointer to DES-Tracker library base structure.
  96.  
  97.     BYTETAB    FilenameString,256 ;Used to construct file/path specifications.
  98.  
  99.     LABEL    MJUKE_SIZE    ;Size of the memory area required for variables.
  100.  
  101. ;---------------------------------------------------------------
  102. ; In the beginning, there was "Main". :)  I start out by allocating
  103. ; a block of memory to be used for all of this program's variables.
  104. ; This is much more elegant than simply throwing all the variables
  105. ; into the block storage segment...
  106.  
  107. Main        Move.L    A0,A5        ;Cache CLI argstring pointer in A5.
  108.  
  109. ; Allocate space for program variables...
  110.  
  111.         LOADLIB    SYS        ;Need SYS_Base in A6.
  112.         Move.L    #MJUKE_SIZE,D0    ;Size of the variable space I need.
  113.         Move.L    #MEMF_CLEAR,D1    ;Initialize everything to 0 for me. :)
  114.         SYS    AllocMem    ;Attempt to allocate the mem.
  115.         Tst.L    D0        ;Allocate error?
  116.         Ble    .ProgAbort    ;Yup, leave immediately.
  117.         Move.L    D0,A4        ;A4 is now sacred (pts to variable space).
  118.  
  119.         Bsr    Initialize    ;Initialize everything.
  120.         Tst.L    D0        ;Error during initialization?
  121.         Bne    .Abort        ;Yup, abort with error.
  122.  
  123. ;-------------------------------
  124. ; Static initialization and setup is now complete, now parse the command line
  125. ; argstring, build the list of song filenames to load and play, shuffle them
  126. ; randomly, and then play the bleedin' songs...
  127.  
  128.         Bsr    ProcessCmdLine    ;Parse cmd-line args, collect filenames.
  129.         Tst.L    D0        ;Did an error occur?
  130.         Bne    .Error        ;Yup.
  131.  
  132.         Bsr    MakePtrTable    ;Build and shuffle filename ptr array.
  133.         Tst.L    D0        ;Error?
  134.         Bne    .Error        ;Yuppers. So abort.
  135.  
  136.         Tst.B    ShuffleFlag(A4)    ;Should I shuffle the filenames?
  137.         Beq    .NoShuffle    ;Nope.
  138.         Bsr    ShuffleSongs    ;Randomize filenames in pointer array.
  139. .NoShuffle
  140.         Bsr    PlaySongs    ;No problems, so go play the songs.
  141.         Tst.L    D0        ;Error?
  142.         Bne    .Error        ;Yes, someone must have locked the library.
  143.  
  144.         Move.L    #JukeDoneText,D2 ;Say "Hasta la vista, baby!"
  145.         Bsr    PrintNicely    ;(or something along those lines).
  146.  
  147.         MoveQ    #0,D7        ;Indicate success upon exit.
  148.  
  149. ;-------------------------------
  150. ; Deallocate everything and leave.  Note that I don't bother calling
  151. ; RemStatusSignal for the two signal bits I use with DES-Tracker, since
  152. ; DES-Tracker will remove them for me when I close the library.
  153.  
  154. .Abort        Bsr    DeInitialize    ;Free up used resources.
  155.  
  156.         Move.L    D7,D0        ;Return exit code in D0.
  157.  
  158. .Leave        Rts            ;Byeeee!
  159.  
  160.  
  161. .Error        MoveQ    #10,D7        ;Set error exit flag & bail out.
  162.         Bra    .Abort
  163.  
  164. .ProgAbort    MoveQ    #10,D7        ;Exit with error code in D0.
  165.         Bra    .Leave
  166.  
  167. ;---------------------------------------------------------------
  168. ; ProcessCmdLine routine.  Parses the command line, determines whether or not
  169. ; the argument is a pathname or a filename, and calls either ReadPath or
  170. ; ReadScript as a result.
  171. ;
  172. ;   Input: A5 =    Ptr to the command line argstring.
  173. ;
  174. ;  Output: D0 =    0  if song file list was created successfully.
  175. ;        -1 if an error occurred along the way.
  176. ;
  177. ; Trashes: D1,D2,D3,A0,A1,A2,A5,A6
  178. ;
  179.  
  180. ProcessCmdLine    Bsr    GetFilespec    ;Get filespec/pathspec from argstring.
  181.         Tst.W    D0        ;Was there a file/path spec?
  182.         Bne    .ShowUsage    ;No, just print out usage text.
  183.  
  184.         Lea    FilenameString(A4),A0    ;Yes, get ptr to file/path spec.
  185.         Bsr    VerifyPath        ;See whether it's a path or file.
  186.  
  187.         Tst.L    D0        ;It's neither a path nor a file.
  188.         Bmi    .BadPath    ;(must be gibberish from the abuser).
  189.  
  190.         Move.L    D0,-(Sp)    ;   Save file/path status temporarily.
  191.  
  192.         Move.L    #CFilesText,D2    ;Say "Collecting filenames..."
  193.         Bsr    PrintN2Text
  194.  
  195.         Move.L    (Sp)+,D0    ;   Restore file/path status.
  196.         Beq    .IsFile        ;D0 = 0 means it's a filespec.
  197.  
  198. ; User specified a pathname, add it to DES-Tracker's list of search paths...
  199.  
  200.         Move.L    DTBase(A4),A6    ;Get DES-Tracker base ptr.
  201.         Sub.L    A0,A0        ;Pass NULL to clear all existing paths.
  202.         SYS    SetModulePath    ;Do it.
  203.  
  204.         Lea    FilenameString(A4),A0    ;Get ptr to pathspec string.
  205.         SYS    SetModulePath    ;Add pathspec to search path list.
  206.  
  207.         Bsr    ReadPath    ;Read in all the filenames.
  208.         Bra    .Done        ;And leave. :)
  209.  
  210.  
  211. ; User specified a file, so first check to make sure it's a script...
  212.  
  213. .IsFile        Move.L    MyFileInfoBlock(A4),A0    ;Info Block filled in by DOS.
  214.         Move.L    fib_Protection(A0),D0    ;Get file's protection bits.
  215.         BTst    #FIBB_SCRIPT,D0        ;Is script bit set?
  216.         Bne    .IsScript        ;Yup, go read it in.
  217.  
  218.         Move.L    #NotScriptText,D2    ;Nope, tell user about it.
  219.         Bsr    PrintNicely
  220.         Bra    .Error            ;And abort.
  221.  
  222. .IsScript    Bsr    ReadScript        ;Read script, record song filenames.
  223.         
  224. .Done        Move.L    D0,-(Sp)        ;   Save return code temporarily.
  225.         Move.L    #IPlayText,D2        ;Say "Press CTRL-C to abort..."
  226.         Bsr    PrintNicely
  227.         Move.L    (Sp)+,D0        ;   Restore return code in D0.
  228.  
  229. .Leave        Rts                ;All done.
  230.  
  231.  
  232. .ShowUsage    Move.L    #ComText,D2        ;No parms specified, show usage.
  233.         Bsr    PrintNicely
  234.         Bra    .Error            ;And abort.
  235.  
  236.  
  237. .BadPath    Move.L    #ComText,D2        ;User not clear on concept,
  238.         Bsr    PrintNicely        ; so show usage text
  239.  
  240.         Move.L    #BadPathText,D2        ; and then say "Illegal path...".
  241.         Bsr    PrintNicely
  242.  
  243. .Error        MoveQ    #-1,D0            ;D0 = error return code.
  244.         Bra    .Leave            ;Leave.
  245.  
  246. ;---------------------------------------------------------------
  247. ; ReadScript routine.  Reads in the specified script file (if possible) and
  248. ; parses all the song filenames, storing them into the filename buffer.  Any
  249. ; lines in the script that start with a "#" character are assumed to have a
  250. ; search pathname immediately following the "#".  Search paths are added to
  251. ; the DES-Tracker library's list of search paths.
  252. ;
  253. ;   Input: FilenameString(A4) must hold the complete filespec of the script file.
  254. ;
  255. ;  Output: D0 =    0  if script file parsed successfully.
  256. ;        -1 if an error occurred while parsing the file.
  257. ;
  258. ; Trashes: D1,D2,D3,D6,A0,A1,A2,A6
  259. ;
  260.  
  261. ReadScript    Clr.W    NumOfFiles(A4)        ;Initialize song count.
  262.  
  263.         Bsr    AllocFNameBuffer    ;Allocate an initial filename buffer.
  264.         Tst.L    D0            ;Error?
  265.         Bmi    .InsuffMem        ;Yup, so abort.
  266.  
  267. ; Now open the script file...
  268.  
  269.         Lea    FilenameString(A4),A0    ;Pointer to the script filename.
  270.         Move.L    A0,D1            ; In D1.
  271.         Move.L    #MODE_OLDFILE,D2
  272.         Move.L    DosBase(A4),A6        ;Use DOS_Base.
  273.         SYS    Open            ;Attempt to open script file.
  274.         Move.L    D0,MyFileHandle(A4)    ;Store file handle ptr.
  275.         Beq    .Error            ;If 0, then file didn't open.
  276.  
  277. ; Script file opened, so first determine how big the file is so I can
  278. ; allocate enough space to read it in...
  279.  
  280.         Move.L    D0,D1            ;Need file handle in D1.
  281.         MoveQ    #0,D2
  282.         Move.L    #OFFSET_END,D3        ;Seek to end of file.
  283.         SYS    Seek
  284.         Move.L    MyFileHandle(A4),D1    ;Restore file handle in D1.
  285.         MoveQ    #0,D2
  286.         Move.L    #OFFSET_BEGINNING,D3    ;Seek back to beginning of file.
  287.         SYS    Seek
  288.         Move.L    D0,FileSize(A4)        ;D0 holds file size, save it.
  289.  
  290. ; Now allocate enough memory to read in the script...
  291.  
  292.         LOADLIB    SYS            ;Need SYS_Base to do it.
  293.         Move.L    #MEMF_CLEAR,D1        ;Clear the memory for me.
  294.         SYS    AllocMem        ;Attempt to allocate the mem.
  295.         Move.L    D0,ScriptAddr(A4)    ;Save ptr to script memory.
  296.         Beq    .Error            ;If 0, then allocate failed.
  297.  
  298. ; Now read in the script file...
  299.  
  300.         Move.L    DosBase(A4),A6        ;Get DOS_Base
  301.         Move.L    MyFileHandle(A4),D1    ;File handle in D1.
  302.         Move.L    D0,D2            ;Ptr to dest buffer in D2.
  303.         Move.L    FileSize(A4),D3        ;# of bytes to read in D3.
  304.         SYS    Read            ;Attempt to read the script file.
  305.         Tst.L    D0            ;Error?
  306.         Bgt    .Cont1            ;Nope.
  307.  
  308.         Move.L    #ReadErrText,D2        ;Yup, tell user about it.
  309.         Bsr    PrintNicely
  310.         Bra    .Error            ;And abort.
  311.  
  312. ; Now I must parse the script file in memory...
  313.  
  314. .Cont1        Move.L    FileSize(A4),D0        ;Get script file size.
  315.         Move.L    ScriptAddr(A4),A0    ;Pointer to script in A0.
  316.         Lea    0(A0,D0.L),A1        ;A1 points to end of script.
  317.  
  318. .ParseLoop    Bsr    ReadLine        ;Read in line from script.
  319.         Tst.L    D0            ;Reached end of file yet?
  320.         Bne    .Done            ;Yup.
  321.  
  322.         Lea    FilenameString(A4),A2    ;Nope, get ptr to the line.
  323.         Tst.B    PathnameFlag(A4)    ;Is it a filename or search path?
  324.         Beq    .StoreName        ;It's a filename, store in buffer.
  325.  
  326.         Move.L    DTBase(A4),A6        ;It's a search path.
  327.         MoveM.L    A0-A1,-(Sp)        ;   Save useful pointers.
  328.         Move.L    A2,A0            ;Ptr to path string in A0
  329.         SYS    SetModulePath        ;Add search path to library's list.
  330.         MoveM.L    (Sp)+,A0-A1        ;   Restore useful pointers.
  331.  
  332.         Bra    .ParseLoop        ;Extract & parse next line in script.
  333.  
  334. ; Here, a filename string has been returned by the ReadLine routine, so I
  335. ; must copy the filename into the filename buffer...
  336.  
  337. .StoreName    Lea    FilenameString(A4),A3    ;Ptr to filename string in A3.
  338.         MoveM.L    A0-A1,-(Sp)        ;   Save useful pointers.
  339.         Bsr    AddFNameToBuffer    ;Add filename string to buffer.
  340.         MoveM.L    (Sp)+,A0-A1        ;   Restore useful pointers.
  341.         Tst.L    D0            ;Error?
  342.         Bmi    .InsuffMem        ;Yup, report it and abort.
  343.  
  344.         AddQ.W    #1,NumOfFiles(A4)    ;Filename added, adjust file count.
  345.         Bra    .ParseLoop        ;Read & parse next line in file.
  346.  
  347. .Done        MoveQ    #0,D6            ;Indicate success in D6.
  348.  
  349. .Leave        Move.L    DosBase(A4),A6        ;Get DOS_Base.
  350.         Move.L    MyFileHandle(A4),D1    ;File handle in D1.
  351.         Beq    .1            ;If 0, then file didn't open.
  352.         SYS    Close            ;Close the script file.
  353.  
  354. .1        LOADLIB    SYS            ;Get SYS_Base.
  355.         Move.L    ScriptAddr(A4),D0    ;Get ptr to script file in memory.
  356.         Beq    .2            ;If ptr is 0, then allocate failed.
  357.         Move.L    D0,A1            ;It didn't fail.
  358.         Move.L    FileSize(A4),D0        ;Size of the memory block.
  359.         SYS    FreeMem            ;Free memory used by script file.
  360.  
  361. .2        Move.L    D6,D0            ;Return code copied to D0.            
  362.         Rts                ;Leave.
  363.  
  364. .Error        MoveQ    #-1,D6            ;Indicate error in D6.
  365.         Bra    .Leave            ;And abort.
  366.  
  367. .InsuffMem    Move.L    #InsuffMemText,D2    ;Report "Not enough memory".
  368.         Bsr    PrintNicely
  369.         Bra    .Error            ;And abort.
  370.  
  371. ;---------------------------------------------------------------
  372. ; ReadLine routine.  Extracts the next line from the script file in memory.
  373. ; This routine will automatically skip blank lines and will parse out
  374. ; comments and white space before returning a valid string.
  375. ;
  376. ; This routine also checks the first non-whitespace character of the line and,
  377. ; if the character is a "#" symbol, then it sets the PathnameFlag variable.
  378. ; This tells the calling routine that the string returned in FilenameString[]
  379. ; is a *pathname* and not a *song filename*.
  380. ;
  381. ;   Input: A0 = ptr to current position in script file in memory.
  382. ;
  383. ;  Output: LineBuffer(A4) holds ptr to buffer containing the parsed input line.
  384. ;
  385. ; Trashes: D0,D1,D2,A0,A1,A2
  386. ;
  387.  
  388. ReadLine    Lea    FilenameString(A4),A2    ;Ptr to dest string buffer in A2.
  389.         Move.L    A2,D1            ;Keep copy in D1.
  390.  
  391.         Bra    .NextLine        ;See if I've reached EOF yet.
  392.  
  393. .ReadLoop    Cmp.B    #";",(A0)        ;Check if 1st char is a ";".
  394.         Bne    .SkipWhite        ;It isn't.
  395.  
  396. .SkipLine    Cmp.B    #LF,(A0)+        ;It is, so skip entire line.
  397.         Bne    .SkipLine
  398.  
  399.         Bra    .NextLine        ;See if I've reached EOF.
  400.  
  401. ; Skip leading white space (if any)...
  402.  
  403. .SkipWhite    Move.B    (A0)+,D0    ;Get char from script.
  404.         Cmp.B    #" ",D0        ;Is it a space character?
  405.         Beq    .SkipWhite    ;Yup, parse it out.
  406.         Cmp.B    #TAB,D0        ;Is it a tab character?
  407.         Beq    .SkipWhite    ;Yup, parse it out.
  408.         Cmp.B    #LF,D0        ;Reached EOL yet?
  409.         Beq    .NextLine    ;Yup, line's blank, check for EOF.
  410.  
  411.         SubQ    #1,A0        ;Char is legit, back up to it.
  412.  
  413. .RLoop        Move.B    (A0)+,D0    ;Fetch next char from script.
  414.         Cmp.B    #LF,D0        ;Reached EOL yet?
  415.         Beq    .Parse        ;Yes, go parse out trailing white space.
  416.         Cmp.B    #"#",D0        ;Pathname prefix character?
  417.         Beq    .SetPath    ;Yes, go set flag indicating so.
  418.         Cmp.B    #";",D0        ;Is it a comment char?
  419.         Bne    .Store        ;Nope, so store char in dest string.
  420.  
  421. .SkipEOL    Cmp.B    #LF,(A0)+    ;Yes, so ignore remainder of this line.
  422.         Bne    .SkipEOL
  423.         Bra    .Parse        ;Go parse what I got from this line.
  424.  
  425. .Store        Move.B    D0,(A2)+    ;Store char in filename string.
  426.  
  427.         Cmp.L    A1,A0        ;Reached EOF yet?
  428.         Blt    .RLoop        ;Nope, go fetch another character.
  429.  
  430.         Bra    .Parse        ;Yup, go parse what I've got so far.
  431.  
  432. .SetPath    St    PathnameFlag(A4) ;Indicate that this is a pathname.
  433.         Bra    .RLoop        ;Go fetch next character.
  434.  
  435. ; Here, I must null-terminate the string I have constructed in FilenameString[].
  436. ; I must also trim the trailing white space from the string...
  437.  
  438. .Parse        Cmp.L    A2,D2        ;Anything stored in dest string?
  439.         Beq    .NextLine    ;Nope, this line parses to a blank line.
  440.  
  441.         Move.B    -(A2),D0    ;Get previous char from dest string.
  442.         Cmp.B    #" ",D0        ;Is it a space character?
  443.         Beq    .Parse        ;Yup, parse it out.
  444.         Cmp.B    #TAB,D0        ;Is it a tab character?
  445.         Beq    .Parse        ;Yup, parse it out.
  446.  
  447.         AddQ    #1,A2        ;No, so move forward to next cell.
  448.         Clr.B    (A2)        ;NULL-terminate the string.
  449.  
  450.         MoveQ    #0,D0        ;Return success code in D0.
  451.  
  452. .Leave        Rts            ;Leave.
  453.  
  454. ; This bit of code is called prior to parsing a line from the script file
  455. ; to see if I've gone past the end of the script file.  Since it's always
  456. ; called before the line is parsed, I clear the PathnameFlag...
  457.  
  458. .NextLine    Clr.B    PathnameFlag(A4) ;Clear pathname flag.
  459.  
  460.         Cmp.L    A1,A0        ;Reached EOF yet?
  461.         Blt    .ReadLoop    ;Nope, it's OK to parse another line.
  462.  
  463.         Move.L    #-1,D0        ;Indicate end of file.
  464.         Bra    .Leave        ;And leave.
  465.  
  466. ;---------------------------------------------------------------
  467. ; ReadPath routine.  Reads all files from the path specified in
  468. ; FilenameString[].  The calling routine must have previously called the
  469. ; VerifyPath routine, which sets up a lock on the path (stored in LockPointer)
  470. ; and also fills out the MyFileInfoBlock structure by calling Examine().
  471. ;
  472. ; All filenames are read in from the path (using ExNext()) and stored in the
  473. ; filename buffer.
  474. ;
  475. ;   Input: LockPointer(A4) must contain lock on path.
  476. ;       MyFileInfoBlock(A4) must point to filled out struct for Examine().
  477. ;
  478. ;  Output: D0 = 0  if all files successfully read in and stored.
  479. ;        -1 if an error occurred.
  480. ;
  481. ; Trashes: D1,D2,D3,A0,A1,A3,A6
  482. ;
  483.  
  484. ReadPath    
  485.  
  486. ; First, allocate a buffer to hold the filenames for all files in the path...
  487.  
  488.         Bsr    AllocFNameBuffer    ;Allocate initial filename buffer.
  489.         Tst.L    D0            ;Did allocate succeed?
  490.         Bmi    .InsuffMem        ;Nope, so abort with error.
  491.  
  492. ; And now, I call ExNext() repeatedly until all filenames have been read in. I
  493. ; must also count the number of files in the path so that I know how large the
  494. ; pointer table must be (which I create after all filenames have been read)...
  495.  
  496.         Move.W    #0,NumOfFiles(A4)    ;Initialize filename counter.
  497.  
  498. .ReadFile    Move.L    DosBase(A4),A6        ;Get DOS_Base.
  499.         Move.L    LockPointer(A4),D1    ;Lock ptr in D1.
  500.         Move.L    MyFileInfoBlock(A4),A0    ;FileInfoBlock struct ptr in A0.
  501.         Move.L    A0,D2            ;DOS wants it in D2.
  502.         SYS    ExNext            ;Get info for next file in path.
  503.         Tst.L    D0            ;Were any files left?
  504.         Beq    .Done            ;Nope, all done.
  505.  
  506. ; Add this filename to the buffer containing all the filenames...
  507.  
  508.         Move.L    MyFileInfoBlock(A4),A3    ;Pointer to file info block.
  509.         Tst.W    fib_DirEntryType(A3)    ;Make sure this is a file.
  510.         Bpl    .ReadFile        ;It's a directory, so skip it.
  511.         Lea    fib_FileName(A3),A3    ;A3 points to filename string.
  512.  
  513.         Bsr    AddFNameToBuffer    ;Add filename string to buffer.
  514.         Tst.L    D0            ;Error in doing so?
  515.         Bmi    .InsuffMem        ;Yup, abort with error.
  516.  
  517.         AddQ.W    #1,NumOfFiles(A4)    ;Nope, adjust filename count.
  518.  
  519. ; Now go back and see if any files remain in path...
  520.  
  521.         Bra    .ReadFile        ;Back for another file.
  522.  
  523. .Done        MoveQ    #0,D0            ;Return with success code.
  524.  
  525. .Leave        Rts                ;Leave.
  526.  
  527. .Error        MoveQ    #-1,D0            ;Return with error code.
  528.         Bra    .Leave            ;Leave.
  529.  
  530. .InsuffMem    Move.L    #InsuffMemText,D2    ;Tell user "Ran outa mem, dude."
  531.         Bsr    PrintNicely
  532.         Bra    .Error            ;Abort with error.
  533.  
  534. ;---------------------------------------------------------------
  535. ; MakePtrTable routine.  Creates a table of pointers to each filename string
  536. ; in the filename buffer and then shuffles the pointers randomly.
  537. ;
  538. ;   Input: NumOfFiles(A4) holds number of filenames in the buffer.
  539. ;       FilenameBufAddr(A4) must hold ptr to filename buffer.
  540. ;
  541. ;  Output: D0 = 0  if pointer table successfully created and shuffled.
  542. ;        -1 if an error occurred.
  543. ;
  544. ; Trashes: D1,D2,D3,A0,A1,A6
  545. ;
  546.  
  547. MakePtrTable    MoveQ    #0,D0
  548.         Move.W    NumOfFiles(A4),D0    ;Get # of filenames in buffer.
  549.         Bne    .AreFiles        ;There's at least one filename.
  550.  
  551.         Move.L    #NoFilesText,D2        ;No filenames in buffer.
  552.         Bsr    PrintNicely
  553.         Bra    .Error            ;Abort with error code.
  554.  
  555. .AreFiles    Add.L    D0,D0            ;Make longword index out of D0.
  556.         Add.L    D0,D0            ;D0 is now size of the ptr array.
  557.         Move.L    D0,PtrTableLen(A4)    ;Store size for deallocation later.
  558.  
  559.         LOADLIB    SYS            ;Get SYS_Base.
  560.         Move.L    #MEMF_CLEAR,D1        ;Clear the memory for me, please.
  561.         SYS    AllocMem        ;Attempt to allocate ptr array mem.
  562.         Move.L    D0,PtrTableAddr(A4)    ;Save ptr to ptr-array memory.
  563.         Bne    .HavePtrMem        ;Allocate was successful.
  564.  
  565. .InsuffMem    Move.L    #InsuffMemText,D2    ;Oop, ran out of memory. Darn.
  566.         Bsr    PrintNicely
  567.         Bra    .Error            ;Abort with error.
  568.  
  569. ; Now fill out the pointer array...
  570.  
  571. .HavePtrMem    Move.L    FilenameBufAddr(A4),A1    ;get ptr to filenames buffer.
  572.         Move.L    D0,A0            ;A0 points to ptr-array.
  573.         Move.W    NumOfFiles(A4),D0    ;Do for # of filenames in buffer.
  574.         SubQ    #1,D0            ;Adjust count for "Do..Until" loop.
  575.  
  576.         Bra    .1
  577.  
  578. .IPALoop    Tst.B    (A1)+            ;Check next char in filename buffer.
  579.         Bne    .IPALoop        ;Search until NULL is found.
  580.  
  581. .1        Move.L    A1,(A0)+        ;Store pointer to filename.
  582.  
  583.         DBra    D0,.IPALoop        ;Find start of next filename string.
  584.  
  585. ; At this point, All filenames have been read in, so I can leave now...
  586.  
  587.         MoveQ    #0,D0            ;Indicate success.
  588.  
  589. .Leave        Move.L    D0,-(Sp)        ;   Save return code.
  590.         Move.L    LockPointer(A4),D1    ;Lock pointer in D1.
  591.         Move.L    DosBase(A4),A6        ;Get DOS_Base.
  592.         SYS    UnLock            ;Don't need lock anymore.
  593.         Clr.L    LockPointer(A4)        ;So exit code knows it's gone.
  594.         Move.L    (Sp)+,D0        ;   Restore return code.
  595.  
  596.         Rts                ;And leave.
  597.  
  598. .Error        MoveQ    #-1,D0            ;Indicate an error occurred.
  599.         Bra    .Leave            ;Abort with error.
  600.  
  601. ;---------------------------------------------------------------
  602. ; ShuffleSongs routine.  Takes each pointer in the pointer array and swaps it
  603. ; with another pointer in the array that is chosen at random.
  604. ; 
  605. ;   Input: PtrTableArray(A4) must point to the pointer array to shuffle.
  606. ;       NumOfFiles(A4) must holds the number of pointers in the array.
  607. ;
  608. ;  Output: Nothing.
  609. ;
  610. ; Trashes: D0,D1,D6,D7,A0
  611. ;
  612.  
  613. ShuffleSongs    Move.L    PtrTableAddr(A4),A0    ;Get ptr to the Pointer-array.
  614.         Move.W    NumOfFiles(A4),D7    ;Do for # of pointers in array.
  615.         SubQ.W    #1,D7            ;Adjust loop count for "Do..Until".
  616.  
  617. .NextFile    Bsr    Random            ;Get a random number.
  618.         MulU    NumOfFiles(A4),D0    ;Create random value in range.
  619.         Swap    D0            ;D0 is now 0..NumOfFiles-1.
  620.  
  621. ; I have a random element, so swap the corresponding pointers...
  622.  
  623.         Add.W    D0,D0            ;Make long index of random index.
  624.         Add.W    D0,D0
  625.         Move.W    D7,D6            ;Copy loop count into D6.
  626.         Add.W    D6,D6            ;Make long index of loop count.
  627.         Add.W    D6,D6
  628.         Move.L    0(A0,D0.W),D1        ;Save random element's pointer.
  629.         Move.L    0(A0,D6.W),0(A0,D0.W)    ;Copy cur. element to random element.
  630.         Move.L    D1,0(A0,D6.W)        ;Store random element in cur. element.
  631.  
  632.         DBra    D7,.NextFile        ;Until all ptrs have been swapped.
  633.  
  634.         Rts
  635.  
  636. ;---------------------------------------------------------------
  637. ; PlaySongs routine.  This is the routine that goes through the entire list
  638. ; of songs, loading and playing each one.  Since I do not lock the library,
  639. ; I have to be wary of the user doing things with DTC like unloading a module
  640. ; on me while I'm playing it.
  641. ;
  642. ;   Input: PtrTableAddr(A4) must hold ptr to array of pointers to song filenames.
  643. ;       NumOfFiles(A4) must hold the number of filenames to load and play.
  644. ;
  645. ;  Output: D0 = 0  if all songs were processed without any trouble.
  646. ;        -1 if another program in memory locked the library.
  647. ;
  648. ; Trashes: D1,D2,D3,A0,A1,A2,A5,A6
  649. ;
  650.  
  651. PlaySongs    Move.W    #0,CurSongNum(A4)    ;Init current song number.
  652.         Move.L    PtrTableAddr(A4),A5    ;Cache ptr-array ptr in A5.
  653.  
  654.         Move.L    DTBase(A4),A6        ;Get DES-Tracker base.
  655.         MoveQ    #0,D0
  656.         Move.B    DTPlayDoneSig(A4),D0    ;Get play-done signal bit #.
  657.         Move.W    #SEF_FINISH|SEF_MODUNLOADED|SEF_STOP|SEF_LIBOWNED,D1 ;Specify events I want.
  658.         SYS    AddStatusSignal        ;Add event signal to library.
  659.  
  660.         MoveQ    #0,D0
  661.         Move.B    DTIterDoneSig(A4),D0    ;Get iteration-done sig bit #.
  662.         Move.W    #SEF_ITERATION|SEF_VOLFADE,D1 ;Specify events I want.
  663.         SYS    AddStatusSignal        ;Add event signal to library.
  664.  
  665.         MoveQ    #0,D0
  666.         Move.B    JukeVolume(A4),D0    ;Get current global juke volume.
  667.         SYS    SetGlobalVolume        ;Set global volume.
  668.  
  669. ;-------------------------------
  670. ; Here begins the load & play loop.  I use the variable WaitSignals(A4) to hold
  671. ; the signal bits that I want to wait for.  I always wait for CTRL-C as well as
  672. ; the play-done signal.  However, if the song is to be played for more than one
  673. ; iteration, then I also need to wait for the iteration-done signal in order for
  674. ; me to know when to start fading out the song...
  675.  
  676. .PlayLoop    Bsr    LoadSong        ;Attempt to load song.
  677.         Tst.L    D0            ;So what happened?
  678.         Beq    .Go            ;Song loaded fine.
  679.         Bpl    .NextSkipTime        ;Couldn't load song. Try next song.
  680.  
  681.         Bra    .Error            ;Library now locked, so abort.
  682.  
  683. ; At this point the module loaded successfully.  First, I'll print "Playing..."
  684. ; and then I must examine the module a bit to determine how I'm to play it...
  685.  
  686. .Go        Move.L    dtl_ModuleStatus+ms_Name(A6),A0
  687.         MoveQ    #-1,D1
  688. .Count        AddQ    #1,D1
  689.         Tst.B    (A0)+
  690.         Bne    .Count
  691.  
  692.         MoveQ    #22,D0
  693.         Sub.W    D1,D0
  694.         Move.B    D0,NumTimeSpaces(A4)
  695.  
  696.         Move.L    #PlayingText,D2        ;Say "Playing "
  697.         Bsr    PrintN2Text
  698.         Move.L    dtl_ModuleStatus+ms_Name(A6),D2
  699.         Bsr    PrintN2Text        ; followed by module name.
  700.         Move.L    #XtraPlayText,D2    ; followed by close quote.
  701.         Bsr    PrintN2Text
  702.  
  703. ;-------------------------------
  704. ; I have to determine the number of iterations for this module.
  705. ; Here's how I adjust for the number of iterations...
  706. ;
  707. ; Module's default    What I convert
  708. ; # of iterations        it to
  709. ;
  710. ;   iter = 1               1
  711. ;   iter = 0              2
  712. ;   iter > 1          iter + 1
  713. ;
  714. ; Also, if the resultant number of iterations is greater than 1, then I have
  715. ; to fade the song out at the beginning of its last iteration...
  716.  
  717.         MoveQ    #0,D0
  718.         Move.B    dtl_DefIterations(A6),D0 ;Get default # of iterations.
  719.         Cmp.W    #1,D0            ;Is it a one-shot tune?
  720.         Beq    .StoreIter        ;Yes, keep it that way.
  721.         Bgt    .AddOneIter        ;>1 means add extra iteration.
  722.  
  723.         MoveQ    #1,D0            ;Next instruction changes it to 2.
  724.         
  725. .AddOneIter    AddQ    #1,D0            ;I will fade on this extra iteration.
  726.  
  727. ; Here, the number of iterations is greater than 1.  This means I must fade
  728. ; the song out at the beginning of the last iteration.  To do this, I'll need
  729. ; to wait for the iteration-done signal bit, so I add it to WaitSignals(A4)...
  730.  
  731.         Move.L    WaitSignals(A4),D2    ;Get wait signal bits
  732.         Move.B    DTIterDoneSig(A4),D1    ;Include the iter-done signal.
  733.         BSet    D1,D2
  734.         Move.L    D2,WaitSignals(A4)    ;Store updated wait signal bits.
  735.  
  736. .StoreIter    Move.W    D0,NumIterations(A4)    ;Store new number of iterations.
  737.         SYS    SetIterations        ;Set new # of iterations.
  738.  
  739.         SYS    BeginPlaySeq        ;Start playing the song.
  740.  
  741. ;-------------------------------
  742. ; Wait until the song is finished or something diabolical happens...
  743.  
  744. .WaitLoop    LOADLIB    SYS            ;Get SYS_Base.
  745.         MoveQ    #0,D0
  746.         Move.L    WaitSignals(A4),D0    ;Wait signals in D0.
  747.         SYS    Wait            ;Wait for something to happen.
  748.  
  749.         Move.L    DTBase(A4),A6        ;Get DES-Tracker base.
  750.  
  751. ;-------------------------------
  752. ; At this point, I've been signalled, so I have to determine which signals I've
  753. ; received and act on them accordingly...
  754.  
  755.         MoveQ    #SIGBREAKB_CTRL_C,D1    ;Get control-C signal bit #.
  756.         BTst    D1,D0            ;Was CTRL-C pressed?
  757.         Beq    .CheckCTRLF        ;Nope.
  758.  
  759.         Move.L    #JukeAbortText,D2    ;Yup, so abort jukebox.
  760.         Bsr    PrintNicely
  761.         Bra    .Error            ;Abort.
  762.  
  763. .CheckCTRLF    MoveQ    #SIGBREAKB_CTRL_F,D1    ;Get control-F signal bit #.
  764.         BTst    D1,D0            ;Was CTRL-F pressed?
  765.         Beq    .CheckDTSig        ;Nope.
  766.         Move.B    dtl_GlobalVolume(A6),JukeVolume(A4)
  767.         Bra    .NextTune        ;Yup, skip to next song.
  768.  
  769. .CheckDTSig    Move.B    DTPlayDoneSig(A4),D1    ;Get play-done sig bit #.
  770.         BTst    D1,D0            ;Play seq done or mod unloaded?
  771.         Beq    .CheckIter        ;Nope.
  772.  
  773. ; Here, either the (one-shot) song has finished playing or the module was unloaded
  774. ; while it was playing.  Before going on to the next song, I must grab the current
  775. ; global volume setting from the library, since the user may have changed it
  776. ; while I was asleep...
  777.  
  778.         Move.B    dtl_GlobalVolume(A6),JukeVolume(A4)    ;Get new global volume.
  779.         Bra    .NextTune        ;Go load and play the next song.
  780.  
  781. .CheckIter    Move.B    DTIterDoneSig(A4),D1    ;Get iter-done sig bit #.
  782.         BTst    D1,D0            ;Iteration or volume fade done?
  783.         Beq    .WaitLoop        ;Nope, go back to sleep.
  784.  
  785.         Tst.B    FadingFlag(A4)        ;Am I waiting for a fade to complete?
  786.         Bne    .NextTune        ;Yup, so go on to next song.
  787.  
  788.         Move.B    dtl_IterationsToGo(A6),D1 ;No, get iterations left to play.
  789.         Cmp.B    #1,dtl_IterationsToGo(A6) ;Started last iteration?
  790.         Bgt    .WaitLoop        ;No, go back to sleep.
  791.  
  792. ; Now song is on last iteration, so start a gobal volume fade.  But, since
  793. ; the user may have changed the global volume while I was asleep, I must
  794. ; grab it and use it to reset the global volume after the volume fade has
  795. ; completed...
  796.  
  797.         MoveQ    #0,D0
  798.         Move.B    dtl_GlobalVolume(A6),JukeVolume(A4) ;Save global volume.
  799.  
  800.         MoveQ    #0,D0            ;Fade to 0 volume.
  801.         SYS    FadeGlobalVolume    ;Start the fade.
  802.         St    FadingFlag(A4)        ;Indicate I'm waiting for fade now.
  803.         Bra    .WaitLoop        ;Go back to sleep.
  804.  
  805. ;-------------------------------
  806. ; Time to go to the next song in the pointer array. I am about to unload the
  807. ; currently loaded module.  Before I do this, I must tell DES-Tracker not to
  808. ; signal me when a module is unloaded.  Otherwise, I'd then load up the next
  809. ; module, and when I go to sleep, I'll be immediately awakened with a
  810. ; MODUNLOADED event (for the previous module).  DES-Tracker will signal me
  811. ; whether I'm asleep or not, so I must inform it that I have no interest in
  812. ; unloaded modules temporarily...
  813.  
  814. .NextTune    
  815.  
  816. ; Display time that song was playing for...
  817.  
  818.         Lea    Spaces,A0
  819.         Move.L    A0,D2
  820.         MoveQ    #0,D3
  821.         Move.B    NumTimeSpaces(A4),D3
  822.         Bsr    PrintCLI
  823.  
  824.         Move.L    #PlayTimeText,D2
  825.         Move.L    #PlayTimeLen,D3
  826.         Bsr    PrintCLI
  827.  
  828.         Lea    UnitsNoColon,A2
  829.         Move.B    dtl_ElapsedHours(A6),D0
  830.         Bsr    BinToBCD
  831.         Move.B    D0,D1
  832.         Lsr.B    #4,D0
  833.         And.B    #$0F,D1
  834.         Add.B    #'0',D0
  835.         Add.B    #'0',D1
  836.         Move.B    D0,(A2)
  837.         Move.B    D1,1(A2)
  838.         Move.L    A2,D2
  839.         MoveQ    #UNoColonLen,D3
  840.         Bsr    PrintCLI
  841.  
  842.         Lea    UnitsColon,A2
  843.         MoveQ    #UColonLen,D3
  844.         Move.B    dtl_ElapsedMinutes(A6),D0
  845.         Bsr    BinToBCD
  846.         Move.B    D0,D1
  847.         Lsr.B    #4,D0
  848.         And.B    #$0F,D1
  849.         Add.B    #'0',D0
  850.         Add.B    #'0',D1
  851.         Move.B    D0,1(A2)
  852.         Move.B    D1,2(A2)
  853.         Move.L    A2,D2
  854.         Bsr    PrintCLI
  855.  
  856.         Lea    UnitsColon,A2
  857.         MoveQ    #UColonLen,D3
  858.         Move.B    dtl_ElapsedSeconds(A6),D0
  859.         Bsr    BinToBCD
  860.         Move.B    D0,D1
  861.         Lsr.B    #4,D0
  862.         And.B    #$0F,D1
  863.         Add.B    #'0',D0
  864.         Add.B    #'0',D1
  865.         Move.B    D0,1(A2)
  866.         Move.B    D1,2(A2)
  867.         Move.L    A2,D2
  868.         Bsr    PrintCLI
  869.  
  870.         Lea    UnitsColon,A2
  871.         MoveQ    #UColonLen,D3
  872.         Move.B    dtl_ElapsedJiffies(A6),D0
  873.         Bsr    BinToBCD
  874.         Move.B    D0,D1
  875.         Lsr.B    #4,D0
  876.         And.B    #$0F,D1
  877.         Add.B    #'0',D0
  878.         Add.B    #'0',D1
  879.         Move.B    D0,1(A2)
  880.         Move.B    D1,2(A2)
  881.         Move.L    A2,D2
  882.         Bsr    PrintCLI
  883.  
  884. .NextSkipTime    MoveQ    #0,D0
  885.         Move.B    DTPlayDoneSig(A4),D0    ;Get play-done sig bit #.
  886.         MoveQ    #0,D1        ;Clear event bits for this signal so I
  887.         SYS    AddStatusSignal    ;don't get signalled for UnloadModule().
  888.  
  889.         SYS    UnloadModule        ;Unload current module.
  890.  
  891. ; Now I can reaffirm my interest in unloaded modules and finished play sequences...
  892.  
  893.         MoveQ    #0,D0
  894.         Move.B    DTPlayDoneSig(A4),D0    ;Get play-done sig bit # again.
  895.         Move.W    #SEF_FINISH|SEF_MODUNLOADED,D1    ;Restore the
  896.         SYS    AddStatusSignal            ; event bits.
  897.  
  898. ; Control is passed directly to this point if an error occurred while the song
  899. ; was being loaded...
  900.  
  901. .SkipSong    MoveQ    #0,D0
  902.         Move.B    JukeVolume(A4),D0    ;Get jukebox volume setting.
  903.         SYS    SetGlobalVolume        ;Reset global volume.
  904.  
  905.         AddQ.W    #1,CurSongNum(A4)    ;Increment song number.
  906.         Move.W    CurSongNum(A4),D0
  907.         Cmp.W    NumOfFiles(A4),D0    ;Played all songs?
  908.         Blt    .PlayLoop        ;Nope, go load next song.
  909.  
  910. ; At this point, all songs have been played.  It's time to go.
  911.  
  912. .Done        MoveQ    #0,D0            ;Return success code.
  913.  
  914. .Leave        Rts                ;Leave.
  915.  
  916. .Error        MoveQ    #-1,D0            ;Return error code.
  917.         Bra    .Leave            ;And leave.
  918.  
  919. ;---------------------------------------------------------------
  920. ; LoadSong routine.  Called by PlaySongs, this routine attempts to load up
  921. ; the next song in the song list.  It also resets the WaitSignals variable
  922. ; for me, as well as a few other flags.
  923. ;
  924. ;   Input: A5 = Ptr to song filename pointer array.
  925. ;       CurSongNum(A4) = number of the song to load (index into ptr array).
  926. ;
  927. ;  Output: D0 = 0  if song loaded successfully.
  928. ;        1  if song couldn't be loaded (so go on to the next song).
  929. ;        -1 if the library has been locked (abort the jukebox).
  930. ;
  931. ; Trashes: D1,D2,D3,A0,A1,A2,A6
  932. ;
  933.  
  934. LoadSong    Move.L    #SIGBREAKF_CTRL_C|SIGBREAKF_CTRL_F,D0    ;CTRL-C & CTRL_F.
  935.         Move.B    DTPlayDoneSig(A4),D1    ;Always wait for play-done.
  936.         BSet    D1,D0
  937.         Move.L    D0,WaitSignals(A4)    ;Store signal bits to wait for.
  938.  
  939.         Clr.B    FadingFlag(A4)        ;Reset "Fade Song" flag.
  940.  
  941.         Move.L    DTBase(A4),A6        ;Get DES-Tracker base.
  942.         Move.W    CurSongNum(A4),D0    ;Get current song number to load.
  943.         Add.W    D0,D0            ;Make long index out of it.
  944.         Add.W    D0,D0
  945.         Move.L    0(A5,D0.W),A0        ;Extract ptr to song's filename.
  946.  
  947.         Move.L    A0,A2            ;Save pointer in A2 for a bit.
  948.         Move.L    #LoadingText,D2        ;Print "Loading "
  949.         Bsr    PrintN2Text
  950.         Move.L    A2,D2            ; followed by song filename
  951.         Bsr    PrintN2Text
  952.         Move.L    #XtraLoadText,D2    ; followed by carriage return.
  953.         Bsr    PrintN2Text
  954.  
  955.         Move.L    A2,A0            ;Get filename ptr back in A0.
  956.         SYS    LoadModule        ;Attempt to load the module.
  957.         Tst.L    D0            ;Error loading module?
  958.         Bpl    .Done            ;Nope, everything's peachy.
  959.  
  960.         Cmp.W    #DE_INSUFFICIENT_MEMORY,D0 ;Yup, not enough memory?
  961.         Bne    .E1            ;Nope, that's not why.
  962.         Move.L    #NoMemText,D2        ;Yes, say "Not enough mem".
  963.         Move.L    #NoMemLen,D3
  964. .PErr        Bsr    PrintCLI
  965.         Bra    .Error            ;And go on to the next song.
  966.  
  967. .E1        Cmp.W    #DE_FILE_LOAD_ERROR,D0    ;Couldn't find the file?
  968.         Bne    .E2            ;Nope, that's not why, either.
  969.         Move.L    #NotFoundText,D2    ;Yup, say "File not found".
  970.         Move.L    #NotFoundLen,D3
  971.         Bra    .PErr            ;And go on to the next song.
  972.  
  973. .E2        Cmp.W    #DE_UNKNOWN_FORMAT,D0    ;Hmm... unknown module format?
  974.         Bne    .E3            ;Damn, that's not it either.
  975.         Move.L    #BadFormatText,D2    ;Yup, say "Crappy file format".
  976.         Move.L    #BadFormatLen,D3
  977.         Bra    .PErr            ;And go on to the next song.
  978.  
  979. .E3        Move.L    #LibOwnedText,D2    ;Must be library locked.
  980.         Bsr    PrintNicely        ;So say so.
  981.         Bra    .Error            ;If lib is locked, I must abort.
  982.  
  983. .Done        MoveQ    #0,D0            ;Song loaded OK.
  984.  
  985. .Leave        Rts                ;Back we go.
  986.  
  987. .Error        LOADLIB    SYS            ;SYS_Base in A6.
  988.         Move.L    TaskPointer(A4),A0    ;If song didn't load
  989.         Move.L    #SIGBREAKF_CTRL_F,D0    ; then clear any CTRL-F signal
  990.         Not.L    D0            ; I may have received so that
  991.         SYS    Forbid            ; I don't wind up skipping the
  992.         And.L    TC_SIGRECVD(A0),D0    ; *next* song I load.
  993.         Move.L    D0,TC_SIGRECVD(A0)    ;Store updated signal bits.
  994.         SYS    Permit            ;Allow multi-tasking once again.
  995.  
  996.         MoveQ    #1,D0            ;Couldn't load song. Go to next one.
  997.         Bra    .Leave
  998.  
  999. ;---------------------------------------------------------------
  1000. ; Random routine.  I originally got this algorithm from a Dr Dobbs journal,
  1001. ; but the author's algorithm was called r235 (or some wierd number).  Also,
  1002. ; his sample code had a *VERY SERIOUS* flaw in it that I can't believe he
  1003. ; didn't notice.  I modified the algorithm to come up with the r256 algorithm
  1004. ; which is more efficient than the r235 version because mine doesn't require
  1005. ; bounds checking on the table index.  Also, this particular version of r256
  1006. ; has been streamlined since it only needs to return 16 rather than 32 bit
  1007. ; values.  The RandIndex variable always holds the index multiplied by 2 (since
  1008. ; the table is made of up of word elements) so that I don't have to keep
  1009. ; doubling it before I use it (that's why I add #103*2 instead of just #103).
  1010. ;
  1011. ;   Input: Nothing, but RandTable must be initialized.
  1012. ;
  1013. ;  Output: D0.W = A pseudo random number.
  1014. ;
  1015. ; Trashes: Nothing.
  1016. ;
  1017.  
  1018. Random        Move.W    D1,-(Sp)        ;   Save D1.
  1019.         Move.W    RandIndex(A4),D0    ;Get current table word index.
  1020.         Move.W    RandTable(A4,D0.W),D1    ;D1 = RandTable[D0]
  1021.         Add.W    #103*2,D0        ;Add prime number to word index.
  1022.         And.W    #$1FF,D0        ;Keep index within table bounds.
  1023.         Move.W    D0,RandIndex(A4)    ;Store updated index.
  1024.         Eor.W    D1,RandTable(A4,D0.W)    ;Modify value at new index with D1.
  1025.         Move.W    RandTable(A4,D0.W),D0    ;Return modified value in D0.
  1026.         Move.W    (Sp)+,D1        ;   Restore D1.
  1027.  
  1028.         Rts                ;And leave.
  1029.  
  1030. ;---------------------------------------------------------------
  1031. ; VerifyPath routine.  Takes a string which might be either a pathname or a
  1032. ; filespec, tries to get a lock on it, and determines whether the string
  1033. ; is a pathname, filespec, or garbage.  I save a lot of registers in this
  1034. ; routine because I just don't trust AmigaDOS (who would?).
  1035. ;
  1036. ;   Input: A0 = Pathname or filespec string (NULL-Terminated).
  1037. ;
  1038. ;  Output: D0 =  0 if string is a filespec.
  1039. ;        >0 if string is a pathname.
  1040. ;        <0 if string is bloody nonsense.
  1041. ;
  1042. ; Trashes: Nothing.
  1043. ;
  1044. VerifyPath    MoveM.L    D1-D7/A0-A3/A5/A6,-(Sp)    ;Speed's not important here. Play it safe.
  1045.  
  1046.         MoveQ    #-1,D6            ;Assume user will type nonsense. :)
  1047.  
  1048.         Move.L    DosBase(A4),A6        ;Get DOS_Base.
  1049.         Move.L    A0,D1            ;Ptr to string in D1.
  1050.         MoveQ    #-2,D2            ;Read only mode for lock.
  1051.         SYS    Lock            ;Attempt to get a lock.
  1052.         Move.L    D0,LockPointer(A4)    ;Save ptr to the lock.
  1053.         Beq    .Leave            ;Couldn't get a lock. Error.
  1054.  
  1055.         Move.L    D0,D7            ;Cache lock pointer in D7.
  1056.         Move.L    D7,D1            ;Put it back in D1.
  1057.         Move.L    MyFileInfoBlock(A4),A0    ;Get ptr to FileInfoBlock.
  1058.         Move.L    A0,D2            ;DOS wants it in D2.
  1059.         SYS    Examine            ;Fill out file info block.
  1060.         Tst.L    D0            ;Was the path/file found?
  1061.         Beq    .Leave            ;Apparently not.
  1062.  
  1063.         Move.L    MyFileInfoBlock(A4),A0    ;Yes, get file info block again.
  1064.         Tst.W    fib_DirEntryType(A0)    ;Check dir entry type.
  1065.         Bmi    .IsFile            ;Negative means it's a file.
  1066.  
  1067.         AddQ.L    #1,D6            ;It's a path, inc D6.
  1068.  
  1069. .IsFile        AddQ.L    #1,D6            ;It's a file, inc D6.
  1070.  
  1071. .Leave        Move.L    D6,D0            ;Return status in D0.
  1072.         MoveM.L    (Sp)+,D1-D7/A0-A3/A5/A6    ;Restore regs.
  1073.         Rts                ;And leave.
  1074.  
  1075. ;---------------------------------------------------------------
  1076. ; AllocFNameBuffer routine.  This routine simply allocates a buffer of a
  1077. ; default initial size which is used for storing filenames of songs.
  1078. ;
  1079. ;   Input: None.
  1080. ;
  1081. ;  Output: D0 = 0  if allocation was successful.
  1082. ;        -1 if allocation failed.
  1083. ;
  1084. ; Trashes: D1,A0,A1,A6
  1085. ;
  1086.  
  1087. DEF_BUF_SIZE    = 512    ;initial buffer size.
  1088.  
  1089. AllocFNameBuffer
  1090.         LOADLIB    SYS            ;Get SYS_Base.
  1091.         Move.L    #DEF_BUF_SIZE,D0    ;Buffer size in D0.
  1092.         Move.L    #MEMF_CLEAR,D1        ;Clear mem for me, please.
  1093.         SYS    AllocMem        ;Attempt to allcate memory.
  1094.         Move.L    D0,FilenameBufAddr(A4)    ;Save ptr to buffer memory.
  1095.         Beq    .Error            ;If 0, then allocation failed.
  1096.  
  1097.         Move.L    #DEF_BUF_SIZE,FilenameBufLen(A4) ;Remember buffer size.
  1098.         Move.L    #0,FilenameBufIndex(A4)    ;Initialize buffer index.
  1099.  
  1100.         MoveQ    #0,D0            ;Return with success code.
  1101. .Leave        Rts                ;Leave.
  1102.  
  1103. .Error        MoveQ    #-1,D0            ;Return with error code.
  1104.         Bra    .Leave            ;Leave.
  1105.  
  1106. ;---------------------------------------------------------------
  1107. ; AddFNameToBuffer routine.  This routine copies the specified NULL-terminated
  1108. ; string into the filenames buffer.  If there is not enough room in the buffer
  1109. ; to hold the filename, then a larger buffer is created and the old buffer
  1110. ; is copied over to the new buffer after which the old buffer is killed.
  1111. ;
  1112. ;   Input: A3 = Pointer to NULL-terminated filename to add to buffer.
  1113. ;
  1114. ;  Output: D0 = 0  if filename was successfully added to the buffer.
  1115. ;        -1 if an error occurred while trying to create a larger buffer.
  1116. ;
  1117. ; Trashes: D1,D5,A0,A1,A3,A6
  1118. ;
  1119.  
  1120. BUF_INC_SIZE    = 256    ;Amount to enlarge buffer by if filename won't fit in it.
  1121.  
  1122. AddFNameToBuffer
  1123.         LOADLIB    SYS            ;Get SYS_Base.
  1124.  
  1125.         Move.L    A3,A1            ;Count length of filename first.
  1126.         MoveQ    #0,D0            ;D0 will hold length of filename.
  1127. .LenLoop    AddQ    #1,D0            ; (length includes NULL).
  1128.         Tst.B    (A1)+
  1129.         Bne    .LenLoop
  1130.  
  1131. ;See if this filename will fit in buffer...
  1132.  
  1133.         Move.L    FilenameBufLen(A4),D1    ;Get length of filenames buffer.
  1134.         Sub.L    FilenameBufIndex(A4),D1    ;Subtract current buffer index.
  1135.         Cmp.L    D1,D0            ;Will filename fit?
  1136.         Blt    .StoreFilename        ;Yup, go copy it in.
  1137.  
  1138. ; Filename doesn't fit in the buffer, so I must enlarge the buffer.  The
  1139. ; filenames buffer is enlarged by BUF_INC_SIZE bytes at a time...
  1140.  
  1141.         Move.L    FilenameBufLen(A4),D5    ;Get length of "old" buffer.
  1142.         Add.L    #BUF_INC_SIZE,D5    ;Calculate new length.
  1143.         Move.L    D5,D0            ;New length in D0.
  1144.         Move.L    #MEMF_CLEAR,D1        ;Clear mem for me, please.
  1145.         SYS    AllocMem        ;Attempt to allocate new buffer.
  1146.         Tst.L    D0            ;Error?
  1147.         Beq    .Error            ;Yup, allocate failed.
  1148.  
  1149. ; Now copy the contents of the old buffer to the new buffer...
  1150.  
  1151.         Move.L    FilenameBufAddr(A4),A0    ;A0 pts to old buffer.
  1152.         Move.L    D0,A1            ;A1 pts to new buffer.
  1153.         Move.L    FilenameBufLen(A4),D1    ;D1 = length of old buffer.
  1154. .CopyBuf    Move.B    (A0)+,(A1)+        ;Copy a byte from old to new.
  1155.         SubQ.L    #1,D1
  1156.         Bgt    .CopyBuf        ;Loop D1 times.
  1157.  
  1158. ; Now deallocate the old buffer...
  1159.  
  1160.         Move.L    D0,-(Sp)        ;Save ptr to new buffer.
  1161.         Move.L    FilenameBufAddr(A4),A1    ;A1 = ptr to old buffer.
  1162.         Move.L    FilenameBufLen(A4),D0    ;D0 = Length of old buffer.
  1163.         SYS    FreeMem            ;Free up the old buffer memory.
  1164.         Move.L    (Sp)+,D0        ;Restore new buffer ptr.
  1165.  
  1166. ; Now update variables for the new buffer...
  1167.  
  1168.         Move.L    D0,FilenameBufAddr(A4)    ;Store ptr to new buffer.
  1169.         Move.L    D5,FilenameBufLen(A4)    ;Store length of new buffer.
  1170.  
  1171. ; Now copy the filename to the filenames buffer...
  1172.  
  1173. .StoreFilename    Move.L    FilenameBufAddr(A4),A0    ;A0 = ptr to filenames buffer.
  1174.         Move.L    FilenameBufIndex(A4),D0    ;D0 = buffer index.
  1175. .CopyNameLoop    Move.B    (A3)+,0(A0,D0.L)    ;Copy byte into buffer.
  1176.         Beq    .CopyDone        ;Stop copying when NULL copied.
  1177.         AddQ.L    #1,D0            ;Inc buffer index.
  1178.         Bra    .CopyNameLoop        ;Copy rest of string into buffer.
  1179.  
  1180. .CopyDone    AddQ.L    #1,D0            ;Inc index for NULL.
  1181.         Move.L    D0,FilenameBufIndex(A4)    ;Store updated buffer index.
  1182.  
  1183.         MoveQ    #0,D0            ;Return with success code.
  1184. .Leave        Rts
  1185.  
  1186. .Error        MoveQ    #-1,D0            ;Return with error code.
  1187.         Bra    .Leave
  1188.  
  1189. ;---------------------------------------------------------------
  1190. ; GetFileSpec routine.  Extracts a file specification from the command line
  1191. ; args.  Stores the extracted filespec in FilenameString[].
  1192. ;
  1193. ;   Input: A5 = pointer to command line argstring.
  1194. ;
  1195. ;  Output: FilenameString[] holds the extracted filespec.
  1196. ;       A5 pts to new current position in argstring.
  1197. ;       D0 = 0  if FilenameString[] holds a valid string.
  1198. ;        -1 if no filespec was specified in the argstring.
  1199. ;
  1200. ; Trashes: A0
  1201. ;
  1202.  
  1203. GetFilespec    Lea FilenameString(A4),A0    ;A0 = ptr to dest string buffer.
  1204.         St    ShuffleFlag(A4)        ;Assume I'll be shuffling songs.
  1205.  
  1206. .Skip        Move.B    (A5),D0        ;Get char from argstring.
  1207.         Cmp.B    #DQUOTE,D0    ;Is it a double quote?
  1208.         Beq.S    .DoQuote    ;Yup, do special quote handling.
  1209.         Cmp.B    #"?",D0        ;Is it a ?
  1210.         Beq    .NoFileSpec    ;Yup, treat as if no filespec specified.
  1211.         Cmp.B    #"-",D0        ;Is it a command prefix character?
  1212.         Beq    .ProcessCmd    ;Yup. Go process command.
  1213.         Cmp.B    #" ",D0        ;Is it a space character?
  1214.         Bgt    .Copy        ;No, ASCII value is greater than space char.
  1215.         Cmp.B    #TAB,D0        ;Is it a tab?
  1216.         Beq    .Skip        ;Yup, ignore it.
  1217.         Cmp.B    #LF,D0        ;Have I reached the end of the argstring?
  1218.         Beq    .NoFileSpec    ;Yup, no filespec was specified.
  1219.  
  1220.         AddQ    #1,A5        ;No, so ignore char and get another.
  1221.         Bra    .Skip
  1222.  
  1223. .DoQuote    AddQ    #1,A5        ;Skip past the double quote character.
  1224.         Move.B    (A5),D0        ;Get char from argstring.
  1225.         Cmp.B    #LF,D0        ;Reached EOL yet?
  1226.         Beq    .Done        ;Yup, no close quote, but that's OK.
  1227.         Cmp.B    #DQUOTE,D0    ;Is it a (close) quote?
  1228.         Beq    .EndQuote    ;Yup, fix up argstring ptr and leave.
  1229.         Move.B    D0,(A0)+    ;Nope, extract this character.
  1230.         Bra    .DoQuote    ;And go get another.
  1231.  
  1232. .EndQuote    AddQ    #1,A5        ;Skip past the close quote.
  1233.         Bra    .Done        ;And leave.
  1234.  
  1235. .Copy        Move.B    (A5)+,(A0)+    ;Copy a character from argstring into buffer.
  1236.         Cmp.B    #" ",(A5)    ;Is next char a space?
  1237.         Beq.S    .Done        ;Yup, NULL-terminate buffer and leave.
  1238.         Cmp.B    #TAB,(A5)    ;Is next char a tab?
  1239.         Beq.S    .Done        ;Yup, all done.
  1240.         Cmp.B    #LF,(A5)    ;Nope, reached EOL yet?
  1241.         Bne.S    .Copy        ;Nope, go copy next character.
  1242.  
  1243. .Done        Clr.B    (A0)        ;NULL-terminate string in buffer.
  1244.         MoveQ    #0,D0        ;Indicate valid string in buffer.
  1245.  
  1246. .Leave        Rts            ;And leave.
  1247.  
  1248. .NoFileSpec    MoveQ    #-1,D0        ;Indicate no filespec was given.
  1249.         Bra    .Leave        ;and leave.
  1250.  
  1251. .ProcessCmd    AddQ    #1,A5        ;Skip command prefix character.
  1252.         Move.B    (A5)+,D0    ;Get command character.
  1253.  
  1254.         Or.B    #$20,D0        ;Make sure char is lower-case.
  1255.         Cmp.B    #"n",D0        ;"No Shuffle" command?
  1256.         Bne    .Skip        ;Nope. "-n" is the only command.
  1257.  
  1258.         Clr.B    ShuffleFlag(A4)    ;Yes, do not shuffle selections.
  1259.         Bra    .Skip        ;Go try to find a filespec.
  1260.  
  1261. ;---------------------------------------------------------------
  1262. ; Initialize routine.  Opens necessary libraries, initializes variables and
  1263. ; tables, etc.
  1264. ;
  1265. ;   Input: A4 = Pointer to allocated program variable space.
  1266. ;
  1267. ;  Output: D0 = 0  if initialization was successful.
  1268. ;        -1 if an error occurred.
  1269. ;
  1270. ; Trashes: D1,D2,D3,A0,A1,A2,A6
  1271. ;
  1272.  
  1273. Initialize
  1274.  
  1275. ; Create Random number table for r256 pseudo-random generator.  The table is
  1276. ; filled with pseudo-random values using a less than efficient (and slow)
  1277. ; algorithm.  I use the current raster beam coordinates as a pseudo-random seed
  1278. ; for this bit of code.  The pseudo-random number generator routine that this
  1279. ; initialization is for is much faster than this rather brutal loop...
  1280.  
  1281.         Lea    RandTable(A4),A0    ;Fetch ptr to prime-index table.
  1282.         Move.W    CHIP+vhposr,D1        ;Prep seed (D1) with cur. raster pos.
  1283.         Move.L    #256-1,D0        ;For all table elements...
  1284.         Add.W    #33247,D1        ;Add something prime to initial seed.
  1285.  
  1286. .MakeRand    MulU    #61141,D1        ;Multiply by a prime #.
  1287.         Swap    D1            ;Use low word of result.
  1288.         Add.W    #33247,D1        ;Add a prime number to low word.
  1289.         Move.W    D1,(A0)+        ;And store result in table.
  1290.         DBra    D0,.MakeRand        ;Go build another table element.
  1291.  
  1292. ; Now open necessary libraries...
  1293.  
  1294.         Lea    DosName,A1        ;Open dos.library.
  1295.         MoveQ.L    #0,D0
  1296.         SYS    OpenLibrary
  1297.         Move.L    D0,DosBase(A4)
  1298.         Beq    .Error
  1299.  
  1300. .1        Move.L    D0,A6            ;Dos_Base in A6.
  1301.         SYS    Output            ;Get standard output handle.
  1302.         Move.L    D0,OutputHandle(A4)    ;Save bptr to it.
  1303.  
  1304.         Move.L    #HelloText,D2        ;Say hello!
  1305.         Bsr    PrintNicely        ;Nicely 'cause you can pause it. :)
  1306.  
  1307.         LOADLIB    SYS            ;SYS_Base in A6.
  1308.         Lea    DTLName,A1        ;Get ptr to "destracker.library"
  1309.         MoveQ    #3,D0            ;Library version 3.0 minimum.
  1310.         SYS    OpenLibrary        ;Open DES-Tracker library.
  1311.         Move.L    D0,DTBase(A4)        ;Save ptr to it.
  1312.         Bne    .MakeInfoBlock
  1313.  
  1314.         Move.L    #NoLibOpenText,D2    ;Couldn't open DES-Tracker.
  1315. .PrintGo    Bsr    PrintNicely
  1316.         Bra    .Error            ;Oh, puh-shaw.
  1317.  
  1318. ; Allocate a file info block structure...
  1319.  
  1320. .MakeInfoBlock    LOADLIB    SYS            ;SYS_Base in A6.
  1321.         Move.L    #fib_SIZEOF,D0        ;Size of the structure.
  1322.         Move.L    #MEMF_CLEAR,D1        ;Clear it out for me, please.
  1323.         SYS    AllocMem        ;Attempt to allocate.
  1324.         Move.L    D0,MyFileInfoBlock(A4)    ;Did it work?
  1325.         Bne    .GetDTSigBits        ;Yup, continue.
  1326.  
  1327.         Move.L    #InsuffMemText,D2    ;Nope, insufficient memory.
  1328.         Bra    .PrintGo        ;Tell user and abort.
  1329.  
  1330. ; Allocate signal bits I'll need to use with DES-Tracker...
  1331.  
  1332. .GetDTSigBits    MoveQ    #-1,D0            ;Give me any available signal bit.
  1333.         Move.B    D0,DTPlayDoneSig(A4)
  1334.         Move.B    D0,DTIterDoneSig(A4)
  1335.  
  1336.         SYS    AllocSignal        ;Allocate a signal bit.
  1337.         Move.B    D0,DTPlayDoneSig(A4)    ;Store number of the bit.
  1338.         Bpl    .2            ;I got a bit number.
  1339.  
  1340. .NoSig        Move.L    #NoDTSigText,D2        ;Couldn't allocate signal bit.
  1341.         Bra    .PrintGo        ;Print error and abort.
  1342.  
  1343. .2        MoveQ    #-1,D0            ;Allocate another signal bit.
  1344.         SYS    AllocSignal
  1345.         Move.B    D0,DTIterDoneSig(A4)    ;Store its bit number.
  1346.         Bmi    .NoSig            ;Didn't get a bit. Damn.
  1347.  
  1348.         Move.L    DTBase(A4),A6        ;DES-Tracker base in A6.
  1349.  
  1350.         SYS    UnloadModule        ;Unload any loaded module.
  1351.  
  1352.         Sub.L    A0,A0            ;Clear any existing search paths.
  1353.         SYS    SetModulePath
  1354.  
  1355.         MoveQ    #0,D0            ;Now grab current global volume
  1356.         Move.B    dtl_GlobalVolume(A6),JukeVolume(A4)    ;and save it.
  1357.         MoveQ    #10,D0            ;Set volume fade rate to
  1358.         SYS    SetVolumeFadeRate    ; nice and slow.
  1359.  
  1360.         LOADLIB    SYS            ;SYS_Base in A6.
  1361.         Sub.L    A0,A0            ;NULL in A0.
  1362.         SYS    FindTask        ;Get pointer to my TCB structure.
  1363.         Move.L    D0,TaskPointer(A4)    ;Save pointer to it.
  1364.  
  1365.         MoveQ    #0,D0            ;Indicate successful init.
  1366.  
  1367. .Leave        Rts                ;And leave.
  1368.  
  1369. .Error        MoveQ    #-1,D0            ;Indicate bad init.
  1370.         Bra    .Leave
  1371.  
  1372. ;---------------------------------------------------------------
  1373. ; DeInitialize routine.  Frees up all used resources.  The Initialize routine
  1374. ; must have been previously called. :)
  1375. ;
  1376. ;   Input: A4 = Pointer to allocated program variable space.
  1377. ;
  1378. ;  Output: Nothing.
  1379. ;
  1380. ; Trashes: D0,D1,D2,D3,A0,A1,A2,A6
  1381. ;
  1382.  
  1383. DeInitialize    Move.L    DosBase(A4),D0
  1384.         Beq    .1
  1385.         Move.L    D0,A6
  1386.  
  1387.         Move.L    LockPointer(A4),D1    ;Get Lock ptr in D1.
  1388.         Beq    .1            ;If 0.L then it doesn't exist.
  1389.         SYS    UnLock            ;Get rid of the lock.
  1390.  
  1391. .1        Move.L    DTBase(A4),D0        ;DES-Tracker base in D0.
  1392.         Beq    .2            ;If 0, then it didn't open.
  1393.         Move.L    D0,A6            ;It is open, put it in A6.
  1394.         SYS    UnloadModule        ;Unload current module.
  1395.         SYS    ResetDefaults        ;Reset library defaults.
  1396.  
  1397.         Move.L    A6,A1            ;Put library base in A1.
  1398.         LOADLIB    SYS            ;Get SYS_Base in A6.
  1399.         SYS    CloseLibrary        ;Close DES-Tracker library.
  1400.  
  1401. .2        LOADLIB    SYS            ;Get SYS_Base in A6.
  1402.         MoveQ    #0,D0
  1403.         Move.B    DTPlayDoneSig(A4),D0    ;Get signal bit I allocated.
  1404.         Bmi    .3            ;The allocation had failed.
  1405.  
  1406.         SYS    FreeSignal        ;Free up the signal.
  1407.  
  1408. .3        MoveQ    #0,D0
  1409.         Move.B    DTIterDoneSig(A4),D0    ;Get other signal bit.
  1410.         Bmi    .4            ;It didn't allocate.
  1411.  
  1412.         SYS    FreeSignal        ;Free up the signal.
  1413.  
  1414. .4        Move.L    MyFileInfoBlock(A4),D0    ;Get ptr to file info block struct.
  1415.         Beq    .5            ;It didn't get alloc'ed.
  1416.         Move.L    D0,A1
  1417.         Move.L    #fib_SIZEOF,D0        ;Size of the structure.
  1418.         SYS    FreeMem            ;Free it.
  1419.  
  1420. .5        Move.L    FilenameBufAddr(A4),D0    ;Get ptr to filename buffer mem.
  1421.         Beq    .6            ;If 0, it doesn't exist.
  1422.         Move.L    D0,A1            ;It exists.
  1423.         Move.L    FilenameBufLen(A4),D0    ;Get length of the buffer.
  1424.         SYS    FreeMem            ;Free up the buffer memory.
  1425.  
  1426. .6        Move.L    PtrTableAddr(A4),D0    ;Get addr of ptr table mem.
  1427.         Beq    .7            ;If 0, then it doesn't exist.
  1428.         Move.L    D0,A1            ;It exists.
  1429.         Move.L    PtrTableLen(A4),D0    ;Get its length.
  1430.         SYS    FreeMem            ;Free up table memory.
  1431.  
  1432. .7        Move.L    DosBase(A4),D0        ;Get pointer to DOS_Base.
  1433.         Beq    .8            ;It didn't open (?)
  1434.         Move.L    D0,A1            ;It is open,
  1435.         SYS    CloseLibrary        ; so close it.
  1436.  
  1437. .8        Move.L    A4,A1            ;Release program variable space.
  1438.         Move.L    #MJUKE_SIZE,D0
  1439.         LOADLIB    SYS
  1440.         SYS    FreeMem            ;No more program variables.
  1441.  
  1442.         Rts                ;All done.
  1443.  
  1444. ;---------------------------------------------------------------
  1445. ; BinToBCD routine.  Converts a binary value (0..99) to a packed BCD value.
  1446. ;
  1447. ;  Input: D0 = Binary value to convert.
  1448. ;
  1449. ; Output: D0.B = The value as a packed binary-coded decimal.
  1450. ;
  1451.  
  1452. BinToBCD    MoveQ    #0,D1
  1453.         Move.B    D0,D1
  1454.         Move.L    D1,D0
  1455.  
  1456.         DivU    #10,D0
  1457.         Asl.B    #4,D0
  1458.         Move.B    D0,D1
  1459.         Swap    D0
  1460.         Or.B    D1,D0
  1461.  
  1462.         Rts
  1463.  
  1464. ;---------------------------------------------------------------
  1465. ; PrintCLI routine.  Prints a text string to the standard output.
  1466. ;
  1467. ;   Input: D2 = Pointer to the text string to print (NOT NULL-terminated).
  1468. ;       D3 = Length of the text string.
  1469. ;
  1470. ;  Output: Nothing.
  1471. ;
  1472. ; Trashes: D0,D1,D2,D3,A0,A1,A2
  1473. ;
  1474.  
  1475. PrintCLI    Move.L    A6,-(Sp)
  1476.         Move.L    OutputHandle(A4),D1
  1477.         Move.L    DosBase(A4),A6
  1478.         SYS    Write
  1479.         Move.L    (Sp)+,A6
  1480.         Rts
  1481.  
  1482. ;---------------------------------------------------------------
  1483. ; PrintNText routine. Prints a NULL-terminated string to the standard output.
  1484. ; Automatically appends a linefeed character to the end of the text output.
  1485. ;
  1486. ;   Input: D2 = Pointer to the NULL-terminated text string to print.
  1487. ;
  1488. ;  Output: Nothing.
  1489. ;
  1490. ; Trashes: D0,D1,D2,D3,A0,A1,A2
  1491. ;
  1492.  
  1493. PrintNText    Bsr    PrintN2Text
  1494.  
  1495.         Move.L    #LineFeed,D2
  1496.         MoveQ    #1,D3
  1497.         Bsr    PrintCLI
  1498.         Rts
  1499.  
  1500. ;---------------------------------------------------------------
  1501. ; PrintN2Text routine.  Prints a NULL-terminated string to the standard output,
  1502. ; just like PrintNText above, but does not output a linefeed at the end.
  1503. ;
  1504. ;   Input: D2 = Pointer to the NULL-terminated text string to print.
  1505. ;
  1506. ;  Output: Nothing.
  1507. ;
  1508. ; Trashes: D0,D1,D2,D3,A0,A1,A2
  1509. ;
  1510.  
  1511. PrintN2Text    MoveQ    #0,D3
  1512.         Move.L    D2,A0
  1513. .1        AddQ    #1,D3
  1514.         Tst.B    (A0)+
  1515.         Bne    .1
  1516.         SubQ    #1,D3
  1517.         Bsr    PrintCLI
  1518.         Rts
  1519.  
  1520. ;---------------------------------------------------------------
  1521. ; PrintNicely routine.  Prints a NULL-Terminated text string one line at a time
  1522. ; (using the PrintCLI routine above) so that the output can be paused by
  1523. ; pressing a key.  It is important to remember that the text string passed to
  1524. ; this routine MUST have a linefeed character immediately preceding the 
  1525. ; terminating NULL.
  1526. ;
  1527. ;   Input: D2 = Pointer to the text string to print (LF & NULL-terminated).
  1528. ;
  1529. ;  Output: Nothing.
  1530. ;
  1531. ; Trashes: D0,D1,D2,D3,A0,A1,A2
  1532. ;
  1533.  
  1534. PrintNicely    MoveM.L    A3/A5,-(Sp)
  1535.         Move.L    D2,A5
  1536.  
  1537. .NextLine    Move.L    A5,A3
  1538.         MoveQ    #0,D3
  1539. .CountChars    AddQ    #1,D3
  1540.         Move.B    (A3)+,D0
  1541.         Beq    .Done
  1542.         Cmp.B    #LF,D0
  1543.         Bne    .CountChars
  1544.  
  1545.         Move.L    A5,D2
  1546.         Move.L    A3,A5
  1547.         Bsr    PrintCLI
  1548.         Bra    .NextLine
  1549.  
  1550. .Done        MoveM.L    (Sp)+,A3/A5
  1551.         Rts
  1552.  
  1553. ;===============================================================
  1554. ; DATA segment.  Consists of static text strings...
  1555.  
  1556.         DATA
  1557.         Even
  1558.  
  1559. ; Run-time messages and substrings...
  1560.  
  1561. CFilesText    Dc.B    "Collecting filenames...",ESC,CEOL,NULL
  1562.  
  1563. LoadingText    Dc.B    LF,'Loading "',NULL
  1564. PlayingText    Dc.B    CR,'Playing "',NULL
  1565. XtraLoadText    Dc.B    '"',ESC,CEOL,NULL
  1566. XtraPlayText    Dc.B    '"',ESC,CEOL,NULL
  1567. LineFeed    Dc.B    LF,NULL
  1568.  
  1569. Spaces        Dc.B    "                      "
  1570. PlayTimeText    Dc.B    "Play Time: ",NULL
  1571. PlayTimeLen    = *-PlayTimeText
  1572. UnitsColon    Dc.B    ":"
  1573. UnitsNoColon    Dc.B    "00"
  1574. UColonLen    = *-UnitsColon
  1575. UNoColonLen    = *-UnitsNoColon
  1576.  
  1577. ; Module load error messages...
  1578.  
  1579. NoMemText    Dc.B    "  --  Insufficient memory!",NULL
  1580. NoMemLen    = *-NoMemText
  1581. NotFoundText    Dc.B    "  --  File not found!",NULL
  1582. NotFoundLen    = *-NotFoundText
  1583. BadFormatText    Dc.B    "  --  Unrecognized module format!",NULL
  1584. BadFormatLen    = *-BadFormatText
  1585.  
  1586. ; Exit error messages...
  1587.  
  1588. JukeDoneText    Dc.B    LF,"MicroJuke is finished!",LF,LF,NULL
  1589. JukeAbortText    Dc.B    LF,"*** Jukebox aborted. ***",LF,LF,NULL
  1590. LibOwnedText    Dc.B    LF,"Library has been locked!  Aborting ...",LF,LF,NULL
  1591.  
  1592.  
  1593. ; Parsing error messages...
  1594.  
  1595. BadPathText    Dc.B    LF,"ERROR: Illegal path/file specification",LF,LF,NULL
  1596. NotScriptText    Dc.B    LF,"ERROR: Not a script file.",LF,LF,NULL
  1597. NoDTSigText    Dc.B    LF,"ERROR: Couldn't allocate signal bit!",LF,LF,NULL
  1598. InsuffMemText    Dc.B    LF,"ERROR: Insufficient memory",LF,LF,NULL
  1599. NoFilesText    Dc.B    LF,"ERROR: Path is empty",LF,LF,NULL
  1600. ReadErrText    Dc.B    LF,"ERROR: Couldn't read file",LF,LF,NULL
  1601. NoLibOpenText    Dc.B    LF,"ERROR: You need destracker.library v3.0",LF,LF,NULL
  1602.  
  1603.  
  1604. ; Title, copyright, and usage text strings...
  1605.  
  1606. HelloText    Dc.B    LF,"destracker.library Micro-Jukebox",LF
  1607.         Dc.B    "Copyright (c)1993 by Darren Schebek",LF
  1608.         Dc.B    "Version 2.0  Dec 18, 1993",LF,LF,NULL
  1609.  
  1610. ComText        Dc.B    "usage: mjuke [-n] {pathname|scriptname}",LF,LF
  1611.         Dc.B    "where: -n = Do not shuffle selections.",LF,LF
  1612. IPlayText    Dc.B    $0D,"CTRL-C aborts jukebox.",LF
  1613.         Dc.B    "CTRL-F skips to next song.",LF,LF,NULL
  1614.  
  1615.  
  1616. ; Library name strings...
  1617.  
  1618. DosName        Dc.B    "dos.library",0
  1619. DTLName        DTLIBNAME
  1620.  
  1621.         Even
  1622.  
  1623.         End
  1624.