AmigActive 13/AACD13.ISO/AACD/System/EASys/EASys!_update_481_to_482/EASys!/Programs/FileManager.rexx

OS/2 REXX Batch file | 2000-07-08 | 69KB | 3,234 lines

/*
  EASys!)  © EasySystem since 1995

  FileManager.rexx
  Full featured and fast FileManager based on RexxReqTools.

  Date:        05/2000
  Author:      Thomas Neidhardt (TNE), Deutschland, Erlangen

  InterNet:    [e-mail]

  Needs:       RexxReqTools Package by Rafael D'Halleweyn ( [e-mail] )
               and the EASys! Configuration Environment.

  Referenced by:  ${RefTable/File-Manager}

  with Options:

  -DIR <dir> starts into Directory <dir> by commandline-argument
  -Cp2Cl     (wrties all workbench selected files to T:FM_cp_clip)
  -Mv2Cl     (wrties all workbench selected files to T:FM_mv_clip)
  -CpClp     (starts EASys! Clip operation on T:FM_mv_clip or T:FM_cp_clip)
  -CopyF     ${RefTable/File-CopyServer}
  -MoveF     ${RefTable/File-MoveServer}
  -MovAs     ${RefTable/File-MoveAs}
  -SavAs     ${RefTable/File-SaveAs}
  -InfoF     ${RefTable/File-Info-Server}
  -fLink     ${RefTable/File-ScriptLink}
  -Ren_F     ${RefTable/File-RenameServer}
  -Fnote     ${RefTable/File-Comment}
  -Trash     ${RefTable/File-Trash}
  -WBst+     Adds selected Item to WBstartup
  -WBst-     Removes selected Item from WBstartup
*/

PARSE ARG UserArgs

OPTIONS RESULTS
OPTIONS FAILAT 21

CALL Init

/* ---------------------- */
Main:

ExitProg=0
wbargs=0
cliargs=0
flist=0

OptChars=6
Option=LEFT(UserArgs,OptChars)

SELECT
WHEN UserArgs="??" THEN
DO
 IF EXISTS('EASys!_bin:'Language'/fm.help') THEN ADDRESS COMMAND 'type EASys!_bin:'Language'/fm.help'
 ELSE ADDRESS COMMAND 'type EASys!_bin:english/fm.help'
 EXIT 0
END

WHEN ~(LEFT(Option,4)='-DIR'|Option='-WBst+'|Option='-WBst-'|Option='-CopyF'|Option='-MoveF'|Option='-Cp2Cl'|Option='-Mv2Cl'|Option='-CpClp'|Option='-Ren_F'|Option='-InfoF'|Option='-Fnote'|Option='-SavAs'|Option='-MovAs'|Option='-fLink'|Option='-sProg'|Option='-Trash') THEN
DO
  /* Other or no Arguments */
  CALL SelectionLoop
END

OTHERWISE
DO
  l=LENGTH(UserArgs)
  Files.1='FILES.1'
  Files.count=0

  SELECT
  WHEN UPPER(LEFT(STRIP(UserArgs,'L','"'),4))='-DIR' THEN
  DO
   ActualPath=RIGHT(UserArgs,l-5)
   ActualPath=STRIP(ActualPath,'B','"')
   UserArgs=''
   CALL SelectionLoop
   CALL ExitMe
  END

  WHEN Option='-WBst+' THEN
  DO
    addWBstart=1
    PARSE VAR UserArgs '-WBst+ 'UserArgs
    IF UserArgs='' THEN EXIT 0

    cliargs=1
    IF GetFileSelection()=0 THEN EXIT 0

    IF IsDir('SYS:StartSys/e_WB/_DIR_WBstartup')=1 THEN
     DestDir='SYS:StartSys/e_WB/_DIR_WBstartup/'
    ELSE
     DestDir='SYS:WBstartup/'

    CALL ScriptLink
    CALL ExitMe
  END

  WHEN Option='-WBst-' THEN
  DO
    PARSE VAR UserArgs '-WBst- 'UserArgs
    IF UserArgs='' THEN EXIT 0

    cliargs=1
    IF GetFileSelection()=0 THEN EXIT 0

    IF IsDir('SYS:StartSys/e_WB/_DIR_WBstartup')=1 THEN
     DestDir='SYS:StartSys/e_WB/_DIR_WBstartup/'
    ELSE
     DestDir='SYS:WBstartup/'

    DO k=1 TO Files.count
     ADDRESS COMMAND
     'delete >NIL: "'DestDir'_'FileName.k'" FORCE QUIET'
     'delete >NIL: "SYS:Tools/Commodities/_'FileName.k'" FORCE QUIET'
     'EASys!_bin:IconKill "'DestDir'_'FileName.k'.info"'
    END

    CALL ExitMe
  END

  OTHERWISE NOP
  END /* SELECT */


  IF l>OptChars+1 THEN UserArgs=RIGHT(UserArgs,l-OptChars-1)
  ELSE UserArgs=''

  SELECT
   WHEN Option='-CpClp' THEN CALL CopyClip
   WHEN WB_port=1 & (UserArgs='' | UserArgs='USERARGS') THEN
   DO
      wbargs=1
      r=GetSelectedIcons()
      IF ~(r=0) THEN CALL SetActualPath
   END

   OTHERWISE
   DO
      r=FileParser()
      IF ~(r=0) THEN CALL SetActualPath
   END
  END /* SELECT */

  SELECT
    WHEN Option='-Cp2Cl' THEN
    DO
       ADDRESS COMMAND 'delete >NIL: T:FM_mv_clip FORCE QUIET'
       CALL WriteFileList('T:FM_cp_clip')
       EXIT 0
    END

    WHEN Option='-Mv2Cl' THEN
    DO
       ADDRESS COMMAND 'delete >NIL: T:FM_cp_clip FORCE QUIET'
       CALL WriteFileList('T:FM_mv_clip')
       EXIT 0
    END

    OTHERWISE NOP
  END /* SELECT */

  IF (Files.1='' | Files.1='FILES.1') & ~(Option='-Trash') & ~(Option='-CpClp') THEN CALL FM_HelpArg

  SELECT
    WHEN Option='-CopyF' THEN
    DO
      CALL CopyStarter
      CALL ExitMe
    END

    WHEN Option='-MoveF' THEN
    DO
      CALL MoveStarter
      CALL ExitMe
    END

    WHEN Option='-CpClp' THEN
    DO
      CALL CopyClip
      CALL ExitMe
    END

    WHEN Option='-SavAs' THEN
    DO
      CALL SaveAsStarter
      CALL ExitMe
    END

    WHEN Option='-MovAs' THEN
    DO
      CALL MoveAsStarter
      CALL ExitMe
    END

    WHEN Option='-Ren_F' THEN
    DO
      AppName="EasyName  © EASys!)"
      CALL RenameIt
      CALL ExitMe
    END

    WHEN Option='-Trash' THEN
    DO
      CALL Trash
      CALL ExitMe
    END

    WHEN Option='-InfoF' THEN
    DO
      AppName="EasyInfo  © EASys!)"
      CALL FileInfo
      CALL ExitMe
    END

    WHEN Option='-Fnote' THEN
    DO
      AppName="EasyComment  © EASys!)"
      CALL FileNote
      CALL ExitMe
    END

    WHEN Option='-fLink' THEN
    DO
      CALL ScriptLink
      CALL ExitMe
    END

    WHEN Option='-sProg' THEN
    DO
      AppName="EasyLaunch  © EASys!)"
      CALL StartProg
      CALL ExitMe
    END

    OTHERWISE CALL ExitMe
  END /* SELECT */
END /* DO */
END /* SELECT */
CALL ExitMe

/* ------------------------- */
FM_HelpArg:

DO FOREVER
 r=ShowMessage('FileManager.0',,,,AppName)
 IF r=0 THEN CALL Help
 IF r=1 | r=2 THEN LEAVE
END

IF r=2 THEN CALL SelectionLoop

CALL ExitMe
RETURN

/* ---------------------- */
SelectionLoop:
/* Start with ActualPathDest as Actualpath only, when another FM is already running. */
/* reverse Path for each second opened FM */

IF ~(FM_ListPos_set=1) THEN
DO
 FM_ListPos_set=1

 FM_ListPos=GetClip('FMlistpos')
 IF FM_ListPos='' | FM_ListPos='FM_LISTPOS' THEN FM_ListPos='LEFT'

 IF FM_ListPos='LEFT' THEN CALL setclip('FMlistpos','RIGHT')
 ELSE CALL setclip('FMlistpos','LEFT')

 FM_cnt=GetClip('FMcnt')
 IF FM_cnt='' | FM_cnt='FM_CNT' THEN FM_cnt=0
 IF FM_cnt<0 THEN FM_cnt=0
 FM_cnt=FM_cnt+1
 CALL setclip('FMcnt',FM_cnt)

 IF FM_cnt > 1 THEN
 DO
  firstselection=1

  IF FM_ListPos='RIGHT' THEN
  DO
   ActualPath=MyGetENV('Flags/ActualPathDest')
   ActualPathDest=MyGetENV('Flags/ActualPath')

   ReqLEFT=ReqLE+370
   PosTags="rt_reqpos=reqpos_topleftscr rt_leftoffset=" ReqLE+30 " rt_topoffset=" ReqTE+24
   FilePosTags="rt_reqpos=reqpos_topleftscr rt_leftoffset=" ReqLEFT " rt_topoffset=" ReqTE
   EZtags=PosTags

   DIR_TAGS=FilePosTags" rtfi_flags=freqf_nofiles|freqf_save rtfi_height=" ReqHeight
   FILE_TAGS=FilePosTags" rtfi_flags=freqf_multiselect|freqf_selectdirs rtfi_height=" ReqHeight
   ONEFILE_TAG=FilePosTags" rtfi_height=" ReqHeight
 END
END

DO FOREVER
 IF GetFileSelection()=0 THEN LEAVE

 CALL FileAction
 IF ExitProg=1 THEN LEAVE

 UserArgs=''
 drop Action
 drop Files
END
CALL ExitMe
/* ---------------------- */
GetFileSelection:

/*
 RETURN 2  signals that files have been handed over by arguments
 flist or from workbench by wbargs or from cli
*/

FileName.1=''
Files.1='FILES.1'
Files.count=0
Path.1=''
ContinuedMode=0

SELECT
 WHEN cliargs=1 THEN
 DO
  r=FileParser()
  cliargs=0
  IF r=0 THEN StartArgs=SelectFiles()
  ELSE StartArgs=2
 END

 WHEN flist=1 THEN
 DO
  r=ReadFileList(filelist_tmp)
  flist=0
  IF r=0 THEN StartArgs=SelectFiles()
  ELSE StartArgs=2
 END

 WHEN wbargs=1 THEN
 DO
  r=GetSelectedIcons()
  wbargs=0
  IF r=0 THEN StartArgs=SelectFiles()
  ELSE StartArgs=2
 END

 OTHERWISE StartArgs=SelectFiles()
END /* SELECT */

IF StartArgs=0 THEN
 RETURN 0
ELSE
DO
 CALL SetActualPath
 RETURN StartArgs
END
/* ---------------------- */
SetActualPath:
i=Files.count
ActualPath=Path.1
Path=Path.i
LastSelected=FileName.1 /* remember */

ADDRESS COMMAND 'SetEnv Flags/ActualPath "'ActualPath'"'
CALL WriteFileList(FileList)  /* Prepare a FileList for external Processes */

RETURN
/* ---------------------- */
SelectFiles:
wbargs=0
cliargs=0
flist=0

Drive=LEFT(ActualPath,POS(':',ActualPath))
ADDRESS COMMAND 'assign >NIL: "'ConvSpecial(Drive)'" EXISTS'

IF RC>0 | ActualPath='' THEN ActualPath="SYS:"
ELSE IF ~EXISTS(ActualPath) THEN ActualPath="SYS:"

IF ~(firstSelection=1) THEN CALL PlaySample(SampleChooseFiles)
IF LastSelected='LASTSELECTED' THEN LastSelected=''

UserArgs=ShowMessage(FileReq,ActualPath,LastSelected,,AppName)
IF UserArgs='' THEN RETURN 0
ELSE ContinuedMode=1

CALL FileParser

firstSelection=1
RETURN 1
/* ---------------------- */
GetSelectedIcons:
OPTIONS RESULTS

ADDRESS WORKBENCH
GETATTR WINDOWS NAME window_list STEM window_list

i=1
DO w=0 TO window_list.count-1
 activewin=window_list.w
 IF ~(RIGHT(activewin,1)=':') & w>0 THEN activewin=activewin'/'

 GETATTR OBJECT WINDOW.ICONS.SELECTED.COUNT NAME activewin
 numselected=RESULT
 IF numselected>0 & w>0 THEN
 DO
  DO j=0 TO numselected-1
   GETATTR OBJECT WINDOW.ICONS.SELECTED.j.NAME NAME activewin
   Files.i=activewin''RESULT
   CALL Analyze

   i=i+1
  END
 END
END
i=i-1
Files.count=i

IF ~(Files.1='' | Files.1='FILES.1') THEN RETURN 1
ELSE RETURN 0

/* ------------------------- */
FileParser:

IF Files.1='' | Files.1='FILES.1' | POS(':',UserArgs)=0 THEN
DO
 i=0

 DO forever
  i=i+1

  Files.i=''
  PrognameBegPos=0
  DevicePos=0
  DirPos=0
  SfxBegin=0

  IF ( POS('"', UserArgs)=0 ) THEN
   PARSE VAR UserArgs Files.i UserArgs
  ELSE
   PARSE VAR UserArgs Files.i '"' UserArgs       /* parse the line */

  IF ( Files.i=" ") THEN
  DO
   IF ( POS('"', UserArgs)=0 ) THEN
    PARSE VAR UserArgs Files.i UserArgs
   ELSE
    PARSE VAR UserArgs Files.i '"' UserArgs       /* parse the line */
  END

  Files.i=strip(Files.i,'T',' ')
  Files.i=strip(Files.i,'B','"')

  IF (Files.i='') THEN
  DO                    /* Break if end of Command-line */
   Files.count=i-1
   LEAVE
  END

  DevicePos=LASTPOS(':',Files.i)

  IF (DevicePos=0) THEN
  DO
   ADDRESS COMMAND 'cd >ENV:'TempPath
   Path.i=MyGetENV(TempPath)

   ADDRESS COMMAND 'delete ENV:'TempPath' QUIET'

   IF (RIGHT(Path.i,1)=':') THEN
     Files.i=Path.i || Files.i
   ELSE
     Files.i=Path.i || '/' || Files.i
  END

  CALL Analyze
 END
END
ELSE
DO i=1 TO Files.count
 PrognameBegPos=0
 DevicePos=0
 DirPos=0
 SfxBegin=0

 CALL Analyze
END

IF ~(Files.1='' | Files.1='FILES.1') THEN RETURN 1
ELSE RETURN 0

/*----------------------------------*/
Analyze:

Files.i=STRIP(Files.i,'T','/')
LengF=LENGTH(Files.i)
DevicePos=LASTPOS(':',Files.i)
DirPos=LASTPOS('/',Files.i)

IF (DirPos > 1) THEN
DO
 PrognameBegPos=DirPos
 Path_Dir.i=LEFT(Files.i, DirPos)
 Path.i=strip(Path_Dir.i,'T','/')
END
ELSE
DO
 PrognameBegPos=DevicePos
 Path.i=LEFT(Files.i, DevicePos)
 Path_Dir.i=Path.i
END

Numchars=LengF - PrognameBegPos
Device.i=LEFT(Files.i, Devicepos)
FileName.i=RIGHT(Files.i, LengF-PrognameBegPos)

SfxBegin=LASTPOS('.',FileName.i)

IF (SfxBegin=0) THEN
DO
 Prefix.i=FileName.i
 Suffix.i=''
END
ELSE
DO
 Prefix.i=LEFT(FileName.i,SfxBegin-1)
 Suffix.i=UPPER(RIGHT(Files.i, NumChars-SfxBegin))
END

RETURN 1

/* ------------------------- */
FileAction:

CALL PlaySample(SampleChooseOp)

IF FileActionFirst='FILEACTIONFIRST' THEN
DO
 FA_Msg='FileManager.1'
 FileActionFirst=0
END

CALL mkReqFList(1)
DO FOREVER  /* for online-Help Support and retrace */

CALL CloseCon(30)

SELECT
 WHEN FA_Msg='FileManager.1' THEN
 DO
  copy=1
  move=2
  delete=3
  rename=4
  view=5
  prev=6
  next=7
  choose=8
  help=9
  cancel=0

  Action=ShowMessage(FA_Msg,,,,AppName,Flist,Param3)  /* Ask for Action */
  SELECT
    WHEN Action=view THEN ADDRESS COMMAND '${RefTable/File-Presentate} -FList 'FileList

    WHEN Action=Copy THEN
    DO
      delAfterCopy=0
      ConMsg='File_Copy.8'
      SampleAction=SampleCopy
      SampleDone=SampleCopied
      CALL Copy_Move
    END

    WHEN Action=Move THEN
    DO
      delAfterCopy=1
      ConMsg='File_Move.1'
      SampleAction=SampleMove
      SampleDone=SampleMoved
      CALL Copy_Move
      LEAVE
    END

    WHEN Action=Delete THEN
    DO
      CALL InitTrash
      CALL DeleteIt
      CALL AppProfile
      LEAVE
    END

    WHEN Action=Rename THEN
    DO
      CALL RenameIt
      LEAVE
    END

    WHEN Action=0 THEN
    DO
      ExitProg=1
      LEAVE
    END

    WHEN Action=Choose THEN
    DO
      Target=Path
      LEAVE
    END

    WHEN Action=help THEN CALL Help
    WHEN Action=next THEN FA_Msg='FileManager.2'
    WHEN Action=prev THEN FA_Msg='FileManager.3'

    OTHERWISE CALL ExitMe
  END /* SELECT */
 END /* .1 */

 WHEN FA_Msg='FileManager.2' THEN
 DO
  copyAs=1
  moveAs=2
  sLink=3
  info=4
  sendto=5
  prev=6
  next=7
  choose=8
  help=9
  cancel=0

  Action=ShowMessage(FA_Msg,,,,AppName,Flist,Param3)  /* Ask for Action */
  SELECT
    WHEN Action=info THEN CALL FileInfo
    WHEN Action=CopyAs THEN
    DO
      AppNameBefore=AppName
      CALL SaveAsStarter
      AppName=AppNameBefore
      LEAVE
    END

    WHEN Action=MoveAs THEN
    DO
      AppNameBefore=AppName
      CALL MoveAsStarter
      AppName=AppNameBefore
      LEAVE
    END

    WHEN Action=sLink THEN
    DO
      AppNameBefore=AppName
      CALL ScriptLink
      AppName=AppNameBefore
      LEAVE
    END

    WHEN Action=sendTo THEN
    DO
      ADDRESS COMMAND '${RefTable/File-Starter} -FList 'FileList
      LEAVE
    END

    WHEN Action=0 THEN
    DO
      ExitProg=1
      LEAVE
    END

    WHEN Action=Choose THEN
    DO
      Target=Path
      LEAVE
    END

    WHEN Action=help THEN CALL Help
    WHEN Action=next THEN FA_Msg='FileManager.3'
    WHEN Action=prev THEN FA_Msg='FileManager.1'

    OTHERWISE CALL ExitMe
  END /* SELECT */
 END /* .2 */

 WHEN FA_Msg='FileManager.3' THEN
 DO
  edit=1
  arc=2
  filemoni=3
  diskspace=4
  tooltypes=5
  prev=6
  next=7
  choose=8
  help=9
  cancel=0

  Action=ShowMessage(FA_Msg,,,,AppName,Flist,Param3)  /* Ask for Action */
  SELECT
    WHEN Action=Edit THEN CALL Edit
    WHEN Action=filemoni THEN CALL FileMon

    WHEN Action=diskspace THEN
    DO f=1 TO Files.count
     ADDRESS COMMAND 'EASys!_bin:GetSize "'ConvSpecial(Files.f)'"'
    END

    WHEN Action=arc THEN ADDRESS COMMAND '${RefTable/Archive-Manager} -FList 'FileList
    WHEN Action=tooltypes THEN
    DO f=1 TO Files.count
     ADDRESS COMMAND '${RefTable/IconToolTypes} "'Files.f'"'
    END

    WHEN Action=0 THEN
    DO
      ExitProg=1
      LEAVE
    END

    WHEN Action=Choose THEN
    DO
      Target=Path
      LEAVE
    END

    WHEN Action=help THEN CALL Help
    WHEN Action=next THEN FA_Msg='FileManager.1'
    WHEN Action=prev THEN FA_Msg='FileManager.2'

    OTHERWISE CALL ExitMe
  END /* SELECT */
 END /* .3 */

 OTHERWISE NOP
END /* SELECT */
END /* FOREVER */
RETURN

/* ------------------------- */
mkReqFList:
PARSE ARG begincount
FList='   'Files.begincount
Param3=1
next=begincount+1
DO f=next to Files.count UNTIL f=8
   Flist=Flist''CR'   'Files.f
END

IF Files.count>1 & Files.count>8 THEN Flist=Flist''CR'   'Path'...'

Param3=Files.count
RETURN

/* ------------------------- */
Edit:

CALL PlaySample(SampleEdit)

DO k=1 to Files.count
   ADDRESS COMMAND '${RefTable/Text-Editor-Sync} "'ConvSpecial(Files.k)'"'
END

RETURN

/* ------------------------- */
FileMon:

CALL PlaySample(SampleFileMon)

DO k=1 to Files.count
   ADDRESS COMMAND '${RefTable/File-Monitor} ${RefTable/File-Monitor-Opts} "'Files.k'"'
END
RETURN

/* ------------------------- */
FileNote:

FileCommentDump='FN_Comment_'ProcessNumber

DO k=1 to Files.count

  aFile=ConvSpecial(Files.k)

  ADDRESS COMMAND 'SYS:c/list >ENV:'FileCommentDump' "'aFile'" LFORMAT "%c"'

  ActualComment=MyGetENV(FileCommentDump)

  length  =LENGTH(File)
  IF length>55 THEN
   FileString='...'RIGHT(File, 52)
  ELSE
   FileString=Files.k

  drop Comment
  Comment=ShowMessage('FileNoteMaker.1',,,ActualComment,AppName,FileString,ActualComment)

  IF Action=1 THEN ADDRESS COMMAND 'SYS:c/FileNote "'aFile'" "'Comment'"'

  ADDRESS COMMAND 'delete >NIL: ENV:'FileCommentDump' QUIET'
END

drop FileCommentDump

RETURN

/* ------------------------- */
RenameIt:

TimeStamp=GetTime()
CALL PlaySample(SampleRename)
IF ConStat=0 THEN CALL ShowMessage('File_Rename.4',,,,AppName)

cpy=cpy_yes
DoNotReplaceFile=0

DO k=1 to Files.count

 NoOper=0

 IF POS('+',Files.k)>0 THEN
 DO
  CALL ShowMessage('FileManager.9',,,,AppName,Files.k)
  NoOper=1
 END

 str_AttrSource=GetFileAttributes(Files.k)

 IF NoOper=0 & Files.count=1 THEN
 DO
     NewName=ShowMessage('File_Rename.1',,,FileName.k,str_AttrSource)
     IF Action=0 THEN LEAVE
     IF Action=1 & ~(FileName.k=NewName) THEN CALL Renamer
 END

 IF NoOper=0 & Files.count>1 THEN
 DO
  NewName=ShowMessage('File_Rename.2',,,FileName.k,str_AttrSource,k,Files.count)

  WildCard=0
  NoAsterisk=0

  IF LEFT(NewName,1)='*' | RIGHT(NewName,1)='*' THEN WildCard=1

  SELECT
   WHEN Action=0 THEN LEAVE
   WHEN Action=1 & WildCard=0 THEN CALL Renamer
   WHEN Action=2 THEN NOP
   WHEN Action=3 THEN WildCard=1
   OTHERWISE NOP
  END

  IF WildCard=1 THEN
  DO
   PatternPrev=NewName
   PatternNew=ShowMessage('File_Rename.3',,,PatternPrev,PatternPrev)
   IF Action=0 THEN LEAVE

   RenLeading=0
   RenTrailing=0
   RenString=0
   RenTrailToLead=0
   RenLeadToTrail=0
   Prev=STRIP(PatternPrev,'B','*')

   SELECT
    WHEN LENGTH(PatternPrev)>1 & LEFT(PatternPrev,1)="*" & RIGHT(PatternPrev,1)="*" THEN
    DO
      RenString=1
      Prev=STRIP(PatternPrev,'B','*')
      PatternNew=STRIP(PatternNew,'B','*')
    END

    WHEN LEFT(PatternPrev,1)="*" & LEFT(PatternNew,1)="*" THEN
    DO
      RenTrailing=1
      Prev=STRIP(PatternPrev,'L','*')
      PatternNew=STRIP(PatternNew,'L','*')
    END

    WHEN RIGHT(PatternPrev,1)="*" & RIGHT(PatternNew,1)="*" THEN
    DO
      RenLeading=1
      Prev=STRIP(PatternPrev,'T','*')
      PatternNew=STRIP(PatternNew,'T','*')
    END

    WHEN LEFT(PatternPrev,1)="*" & RIGHT(PatternNew,1)="*" THEN
    DO
      RenTrailToLead=1
      Prev=STRIP(PatternPrev,'L','*')
      PatternNew=STRIP(PatternNew,'T','*')
    END

    WHEN RIGHT(PatternPrev,1)="*" & LEFT(PatternNew,1)="*" THEN
    DO
      RenLeadToTrail=1
      Prev=STRIP(PatternPrev,'T','*')
      PatternNew=STRIP(PatternNew,'L','*')
    END

    OTHERWISE
    DO
      CALL CloseCon(50)
      RETURN
    END
   END /* SELECT */

   LengP=LENGTH(Prev)

   IF Files.count>1 THEN CALL CreateBarWin(AppName,BarWinL,BarWinT,BarWinW,'Sto_p','Progress',Files.count,0,3,2,,,,)

   DO k=1 to Files.count

     ADDRESS 'FRESHBAR_REXX.1'
     SETCURRENT WinHandle1 BarHandle1 k
     TESTOKBUTTON WinHandle1
     IF RESULT=1 THEN LEAVE k

     NewName=Filename.k
     LengF=LENGTH(FileName.k)

     SELECT
      WHEN RenLeading=1 THEN
      DO
        IF PatternPrev="*" THEN NewName=PatternNew''FileName.k
        ELSE
           IF POS(Prev,FileName.k)=1 THEN NewName=PatternNew''STRIP(FileName.k,'L',Prev)
      END

      WHEN RenTrailing=1 THEN
      DO
        IF PatternPrev="*" THEN NewName=FileName.k''PatternNew
        ELSE
           IF LASTPOS(Prev,FileName.k)=LengF-LengP+1 THEN NewName=STRIP(FileName.k,'T',Prev)''PatternNew
      END

      WHEN RenString=1 THEN
      DO
        Posi=POS(Prev,FileName.k)
        IF Posi>0 THEN
        DO
          NewL=''
          NewR=''
          IF Posi>1 THEN NewL=LEFT(FileName.k,Posi-1)
          IF Posi<LengF-LengP+1 THEN NewR=RIGHT(FileName.k,LengF-Posi-LengP+1)
          NewName=NewL''PatternNew''NewR
        END
      END

      WHEN RenTrailToLead=1 THEN NewName=PatternNew''LEFT(FileName.k,LENGTH(FileName.k)-LengP)
      WHEN RenLeadToTrail=1 THEN NewName=RIGHT(FileName.k,LENGTH(FileName.k)-LengP)''PatternNew

      OTHERWISE NOP
     END /* SELECT */

     IF ~(FileName.k=NewName) THEN CALL Renamer

   END /* subloop k */
   CALL CloseBarWin
   LEAVE
  END /* WildCard */
 END /* Files.count>1 */
 IF cpy=cpy_none | cpy=cpy_stop THEN LEAVE
END /* mainloop k */

CALL CloseCon(50)
RETURN

/* ------------------------- */
Renamer:

r=writeln(Con,"7H"k" / "Files.count"HH"FileName.k"0H9H9H"NewName"0H")

IF UPPER(FileName.k)=UPPER(NewName) THEN
DO
 r=PRAGMA('DIRECTORY',Path.k)

 aName=ConvSpecial(FileName.k)
 bName=ConvSpecial(NewName)

 ADDRESS COMMAND 'rename "'aName'" "'bName'" QUIET'
 IF RC>5 THEN r=ShowMessage('File_Rename.5',,,,AppName,ActualFile,Target,RC)

 RETURN
END

IF ~(cpy=cpy_all | cpy=cpy_none) THEN
DO
 SourceCount=Files.count
 NominalCount=Files.count
 SubCount=k
 ActualFile=Files.k

 IF RIGHT(Path.k,1)=':' THEN
  Target=Path.k''NewName
 ELSE
  Target=Path.k'/'NewName

 CALL CheckExist
END

IF cpy=cpy_yes | cpy=cpy_yesbak | cpy=cpy_all THEN
DO
 r=PRAGMA('DIRECTORY',Path.k)

 IF cpy=cpy_yesbak & ~(UPPER(Target)=UPPER(ActualFile)) THEN
 DO
   tg=ConvSpecial(Target)
   tginf=tg'.info'
   tgfnt=tg'.font'
   ADDRESS COMMAND 'rename "'tg'" "'tg''TimeStamp'"'

   SELECT
    WHEN EXISTS(Target'.info') THEN ADDRESS COMMAND 'rename "'tginf'" "'tginf''TimeStamp'"'
    WHEN EXISTS(Target'.font') THEN ADDRESS COMMAND 'rename "'tgfnt'" "'tgfnt''TimeStamp'"'
    OTHERWISE NOP
   END
 END

 aName=ConvSpecial(FileName.k)
 bName=ConvSpecial(NewName)

 ADDRESS COMMAND
 'delete >NIL: "'bName'" FORCE QUIET'
 'rename "'aName'" "'bName'" QUIET'

 IF RC>5 THEN
 DO
  r=ShowMessage('File_Rename.5',,,,AppName,ActualFile,Target,RC)
  RETURN
 END

 SELECT
  WHEN EXISTS(FileName.k'.info') THEN
  DO
   ADDRESS COMMAND
   'delete >NIL: "'bName'.info" FORCE QUIET'
   'rename "'aName'.info" "'bName'.info" QUIET'
  END
  WHEN UPPER(RIGHT(FileName.k,5))='.INFO' THEN
  DO
   ADDRESS COMMAND
   'delete >NIL: "'LEFT(bName,LENGTH(bName)-5)'" FORCE QUIET'
   'rename "'LEFT(aName,LENGTH(aName)-5)" "'LEFT(bName,LENGTH(bName)-5)'" QUIET'
  END
  WHEN EXISTS(FileName.k'.font') THEN
  DO
   ADDRESS COMMAND
   'delete >NIL: "'bName'.font" FORCE QUIET'
   'rename "'aName'.font" "'bName'.font" QUIET'
  END
  WHEN UPPER(RIGHT(FileName.k,5))='.FONT' THEN
  DO
   ADDRESS COMMAND
   'delete >NIL: "'LEFT(bName,LENGTH(bName)-5)'" FORCE QUIET'
   'rename "'LEFT(aName,LENGTH(aName)-5)" "'LEFT(bName,LENGTH(bName)-5)'" QUIET'
  END
  OTHERWISE NOP
 END
END

r=PRAGMA('DIRECTORY','T:')
RETURN

/* ------------------------- */
InitTrash:

AppName="EasyTrash  © EASys!)"

FileReq='TrashManager.0'
SampleChooseFiles=SampleDir'TrashManagerChooseFile.8SVX'
SampleChooseOp=SampleDir'FileManagerChooseOp.8SVX'
SampleDel=SampleDir'FileManagerDel.8SVX'
SampleDeleted=SampleDir'FileManagerDeleted.8SVX'
SampleDone=SampleDir'FileManagerDeleted.8SVX'
SampleMoveTrash=SampleDir'FileManagerMoveTrash.8SVX'
RETURN

/* ------------------------- */
Trash:

CALL InitTrash

SELECT
 WHEN Files.1='' | Files.1='FILES.1' THEN
 DO FOREVER
    IF SelectFiles()=0 THEN LEAVE
    ELSE CALL SetActualPath

    CALL DeleteIt
    IF ExitProg=1 THEN LEAVE

    MovedTrash=0
    drop Action
    drop Files
    UserArgs=''
 END

 OTHERWISE CALL DeleteIt
END

RETURN

/* ------------------------- */
DeleteIt:

Fprocessed=1  /* File Counter */

cancel=0
del=1
movetrash=2
single=3
fast=4

/* Automatic commandline Restorage yet available within GlobalTrash:

 DO r=1 to Files.count
  IF POS(':TRASHCAN/',UPPER(Files.r))>0 THEN
   DO
      IF(GlobalTrash_active=1) THEN
         ADDRESS COMMAND 'EASys!_bin:GlobalTrashClient WAITRESTORE "'Files.r'"'
      ELSE
         ADDRESS COMMAND '${RefTable/File-MoveServer} "'ConvSpecial(Files.r)'"'
   END
  RETURN
 END
*/

DO FOREVER

 CALL RequestDel
 Act=Action

 IF Act=1 & (Files.count>10 | OneDir=1) THEN Act=fast

 SELECT
  WHEN Act=Cancel THEN
  DO
     UserArgs=''
     drop Files
     CALL ExitMe
  END

  WHEN Act=fast | Act=del THEN
  DO
    IF Act=fast THEN
    DO
     r=FastModeOp('del',1)
     IF ~(r=2) THEN RETURN
     ELSE Act=del
    END

    ActualFile=" "
    DO k=1 to Files.count
       IF ~EXISTS(Files.k) THEN IF EXISTS(Files.k'.info') THEN Files.k=Files.k'.info'
       CALL CheckSource
       CALL DelMonitor(k,Files.k)
       IF Source_Is_Dir THEN
       DO
         IF SourceCount>0 THEN
         DO
           DO SubCount=1 to SourceCount
              ActualFile=SourceDirs.SubCount''SourceFiles.SubCount
              Rest=100-ABS((SourceCount-Subcount)*100 % SourceCount)
              ADDRESS 'FRESHBAR_REXX.1'
              SETCURRENT WinHandle1 BarHandle1 k
              TESTOKBUTTON WinHandle1
              IF RESULT=1 THEN LEAVE k

              CALL DeleteFile
              ADDRESS 'FRESHBAR_REXX.1'
              SETCURRENT WinHandle1 BarHandle2 Rest
           END
         END

         IF DirCount>0 THEN
         DO SubCount=1 to DirCount
            ActualFile=SourceDirs.SubCount
            CALL DeleteFile
         END
       END
       CALL DelFile
    END

    CALL CloseBarWin
    CALL PlaySample(SampleDeleted)
    LEAVE
  END

  WHEN Act=movetrash THEN
  DO
    CALL PlaySample(SampleMoveTrash)

    DO k=1 to Files.count
       ADDRESS 'FRESHBAR_REXX.1'
       SETCURRENT WinHandle1 BarHandle1 k
       TESTOKBUTTON WinHandle1
       IF RESULT=1 THEN LEAVE k
       ActualFile=Files.k

       CALL MoveTrash
       Rest=100-ABS((Files.count-k)*100 % Files.count)
       ADDRESS 'FRESHBAR_REXX.1'
       SETCURRENT WinHandle1 BarHandle2 Rest
    END
    CALL CloseBarWin
    LEAVE
  END

  WHEN Act=single & Files.count=1 THEN LEAVE

  WHEN Act=single THEN
  DO
   delete=1
   MoveTrash=2
   jump=3
   all=4
   Cancel=0

   IF Files.count>1 THEN
   DO
    ActualFile=" "
    DO k=1 TO Files.count
      CALL DelMonitor(k,Files.k)
      ActualFile=Files.k
      IF ~Exists(Files.k) & Exists(Files.k'.info') THEN Files.k=Files.k'.info'
      str_AttrSource=GetFileAttributes(Files.k)
      Action=ShowMessage('TrashManager.2',,,,AppName,k'/'Files.count,str_AttrSource)

      SELECT
       WHEN Action=Cancel THEN LEAVE
       WHEN Action=delete THEN CALL DeleteFile
       WHEN Action=MoveTrash THEN CALL MoveTrash
       WHEN Action=all THEN
       DO
         Fprocessed=k
         DO k=Fprocessed TO Files.count
             CALL DelFile
         END
         LEAVE
       END

       WHEN Action=jump THEN NOP
       OTHERWISE NOP
      END /* SELECT Action */
    END /* DO k */

    LEAVE /* FOREVER */
   END /* DO */
  END

  OTHERWISE NOP
 END /* SELECT act */
END /* FOREVER */

IF GlobalTrash_active=1 & MovedTrash=1 THEN ADDRESS COMMAND 'EASys!_bin:GlobalTrashClient PERFORM'

CALL CloseBarWin
CALL CloseCon(50)
RETURN

/* ------------------------- */
RequestDel:

CALL PlaySample(SampleDel)

IF Files.count=1 THEN
DO
  Mesg='TrashManager.3'
  IF ~Exists(Files.1) & Exists(Files.1'.info') THEN Files.1=Files.1'.info'
  Parameter2=GetFileAttributes(Files.1)
  Parameter3=''
END
ELSE
DO
  drop SelList
  SelList='   'Files.Fprocessed

  DO j=(Fprocessed+1) to 5 WHILE (j < Files.count+1)
     SelList=SelList''CR'   'Files.j
  END

  IF Files.count>j THEN
     SelList=SelList''CR'   'Path' ...'

  IF Files.count>1 THEN
  DO
     Mesg='TrashManager.1'
     Parameter2=SelList
     Parameter3=Files.count-Fprocessed+1
  END
END
Action=ShowMessage(Mesg,,,,AppName,Parameter2,Parameter3)

RETURN

/* ------------------------- */
DelFile:

ADDRESS 'FRESHBAR_REXX.1'
SETCURRENT WinHandle1 BarHandle1 k
TESTOKBUTTON WinHandle1
IF RESULT=1 THEN LEAVE k
CALL DelMonitor(k,Files.k)
ActualFile=Files.k

CALL DeleteFile
Rest=100-ABS((Files.count-k)*100 % Files.count)
ADDRESS 'FRESHBAR_REXX.1'
SETCURRENT WinHandle1 BarHandle2 Rest
RETURN

/* ------------------------- */
DeleteFile:

FileIsDir=0
delFile=0
delFileIcon=0
delDirIcon=0
delDir=0
delFont=0
delFontDir=0
delSimple=0

aFile=ConvSpecial(ActualFile)
FileSfx=UPPER(RIGHT(ActualFile,5))
IF IsDir(ActualFile)=1 THEN
DO
 FileIsDir=1
 aFile=STRIP(aFile,'T','/')
END

IF (FileIsDir=1 & FileSfx='.INFO') | FileSfx='.FONT' THEN DirName=LEFT(ActualFile,LENGTH(ActualFile)-5)

CALL DelMonitor(k,Files.k)

SELECT
 WHEN FileSfx='.FONT' THEN delFont=1
 WHEN FileSfx='.INFO' THEN delFileIcon=1
 WHEN EXISTS(ActualFile'.FONT') THEN delFontDir=1
 WHEN FileIsDir=1 & ~(FileSfx='.INFO') THEN delDir=1
 WHEN FileIsDir=1 & FileSfx='.INFO' THEN delDirIcon=1
 WHEN Source_is_Dir=1 THEN delSimple=1
 WHEN FileIsDir=0 & ~(FileSfx='.INFO') & ~EXISTS(ActualFile'.info') THEN delFile=1
 OTHERWISE delFile=1
END

SELECT
  WHEN delSimple THEN
  DO
   ADDRESS COMMAND 'delete >NIL: "'aFile'" FORCE QUIET'
   rCode=RC
  END

  WHEN delFile THEN
  DO
   ADDRESS COMMAND 'delete >NIL: "'aFile'" FORCE QUIET'
   rCode=RC
   ADDRESS COMMAND 'EASys!_bin:IconDelete "'aFile'"'
  END

  WHEN delFileIcon THEN
  DO
   ADDRESS COMMAND 'EASys!_bin:IconDelete "'aFile'"'
   rCode=RC
  END

  WHEN delDir THEN
  DO
    ADDRESS COMMAND 'delete >NIL: "'aFile'" FORCE ALL QUIET'
    rCode=RC
    ADDRESS COMMAND 'EASys!_bin:IconDelete "'aFile'"'
  END

  WHEN delDirIcon THEN
  DO
   ADDRESS COMMAND 'EASys!_bin:IconDelete "'aFile'"'
   rCode=RC
  END

  WHEN delFont THEN
  DO
    ADDRESS COMMAND 'EASys!_bin:IconDelete  "'aFile'"'

    IF EXISTS(DirName) THEN
    DO
      ADDRESS COMMAND
      'EASys!_bin:IconDelete "'ConvSpecial(DirName)'"'
      'delete >NIL: "'ConvSpecial(DirName)'" FORCE ALL QUIET'
    END
  END

  WHEN delFontDir THEN
  DO
    ADDRESS COMMAND
    'EASys!_bin:IconDelete "'aFile'"'
    'delete >NIL: "'aFile'" FORCE ALL QUIET'
    rCode=RC

    IF EXISTS(aFile'.font') THEN
    DO
      'delete >NIL: "'aFile'.font" FORCE QUIET'
      'EASys!_bin:IconDelete "'aFile'.font"'
    END
  END

  OTHERWISE NOP
END

IF rCode<5 THEN Deleted=1
RETURN

/* ------------------------- */
MoveTrash:

CALL DelMonitor(k,Files.k)

aFile=ConvSpecial(ActualFile)
bFile=ConvSpecial(Path_Dir.k''Prefix.k)

IF GlobalTrash_active=1 THEN
DO
  IF POS('[',ActualFile)>0 | POS(']',ActualFile)>0 | POS('{',ActualFile)>0 | POS('}',ActualFile)>0 THEN
  DO
   CALL ShowMessage('FileManager.9',,,,AppName,ActualFile)
   MovedTrash=0
   RETURN
  END

  ADDRESS COMMAND 'EASys!_bin:GlobalTrashClient WAIT "'ActualFile'"'
  IF ~(Suffix.k='INFO') & EXISTS(ActualFile'.info') THEN ADDRESS COMMAND 'EASys!_bin:GlobalTrashClient WAIT "'ActualFile'.info"'
END
ELSE
DO
  ADDRESS COMMAND 'copy "'aFile'" "${RefTable/TrashCan}" CLONE ALL QUIET'
  IF EXISTS(ActualFile'.info') THEN ADDRESS COMMAND 'copy "'aFile'.info" "${RefTable/TrashCan}" CLONE QUIET'

  IF Suffix.k='FONT' THEN
     IF EXISTS(Path_Dir.k''Prefix.k) THEN ADDRESS COMMAND 'copy "'bFile'" "${RefTable/TrashCan}" ALL QUIET'
  ELSE
     IF EXISTS(ActualFile'.font') THEN ADDRESS COMMAND 'copy "'aFile'.font" "${RefTable/TrashCan}" QUIET'

  CALL DeleteFile
END

MovedTrash=1
RETURN

/* ------------------------- */
DelMonitor:
PARSE ARG num,file

IF Files.count=1 & Source_Is_Dir=0 THEN RETURN

file=STRIP(file,'B','"')

IF ConStat=0 THEN
DO
  CALL ShowMessage('TrashManager.4',,,,AppName)
  CALL CreateBarWin(AppName,BarWinL,BarWinT,BarWinW,'Sto_p','Progress',Files.Count,0,3,2,'Drawer',100,0,3,1)
END

r=writeln(Con,"7H"num" / "Files.count"2H2H"file"0H")
RETURN

/* ------------------------- */
FileInfo:
CALL PlaySample(SampleFileInfo)

DO k=1 to Files.count
 ActualFile=Files.k

 DO FOREVER
  str_AttrSource=GetFileAttributes(ActualFile)

  Action=ShowMessage('File_Info.1',,,,AppName,str_AttrSource)
  SELECT
   WHEN Action=0 THEN LEAVE k
   WHEN Action=1 THEN LEAVE
   WHEN Action=2 THEN ADDRESS COMMAND '${RefTable/ManualServer} "'ConvSpecial(FileName.k)'"'
   WHEN Action=3 THEN
   DO
     TrueCount=Files.count  /* Store State */
     TrueFirstFile=Files.1
     ActualFile=Files.k
     ActualNum=k

     Files.count=1          /* Manipulate for internal use */
     Files.1=Files.k

     CALL FileMon

     Files.count=TrueCount   /* Restore */
     Files.1=TrueFirstFile
     Files.k=ActualFile
     k=ActualNum
   END

   WHEN Action=4 THEN
   DO
     TrueCount=Files.count  /* Store State */
     TrueFirstFile=Files.1
     ActualFile=Files.k
     ActualNum=k

     Files.count=1          /* Manipulate for internal use */
     Files.1=Files.k

     CALL FileNote

     Files.count=TrueCount   /* Restore */
     Files.1=TrueFirstFile
     Files.k=ActualFile
     k=ActualNum
   END

   WHEN wb_port=1 & Action=5 THEN ADDRESS WORKBENCH 'INFO "'Files.k'"'
   WHEN Action=5 THEN ADDRESS COMMAND '${RefTable/IconToolTypes} "'ConvSpecial(Files.k)'"'
   OTHERWISE CALL ExitMe
  END /* SELECT */
 END /* DO FOREVER */
END /* DO k */
RETURN

/* ------------------------- */
StartProg:

DO i=1 to Files.count
 CALL ChooseProg

 drop Action

 DO UNTIL(Action=1 | Action=0)
   str_AttrSource=GetFileAttributes(Files.i)
   CmdLine=ShowMessage('StartProg.1',,,CommandLine,AppName,str_AttrSource)

   SELECT
    WHEN Action=1 THEN ADDRESS COMMAND ConvSpecial(CmdLine)
    WHEN Action=2 THEN ADDRESS COMMAND '${RefTable/File-Monitor} ${RefTable/File-Monitor-Opts} "'ConvSpecial(Files.i)'"'
    WHEN Action=3 THEN ADDRESS COMMAND '${RefTable/ManualServer} "'ConvSpecial(FileName.i)'"'
    OTHERWISE CALL ExitMe
   END
 END
END

RETURN

/* ------------------------- */
ChooseProg:

ActualPath=TestPath(ActualPath)
IF UPPER(LEFT(FileName.i, 7))="-OTHERS" THEN
 DO
  i=i+1

  theProg=ShowMessage('StartProg.2',ActualPath,'',,FileName.i'    'AppName)

  TheConsole='>'ConsoleType''ConsoleSize'/'FileName.i'_Messages.../AUTO/CLOSE/WAIT'
  CommandLine=theProg TheConsole '"'Files.i'"'
 END
ELSE
 DO
  IF EXISTS(Files.i'.info') THEN CommandLine='EASys!_bin:WBrun "'Files.i'"'
  ELSE
   DO
    theProg="run"
    TheConsole='>'ConsoleType''ConsoleSize'/'FileName.i'_Messages.../AUTO/CLOSE/WAIT'
    CommandLine=theProg  TheConsole '"'Files.i'"'
   END
 END

IF theProg="" THEN CALL ExitMe
ELSE RETURN

/* ------------------------- */
ScriptLink:

AppName="EasyLink  © EASys!)"

k=1
IF ~(addWBstart=1) THEN
DO
 CALL RequestDest('File_ScriptLink.1','getpath')
 IF DestDir='' THEN RETURN
END

DO i=1 to Files.count

 SourceFile=Files.i
 SourceIcon=Files.i'.info'

 IF RIGHT(SourceFile,1)=':' THEN
 DO
  PARSE VAR SourceFile FileName.i':'
  SourceIcon=Files.i'disk.info'
 END

 DestFile=DestDir'_'FileName.i
 DestIcon=DestFile'.info'

 IF ~EXISTS(SourceFile) THEN
 DO
   IF ~EXISTS(SourceIcon) THEN RETURN

   DestIcon=DestDir''FileName.i'.info'

   aIcon=ConvSpecial(SourceFile)

   ADDRESS COMMAND
   'delete >NIL: "'DestIcon'" FORCE QUIET'
   iconcopy' "'aIcon''infoSfx'" "'DestFile''infoSfx'" 'iconcopyOpts
   RETURN
 END

 SELECT
  WHEN IsDir(SourceFile) THEN
  DO
    IF ~(WB_port=1) THEN r=rtezrequest("Get OS3.5! It's worth it."CR"Drawer-Links are only possible on OS3.5 systems.",'Aha!',ReqTitle,PosTags)
    ELSE
    DO
     IF ~Open(FILE,DestFile,'write') THEN CALL Err_ShowMessage(msg_no_wr''DestFile)
     ELSE
     DO
      r=WriteLn(FILE, '/* EASys! Scriptlink: open OS3.5 WB Drawer */')
      r=WriteLn(FILE, 'ADDRESS WORKBENCH')
      r=WriteLn(FILE, 'WINDOW "'SourceFile'" OPEN')
      r=Close(FILE)
      CALL MakeIcon('rx')
     END
    END
  END

  WHEN CheckExecutable(SourceFile) THEN
  DO
    IF ~Open(FILE,DestFile,'write') THEN CALL Err_ShowMessage(msg_no_wr''DestFile)
    ELSE
    DO
     r=WriteLn(FILE, '.key Arg')
     r=WriteLn(FILE, ';Script_link EASys!-System')

     IF exists(SourceIcon) THEN
        r=WriteLn(FILE, 'EASys!_bin:WBrun "'SourceFile'" <Arg>')
     ELSE
        r=WriteLn(FILE, 'run 'Console' "'SourceFile'" <Arg>')

     r=Close(FILE)
     CALL MakeIcon('exe')
    END
  END

  OTHERWISE
  DO
    IF ~Open(FILE,DestFile,'write') THEN CALL Err_ShowMessage(msg_no_wr''DestFile)
    ELSE
    DO
     r=WriteLn(FILE, '.key Arg')
     r=WriteLn(FILE, ';Script_link EASys!-System')

     IF EXISTS(SourceIcon) THEN
         r=WriteLn(FILE, 'EASys!_bin:WBrun "'SourceFile'" <Arg>')
     ELSE
         r=WriteLn(FILE, '${RefTable/View-Master} "'SourceFile'" <Arg>')

     r=Close(FILE)
     CALL MakeIcon('other')
    END
  END
 END
END
CALL OpenDestDrawer(STRIP(DestDir,'T','/'))

RETURN

/* ------------------------- */
MakeIcon:
PARSE ARG type

PARSE VAR SourceIcon aIcon'.info'
aIcon=ConvSpecial(aIcon)

SELECT
 WHEN type='rx' THEN
 DO
   IF EXISTS(SourceIcon) THEN
     ADDRESS COMMAND 'copy "'aIcon'.info" "'DestFile'.info" CLONE QUIET'
   ELSE
     ADDRESS COMMAND 'copy "ENV:Sys/def_Drawer.info" "'DestFile'.info" CLONE QUIET'

   ADDRESS COMMAND
   'EASys!_bin:DoIcon "'DestFile'" newT="Project" QUIET'
   'EASys!_bin:DoIcon "'DestFile'" newDT=rx QUIET'
   'EASys!_bin:DoIcon "'DestFile'" ClearTT QUIET'
   'EASys!_bin:DoIcon "'DestFile'" aTT="CONSOLE=NIL:" QUIET'
   'EASys!_bin:DoIcon "'DestFile'" aTT="DONOTWAIT" QUIET'
 END

 OTHERWISE
 DO
   IF EXISTS(SourceIcon) THEN
   DO
     ADDRESS COMMAND
     'copy "'aIcon'.info" "'DestFile'.info" CLONE QUIET'
     'EASys!_bin:DoIcon "'DestFile'" NEWT="Project" QUIET'
     'EASys!_bin:DoIcon "'DestFile'" NEWDEFAULTTOOL=c:IconX QUIET'
     'EASys!_bin:DoIcon "'DestFile'" ClearTT QUIET'
     'EASys!_bin:DoIcon "'DestFile'" aTT="DONOTWAIT" QUIET'
   END
 END
END
RETURN

/* ------------------------- */
CopyClip:

IF WB_port=1 THEN
DO
 ADDRESS WORKBENCH

 GETATTR OBJECT WINDOWS.ACTIVE
 Files.1=result
END

SELECT
 WHEN Files.1='' | Files.1='FILES.1' THEN destreq=1
 WHEN IsDir(Files.1)=1 THEN DestDir=Files.1
 OTHERWISE DestDir=ExtractPath(Files.1)
END

IF ~(destreq=1) THEN
DO
  destreq=0
  DestDir=STRIP(DestDir,'B','"')
  r=RIGHT(DestDir,1)
  IF ~(r='/' | r=':') THEN DestDir=DestDir'/'
END

IF WB_port=1 THEN
 SELECT
  WHEN EXISTS('T:FM_mv_clip') THEN
  DO
     CALL ReadFileList('T:FM_mv_clip')
     ADDRESS COMMAND 'delete >NIL: T:FM_mv_clip QUIET'
     mv=1
  END

  WHEN EXISTS('T:FM_cp_clip') THEN
  DO
     CALL ReadFileList('T:FM_cp_clip')
     cp=1
  END

  OTHERWISE CALL ExitMe
 END
ELSE
DO
 SELECT
  WHEN EXISTS('ENV:FM_mv_clip') THEN
  DO
     UserArgs=MyGetENV('FM_mv_clip')
     ADDRESS COMMAND 'delete >NIL: ENV:FM_mv_clip QUIET'
     mv=1
  END

  WHEN EXISTS('ENV:FM_cp_clip') THEN
  DO
     UserArgs=MyGetENV('FM_cp_clip')
     cp=1
  END

  OTHERWISE CALL ExitMe
 END

 Files.1='FILES.1'
 Files.count=0

 UserArgs=STRIP(UserArgs,'L',' ')
 CALL FileParser
END

IF Files.count=0 THEN CALL ExitMe

IF cp=1 THEN CALL CopyStarter
IF mv=1 THEN CALL MoveStarter

CALL ExitMe

/* ------------------------- */
CopyStarter:
AppName='EasyCopy  © EASys!)'
ConMsg='File_Copy.8'

SampleAction=SampleCopy
SampleDone=SampleCopied

delAfterCopy=0
CALL Copy_Move
RETURN

/* ------------------------- */
MoveStarter:
AppName='EasyMove  © EASys!)'
ConMsg='File_Move.1'

SampleAction=SampleMove
SampleDone=SampleMoved

delAfterCopy=1
CALL Copy_Move
RETURN

/* ------------------------- */
SaveAsStarter:
AppName='SaveAsEasy  © EASys!)'
ConMsg='File_Rename.4'
DestMsg='File_SaveAs.2'

SampleAction=SampleCopy
SampleDone=SampleCopied

delAfterCopy=0
CALL SaveMoveAs
RETURN

/* ------------------------- */
MoveAsStarter:
AppName='MoveAsEasy  © EASys!)'
ConMsg='File_Rename.4'
DestMsg='File_SaveAs.3'

SampleAction=SampleMove
SampleDone=SampleMoved

delAfterCopy=1
CALL SaveMoveAs
RETURN

/* ------------------------- */
SaveMoveAs:

DoneOnce=0
DO k=1 to Files.count
 IF ~EXISTS(Files.k) THEN
 DO
   r=ShowMessage('File_SaveAs.1',,,,AppName,Files.k)
   RETURN
 END

 CALL PlaySample(SampleSaveAs)

 /* Action="Save As" */

 CALL RequestDest(DestMsg,'getfile')
 IF DestFile='' THEN RETURN

 ActualFile=Files.k
 Target=DestFile

 TmpIcon=0
 IF UPPER(RIGHT(Target,5))=".INFO" & ~(UPPER(RIGHT(ActualFile,5))=".INFO") THEN
 DO
    ADDRESS COMMAND 'copy "'ActualFile'" "T:'FileName.k'.info"'
    ActualFile='T:'FileName.k'.info'
    TmpIcon=1
 END

 COPYALL="ALL"
 CopyRelatedFiles=1
 DoNotReplaceFile=0
 cpy=cpy_yes

 IF ConStat=0 THEN CALL ShowMessage('File_rename.4',,,,AppName)

 CALL CheckSource
 CALL ManageCopying

 IF TmpIcon=1 THEN
 DO
    ADDRESS COMMAND 'delete >NIL: "T:'FileName.k'.info" QUIET'
    TmpIcon=0
 END

 CALL CloseCon(50)
 CALL ErrHandler
END
COPYALL=''

RETURN

/* ------------------------- */
Copy_Move:

CALL PlaySample(SampleAction)

k=1

IF ~(destreq=0) THEN
DO
   IF DelAfterCopy=0 THEN
      CALL RequestDest('File_Copy.1','getpath')
   ELSE
      CALL RequestDest('File_Move.2','getpath')
END

IF DestDir='' THEN RETURN

IF POS('@',DestDir)>1 THEN  /* send by EMail */
DO
 DestAddr=STRIP(DestDir,'T','/')
 DevPos=POS(':',DestAddr)
 SlashPos=LASTPOS('/',DestAddr)
 IF SlashPos>0 THEN
    DestAddr=RIGHT(DestAddr,LENGTH(DestAddr)-SlashPos)
 ELSE
    DestAddr=RIGHT(DestAddr,LENGTH(DestAddr)-DevPos)

 ADDRESS COMMAND '${RefTable/Archive-Manager} -sendMail "'DestAddr'" -FList 'FileList
 RETURN
END

DoneOnce=0
cpy=cpy_yes

CALL CopyLoop
CALL ErrHandler

RETURN

/* ----------------------------- */
CopyLoop:

normalcopy='?'

/* create Freshbar window and status console */
Barwin=0
IF ConStat=0 THEN CALL ShowMessage(ConMsg,,,,AppName,'kopiert')
IF Files.count>1 THEN CALL CreateBarWin(AppName,BarWinL,BarWinT,BarWinW,'Sto_p','Progress',Files.count,0,3,2,'Drawer',100,0,3,1)

exist=0
DO k=1 TO Files.count
 IF ~(Files.k='') & EXISTS(DestDir''FileName.k) THEN
 DO
  exist=1
  LEAVE k
 END
END

IF exist=0 THEN /* if none exists, do fast mode copy/move */
DO
  CALL FastModeOp('copy',1,'noask')
  CALL CloseBarWin
  CALL CloseCon(50)
  RETURN
END

IF ~(Files.1='') & IsDir(Files.1)=1 | ~(Files.2='') & IsDir(Files.2)=1 | ~(Files.3='') & IsDir(Files.3)=1 | Files.count>10 THEN
 IF FastModeOp('copy',1)=1 THEN
 DO
  CALL CloseBarWin
  CALL CloseCon(50)
  RETURN
 END

DoNotReplaceFile=0

DO k=1 to Files.count
 CALL CheckSource
 IF Barwin=0 & SourceCount>1 THEN CALL CreateBarWin(AppName,BarWinL,BarWinT,BarWinW,'Sto_p','Progress',Files.count,0,3,2,'Drawer',100,0,3,1)

 CopyRelatedFiles=1
 IF ~(Source_is_Dir) THEN
 DO
   ActualFile=Files.k
   Target=DestDir''Filename.k
   CopyRelatedFiles=1
   CALL ManageCopying
   IF cpy=cpy_stop THEN LEAVE k
 END
 ELSE
 DO
   MainDestDir=DestDir''Filename.k
   MainDirLength=LENGTH(Files.k)
   IF IsDir(MainDestDir)=0 THEN /* dest is a file, no folder */
   DO
    r=ShowMessage('FileManager.8',,,,AppName,Files.k,MainDestDir)
    LEAVE
   END

   IF IsDir(MainDestDir)=-1 THEN r=makedir(ConvSpecial(MainDestDir))
   IF normalcopy='?' THEN IF FastModeOp('copy',k)=1 THEN LEAVE k

   /* Create Destination Sub-Directories */

   IF DirCount>0 THEN
   DO SubCount=1 to DirCount
      ThisDestDir=MainDestDir''RIGHT(SourceDir.SubCount, LENGTH(SourceDir.SubCount)-MainDirLength)
      MakeDestDir=Strip(ThisDestDir,'T','/')

      IF IsDir(MakeDestDir)=-1 THEN r=makedir(ConvSpecial(MakeDestDir))
   END

   IF SourceCount>0 THEN
   DO
     CopyRelatedFiles=0
     DO SubCount=1 to SourceCount
        ActualFile=SourceDirs.SubCount''SourceFiles.SubCount
        Target=MainDestDir''RIGHT(SourceDirs.SubCount, LENGTH(SourceDirs.SubCount)-MainDirLength)''SourceFiles.SubCount

        ADDRESS 'FRESHBAR_REXX.1'
        TESTOKBUTTON WinHandle1
        IF RESULT=1 THEN LEAVE k

        CALL ManageCopying
        IF cpy=cpy_stop THEN LEAVE k
     END
   END

   /* Operations on Directory Files.k finally */
   NominalCount=NominalCount+1
   ActualFile=Files.k
   Target=DestDir''Filename.k
   CopyRelatedFiles=1

   CALL ManageCopying

   IF cpy=cpy_stop THEN LEAVE k
 END

 /* test the button state */
 ADDRESS 'FRESHBAR_REXX.1'
 TESTOKBUTTON WinHandle1
 IF RESULT=1 THEN LEAVE
END

IF k>=Files.count THEN
DO
 ADDRESS 'FRESHBAR_REXX.1'
 SETCURRENT WinHandle1 BarHandle2 100
END

CALL EndLoop
RETURN

/* ----------------------------- */
EndLoop:

CALL CloseBarWin

IF DoneOnce=1 THEN
DO
 CALL CloseCon(1)
 CALL PlaySample(SampleDone)
END
ELSE RETURN

CALL CloseCon(50)
CALL OpenDestDrawer(DestDir)

RETURN

/* ----------------------------- */
OpenDestDrawer:
PARSE ARG Dir

IF WB_port=1 THEN
DO
 ADDRESS 'WORKBENCH'
 WINDOWTOFRONT Dir

 IF ~(WORKBENCH.LASTERROR = 205) THEN
 DO
  ADDRESS WORKBENCH
  MENU WINDOW Dir INVOKE WINDOW.UPDATE
 END
END
RETURN

/* ----------------------------- */
FastModeOp:
PARSE ARG mode,startnum,ask

CALL mkReqFList(startnum)
RestFiles=Files.count-startnum+1
ShowCon='>"'ConsoleType''ReqLE'/'ReqTE+220'/'ConW'/90/FM Stop: [Ctrl] c .. Pause: [SPACE] ..'

IF DelAfterCopy=1 THEN mode='move'

r=5

SELECT
 WHEN mode='copy' THEN
 DO
  IF ~(ask='noask') THEN r=ShowMessage('FileManager.10',,,,AppName,FList,RestFiles,DestDir)
  IF r=0 THEN RETURN 1
  IF r=2 THEN
  DO
   NormalCopy=1
   RETURN 0
  END

  IF ~(ask='noask') THEN r=ShowMessage('FileManager.11',,,,AppName,FList,RestFiles,DestDir)
  IF r=0 THEN RETURN 1
  IF r=2 THEN
  DO
   NormalCopy=1
   RETURN 0
  END

  ShowCon=ShowCon'Fast mode copying ../AUTO/NOCLOSE"'
 END

 WHEN mode='del' THEN
 DO
  IF ~(ask='noask') THEN r=ShowMessage('TrashManager.5',,,,AppName,FList,RestFiles)
  IF r=2 THEN RETURN 2
  IF r=0 THEN RETURN 0

  CALL DelMonitor(startnum,Files.startnum)
  ShowCon=ShowCon'Fast mode deleting ../AUTO/NOCLOSE"'
 END

 WHEN mode='move' THEN
 DO
  IF ~(ask='noask') THEN r=ShowMessage('FileManager.10',,,,AppName,FList,RestFiles,DestDir)
  IF r=0 THEN RETURN 1
  IF r=2 THEN
  DO
   NormalCopy=1
   RETURN 0
  END

  IF ~(ask='noask') THEN r=ShowMessage('FileManager.11',,,,AppName,FList,RestFiles,DestDir)
  IF r=0 THEN RETURN 1
  IF r=2 THEN
  DO
   NormalCopy=1
   RETURN 0
  END

  ShowCon=ShowCon'Fast mode moving ../AUTO/NOCLOSE"'
 END

 OTHERWISE NOP
END

DO k=startnum TO Files.count

 aFile=ConvSpecial(Files.k)
 DestFile=DestDir''FileName.k
 reqfile=STRIP(RIGHT(FileName.k,20),'L',' ')

 Rest=Files.count-k
 c=100-ABS(Rest*100 % Files.count)
 ADDRESS 'FRESHBAR_REXX.1'
 SETCURRENT WinHandle1 BarHandle1 k
 TESTOKBUTTON WinHandle1
 IF RESULT=1 THEN LEAVE k

 SELECT
  WHEN mode='copy' THEN
  DO
   r=writeln(Con,"7H"k" / "Files.count"0H0H"Rest"HH"Files.k"0H9H9H"DestFile"0H")

   IF IsDir(Files.k)=1 THEN ADDRESS COMMAND 'copy 'ShowCon' "'aFile'" "'DestFile'" CLONE ALL'
   ELSE ADDRESS COMMAND 'copy "'aFile'" "'DestFile'" CLONE QUIET'

   IF EXISTS(Files.k'.info') THEN ADDRESS COMMAND iconcopy' "'aFile''infoSfx'" "'DestFile''infoSfx'" 'iconcopyOpts
   IF EXISTS(Files.k'.font') THEN ADDRESS COMMAND 'copy "'aFile'.font" "'DestFile'.font" CLONE QUIET'
  END

  WHEN mode='del' THEN
  DO
   IF IsDir(Files.k)=1 THEN
   DO
    ADDRESS COMMAND
    'delete 'ShowCon' "'aFile'" FORCE ALL'
    'EASys!_bin:IconDelete "'aFile'"'
   END
   ELSE ADDRESS COMMAND 'EASys!_bin:IconKill "'aFile'"'

   IF EXISTS(Files.k'.font') THEN ADDRESS COMMAND 'delete >NIL: "'aFile'.font" FORCE QUIET'
   CALL DelMonitor(k,Files.k)
  END

  WHEN mode='move' THEN
  DO
   r=writeln(Con,"7H"k" / "Files.count"0H0H"Rest"HH"Files.k"0H9H9H"DestFile"0H")

   movedir=STRIP(DestDir,'T','/')
   DeviceSrc=LEFT(Files.k,LASTPOS(':',Files.k))
   DeviceDest=LEFT(DestDir,LASTPOS(':',DestDir))
   IF DeviceSrc=DeviceDest & ~EXISTS(DestDir''FileName.k) THEN
   DO
    ADDRESS COMMAND 'rename "'aFile'" "'DestFile'" QUIET'
    IF EXISTS(Files.k'.font') THEN ADDRESS COMMAND 'rename "'aFile'.font" "'DestFile'.font" QUIET'
   END
   ELSE
   DO
    IF IsDir(Files.k)=1 THEN ADDRESS COMMAND 'move 'ShowCon' "'aFile'" "'movedir'" CLONE FORCE'
    ELSE ADDRESS COMMAND 'move >NIL: "'aFile'" "'movedir'" CLONE FORCE QUIET'

    IF EXISTS(Files.k'.font') THEN ADDRESS COMMAND 'move "'aFile'.font" "'movedir'" CLONE FORCE QUIET'
   END
   IF EXISTS(Files.k'.info') THEN ADDRESS COMMAND iconcopy' "'aFile''infoSfx'" "'DestFile''infoSfx'" 'iconcopyOpts

   ADDRESS COMMAND 'EASys!_bin:IconKill "'aFile'"'
  END

  OTHERWISE NOP
 END /* SELECT */

 ADDRESS 'FRESHBAR_REXX.1'
 SETCURRENT WinHandle1 BarHandle2 c
END

IF k>=Files.count THEN
DO
 ADDRESS 'FRESHBAR_REXX.1'
 SETCURRENT WinHandle1 BarHandle2 100
END

DoneOnce=1
deleted=1

CALL EndLoop
RETURN 1

/* ----------------------------- */
ManageCopying:

IF EXISTS(Target) & DoNotReplaceFile=1 THEN RETURN

Target_Path=''
IF POS('[',ActualFile)>0 | POS(']',ActualFile)>0 | POS('{',ActualFile)>0 | POS('}',ActualFile)>0 | POS('#',ActualFile)>0 THEN
DO
 IF IsDir(ActualFile)=1 THEN
 DO
  IF ~(cpy=cpy_all) THEN CALL ShowMessage('FileManager.9',,,,AppName,ActualFile)
  ADDRESS COMMAND 'echo >>'ErrLog' "Copying failed, special characters in filename:*n'ActualFile'*n"'
  RETURN
 END
 ELSE Target_Path=ExtractPath(Target)
END

delAfterCopyPrev=delAfterCopy

IF ~(cpy=cpy_all) THEN CALL CheckExist
IF cpy=cpy_stop | cpy=cpy_no | cpy=cpy_none THEN RETURN

TimeStamp=GetTime()
CALL ExecuteCopying

IF jump=1 THEN
DO
  jump=0
  delAfterCopy=delAfterCopyPrev
  RETURN
END

IF (CopyRelatedFiles) THEN
DO
  IF EXISTS(ActualFile'.info') THEN
  DO
    ActualFile=ActualFile'.info'
    Target=Target'.info'

    IF ~(cpy=cpy_all) THEN CALL CheckExist
    IF cpy=cpy_stop | cpy=cpy_no THEN RETURN
    CALL ExecuteCopying
  END

  IF EXISTS(ActualFile'.font') THEN
  DO
    ActualFile=ActualFile'.font'
    Target=Target'.font'

    IF ~(cpy=cpy_all) THEN CALL CheckExist
    IF cpy=cpy_stop | cpy=cpy_no THEN RETURN
    CALL ExecuteCopying
  END
  ELSE IF UPPER(RIGHT(ActualFile,5))='.FONT' THEN
  DO
   FontDir=LEFT(ActualFile,LENGTH(ActualFile)-5)
   IF EXISTS(FontDir) THEN
   DO
     Target=LEFT(Target,LENGTH(Target)-5)
     ActualFile=FontDir

     IF ~(cpy=cpy_all) THEN CALL CheckExist
     IF cpy=cpy_stop | cpy=cpy_no THEN RETURN
     CALL ExecuteCopying
   END
  END
END

delAfterCopy=delAfterCopyPrev
DoneOnce=1
RETURN

/* ----------------------------- */
ExecuteCopying:

aFile=ConvSpecial(ActualFile)
bFile=ConvSpecial(Target)
IF ~(Target_Path='') THEN bFile=Target_Path

CALL CalculateRest

r=writeln(Con,"7H"k" / "Files.count"0H0H"Rest"HH"ActualFile"0H9H9H"Target"0H")

ADDRESS 'FRESHBAR_REXX.1'
SETCURRENT WinHandle1 BarHandle1 k

TargetIconExists=0
IF UPPER(RIGHT(Target,5))='.INFO' THEN
DO
  TargetIconExists=1
  TargetFileName=LEFT(Target,LENGTH(Target)-5) /* needed below */

  IF cpy=cpy_yesbak THEN ADDRESS COMMAND iconcopy' "'TargetFileName''infoSfx'" "'TargetFileName''TimeStamp''infoSfx'" 'iconcopyOpts

  ADDRESS COMMAND
  'delete >NIL: "'bFile'" FORCE QUIET'
  iconcopy' "'LEFT(aFile,LENGTH(aFile)-5)''infoSfx'" "'TargetFileName''infoSfx'" 'iconcopyOpts
END
ELSE
DO
  IF cpy=cpy_yesbak THEN ADDRESS COMMAND 'copy "'bFile'" "'bFile''TimeStamp'" CLONE 'COPYALL' QUIET'

  ADDRESS COMMAND 'copy "'aFile'" "'bFile'" CLONE 'COPYALL' QUIET'
  rCode=RC
END

jump=0

SELECT
  WHEN rCode=5 THEN
  DO
    IF ~(cpy=cpy_all) THEN Action=ShowMessage('FileManager.7',,,,AppName,Target)
    ELSE Action=1

    IF Action=1 THEN
    DO
       ADDRESS COMMAND
       'delete >NIL: "'bFile'" FORCE QUIET'
       'copy "'aFile'" "'bFile'" CLONE 'COPYALL' QUIET'

       rCode=RC
    END
    ELSE
    DO
       ADDRESS COMMAND 'echo >>'ErrLog' "Not replaced, destination writeprotected:*n'ActualFile'*n"'
       delAfterCopy=0  /* avoid IconKill */
    END
  END

  WHEN rCode=10 THEN
  DO
    j=0
    DO i=1 to Files.count
       IF i=k THEN i=i+1 /* continue with next file */
       ELSE
       DO
        j=j+1
        Files.j=Files.i
        FileName.j=FileName.i
        Path.j=Path.i
        Prefix.j=Prefix.i
        Suffix.j=Suffix.i
       END
    END

    Files.count=Files.count-1
    SourceCount=SourceCount-1
    NominalCount=NominalCount-1

    ADDRESS COMMAND 'echo >>'ErrLog' "Copying failed, special characters in filename, or destination full:*n'ActualFile'*n"'
    IF ~(cpy=cpy_all) THEN CALL ShowMessage('FileManager.6',,,,AppName,ActualFile,rCode,Target)

    jump=1
  END

  WHEN delAfterCopy=1 THEN
  DO
   IF IsDir(ActualFile)=1 THEN ADDRESS COMMAND 'delete >NIL: "'aFile'" ALL QUIET'
   SELECT
    WHEN TargetIconExists=0 & ~EXISTS(Actualfile'.info') THEN ADDRESS COMMAND 'EASys!_bin:IconKill "'aFile'"'
    WHEN TargetIconExists & EXISTS(TargetFileName) THEN ADDRESS COMMAND 'EASys!_bin:IconKill "'aFile'"'
    OTHERWISE NOP
   END
  END

  OTHERWISE NOP
END

ADDRESS 'FRESHBAR_REXX.1'
SETCURRENT WinHandle1 BarHandle2 c

RETURN

/* ----------------------------- */
CheckExist:

cpy=cpy_yes /* Preset */

IF EXISTS(Target) & IsDir(Target)=0 THEN
DO
 IF DoNotReplaceFile=0 THEN
 DO
  str_AttrSource=GetFileAttributes(ActualFile)
  str_AttrDest=GetFileAttributes(Target)
  IF str_AttrDest='DOESNOTEXIST' THEN RETURN /* File exists in other Assign Directory but is not really here */

  CALL CalculateRest

  IF Files.count>1 | Source_is_Dir=1 THEN
   MsgOffset=3
  ELSE
   MsgOffset=0

  MsgNr=2
  SELECT
   WHEN Rest>1 THEN MsgNr=2+MsgOffset
   WHEN Rest=1 THEN MsgNr=3+MsgOffset
   WHEN Rest=0 THEN MsgNr=4+MsgOffset
   OTHERWISE
   DO
     Rest=0
     MsgNr=4+MsgOffset
   END
  END

  cpy=ShowMessage('File_Copy.'MsgNr,,,,str_AttrDest,str_AttrSource,Rest,k,Files.count,AppName)
  IF cpy=cpy_none THEN DoNotReplaceFile=1
 END
 ELSE cpy=cpy_no
END
RETURN

/* ----------------------------- */
GetFileAttributes:
PARSE ARG CheckedFile

BytesTemp='T:FM_Bytes'ProcessNumber
AttrFile='T:FM_Attr_'ProcessNumber
DirChecked=0

aFile=ConvSpecial(CheckedFile)

IF IsDir(CheckedFile)=1 THEN
DO
  DirChecked=1
  ADDRESS COMMAND 'list >'AttrFile' "'aFile'" FILES LFORMAT "    'CheckedFile'*n    DIRECTORY*n*n    %d   %t*n    %c"'
END
ELSE
DO
  ADDRESS COMMAND 'list >'BytesTemp' "'aFile'" LFORMAT "%l"'

  IF RC>0 THEN RETURN "DOESNOTEXIST"

  IF ~Open(fTMP,BytesTemp,'read') THEN CALL Err_ShowMessage(msg_no_r''BytesTemp)
  ELSE
  DO
    Bytes=VALUE(ReadLn(fTMP))
    StrBytes=Bytes' Bytes'
    r=Close(fTMP)
  END

  ADDRESS COMMAND
  'delete >NIL: 'BytesTemp' QUIET'
  'list >'AttrFile' "'aFile'" LFORMAT "    %n*n    %p*n    'StrBytes'*n    %d   %t*n    %c"'
END

IF DirChecked=0 THEN
DO
  IsExecutable=CheckExecutable(CheckedFile)

  Ver=???
  VerName=''
  VerTmp='FMver_'ProcessNumber
  sz_version=''

  IF Bytes<850000 & (IsExecutable | UPPER(RIGHT(CheckedFile,8))='.CATALOG') THEN
  DO
   ADDRESS COMMAND 'version >ENV:'VerTmp' "'aFile'"'
   IF RC<20 THEN
   DO
    transfrom='a0'x || ''
    transto='  '
    Version=Translate(MyGetENV(VerTmp),transto,transfrom,' ')
    VerName=Word(Version,1)
    IF ~((LEFT(Version, 14)="Could not find") | Words(Version)<2) THEN
    DO
      transfrom='AaßbBcCdDeEfFgGhH¹²³,_iIjJkKlLmMnNoOpPqQrRsStTuUvVwWxXyYzZ;::/+-~#"&$%§[]{}=>|<!?@ '
      transto=  '11222334455667788123.'
      VersionNr=STRIP(Translate(Word(Version,2),transto,transfrom,' '),'B',' ')
      IF POS(' ',VersionNr)=0 THEN Ver=Value(STRIP(VersionNr,'T','.'))
    END
   END
   ADDRESS COMMAND 'delete >NIL: ENV:'VerTmp' QUIET'
  END

  IF (IsExecutable) THEN sz_Version='    Version:       'VerName Ver
END

IF ~Open(fTMP,AttrFile,'read') THEN CALL Err_ShowMessage(msg_no_r''AttrFile)
ELSE
DO
  str_Attr=ReadLn(fTMP)
  IF LENGTH(str_attr)>0 THEN
  DO
   str_Attr=str_Attr''CR''ReadLn(fTMP)
   str_Attr=str_Attr''CR''LEFT(ReadLn(fTMP), 85)
   str_Attr=str_Attr''CR''ReadLn(fTMP)
   str_Attr=str_Attr''CR''LEFT(ReadLn(fTMP), 85)
   IF DirChecked=0 THEN str_Attr=str_Attr''CR''LEFT(sz_Version, 80)
  END
  ELSE SELECT
    WHEN DirChecked=1 THEN str_Attr='    DIRECTORY'CR'    'CheckedFile
    OTHERWISE str_Attr='    FILE'CR'    'CheckedFile
  END

  r=Close(fTMP)
END

ADDRESS COMMAND 'delete >NIL: 'AttrFile' QUIET'
RETURN str_Attr

/*-----------------------------*/
CalculateRest:

IF Source_is_Dir=1 & SourceCount>0 THEN
  Rest=NominalCount-SubCount
ELSE
  Rest=NominalCount-k

c=100-ABS(Rest*100 % NominalCount)
RETURN

/* ----------------------------- */
ErrHandler:

IF EXISTS(ErrLog) THEN
DO
  ADDRESS COMMAND
  '${RefTable/Text-ViewASCII} 'ErrLog
  'delete >NIL: 'ErrLog' QUIET'
END
RETURN

/*-----------------------------*/
CheckExecutable:
PARSE ARG CheckExeFile

Flag=0

IF ~Open(fTMP,CheckExeFile,'read') THEN CALL Err_ShowMessage(msg_no_r''CheckExeFile)
ELSE
DO
 Head=ReadCh(fTMP, 4)
 HeaderBytes=c2x(Head)
 r=Close(fTMP)
END

IF HeaderBytes='000003F3' THEN Flag=1    /* Executable */

RETURN Flag

/* ----------------------------- */
CheckSource:

Source_is_Dir=0   /* Preset */
SourceCount=Files.count - k
SubCount=0

IF ~(IsDir(Files.k)=1) THEN
DO
  NominalCount=Files.count
  RETURN
END
ELSE
DO
  Source_is_Dir=1

  aFile=ConvSpecial(Files.k)

  ADDRESS COMMAND
  'list "'aFile'" >'CheckSourceDirs' ALL DIRS LFORMAT="%p%s"'
  'list "'aFile'" >'CheckSourceFile' ALL FILES LFORMAT="%p*n%s"'

  SourceCount=1
  IF ~Open(fTMP,CheckSourceFile,'read') THEN CALL Err_ShowMessage(msg_no_r''CheckSourceFile)
  ELSE
  DO
    DO UNTIL (EOF(fTMP))
      SourceDirs.SourceCount=ReadLn(fTMP)
      SourceFiles.SourceCount=ReadLn(fTMP)
      SourceCount=SourceCount + 1
    END

    SourceCount=SourceCount - 2  /* 2 Lines Overhead in each "list" File */

    r=Close(fTMP)
    ADDRESS COMMAND 'delete >NIL: 'CheckSourceFile' QUIET'
  END
  NominalCount=SourceCount

  IF ~Open(fTMP,CheckSourceDirs,'read') THEN CALL Err_ShowMessage(msg_no_r''CheckSourceDirs)
  ELSE
  DO
    DirCount=1
    DO UNTIL (EOF(fTMP))
      SourceDir.DirCount=ReadLn(fTMP)
      DirCount=DirCount + 1
    END

    DirCount=DirCount - 2  /* 2 Lines Overhead in each "list" File */
    r=Close(fTMP)

    ADDRESS COMMAND 'delete >NIL: 'CheckSourceDirs' QUIET'
  END
END
RETURN

/* ------------------------- */
IsDir:     PROCEDURE
PARSE ARG name

r=PRAGMA('DIRECTORY',name)
IF ~(r='') THEN
   DirFlag=1
ELSE
DO
 IF ~Exists(name) THEN
   DirFlag=-1
 ELSE
   DirFlag=0
END

r=PRAGMA('DIRECTORY','T:')
RETURN DirFlag

/* ----------------------------- */
RequestDest:
PARSE ARG Mesg,Mode

IF LENGTH(FileName.k)>18 THEN Parameter2=LEFT(FileName.k,18)'..'
ELSE Parameter2=FileName.k

IF Files.count>1 THEN Parameter2=Parameter2', ...'

ActualPathDest=TestPath(ActualPathDest)
Chosen=ShowMessage(Mesg,ActualPathDest,FileName.k,,AppName,Parameter2)

IF Mode='getpath' THEN
DO
 DestDir=Chosen
 IF DestDir='' THEN RETURN
END
ELSE
DO
 DestFile=Chosen
 IF DestFile='' THEN RETURN

 DevicePos=LastPos(':',DestFile)
 DirPos=LastPos('/',DestFile)
 IF DirPos>0 THEN
    DestDir=LEFT(DestFile,DirPos)
 ELSE
    DestDir=LEFT(DestFile,DevicePos)
END

ActualPathDest=DestDir

ADDRESS COMMAND
'SetEnv Flags/ActualPathDest "'DestDir'"'
'SetEnv Flags/ActualPath "'Path.1'"'

CALL SaveFlags
RETURN

/* ------------------------- */
ShowMessage:
PARSE ARG Mesg,ReqPath,ReqFile,PresetString,Parameter1,Parameter2,Parameter3,Parameter4,Parameter5,Parameter6

drop Action
ReqType=''

MsgFile='EASys!_rexx:'Language'/'Mesg
IF ~Open(fTMP,MsgFile,'read') THEN CALL Err_ShowMessage(msg_no_r''MsgFile)
ELSE
DO
  ReqType=ReadLn(fTMP)  /* read Requester-Type */

  Line=ReadLn(fTMP)  /* read Title-Line */
  CALL Substitutions
  ReqTitle=Line

  Line=ReadLn(fTMP)  /* free line after Title */

  Message=''

  DO UNTIL EOF(fTMP)

    Line=ReadLn(fTMP)
    CALL Substitutions

    IF POS(">>>", Line) > 0 THEN
    DO
      rtBtns=STRIP(Line, 'L', '>')
      LEAVE
    END
    ELSE
        Message=Message''CR''Line
  END

  r=Close(fTMP)
END

uReqType=UPPER(ReqType)
pubname=getpubscreen()
IF ~(pubname='') THEN r=setpubscreen(pubname' Default')

SELECT
 WHEN (uReqType='MULTI REQUEST') THEN
 DO
  r=rtezrequest(Message,rtBtns,ReqTitle,PosTags)
  RETURN r
 END

 WHEN (uReqType='GET ONE FILE') THEN
 DO
  r=rtfilerequest(ReqPath,ReqFile,ReqTitle,rtBtns,ONEFILE_TAG, Files)
  RETURN r
 END

 WHEN (uReqType='GETFILES') THEN
 DO
  r=rtfilerequest(ReqPath,ReqFile,ReqTitle,rtBtns, FILE_TAGS, Files)
  RETURN r
 END

 WHEN (uReqType='GETPATH') THEN
 DO
  r=rtfilerequest(ReqPath,,ReqTitle,rtBtns, DIR_TAGS)
  RETURN r
 END

 WHEN (uReqType='GETSTRING') THEN
 DO
  r=rtgetstring(PresetString,Message,ReqTitle,rtBtns,GStags,Action)
  RETURN r
 END

 WHEN (uReqType='GETSTRING SIMPLE') THEN
 DO
  r=rtgetstring(PresetString,Message,ReqTitle,,GStags,Action)
  RETURN r
 END

 WHEN (uReqType='CONSOLE') THEN
 DO
  ShowConsole=ConsoleType''ReqLE'/'ReqTE'/'ConW'/'ConH'/'ReqTitle'/NOCLOSE'
  IF ~Open(Con,ShowConsole,'write') THEN CALL Err_ShowMessage(msg_no_wr''ShowConsole)
  ELSE ConStat=1

  r=WriteLn(Con,Message)
  RETURN 1
 END

 OTHERWISE CALL Err_ShowMessage('ReqType unknown: 'MsgFile)  /* Error if arrived here */
END /* SELECT */

RETURN

/* ------------------------- */
Substitutions:

IF POS("%1", Line) > 0 THEN             /* substitution parameters for each message */
DO UNTIL POS("%1", Line)=0            /* and per line */
   parse var Line part1 '%1' part2
   Line=part1''parameter1''part2
END

IF POS("%2", Line) > 0 THEN
DO UNTIL POS("%2", Line)=0
   parse var Line part1 '%2' part2
   Line=part1''parameter2''part2
END

IF POS("%3", Line) > 0 THEN
DO UNTIL POS("%3", Line)=0
   parse var Line part1 '%3' part2
   Line=part1''parameter3''part2
END

IF POS("%4", Line) > 0 THEN
DO UNTIL POS("%4", Line)=0
   parse var Line part1 '%4' part2
   Line=part1''parameter4''part2
END

IF POS("%5", Line) > 0 THEN
DO UNTIL POS("%5", Line)=0
   parse var Line part1 '%5' part2
   Line=part1''parameter5''part2
END

IF POS("%6", Line) > 0 THEN
DO UNTIL POS("%6", Line)=0
   parse var Line part1 '%6' part2
   Line=part1''parameter6''part2
END

RETURN

/* ------------------------- */
Err_ShowMessage:
PARSE ARG Msg

Message=AppName':' CR CR "Sorry, an error has occured:" CR CR "    "Msg CR CR "... exiting."
rtBtns='Oh no!'
r=rtezrequest(Message,rtBtns,ReqTitle,PosTags)
CALL ExitMe

RETURN

/* ------------------------- */
CloseCon:
PARSE ARG wait

IF ConStat=1 THEN
DO
 CALL DELAY(wait)
 r=Close(Con)
 ConStat=0
END
RETURN

/* ----------------------------- */
CreateBarWin:
PARSE ARG wTitle,wLeft,wTop,wWidth,btn,Bar1Title,Bar1Count,Bar1BG,Bar1Fill,Bar1Mode,Bar2Title,Bar2Count,Bar2BG,Bar2Fill,Bar2Mode

IF Barwin=1 THEN RETURN

ADDRESS 'FRESHBAR_REXX.1'
'CREATEBARWINDOW TITLE "'wTitle'" BUTTONTEXT "'btn'"'
WinHandle1=RESULT
SETBARWINDOWWIDTH WinHandle1 wWidth

/* bars */
IF ~(Bar1Title='BAR1TITLE' | Bar1Title='') THEN
DO
 ADDBAR WinHandle1 Bar1Count NAME Bar1Title
 BarHandle1=RESULT
 SETBACKPEN WinHandle1 BarHandle1 Bar1BG
 SETFILLPEN WinHandle1 BarHandle1 Bar1Fill
 SETPROGRESSMODE WinHandle1 BarHandle1 Bar1Mode
END

IF ~(Bar2Title='BAR2TITLE' | Bar2Title='') THEN
DO
 ADDBAR WinHandle1 Bar2Count NAME Bar2Title
 BarHandle2=RESULT
 SETBACKPEN WinHandle1 BarHandle2 Bar2BG
 SETFILLPEN WinHandle1 BarHandle2 Bar2Fill
 SETPROGRESSMODE WinHandle1 BarHandle2 Bar2Mode
END

/* Now open the window */
OPENBARWINDOW WinHandle1
SETBARWINDOWPOS WinHandle1 wLeft wTop
Barwin=1
RETURN

/* ------------------------- */
CloseBarWin:

ADDRESS "FRESHBAR_REXX.1"
DELETEBARWINDOW WinHandle1
Barwin=0
RETURN

/* ---------------------- */
MyGetENV:     PROCEDURE
PARSE ARG name

TheFile="ENV:" || name
IF (open(TEMPFILE, TheFile, 'read')) THEN
DO
 ENVvalue=READLN(TEMPFILE)
 Result=close(TEMPFILE)
END
ELSE
 ENVvalue=''

RETURN ENVvalue

/* ------------------------- */
ExtractPath:
PARSE ARG File

LengF=LENGTH(File)
DevicePos=LASTPOS(':',File)
DirPos=LASTPOS('/',File)

IF DirPos>1 THEN
DO
  PrognameBegPos=DirPos
  P_Dir=LEFT(File, DirPos)
  P=strip(P_Dir, T, '/')
END
ELSE
DO
  PrognameBegPos=DevicePos
  P=LEFT(File, DevicePos)
  P_Dir.i=P
END

RETURN P

/* ---------------------- */
TestPath:
PARSE ARG tstpath

Drive=LEFT(tstpath,POS(':',tstpath))
ADDRESS COMMAND 'assign >NIL: "'ConvSpecial(Drive)'" EXISTS'

IF RC>0 | tstPath='' THEN tstPath="SYS:"
ELSE IF ~EXISTS(tstPath) THEN tstPath="SYS:"

RETURN tstpath

/* ------------------------- */
ConvSpecial:
PARSE ARG File

posi=POS('~',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

posi=POS('(',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

posi=POS(')',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

posi=POS('[',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

posi=POS(']',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

posi=POS('{',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

posi=POS('}',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

posi=POS('#',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

posi=POS('?',File)
IF posi>0 THEN File=INSERT("'",File,posi-1)

RETURN File

/* ---------------------- */
WriteFileList:
PARSE ARG listname

IF ~Open(fTMP,listname,'write') THEN CALL Err_ShowMessage(msg_no_wr''listname)
ELSE
DO
  DO k=1 to Files.count
    r=WriteLn(fTMP,Files.k)
    r=WriteLn(fTMP,Path.k)
    r=WriteLn(fTMP,FileName.k)
    r=WriteLn(fTMP,Prefix.k)
    r=WriteLn(fTMP,Suffix.k)
  END

  r=Close(fTMP)
END
RETURN

/* ---------------------- */
ReadFileList:
PARSE ARG list
i=0

IF ~Open(TMP,list,'read') THEN CALL ExitMe
DO UNTIL EOF(TMP)
 i=i+1
 Files.i=READLN(TMP)
 Path.i=READLN(TMP)
 FileName.i=READLN(TMP)
 Prefix.i=READLN(TMP)
 Suffix.i=READLN(TMP)
END

Result=Close(TMP)

n=i-1
Files.count=n
Path=Path.n

RETURN

/* ---------------------- */
Help:
ADDRESS COMMAND '${RefTable/Text-ViewGuide} EASys!:Help/'Language'/EASys!_FM.guide'
RETURN

/* ---------------------- */
PlaySample:
PARSE ARG Sample

IF TalkToUser="0" THEN RETURN

IF EXISTS('ENV:ProcessTalk') THEN
DO
  ProcessTalk=Strip(SubWord(MyGetENV("ProcessTalk"),2), T, ']')

  ADDRESS COMMAND 'status >ENV:VoiceSTATUS PROCESS 'ProcessTalk
  VStatus=MyGetENV('VoiceSTATUS')

  IF POS(Play_Voice_Cmd,VStatus)>0 THEN ADDRESS COMMAND 'break' ProcessTalk 'c'
END

ADDRESS COMMAND Play_Voice Sample

RETURN

/*-----------------------*/
GetTime:   PROCEDURE

today=Date(n)
date=Date(s)
yy=LEFT(date,4)
mmdd=RIGHT(date,4)
mm=LEFT(mmdd,2)
dd=RIGHT(mmdd,2)

time=RIGHT(Time(n),8)
MinSec=Right(time,5)
Hrs=Left(time,2)
Mins=Left(MinSec,2)
Secs=Right(time,2)

time_hhmmss=Hrs''Mins''Secs
TimeStamp=RIGHT(yy,2)''mmdd''Hrs''Mins
RETURN TimeStamp

/* ---------------------- */
Init:

CR='0a'x

Language=GetClip('Language')
IF ~EXISTS('EASys!_rexx:'Language'/FileManager.1') THEN Language='english'

ProcessNumber=PRAGMA('ID')

MaxTitleChars=MyGetENV("RefTable/GUI-ShellTitleChars")

ConsoleType=MyGetENV('RefTable/GUI-ConsoleType')
IF ConsoleType='' THEN ConsoleType="CON:"

ConsoleSize=MyGetENV('SHELLsize')
IF ConsoleSize='' THEN ConsoleSize="40/50/600/200"

ReqLE=MyGetENV('RefTable/GUI-ReqLE')  /* Main Window */
ReqTE=MyGetENV('RefTable/GUI-ReqTE')
ReqHeight=MyGetENV("RefTable/GUI-ReqHeight")

ConW=520
ConH=210

BarWinW=250
BarWinL=ReqLE+ConW-BarWinW
BarWinT=ReqTE

PosTags="rt_reqpos=reqpos_topleftscr rt_leftoffset=" ReqLE " rt_topoffset=" ReqTE
EZtags=PosTags
GLtags=PosTags' rtgl_min=0 rtgl_max=1500 rtgl_backfill=true '
GStags=PosTags' rtgs_backfill=false rtgs_width=300'

POINTER_TAGS='rt_reqpos=reqpos_pointer'
DIR_TAGS=PosTags' rtfi_flags=freqf_nofiles|freqf_save rtfi_height='ReqHeight
FILE_TAGS=PosTags' rtfi_flags=freqf_multiselect|freqf_selectdirs rtfi_height='ReqHeight
ONEFILE_TAG=PosTags' rtfi_height='ReqHeight

Console='>"'ConsoleType''ConsoleSize'/'AppName' Messages.../AUTO/NOClose/ALT'ReqLE'/'ReqTE'/ConW/ConH"'

ConStat=0
msg_no_wr='Writing impossible: '
msg_no_r='Reading impossible: '

/* OS 3.5 WB Port */
IF SHOW('P','WORKBENCH') THEN
DO
 WB_port=1
 iconcopy='EASys!_bin:IconCopy'
 iconcopyOpts=''
 InfoSfx=''
END
ELSE
DO
 iconcopy='EASys!_bin:IconCopy'
 iconcopyOpts=''
 infoSfx=''
END


/* --------- pathes -------- */
r=PRAGMA('DIRECTORY', 'T:')
TempPath='FM_path_'ProcessNumber

CALL GetActualPath

CheckSourceFile='T:FM_FileList_'ProcessNumber
CheckSourceDirs='T:FM_DirsList_'ProcessNumber
FileList='T:FM_FileList_'ProcessNumber
ErrLog='T:FM_'ProcessNumber'_ErrorLog'

ADDRESS COMMAND 'EASys!_bin:CLIexchange >ENV:GT_info GlobalTrash INFO'

IF LEFT(MyGetENV('GT_info'),11)='GlobalTrash' THEN
  GlobalTrash_active=1
ELSE
  GlobalTrash_active=0

IF ~SHOW('P','FRESHBAR_REXX.1') THEN ADDRESS COMMAND 'run >NIL: SYS:RexxC/freshbar'

COPYALL=''

/* File_Copy.x Buttonbank */
cpy_yes=1
cpy_yesbak=2
cpy_no=3
cpy_all=4
cpy_none=5
cpy_stop=0

/* --------- Voice ------------ */
TalkToUser=MyGetENV("Flags/TalkToUser")
Play_Voice='run >ENV:ProcessTalk ${RefTable/Sound-voice}'
Play_Voice_Cmd=SubWord(MyGetENV('RefTable/Sound-voice'),1,1)
SampleDir='EASys!:Voice/'Language'/'

SampleCopy=SampleDir'FileManagerCopy.8SVX'
SampleCopied=SampleDir'FileManagerCopied.8SVX'
SampleChooseOp=SampleDir'FileManagerChooseOp.8SVX'
SampleChooseFiles=SampleDir'FileManagerChooseFile.8SVX'
SampleEdit=SampleDir'FileManagerStartEdit.8SVX'
SampleFileInfo=SampleDir'FileManagerFileInfo.8SVX'
SampleFileMon=SampleDir'FileManagerFileMon.8SVX'
SampleMove=SampleDir'FileManagerMove.8SVX'
SampleMoved=SampleDir'FileManagerMoved.8SVX'
SampleRename=SampleDir'FileManagerRename.8SVX'
SampleSaveAs=SampleDir'FileSaveAs.8SVX'

SampleBye=SampleDir'AppSayBye.8SVX'

/* --------- Special ------------ */
AppProfile:

AppName="EasyFiler  © EASys!)"
FileReq='FileManager.4' /* standard */
RETURN

/* --------------------- */
GetActualPath:
ActualPath=MyGetENV('Flags/ActualPath')
ActualPathDest=MyGetENV('Flags/ActualPathDest')
RETURN

/* --------------------- */
SaveFlags:

IF ~(Files.1='' | "FILES.1"=Files.1) THEN
DO
 ADDRESS COMMAND
 'assign >NIL: Profile: EXISTS'
 IF RC=0 THEN
 DO
  ADDRESS COMMAND
  'copy ENV:Flags/ActualPath Profile:ENV/Flags CLONE'
  'copy ENV:Flags/ActualPathDest Profile:ENV/Flags CLONE'
 END
 ELSE
 DO
  ADDRESS COMMAND
  'copy ENV:Flags/ActualPath EASys!:Flags CLONE'
  'copy ENV:Flags/ActualPathDest EASys!:Flags CLONE'
 END
END
RETURN

/* ---------------------- */
ExitMe:

IF ConStat=1 THEN r=Close(Con)

r=PRAGMA('DIRECTORY', 'T:')

drop UserArgs
drop Files
drop FileName
drop Suffix
drop Prefix
drop Path

drop SourceDir
drop SourceDirs
drop SourceFiles

IF EXISTS('ENV:ProcessTalk') THEN ADDRESS COMMAND 'delete >NIL: ENV:ProcessTalk QUIET'
IF EXISTS('ENV:VoiceSTATUS') THEN ADDRESS COMMAND 'delete >NIL: ENV:VoiceSTATUS QUIET'
IF EXISTS(FileList) THEN ADDRESS COMMAND 'delete >NIL: 'FileList' QUIET'
IF EXISTS('ENV:GT_info') THEN ADDRESS COMMAND 'delete >NIL: ENV:GT_info QUIET'


CALL setclip('FMlistpos',FM_ListPos)

FM_cnt=GetClip('FMcnt')-1
CALL setclip('FMcnt',FM_cnt)

r=setpubscreen('Workbench Default')

EXIT 0