Amiga Format 123/af123sub.adf/PrintManager39.lzx/PrintManager39/Install

Text File | 1999-03-02 | 5KB | 220 lines

; $VER: Installer script for PrintManager 1.8 (15.01.99) © 1997-1999 by Stephan Rupprecht

;--- localize strings ----
(if (= @language "deutsch")
(
    (set #wrongver "PrintManager benötigt mindestens AmigaOS3.0.\nInstallation kann nicht durchgeführt werden.")
    (set #askdir_prompt "Bitte wählen Sie das Zielverzeichnis für den PrintManager")
    (set #install_doc "Bitte wählen Sie das Verzeichnis für die Anleitung")
    (set #no_doc "Anleitung nicht installieren")
    (set #patch_err "Die Version für 68020 Prozessoren kann nicht erstellt werden")
    (set #apply_020patch "Ein 68020+ Prozessor wurde erkannt.\nEs wird nun eine optimierte Version des Programms erstellt ...\n\nGPatch ist (c) 1997-1998 by Ralf Gruner")
    (set #apply_fparpatch "Die fastpar.device wird nun auf den aktuellen Stand gebracht.\nFalls Sie schon die Version 37.6 besitzen, so können Sie\neine mögliche Fehlermeldung ignorieren.")
    (set #apply_fparpatch_err "Update der fastpar.device kann nicht durchgeführt werden")
)
(
    (if (= @language "español")
    (
        (set #wrongver "PrintManager requiere al menos S.O. 3.0\nInstalación abortada.")
        (set #askdir_prompt "Por favor, elija el cajón donde desea que PrintManager sea instalado.")
        (set #install_doc "Por favor, elija el cajón donde desea instalar la documentación.")
        (set #no_doc "No instalar documentación")
        (set #patch_err "¡Imposible crear versión 68020+!")
        (set #apply_020patch "He encontrado un procesador 68020+:\ncreando versión optimizada de PrintManager...\n\nGPatch es (c) 1997-1998 de Ralf Gruner")
        (set #apply_fparpatch "Ahora se va actualizar `fastpar.device' (37.6).\nEsta operación puede fracasar cuando la versión más reciente ya se encuentra instalada.")
        (set #apply_fparpatch_err "Intento fallido de actualizar `fastpar.device'")
    )
    (
        (set #wrongver "PrintManager requires at least AmigaOS3.0\nInstallation aborted.")
        (set #askdir_prompt "Please select the drawer where PrintManger should be installed")
        (set #install_doc "Please select the drawer for the documentation")
        (set #no_doc "Don't install doc")
        (set #patch_err "Failed to create 68020+ version")
        (set #apply_020patch "Found a 68020+ cpu.\nCreating optimized version of PrintManager now ...\n\nGPatch is (c) 1997-1998 by Ralf Gruner")
        (set #apply_fparpatch "Now going to update fastpar.device (37.6).\nThis operation failes when the latest version is already installed.")
        (set #apply_fparpatch_err "Failed to update fastpar.device")
    )
    )
)
)

;--- check os version ---
(set #vernum (getversion "exec.library" (resident)))
(set #vernum (/ #vernum 65536))

(if(< #vernum 39)
    (abort #wrongver)
)

;--- copy main program ---
(set @default-dest
    (askdir
        (prompt #askdir_prompt)
        (help @askdir-help)
        (default "SYS:WBStartup")
    )
)

(if (patmatch "68000|68010" (database "cpu"))
(
    (copyfiles
        (help @copyfiles-help)
        (source "PrintManager")
        (dest @default-dest)
    )
)
;--- 020+ cpu installed, create optimized version
(
    (message #apply_020patch)

    (set #newname
        (tackon @default-dest "PrintManager" )
    )

    (set #cmd
        (cat "gpatch PrintManager 020patch.gp " #newname)
    )

    (set #err
        (run #cmd
        )
    )

    (if (> #err 0)
        (abort #patch_err)
    )
)
)

;--- copy .info file if neccessary ---
(set #info_path (tackon @default-dest "PrintManager.info") )

(if (not (exists #info_path) )
    (copyfiles
        (help @copyfiles-help)
        (source "PrintManager.info")
        (dest @default-dest)
    )
)

;--- delete spool.device ---
(if (exists "DEVS:spool.device")
    (delete "DEVS:spool.device"
    )
)

;--- copy catalog ---
(if (NOT (= @language "english"))
(
    (set #src_name
        (tackon "Catalogs/" @language)
    )

    (set #dst_name
        (tackon "LOCALE:" #src_name)
    )

    (set #src_name
        (tackon #src_name "printmanager.catalog")
    )

    (if (exists #src_name (noreq))
    (
        (copyfiles
            (help @copyfiles-help)
            (source #src_name)
            (dest #dst_name)
        )
    )
        (message "Sorry, there is no " @language " catalog available at the moment!")
    )
)
)

;--- copy doc ---
(set #progdir
    (cat "PROGDIR:" " (aka " @default-dest ")" )
)

(set #helpdir
    (tackon "HELP:" @language)
)

(set #choice
    (askchoice
        (prompt #install_doc)
        (help @askchoice-help)
        (choices #helpdir #progdir #no_doc)
        (default 0)
    )
)

(if (< #choice 2)
(
    (if (exists "HELP:PrintManager.guide")
    (
        (Delete "HELP:PrintManager.guide")
    )
    )

    (if (= #choice 1)
    (
        (set #dst_name @default-dest)
    )
        (set #dst_name #helpdir)
    )

    (set #src_name
        (cat "docs/" @language "/PrintManager.guide")
    )

    (if (NOT (exists #src_name) )
    (
        (set #src_name "docs/english/PrintManager.guide")
    )
    )

    (copyfiles
        (help  @copyfiles-help)
        (source #src_name)
        (dest #dst_name)
    )
)
)

;--- update fastpar.device ---
;--- revision check doesn't work due a bug in 'getversion' ---
;(set #vernum (getversion "devs:fastpar.device"))
;(set #vernum (/ #vernum 65536))
;(set #rev (- #vernum (* #vernum 65536) ) )

;(if(< #rev 6)
;(
    (if (exists "DEVS:fastpar.device")
    (
        (message #apply_fparpatch)

        (set #err
            (run "gpatch DEVS:fastpar.device fastpar.ptch t:fastpar.device")
        )

        (if (> #err 0)
        (
            (message #apply_fparpatch_err)
        )
        (
            (copyfiles
                (help @copyfiles-help)
                (source "t:fastpar.device")
                (dest "devs:")
            )

            (delete "t:fastpar.device")
        )
        )
    )
    )
;)
;)
;--- eof ---