home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / r_aliasppc.s < prev    next >
Text File  |  2000-06-17  |  7KB  |  268 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. ##
  21. ## Quake for AMIGA
  22. ##
  23. ## r_aliasPPC.s
  24. ##
  25. ## Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. ##
  27.  
  28. .set NOLR,1
  29. .include        "macrosPPC.i"
  30.  
  31. #
  32. # external references
  33. #
  34.  
  35.     xrefa    aliastransform
  36.     xrefa    r_avertexnormals
  37.     xrefa    r_plightvec
  38.     xrefv    r_ambientlight
  39.     xrefv    r_shadelight
  40.     xrefv    ziscale
  41.     xrefv    aliasxscale
  42.     xrefv    aliasyscale
  43.     xrefv    aliasxcenter
  44.     xrefv    aliasycenter
  45.     xrefv    INT2DBL_0
  46.     xrefv    c0
  47.  
  48. #
  49. # defines
  50. #
  51.  
  52. .set    FV_V               ,0
  53. .set    FV_FLAGS           ,24
  54. .set    FV_RESERVED        ,28
  55. .set    FV_SIZEOF          ,32
  56. .set    FV_SIZEOF_EXP      ,5
  57.  
  58. .set    TV_V               ,0
  59. .set    TV_LIGHTNORMALINDEX,3
  60.  
  61. .set    SV_ONSEAM          ,0
  62. .set    SV_S               ,4
  63. .set    SV_T               ,8
  64.  
  65.  
  66.  
  67.  
  68.  
  69. ###########################################################################
  70. #
  71. #       void R_AliasTransformVector (vec3_t in, vec3_t out)
  72. #
  73. ###########################################################################
  74.  
  75.     funcdef    R_AliasTransformVector
  76.  
  77.         lxa     r5,aliastransform
  78.         lfs     f3,12(r5)
  79.         lfs     f1,0(r3)
  80.         lfs     f2,0(r5)
  81.         fmadds  f0,f1,f2,f3
  82.         lfs     f4,4(r3)
  83.         lfs     f5,4(r5)
  84.         fmadds  f0,f4,f5,f0
  85.         lfs     f6,8(r3)
  86.         lfs     f7,8(r5)
  87.         fmadds  f0,f6,f7,f0
  88.         stfs    f0,0(r4)
  89.         lfs     f3,12+16(r5)
  90.         lfs     f2,0+16(r5)
  91.         fmadds  f0,f1,f2,f3
  92.         lfs     f5,4+16(r5)
  93.         fmadds  f0,f4,f5,f0
  94.         lfs     f7,8+16(r5)
  95.         fmadds  f0,f6,f7,f0
  96.         stfs    f0,4(r4)
  97.         lfs     f3,12+2*16(r5)
  98.         lfs     f2,0+2*16(r5)
  99.         fmadds  f0,f1,f2,f3
  100.         lfs     f5,4+2*16(r5)
  101.         fmadds  f0,f4,f5,f0
  102.         lfs     f7,8+2*16(r5)
  103.         fmadds  f0,f6,f7,f0
  104.         stfs    f0,8(r4)
  105.         blr
  106.  
  107.     funcend    R_AliasTransformVector
  108.  
  109.  
  110.  
  111.  
  112. ###########################################################################
  113. #
  114. #       void R_AliasTransformFinalVert (finalvert_t *fv, auxvert_t *av,
  115. #                                      trivertx_t *pverts, stvert_t *pstverts)
  116. #
  117. ###########################################################################
  118.  
  119.     funcdef    R_AliasTransformFinalVert
  120.  
  121.     init    0,16,0,0
  122.  
  123.     ls    f13,c0
  124.     lxa    r7,aliastransform
  125.     lf      f11,INT2DBL_0              #for int2dbl_setup, tmp=r11
  126.     stfd    f11,local(r1)
  127.  
  128. #        av->fv[0] = DotProduct(pverts->v, aliastransform[0]) +
  129. #                        aliastransform[0][3];
  130. #        av->fv[1] = DotProduct(pverts->v, aliastransform[1]) +
  131. #                        aliastransform[1][3];
  132. #        av->fv[2] = DotProduct(pverts->v, aliastransform[2]) +
  133. #                        aliastransform[2][3];
  134.  
  135.          lbz     r8,0(r5)
  136.          int2dbl f1,r8,r11,local,f11
  137.          lfs     f3,12(r7)
  138.          lfs     f2,0(r7)
  139.          fmadds  f0,f1,f2,f3
  140.          lbz     r8,1(r5)
  141.          int2dbl f4,r8,r11,local,f11
  142.          lfs     f5,4(r7)
  143.          fmadds  f0,f4,f5,f0
  144.          lbz     r8,2(r5)
  145.          int2dbl f6,r8,r11,local,f11
  146.          lfs     f7,8(r7)
  147.          fmadds  f0,f6,f7,f0
  148.          stfs    f0,0(r4)
  149.          lfs     f3,12+16(r7)
  150.          lfs     f2,0+16(r7)
  151.          fmadds  f0,f1,f2,f3
  152.          lfs     f5,4+16(r7)
  153.          fmadds  f0,f4,f5,f0
  154.          lfs     f7,8+16(r7)
  155.          fmadds  f0,f6,f7,f0
  156.          stfs    f0,4(r4)
  157.          lfs     f3,12+2*16(r7)
  158.          lfs     f2,0+2*16(r7)
  159.          fmadds  f0,f1,f2,f3
  160.          lfs     f5,4+2*16(r7)
  161.          fmadds  f0,f4,f5,f0
  162.          lfs     f7,8+2*16(r7)
  163.          fmadds  f0,f6,f7,f0
  164.          stfs    f0,8(r4)
  165.  
  166. #        fv->v[2] = pstverts->s;
  167. #        fv->v[3] = pstverts->t;
  168. #
  169. #        fv->flags = pstverts->onseam;
  170.  
  171.         lwz     r0,SV_S(r6)
  172.         stw     r0,8(r3)
  173.         lwz     r8,SV_T(r6)
  174.         stw     r8,12(r3)
  175.         lwz     r9,SV_ONSEAM(r6)
  176.         stw     r9,FV_FLAGS(r3)
  177.  
  178. #        plightnormal = r_avertexnormals[pverts->lightnormalindex];
  179. #        lightcos = DotProduct (plightnormal, r_plightvec);
  180. #        temp = r_ambientlight;
  181.  
  182.         lxa     r7,r_avertexnormals
  183.         lbz     r8,TV_LIGHTNORMALINDEX(r5)
  184.         mulli   r8,r8,12
  185.         add     r7,r7,r8
  186.         lxa     r9,r_plightvec
  187.         lfs     f1,0(r7)
  188.         lfs     f2,0(r9)
  189.         fmuls   f3,f1,f2
  190.         lfs     f4,4(r7)
  191.         lfs     f5,4(r9)
  192.         fmadds  f3,f4,f5,f3
  193.         lfs     f6,8(r7)
  194.         lfs     f7,8(r9)
  195.         fmadds  f3,f6,f7,f3
  196.         lw      r10,r_ambientlight
  197.  
  198. #        if (lightcos < 0)
  199. #        {
  200. #                temp += (int)(r_shadelight * lightcos);
  201. #
  202. #        // clamp; because we limited the minimum ambient and shading light, we
  203. #        // don't have to clamp low light, just bright
  204. #                if (temp < 0)
  205. #                        temp = 0;
  206. #        }
  207. #
  208. #        fv->v[4] = temp;
  209.  
  210.         fcmpo   cr0,f3,f13
  211.         bge     .cont
  212.         ls      f12,r_shadelight
  213.         fmuls   f3,f3,f12
  214.         fctiwz  f0,f3
  215.         stfd    f0,local+8(r1)
  216.         lwz     r11,local+12(r1)
  217.         add.    r10,r10,r11
  218.         bge     .cont
  219.         li      r10,0
  220. .cont:
  221.         stw     r10,16(r3)
  222.     exit
  223.  
  224.     funcend    R_AliasTransformFinalVert
  225.  
  226.  
  227.  
  228.  
  229. ###########################################################################
  230. #
  231. #       void R_AliasProjectFinalVert (finalvert_t *fv, auxvert_t *av,)
  232. #
  233. ###########################################################################
  234.  
  235.     funcdef    R_AliasProjectFinalVert
  236.  
  237.     init    0,8,0,0
  238.  
  239.         lfs     f1,8(r4)
  240.         ls      f2,ziscale
  241.         fres    f1,f1
  242.         fmuls   f3,f1,f2
  243.         fctiwz  f0,f3
  244.         stfd    f0,local(r1)
  245.         lwz     r5,local+4(r1)
  246.         stw     r5,20(r3)
  247.         lfs     f4,0(r4)
  248.         lfs     f5,4(r4)
  249.         fmuls   f4,f4,f1
  250.         fmuls   f5,f5,f1
  251.         ls      f6,aliasxscale
  252.         ls      f7,aliasxcenter
  253.         fmadds  f4,f4,f6,f7
  254.         fctiwz  f0,f4
  255.         stfd    f0,local(r1)
  256.         lwz     r5,local+4(r1)
  257.         stw     r5,0(r3)
  258.         ls      f6,aliasyscale
  259.         ls      f7,aliasycenter
  260.         fmadds  f5,f5,f6,f7
  261.         fctiwz  f0,f5
  262.         stfd    f0,local(r1)
  263.         lwz     r5,local+4(r1)
  264.         stw     r5,4(r3)
  265.     exit
  266.  
  267.     funcend    R_AliasProjectFinalVert
  268.