home *** CD-ROM | disk | FTP | other *** search
/ RBBS in a Box Volume 1 #3.1 / RBBSIABOX31.cdr / fwrd / fractal.bas < prev    next >
BASIC Source File  |  1985-10-09  |  1KB  |  50 lines
  1. 5 REM Fractal program from Byte Magazine Sept. 1984 by Greg Turk
  2. 6 REM converted from AppleSoft Basic to IBM basic by Ed Schmeckpeper
  3. 10 CX = 160!: CY = 96!   ' screen parameters width/2, height/2
  4. 20 X= .50001: Y=0!
  5. 100 GOSUB 5000
  6. 110 SCREEN 1,1:COLOR 0,15' convert color command from applesoft
  7. 120 FOR I= 1 TO 10:GOSUB 4000:NEXT
  8. 140 GOSUB 6000
  9. 160 GOSUB 4000
  10. 170 A$=INKEY$:IF A$<>"" THEN 10000
  11. 180 GOTO 140
  12. 999 END
  13. 1000 REM square root of x,y
  14. 1005 T = Y
  15. 1010 S = SQR((X*X)+(Y*Y))
  16. 1020 Y = SQR(ABS((-X+S)/2))
  17. 1030 X = SQR((X+S)/2)
  18. 1040 IF T< 0 THEN X= -X
  19. 1050 RETURN
  20. 2000 REM four over l
  21. 2010 S =(LX*LX)+ (LY*LY)
  22. 2020 LX = 4 * LX/S
  23. 2030 LY = -4 *LY/S
  24. 2040 RETURN
  25. 3000 REM x,y times l
  26. 3010 TX = X: TY = Y
  27. 3020 X = (TX*LX)-(TY*LY)
  28. 3030 Y = (TX*LY)+(TY*LX)
  29. 3040 RETURN
  30. 4000 REM function of x,y
  31. 4010 GOSUB 3000
  32. 4020 X=1-X
  33. 4030 GOSUB 1000
  34. 4040 IF RND(1) <.5 THEN X=-X:Y=-Y
  35. 4050 X=1-X
  36. 4060 X=X/2:Y=Y/2
  37. 4070 RETURN
  38. 5000 REM get values
  39. 5010 KEY OFF:CLS
  40. 5020 INPUT "What is LAMBDA (LX,LY) ";LX,LY
  41. 5030 GOSUB 2000
  42. 5040 INPUT "What is SCALE FACTOR ";SC
  43. 5050 SC= 2*CX/SC
  44. 5055 CLS
  45. 5060 RETURN
  46. 6000 REM plot x,y
  47. 6010 PSET ((SC*(X-.5)+CX),(CY-(SC*Y))),1
  48. 6020 RETURN
  49. 10000 END
  50.