home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / d_skyppc.s < prev    next >
Text File  |  2000-06-17  |  13KB  |  422 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. ##
  21. ## Quake for AMIGA
  22. ##
  23. ## d_skyPPC.s
  24. ##
  25. ## Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. ##
  27.  
  28. .set NOLR,1
  29. .include        "macrosPPC.i"
  30.  
  31. #
  32. # external references
  33. #
  34.  
  35.     xrefv    d_viewbuffer
  36.     xrefv    screenwidth
  37.     xrefa    r_refdef
  38.     xrefv    r_skysource
  39.     xrefa    vid
  40.     xrefa    vright
  41.     xrefa    vpn
  42.     xrefa    vup
  43.     xrefv    skytime
  44.     xrefv    skyspeed
  45.  
  46.     xrefv    INT2DBL_0
  47.     xrefv    c0
  48.     xrefv    c0_5
  49.     xrefv    c65536
  50.     xrefa    _ReciprocTable
  51.  
  52.  
  53. #
  54. # defines
  55. #
  56.  
  57. .set    PSPAN_NEXT         ,12
  58. .set    REFDEF_VRECT_X     ,0
  59. .set    REFDEF_VRECT_Y     ,4
  60. .set    REFDEF_VRECT_WIDTH ,8
  61. .set    REFDEF_VRECT_HEIGHT,12
  62. .set    VID_WIDTH          ,20
  63. .set    VID_HEIGHT         ,24
  64.  
  65. .set    SKYSHIFT           ,7
  66. .set    SKYSIZE            ,(1<<SKYSHIFT)
  67. .set    SKYMASK            ,(SKYSIZE-1)
  68. .set    SKY_SPAN_SHIFT     ,5
  69. .set    SKY_SPAN_MAX       ,(1<<SKY_SPAN_SHIFT)
  70. .set    R_SKY_SMASK        ,0x7f0000
  71. .set    R_SKY_TMASK        ,0x7f0000
  72.  
  73.  
  74.  
  75.  
  76.  
  77. ###########################################################################
  78. #
  79. #       void D_DrawSkyScans8 (espan_t *pspan)
  80. #
  81. #       standard scan drawing function for the sky
  82. #
  83. #       D_Sky_uv_To_st is inlined.
  84. #
  85. #       IMPORTANT!! SKY_SPAN_SHIFT must *NOT* exceed 5 (The ReciprocTable
  86. #       has to be extended)
  87. #
  88. ###########################################################################
  89.  
  90.     funcdef    D_DrawSkyScans8
  91.  
  92.     init    0,16,12,12
  93.     stmw    r20,gb(r1)
  94.     stfd    f14,fb+0*8(r1)
  95.     stfd    f15,fb+1*8(r1)
  96.     stfd    f16,fb+2*8(r1)
  97.     stfd    f17,fb+3*8(r1)
  98.     stfd    f18,fb+4*8(r1)
  99.     stfd    f19,fb+5*8(r1)
  100.     stfd    f20,fb+6*8(r1)
  101.     stfd    f21,fb+7*8(r1)
  102.     stfd    f22,fb+8*8(r1)
  103.     stfd    f23,fb+9*8(r1)
  104.     stfd    f24,fb+10*8(r1)
  105.     stfd    f25,fb+11*8(r1)
  106.  
  107.     lf      f1,INT2DBL_0        #for int2dbl_setup, r4=tmp
  108.     stfd    f1,local(r1)
  109.         lw      r5,d_viewbuffer         #r5 = d_viewbuffer
  110.         lw      r6,screenwidth          #r6 = screenwidth
  111.         lw      r7,r_skysource          #r7 = r_skysource
  112.         lxa     r8,_ReciprocTable
  113.         lxa     r9,r_refdef
  114.         lxa     r12,vid            #r12 = vid
  115.         lxa     r31,vpn
  116.         lxa     r30,vup
  117.         lxa     r29,vright
  118.         lwz     r10,REFDEF_VRECT_HEIGHT(r9)
  119.         lwz     r11,REFDEF_VRECT_WIDTH(r9)
  120.         cmpw    r11,r10
  121.         blt     .height
  122.         int2dbl f2,r11,r4,local,f1    #f2 = temp = (float)r_refdef...
  123.         b       .width
  124. .height:
  125.         int2dbl f2,r10,r4,local,f1    #f2 = temp = (float)r_refdef...
  126. .width:
  127.         ls      f3,c8192
  128.         ls      f5,c4096                #f5 = 4096
  129.         ls      f0,c3
  130.         ls      f15,ca
  131.         ls      f19,c0
  132.         ls      f20,c0_5
  133.         lfs     f6,0(r31)
  134.         fmuls   f6,f6,f5                #f6 = 4096*vpn[0]
  135.         lfs     f7,4(r31)
  136.         fmuls   f7,f7,f5                #f7 = 4096*vpn[1]
  137.         lfs     f8,8(r31)
  138.         fmuls   f8,f8,f5                #f8 = 4096*vpn[2]
  139.         fdivs   f3,f3,f2                #f3 = 8192 / temp
  140.         subi    r3,r3,4
  141.         lwz     r31,VID_WIDTH(r12)
  142.         srawi   r31,r31,1               #r31 = vid.width >> 1
  143.         lwz     r12,VID_HEIGHT(r12)
  144.         srawi   r12,r12,1               #r12 = vid.height >> 1
  145.         int2dbl f9,r12,r4,local,f1    #f9 = (float)vid.height >> 1
  146.  
  147.         ls      f14,skytime
  148.         ls      f4,skyspeed
  149.         fmuls   f14,f14,f4
  150.         ls      f4,c65536
  151.         fmuls   f14,f14,f4
  152.         fctiwz  f14,f14
  153.         stfd    f14,local+8(r1)
  154.         lwz     r27,local+12(r1)        #r27 = skytime * skyspeed*$10000
  155. .loop:
  156.         lwzu    r9,4(r3)                #r9 = u
  157.         lwzu    r10,4(r3)               #r10 = v
  158.         int2dbl f4,r10,r4,local,f1    #f4 = (float)pspan->v
  159.         mullw   r0,r10,r6
  160.         add     r0,r0,r9
  161.         add     r11,r5,r0               #r11 = pdest = d_viewbuffer + ...
  162.         subi    r11,r11,1               #prepare for postincrement
  163.         fsubs   f10,f9,f4               #f10 = ((vid.height>>1)-v)
  164.         fmuls   f10,f10,f3              #wv = 8192 * fp0 / temp
  165.         lfs     f11,0(r30)
  166.         fmadds  f23,f11,f10,f6          #f23 = 4096*vpn[0] + wv*vup[0]
  167.         lfs     f11,4(r30)
  168.         fmadds  f24,f11,f10,f7          #f24 = 4096*vpn[1] + wv*vup[1]
  169.         lfs     f11,8(r30)
  170.         fmadds  f25,f11,f10,f8          #f25 = 4096*vpn[2] + wv*vup[2]
  171.         lfs     f4,0(r29)
  172.         fmuls   f4,f4,f3                #f4 = 8192 * vright[0] / temp
  173.         lfs     f12,4(r29)
  174.         fmuls   f12,f12,f3              #f12 = 8192 * vright[1] / temp
  175.         lfs     f13,8(r29)
  176.         fmuls   f13,f13,f3              #f13 = 8192 * vright[2] / temp
  177.         fmuls   f25,f25,f0
  178.         fmuls   f13,f13,f0
  179.         lwzu    r28,4(r3)               #r28 = count = pspan->count
  180.         li      r0,1
  181.         dcbtst  r11,r0
  182.  
  183. ######  D_Sky_uv_To_st (inlined)
  184.  
  185.         subf    r0,r31,r9
  186.         int2dbl f16,r0,r4,local,f1    #f16 = (float(u-vid.width>>1))
  187.         fmadds  f21,f16,f4,f23          #f17 = end[0]
  188.         fmuls   f17,f21,f21
  189.         fmadds  f22,f16,f12,f24         #f18 = end[1]
  190.         fmadds  f17,f22,f22,f17         #f17 = end[0]^2 + end[1]^2
  191.         fmadds  f18,f16,f13,f25         #f18 = end[2]
  192.         fmadds  f17,f18,f18,f17         #f17 = end[0]^2 + end[1]^2 + end[2]^2
  193.         fcmpo   cr0,f17,f19
  194.         beq     .zero
  195.         frsqrte f16,f17
  196.         fres    f16,f16
  197.         fdivs   f18,f17,f16
  198.         fadd    f16,f18,f16
  199.         fmul    f17,f16,f20             #f17 = sqrt(...)
  200. .zero:
  201.         fdivs   f18,f15,f17
  202.         fmuls   f21,f21,f18             #f21 = 6*(SKYSIZE/2-1)*end[0]
  203.         fmuls   f22,f22,f18             #f22 = 6*(SKYSIZE/2-1)*end[1]
  204.         fctiwz  f21,f21
  205.         stfd    f21,local+8(r1)
  206.         lwz     r26,local+12(r1)
  207.         add     r26,r26,r27             #r26 = s
  208.         fctiwz  f22,f22
  209.         stfd    f22,local+8(r1)
  210.         lwz     r25,local+12(r1)
  211.         add     r25,r25,r27             #r25 = t
  212.  
  213. ######  end of D_Sky_uv_To_st
  214.  
  215. ######  Second loop. In every iteration one part of the whole span is drawn
  216.  
  217. #                do
  218. #                {
  219. #                        if (count >= SKY_SPAN_MAX)
  220. #                                spancount = SKY_SPAN_MAX;
  221. #                        else
  222. #                                spancount = count;
  223. #
  224. #                        count -= spancount;
  225. #
  226. #                        if (count)
  227. #                        {
  228.  
  229. .loop2:
  230.         cmpwi   r28,SKY_SPAN_MAX
  231.         bgt     .cont
  232.         mtctr   r28
  233.         subi    r20,r28,1               #r20 = spancountminus1
  234.         li      r28,0                   #r28 = count -= spancount
  235.         b       .finalpart
  236. .cont:
  237.         li      r20,SKY_SPAN_MAX        #r20 = spancount = SKY_SPAN_MAX
  238.         subf    r28,r20,r28             #r28 = count -= spancount
  239.         mtctr   r20
  240.  
  241.  
  242. ######  Evaluation of the values for the inner loop. This version is used for
  243. ######  span size = SKY_SPAN_MAX
  244.  
  245. #                        // calculate s and t at far end of span,
  246. #                        // calculate s and t steps across span by shifting
  247. #                                u += spancount;
  248. #
  249. #                                D_Sky_uv_To_st (u, v, &snext, &tnext);
  250. #
  251. #                                sstep = (snext - s) >> SKY_SPAN_SHIFT;
  252. #                                tstep = (tnext - t) >> SKY_SPAN_SHIFT;
  253. #                        }
  254.  
  255.  
  256.         add     r9,r9,r20               #u += spancount
  257.  
  258. ######  D_Sky_uv_To_st (inlined)
  259.  
  260.         subf    r0,r31,r9
  261.         int2dbl f16,r0,r4,local,f1    #f16 = (float(u-vid.width>>1))
  262.         fmadds  f21,f16,f4,f23          #f17 = end[0]
  263.         fmuls   f17,f21,f21
  264.         fmadds  f22,f16,f12,f24         #f18 = end[1]
  265.         fmadds  f17,f22,f22,f17         #f17 = end[0]^2 + end[1]^2
  266.         fmadds  f18,f16,f13,f25         #f18 = end[2]
  267.         fmadds  f17,f18,f18,f17         #f17 = end[0]^2 + end[1]^2 + end[2]^2
  268.         fcmpo   cr0,f17,f19
  269.         beq     .zero2
  270.         frsqrte f16,f17
  271.         fres    f16,f16
  272.         fdivs   f18,f17,f16
  273.         fadd    f16,f18,f16
  274.         fmul    f17,f16,f20             #f17 = sqrt(...)
  275. .zero2:
  276.         fdivs   f18,f15,f17
  277.         fmuls   f21,f21,f18             #f21 = 6#(SKYSIZE/2-1)*end[0]
  278.         fctiwz  f21,f21
  279.         stfd    f21,local+8(r1)
  280.         fmuls   f22,f22,f18             #f22 = 6*(SKYSIZE/2-1)*end[1]
  281.         lwz     r24,local+12(r1)
  282.         fctiwz  f22,f22
  283.         stfd    f22,local+8(r1)
  284.         add     r24,r24,r27             #r24 = snext
  285.         lwz     r23,local+12(r1)
  286.         add     r23,r23,r27             #r23 = tnext
  287.  
  288. ######  end of D_Sky_uv_To_st
  289.  
  290.         subf    r22,r26,r24             #r22 = snext - s
  291.         subf    r21,r25,r23             #r21 = tnext - t
  292.         srawi   r22,r22,SKY_SPAN_SHIFT  #r22 = sstep
  293.         srawi   r21,r21,SKY_SPAN_SHIFT  #r21 = tstep
  294.         b       .mainloop
  295.  
  296.  
  297. .finalpart:
  298.         add     r9,r9,r20               #u += spancountminus1
  299.  
  300. ######  D_Sky_uv_To_st (inlined)
  301.  
  302.         subf    r0,r31,r9
  303.         int2dbl f16,r0,r4,local,f1    #f16 = (float(u-vid.width>>1))
  304.         fmadds  f21,f16,f4,f23          #f17 = end[0]
  305.         fmuls   f17,f21,f21
  306.         fmadds  f22,f16,f12,f24         #f18 = end[1]
  307.         fmadds  f17,f22,f22,f17         #f17 = end[0]^2 + end[1]^2
  308.         fmadds  f18,f16,f13,f25         #f18 = end[2]
  309.         fmadds  f17,f18,f18,f17         #f17 = end[0]^2 + end[1]^2 + end[2]^2
  310.         fcmpo   cr0,f17,f19
  311.         beq     .zero3
  312.         frsqrte f16,f17
  313.         fres    f16,f16
  314.         fdivs   f18,f17,f16
  315.         fadd    f16,f18,f16
  316.         fmul    f17,f16,f20             #f17 = sqrt(...)
  317. .zero3:
  318.         cmplwi  r20,5
  319.         fdivs   f18,f15,f17
  320.         fmuls   f21,f21,f18             #f21 = 6*(SKYSIZE/2-1)*end[0]
  321.         fctiwz  f21,f21
  322.         stfd    f21,local+8(r1)
  323.         fmuls   f22,f22,f18             #f22 = 6*(SKYSIZE/2-1)*end[1]
  324.         lwz     r24,local+12(r1)
  325.         fctiwz  f22,f22
  326.         stfd    f22,local+8(r1)
  327.         add     r24,r24,r27             #r24 = snext
  328.         lwz     r23,local+12(r1)
  329.         add     r23,r23,r27             #r23 = tnext
  330.  
  331. ######  end of D_Sky_uv_To_st
  332.  
  333.         subf    r22,r26,r24             #r22 = snext - s
  334.         subf    r21,r25,r23             #r21 = tnext - t
  335.  
  336.         blt     .special
  337. .qdiv:
  338.         slwi    r0,r20,2
  339.         lwzx    r0,r8,r0
  340.         mulhw   r22,r22,r0
  341.         mulhw   r21,r21,r0
  342.         b       .mainloop
  343. .special:
  344.         cmplwi  r20,1
  345.         ble     .mainloop
  346.         cmplwi  r20,3
  347.         beq     .qdiv
  348.         blt     .spec_2
  349.         srawi   r22,r22,2
  350.         srawi   r21,r21,2
  351.         b       .mainloop
  352. .spec_2:
  353.         srawi   r22,r22,1
  354.         srawi   r21,r21,1
  355.  
  356.  
  357. ######  Main drawing loop.
  358.  
  359. #                        do
  360. #                        {
  361. #                                *pdest++ = r_skysource[((t & R_SKY_TMASK) >> 8) +
  362. #                                                ((s & R_SKY_SMASK) >> 16)];
  363. #                                s += sstep;
  364. #                                t += tstep;
  365. #                        } while (--spancount > 0);
  366.  
  367.  
  368. .mainloop:
  369.         rlwinm  r0,r25,24,17,23         #implied: R_SKY_TMASK
  370.         add     r25,r25,r21             #t += tstep
  371.         rlwimi  r0,r26,16,25,31         #implied: R_SKY_SMASK
  372.         add     r26,r26,r22             #s += sstep
  373.         lbzx    r0,r7,r0                #r_skysource[...]
  374.         stbu    r0,1(r11)
  375.         bdnz    .mainloop
  376.  
  377. ######  loop terminations
  378.  
  379.         mr      r26,r24                 #s = snext
  380.         mr      r25,r23                 #t = tnext
  381.         mr.     r28,r28
  382.         bgt     .loop2
  383.         lwz     r3,4(r3)
  384.         mr.     r3,r3
  385.         subi    r3,r3,4
  386.         bne     .loop
  387.  
  388.     lfd    f14,fb+0*8(r1)
  389.     lfd    f15,fb+1*8(r1)
  390.     lfd    f16,fb+2*8(r1)
  391.     lfd    f17,fb+3*8(r1)
  392.     lfd    f18,fb+4*8(r1)
  393.     lfd    f19,fb+5*8(r1)
  394.     lfd    f20,fb+6*8(r1)
  395.     lfd    f21,fb+7*8(r1)
  396.     lfd    f22,fb+8*8(r1)
  397.     lfd    f23,fb+9*8(r1)
  398.     lfd    f24,fb+10*8(r1)
  399.     lfd    f25,fb+11*8(r1)
  400.     lmw    r20,gb(r1)
  401.     exit
  402.  
  403.     funcend    D_DrawSkyScans8
  404.  
  405.  
  406.  
  407.  
  408. .ifdef    WOS
  409.     .tocd
  410. .else
  411.     .data
  412. .endif
  413.  
  414. lab c8192
  415.     .float    8192.0
  416. lab c4096
  417.     .float    4096.0
  418. lab c3
  419.     .float    3.0
  420. lab ca
  421.     .float    24772608.0    # => 65536*6*(SKYSIZE/2-1)
  422.