AmigActive 13/AACD13.ISO/AACD/Utilities/DA3Demo/Installation/Install

Text File | 1992-08-27 | 5KB | 219 lines

;$VER: Digital Almanac III Demo Installer Script 1.0

(procedure P_INSTALL_EXE
    (
    (makedir #inst-dir)
    (copyfiles
        (source "//DA3Demo.info")
        (dest (tackon #inst-dir "/"))
        (newname (cat #inst-dir ".info"))
        (noposition)
    )

    (if (= #cpu 0)
        (set #name "/DigitalAlmanac020")
        (set #name "/DigitalAlmanacPPC")
    )
    (copyfiles
        (source #name)
        (dest #inst-dir)
        (newname "DigitalAlmanac")
    )
    (copyfiles
        (source "/DigitalAlmanac.info")
        (dest #inst-dir)
        (noposition)
    )

;*** Data ***
    (makedir (tackon #inst-dir "Data"))
    (copyfiles
        (source "/Data")
        (dest (tackon #inst-dir "Data"))
        (all)
    )

;*** User ***
    (makedir (tackon #inst-dir "User"))
    (copyfiles
        (source "/User")
        (dest (tackon #inst-dir "User"))
        (all)
    )

;*** Misc ***
    (makedir (tackon #inst-dir "Misc"))
    (copyfiles
        (source "/Misc")
        (dest (tackon #inst-dir "Misc"))
        (all)
    )

;*** Fonts ***
    (makedir (tackon #inst-dir "Fonts"))
    (copyfiles
        (source "/Fonts")
        (dest (tackon #inst-dir "Fonts"))
        (all)
    )

;*** Catalog ***
    (set #name (tackon #inst-dir "Catalogs"))
    (makedir #name)
    (if (= @language "deutsch")
        (
        (set #name (tackon #name "Deutsch"))
        (makedir #name)
        (copyfiles
            (source "/Catalogs/Deutsch/DA3Demo.catalog")
            (dest #name)
        )
        )
    )
    (if (= @language "english")
        (
        (set #name (tackon #name "English"))
        (makedir #name)
        (copyfiles
            (source "/Catalogs/English/DA3Demo.catalog")
            (dest #name)
        )
        )
    )

;*** Toolbar ***
    (makedir (tackon #inst-dir "Toolbar"))
    (copyfiles
        (source "/Toolbar")
        (dest (tackon #inst-dir "Toolbar"))
        (all)
    )

;*** Libraries ***
    (copylib
        (prompt "asyncio.library")
        (help @copylib-help)
        (source "/Libs/asyncio.library")
        (dest "LIBS:")
        (confirm "average")
    )

    (copylib
        (prompt "imagepool.library")
        (help @copylib-help)
        (source "/Libs/imagepool.library")
        (dest "LIBS:")
        (confirm "average")
    )

    (copylib
        (prompt "TransferAnim.mcc")
        (help @copylib-help)
        (source "/Libs/MUI/TransferAnim.mcc")
        (dest "MUI:Libs/MUI")
        (confirm "average")
    )

    (copylib
        (prompt "TransferAnim.mcp")
        (help @copylib-help)
        (source "/Libs/MUI/TransferAnim.mcp")
        (dest "MUI:Libs/MUI")
        (confirm "average")
    )

;*** HTML ***

    (makedir (tackon #inst-dir "HTML"))
    (copyfiles
        (prompt "HTML-Dokumentation")
        (source "/HTML")
        (dest (tackon #inst-dir "HTML"))
        (all)
    )
    (copyfiles
        (prompt "HTML-Dokumentation")
        (source "/HTML.info")
        (dest #inst-dir)
        (noposition)
    )
    )
)

;*** Installer Start ***

(if (= @language "deutsch")
    (
    (set #ask-inst-dir "\
Wo soll das Verzeichnis von DA III Demo angelegt werden ?\n\
Ein Ordner namens \"DA3Demo\" wird in dem gewählten Verzeichnis automatisch angelegt.")
    (set #choice-cpu "Für welchen Prozessor soll installiert werden ?")
    (set #choice-cpu1 "Beliebige 68k-CPU")
    (set #choice-cpu2 "PPC mit 68040 oder 68060")
    (set #font-msg "\
Zum Schluss müssen Sie noch eine Einstellung von Hand durchführen, zu welchem der Installer nicht in der Lage ist.\n\
Starten Sie DA III und wählen Sie den Menüpunkt Projekt/MUI-Einstellungen aus. Geben Sie dann im sich öffnenden \
MUI-Fenster unter Fenster/Zeichensätze/Normal den Text Astro/11 ein und speichern Sie ab (registrierter MUI-Besitzer !).\n\
Diese Einstellung ist nicht unbedingt notwendig, erleichert aber die Lesbarkeit in einigen Requestern.\n\n\
Soll DA III für diese Einstellung nun gestartet werden ?")
    (set #msg-ende "Ende")
    )
)

(if (= @language "english")
    (
    (set #ask-inst-dir "\
Where do you want to create the folder for DA III Demo ?\n\
A folder called \"DA3Demo\" will be automatically created.")
    (set #choice-cpu "For what type of CPU do you want to install ?")
    (set #choice-cpu1 "Any 68k-CPU")
    (set #choice-cpu2 "PPC with 68040 or 68060")
    (set #font-msg "\
Finally you must perform an adjustment manually, because the installer is not able to do so.\n\
Start DA III and select the menuitem Projects/MUI setting. After the window has opened, look for the\
string field Window/Fonts/Normal, enter the text Astro/11 and save it (registered MUI user !).\n\
This adjustment is not really required, but simplifies the readability of some requesters.\n\n\
Do you want to start DA III to make the adjustment ?")
    (set #msg-ende "Finished")
    )
)

(set #inst-dir
    (askdir
        (prompt #ask-inst-dir)
        (help @askdir-help)
        (default @default-dest)
        (disk)
    )
)

(set #inst-dir (tackon #inst-dir "DA3Demo"))

(if (exists "LIBS:powerpc.library" (noreq))
    (set #cpu 1)
    (set #cpu 0)
)

(set #cpu
    (askchoice
        (prompt #choice-cpu)
        (choices #choice-cpu1 #choice-cpu2)
        (help @askchoice-help)
        (default #cpu)
    )
)

(P_INSTALL_EXE)

(if (=
    (askbool
        (prompt #font-msg)
        (help @askbool-help)
    ) 1)
    (execute (cat "DA-Start " #inst-dir))
)

(set @default-dest #inst-dir)
(message #msg-ende)