home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / d_part68k.s < prev    next >
Text File  |  2000-06-17  |  8KB  |  265 lines
  1. * 
  2. * Copyright (C) 1996-1997 Id Software, Inc. 
  3. * 
  4. * This program is free software; you can redistribute it and/or 
  5. * modify it under the terms of the GNU General Public License 
  6. * as published by the Free Software Foundation; either version 2 
  7. * of the License, or (at your option) any later version. 
  8. * 
  9. * This program is distributed in the hope that it will be useful, 
  10. * but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. * 
  13. * See the GNU General Public License for more details. 
  14. * 
  15. * You should have received a copy of the GNU General Public License 
  16. * along with this program; if not, write to the Free Software 
  17. * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. * 
  19.  
  20. **
  21. ** Quake for AMIGA
  22. ** d_part.c assembler implementations by Frank Wille <frank@phoenix.owl.de>
  23. **
  24.  
  25.         XREF    _r_origin
  26.         XREF    _r_pright
  27.         XREF    _r_pup
  28.         XREF    _r_ppn
  29.         XREF    _xcenter
  30.         XREF    _ycenter
  31.         XREF    _d_vrectbottom_particle
  32.         XREF    _d_vrectright_particle
  33.         XREF    _d_vrecty
  34.         XREF    _d_vrectx
  35.         XREF    _d_pzbuffer
  36.         XREF    _d_zwidth
  37.         XREF    _d_viewbuffer
  38.         XREF    _d_scantable
  39.         XREF    _d_y_aspect_shift
  40.         XREF    _d_pix_min
  41.         XREF    _d_pix_max
  42.         XREF    _d_pix_shift
  43.         XREF    _screenwidth
  44.  
  45.         XDEF    _D_DrawParticle
  46.  
  47. PARTICLE_Z_CLIP         equ.s   8.0             ;must match the values in d_iface.h!
  48.  
  49. PART_ORG        =       0
  50. PART_COLOR      =       12
  51.  
  52. ******************************************************************************
  53. *
  54. *       void _D_DrawParticle (particle_t *pparticle)
  55. *
  56. ******************************************************************************
  57.  
  58.         cnop    0,4
  59. _D_DrawParticle
  60.  
  61.         rsreset
  62. .fpuregs        rs.x    4
  63. .regs           rs.l    8
  64.         rs.l    1
  65. .pparticle      rs.l    1
  66.  
  67.         movem.l d2-d7/a2/a3,-(sp)
  68.         fmovem.x        fp2-fp5,-(sp)
  69.         move.l  .pparticle(sp),a2
  70.         lea     _r_origin,a0
  71.         fmove.s (a2)+,fp0
  72.         fsub.s  (a0)+,fp0               ;fp0 = local[0]
  73.         fmove.s (a2)+,fp1
  74.         fsub.s  (a0)+,fp1               ;fp1 = local[1]
  75.         fmove.s (a2)+,fp2
  76.         fsub.s  (a0)+,fp2               ;fp2 = local[2]
  77.         lea     -12(a2),a2
  78.         lea     _r_pright,a1
  79.         fmove.s (a1)+,fp3
  80.         fmul    fp0,fp3
  81.         fmove.s (a1)+,fp4
  82.         fmul    fp1,fp4
  83.         fadd    fp4,fp3
  84.         fmove.s (a1)+,fp4
  85.         fmul    fp2,fp4
  86.         fadd    fp4,fp3                 ;fp3 = transformed[0]
  87.         lea     _r_pup,a1
  88.         fmove.s (a1)+,fp4
  89.         fmul    fp0,fp4
  90.         fmove.s (a1)+,fp5
  91.         fmul    fp1,fp5
  92.         fadd    fp5,fp4
  93.         fmove.s (a1)+,fp5
  94.         fmul    fp2,fp5
  95.         fadd    fp5,fp4                 ;fp4 = transformed[1]
  96.         lea     _r_ppn,a1
  97.         fmul.s  (a1)+,fp0
  98.         fmul.s  (a1)+,fp1
  99.         fadd    fp0,fp1
  100.         fmul.s  (a1)+,fp2
  101.         fadd    fp1,fp2                 ;fp2 = transformed[2]
  102.         fcmp.s  #PARTICLE_Z_CLIP,fp2
  103.         fblt.w  .exit
  104.         fmove.s #1,fp0
  105.         fdiv    fp2,fp0                 ;zi = 1.0 / transformed[2]
  106.         fmove.s #0.5,fp1
  107.         fmul    fp0,fp3
  108.         fmul    fp0,fp4
  109.         fadd    fp1,fp3
  110.         fadd    fp1,fp4
  111.         fadd.s  _xcenter,fp3
  112.         fmove.l fp3,d0                  ;d0 = u
  113.         fsub.s  _ycenter,fp4
  114.         fneg    fp4
  115.         fmove.l fp4,d1                  ;d1 = v
  116.         cmp.l   _d_vrectbottom_particle,d1
  117.         bgt.w   .exit
  118.         cmp.l   _d_vrectright_particle,d0
  119.         bgt.w   .exit
  120.         cmp.l   _d_vrecty,d1
  121.         blt.w   .exit
  122.         cmp.l   _d_vrectx,d0
  123.         blt.w   .exit
  124.         move.l  _d_pzbuffer,a0
  125.         lea     _d_scantable,a1
  126.         move.l  0(a1,d1.l*4),a1
  127.         move.l  _d_zwidth,d2            ;d2 = d_zwidth
  128.         muls    d2,d1
  129.         add.l   d0,d1
  130.         lea     0(a0,d1.l*2),a0         ;a0 = pz
  131.         add.l   d0,a1
  132.         add.l   _d_viewbuffer,a1        ;a1 = pdest
  133.         fmul.s  #32768,fp0
  134.         fmove.l fp0,d0                  ;izi = (int)(zi * 0x8000)
  135.         move.l  d0,d5                   ;d5 = izi
  136.         move.l  _d_pix_shift,d1
  137.         asr.l   d1,d0                   ;d0 = pix
  138.         move.l  _d_pix_min,d1
  139.         cmp.l   d1,d0
  140.         bgt.b   .cont
  141.         move.l  d1,d0
  142. .cont
  143.         move.l  _d_pix_max,d1
  144.         cmp.l   d1,d0
  145.         blt.b   .cont2
  146.         move.l  d1,d0
  147. .cont2
  148.         fmove.s PART_COLOR(a2),fp0
  149.         fmove.l fp0,d4
  150.         move.l  _screenwidth,d1
  151.         move.l  _d_y_aspect_shift,d3
  152.         cmp.l   #4,d0                   ;switch (pix)
  153.         bgt.b   .more
  154.         beq.b   .four
  155.         cmp.l   #2,d0
  156.         bgt.b   .three
  157.         beq.b   .two
  158. .one                                            ;case 1
  159.         lsl     d3,d0
  160.         subq    #1,d0
  161. .one_loop
  162.         cmp     (a0),d5                 ;if (pz[0] <= izi)
  163.         blt.b   .one_next
  164.         move    d5,(a0)                 ;pz[0] = izi
  165.         move.b  d4,(a1)                 ;pdest[0] = pparticle->color
  166. .one_next
  167.         add.l   d1,a1                   ;pdest += screenwidth
  168.         lea     0(a0,d2.l*2),a0         ;pz += d_zwidth
  169.         dbra    d0,.one_loop            ;count--
  170.         bra.w   .exit
  171. .two                                            ;case 2
  172.         lsl     d3,d0
  173.         subq    #1,d0
  174. .two_loop
  175.         cmp     (a0),d5                 ;if (pz[0] <= izi)
  176.         blt.b   .two_2
  177.         move    d5,(a0)                 ;pz[0] = izi
  178.         move.b  d4,(a1)                 ;pdest[0] = pparticle->color
  179. .two_2
  180.         cmp     2(a0),d5                ;if (pz[1] <= izi)
  181.         blt.b   .two_next
  182.         move    d5,2(a0)                ;pz[1] = izi
  183.         move.b  d4,1(a1)                ;pdest[1] = pparticle->color
  184. .two_next
  185.         add.l   d1,a1                   ;pdest += screenwidth
  186.         lea     0(a0,d2.l*2),a0         ;pz += d_zwidth
  187.         dbra    d0,.two_loop            ;count--
  188.         bra.w   .exit
  189. .three                                          ;case3
  190.         lsl     d3,d0
  191.         subq    #1,d0
  192. .three_loop
  193.         cmp     (a0),d5                 ;if (pz[0] <= izi)
  194.         blt.b   .three_2
  195.         move    d5,(a0)                 ;pz[0] = izi
  196.         move.b  d4,(a1)                 ;pdest[0] = pparticle->color
  197. .three_2
  198.         cmp     2(a0),d5                ;if (pz[1] <= izi)
  199.         blt.b   .three_3
  200.         move    d5,2(a0)                ;pz[1] = izi
  201.         move.b  d4,1(a1)                ;pdest[1] = pparticle->color
  202. .three_3
  203.         cmp     4(a0),d5                ;if (pz[2] <= izi)
  204.         blt.b   .three_next
  205.         move    d5,4(a0)                ;pz[2] = izi
  206.         move.b  d4,2(a1)                ;pdest[2] = pparticle->color
  207. .three_next
  208.         add.l   d1,a1                   ;pdest += screenwidth
  209.         lea     0(a0,d2.l*2),a0         ;pz += d_zwidth
  210.         dbra    d0,.three_loop          ;count--
  211.         bra.b   .exit
  212. .four                                           ;case4
  213.         lsl     d3,d0
  214.         subq    #1,d0
  215. .four_loop
  216.         cmp     (a0),d5                 ;if (pz[0] <= izi)
  217.         blt.b   .four_2
  218.         move    d5,(a0)                 ;pz[0] = izi
  219.         move.b  d4,(a1)                 ;pdest[0] = pparticle->color
  220. .four_2
  221.         cmp     2(a0),d5                ;if (pz[1] <= izi)
  222.         blt.b   .four_3
  223.         move    d5,2(a0)                ;pz[1] = izi
  224.         move.b  d4,1(a1)                ;pdest[1] = pparticle->color
  225. .four_3
  226.         cmp     4(a0),d5                ;if (pz[2] <= izi)
  227.         blt.b   .four_4
  228.         move    d5,4(a0)                ;pz[2] = izi
  229.         move.b  d4,2(a1)                ;pdest[2] = pparticle->color
  230. .four_4
  231.         cmp     6(a0),d5                ;if (pz[3] <= izi)
  232.         blt.b   .four_next
  233.         move    d5,6(a0)                ;pz[3] = izi
  234.         move.b  d4,3(a1)                ;pdest[3] = pparticle->color
  235. .four_next
  236.         add.l   d1,a1                   ;pdest += screenwidth
  237.         lea     0(a0,d2.l*2),a0         ;pz += d_zwidth
  238.         dbra    d0,.four_loop           ;count--
  239.         bra.b   .exit
  240. .more
  241.         move    d0,d6
  242.         subq    #1,d6
  243.         lsl     d3,d0
  244.         subq    #1,d0
  245. .more_loop
  246.         move.l  a0,a2
  247.         move.l  a1,a3
  248.         move    d6,d7
  249. .more_loop2
  250.         addq.l  #1,a3
  251.         cmp     (a2)+,d5                ;if (pz[i] <= izi)
  252.         blt.b   .more_next
  253.         move    d5,-2(a2)               ;pz[i] = izi
  254.         move.b  d4,-1(a3)               ;pdest[i] = pparticle->color
  255. .more_next
  256.         dbra    d7,.more_loop2
  257.         add.l   d1,a1                   ;pdest += screenwidth
  258.         lea     0(a0,d2.l*2),a0         ;pz += d_zwidth
  259.         dbra    d0,.more_loop
  260. .exit
  261.         fmovem.x        (sp)+,fp2-fp5
  262.         movem.l (sp)+,d2-d7/a2/a3
  263.         rts
  264.  
  265.