home *** CD-ROM | disk | FTP | other *** search
/ RBBS in a Box Volume 1 #3.1 / RBBSIABOX31.cdr / mlpc / memintel.bas < prev    next >
BASIC Source File  |  1985-08-19  |  1KB  |  50 lines
  1. 1 REM "Memory to INTEL (MCS-86) Hex Converter"
  2. 10 V$="1.0"
  3. 20 CLS
  4. 30 DEFINT A-Z
  5. 40 LOCATE 1,20
  6. 50 PRINT "ROM to Intel Hex (MCS-86) Converter ";V$
  7. 60 LOCATE 5,20
  8. 70 LINE INPUT "Enter Starting Paragraph. ";ROM$
  9. 80 ROM$="&H"+ROM$
  10. 90 SEG=VAL(ROM$)
  11. 100 DEF SEG=SEG
  12. 110 LOCATE 7,20
  13. 120 LINE INPUT "File to Contain Hex Code? ";FILE$
  14. 130 OPEN "O",#1,FILE$
  15. 140 LOCATE 9,20
  16. 150 LINE INPUT "Enter Number of Bytes . . ";NUMBYTES$
  17. 160 NUMBYTES=VAL(NUMBYTES$)
  18. 170 NUMPARAGRAPHS=NUMBYTES/16
  19. 180 LOCATE 11,20 : PRINT "Paragraphs to go . . . . ";
  20. 190 FOR J=0 TO NUMPARAGRAPHS-1
  21. 200 LOCATE 11,45
  22. 210 PRINT NUMPARAGRAPHS-(J+1)
  23. 220 PRINT #1,
  24. 230 PRINT #1,":10";
  25. 240 CKSUM=&H10
  26. 250 X=((J AND &HFF0)/16) AND &HFF
  27. 260 CKSUM=CKSUM+X
  28. 270 PRINT #1,RIGHT$("00"+HEX$(X),2);
  29. 280 X=(J AND &HF)*16
  30. 290 CKSUM=CKSUM+X
  31. 300 PRINT #1,RIGHT$("00"+HEX$(X),2);
  32. 310 PRINT #1,"00";
  33. 320 FOR I=0 TO 15
  34. 330 X=PEEK (I+(J*16))
  35. 340 PRINT #1,RIGHT$("00"+HEX$(X),2);
  36. 350 CKSUM=CKSUM+X
  37. 360 NEXT I
  38. 370 CKSUM=CKSUM AND &HEF
  39. 380 CKSUM=-CKSUM AND &HEF
  40. 390 PRINT #1,RIGHT$("00"+HEX$(CKSUM),2);
  41. 400 NEXT J
  42. 410 PRINT #1, :PRINT #1,":00000001FF"
  43. 420 CLOSE
  44. 430 LOCATE 13,20 : LINE INPUT "More ROMs to do? ";Y$
  45. 440 IF LEFT$(Y$,1)="Y" OR LEFT$(Y$,1)="y" THEN 10
  46. 450 LOCATE 15,20
  47. 460 LINE INPUT "Exit Basic? ";Y$
  48. 470 IF LEFT$(Y$,1)="Y" OR LEFT$(Y$,1)="y" THEN CLS : SYSTEM
  49. 480 END
  50.