home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / r_drawppc.s < prev    next >
Text File  |  2000-06-17  |  26KB  |  924 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. ##
  21. ## Quake for AMIGA
  22. ##
  23. ## r_drawPPC.s
  24. ##
  25. ## Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. ##
  27.  
  28. .include        "macrosPPC.i"
  29.  
  30. #
  31. # external references
  32. #
  33.     xrefv    r_lastvertvalid
  34.     xrefv    r_u1
  35.     xrefv    r_v1
  36.     xrefv    r_lzi1
  37.     xrefv    r_ceilv1
  38.     xrefv    r_nearzi
  39.     xrefv    r_nearzionly
  40.     xrefv    r_emitted
  41.     xrefv    r_framecount
  42.     xrefv    r_pedge
  43.     xrefa    r_refdef
  44.     xrefv    r_leftclipped
  45.     xrefv    r_rightclipped
  46.     xrefa    r_leftexit
  47.     xrefa    r_rightexit
  48.     xrefa    r_leftenter
  49.     xrefa    r_rightenter
  50.     xrefv    r_edges
  51.     xrefv    r_outofsurfaces
  52.     xrefv    r_outofedges
  53.     xrefv    r_pcurrentvertbase
  54.     xrefv    r_polycount
  55.     xrefv    r_currentkey
  56.     xrefv    c_faceclip
  57.     xrefa    modelorg
  58.     xrefv    xscale
  59.     xrefv    yscale
  60.     xrefv    xscaleinv
  61.     xrefv    yscaleinv
  62.     xrefv    xcenter
  63.     xrefv    ycenter
  64.     xrefa    vright
  65.     xrefa    vup
  66.     xrefa    vpn
  67.     xrefv    cacheoffset
  68.     xrefv    edge_p
  69.     xrefv    surfaces
  70.     xrefv    surface_p
  71.     xrefv    surf_max
  72.     xrefv    edge_max
  73.     xrefa    newedges
  74.     xrefa    removeedges
  75.     xrefa    view_clipplanes
  76.     xrefv    insubmodel
  77.     xrefv    currententity
  78.     xrefv    makeleftedge
  79.     xrefv    makerightedge
  80.     xrefv    INT2DBL_0
  81.     xrefv    c0
  82.     xrefv    c2
  83.  
  84.  
  85. #
  86. # defines
  87. #
  88.  
  89. .set    FULLY_CLIPPED_CACHED   ,0x80000000
  90. .set    FRAMECOUNT_MASK        ,0x7fffffff
  91.  
  92. .set    REFDEF_FVRECTX_ADJ     ,68
  93. .set    REFDEF_FVRECTY_ADJ     ,72
  94. .set    REFDEF_VRECTX_ADJ_S20  ,76
  95. .set    REFDEF_VRECTXR_ADJ_S20 ,80
  96. .set    REFDEF_FVRECTRIGHT_ADJ ,84
  97. .set    REFDEF_FVRECTBOTTOM_ADJ,88
  98.  
  99. .set    EDGE_U                 ,0
  100. .set    EDGE_U_STEP            ,4
  101. .set    EDGE_PREV              ,8
  102. .set    EDGE_NEXT              ,12
  103. .set    EDGE_SURFS             ,16
  104. .set    EDGE_NEXTREMOVE        ,20
  105. .set    EDGE_NEARZI            ,24
  106. .set    EDGE_OWNER             ,28
  107. .set    EDGE_SIZEOF_EXP        ,5
  108. .set    EDGE_SIZEOF            ,(1<<EDGE_SIZEOF_EXP)
  109.  
  110. .set    CLIP_NORMAL            ,0
  111. .set    CLIP_DIST              ,12
  112. .set    CLIP_NEXT              ,16
  113. .set    CLIP_LEFTEDGE          ,20
  114. .set    CLIP_RIGHTEDGE         ,21
  115. .set    CLIP_RESERVED          ,22
  116. .set    CLIP_SIZEOF            ,24
  117.  
  118. .set    MVERTEX_SIZEOF         ,12
  119.  
  120. .set    MEDGE_V                ,0
  121. .set    MEDGE_CEO              ,4
  122. .set    MEDGE_SIZEOF_EXP       ,3
  123. .set    MEDGE_SIZEOF           ,(1<<MEDGE_SIZEOF_EXP)
  124.  
  125. .set    MSURFACE_VISFRAME      ,0
  126. .set    MSURFACE_DLIGHTFRAME   ,4
  127. .set    MSURFACE_DLIGHTBITS    ,8
  128. .set    MSURFACE_PLANE         ,12
  129. .set    MSURFACE_FLAGS         ,16
  130. .set    MSURFACE_FIRSTEDGE     ,20
  131. .set    MSURFACE_NUMEDGES      ,24
  132. .set    MSURFACE_CACHESPOTS    ,28
  133. .set    MSURFACE_TEXTUREMINS   ,44
  134. .set    MSURFACE_EXTENTS       ,48
  135. .set    MSURFACE_TEXINFO       ,52
  136. .set    MSURFACE_STYLES        ,56
  137. .set    MSURFACE_SAMPLES       ,60
  138. .set    MSURFACE_SIZEOF_EXP    ,6
  139. .set    MSURFACE_SIZEOF        ,(1<<MSURFACE_SIZEOF_EXP)
  140.  
  141. .set    MPLANE_NORMAL          ,0
  142. .set    MPLANE_DIST            ,12
  143. .set    MPLANE_TYPE            ,16
  144. .set    MPLANE_SIGNBITS        ,17
  145. .set    MPLANE_SIZEOF          ,20
  146.  
  147. .set    SURF_NEXT              ,0
  148. .set    SURF_PREV              ,4
  149. .set    SURF_SPANS             ,8
  150. .set    SURF_KEY               ,12
  151. .set    SURF_LAST_U            ,16
  152. .set    SURF_SPANSTATE         ,20
  153. .set    SURF_FLAGS             ,24
  154. .set    SURF_DATA              ,28
  155. .set    SURF_ENTITY            ,32
  156. .set    SURF_NEARZI            ,36
  157. .set    SURF_INSUBMODEL        ,40
  158. .set    SURF_D_ZIORIGIN        ,44
  159. .set    SURF_D_ZISTEPU         ,48
  160. .set    SURF_D_ZISTEPV         ,52
  161. .set    SURF_SIZEOF_EXP        ,6
  162. .set    SURF_SIZEOF            ,(1<<SURF_SIZEOF_EXP)
  163.  
  164. .set    ENTITY_FORCELINK     ,0
  165. .set    ENTITY_UPDATE_TYPE   ,4
  166. .set    ENTITY_BASELINE      ,8
  167. .set    ENTITY_MSGTIME       ,52
  168. .set    ENTITY_MSG_ORIGINS   ,60
  169. .set    ENTITY_ORIGIN        ,84
  170. .set    ENTITY_MSG_ANGLES    ,96
  171. .set    ENTITY_ANGLES        ,120
  172. .set    ENTITY_MODEL         ,132
  173. .set    ENTITY_EFRAG         ,136
  174. .set    ENTITY_FRAME         ,140
  175. .set    ENTITY_SYNCBASE      ,144
  176. .set    ENTITY_COLORMAP      ,148
  177. .set    ENTITY_EFFECTS       ,152
  178. .set    ENTITY_SKINNUM       ,156
  179. .set    ENTITY_VISFRAME      ,160
  180. .set    ENTITY_DLIGHTFRAME   ,164
  181. .set    ENTITY_DLIGHTBITS    ,168
  182. .set    ENTITY_TRIVIAL_ACCEPT,172
  183. .set    ENTITY_TOPNODE       ,176
  184. .set    ENTITY_SIZEOF        ,216
  185.  
  186.  
  187.  
  188.  
  189. ###########################################################################
  190. #
  191. #       void R_EmitEdge (mvertex_t *pv0, mvertex_t *pv1)
  192. #
  193. ###########################################################################
  194.  
  195.     funcdef    R_EmitEdge
  196.  
  197.     init    0,16,0,7
  198.     stfd    f14,fb+0*8(r1)
  199.     stfd    f15,fb+1*8(r1)
  200.     stfd    f16,fb+2*8(r1)
  201.     stfd    f17,fb+3*8(r1)
  202.     stfd    f18,fb+4*8(r1)
  203.     stfd    f19,fb+5*8(r1)
  204.     stfd    f20,fb+6*8(r1)
  205.     ls    f0,c2
  206.     lf      f11,INT2DBL_0           #for int2dbl_setup
  207.     stfd    f11,local(r1)
  208.  
  209.         lxa     r12,r_refdef
  210.         lxa     r6,vright
  211.         lfs     f14,0(r6)
  212.         lfs     f15,4(r6)
  213.         lfs     f16,8(r6)
  214.         lxa     r6,vup
  215.         lfs     f17,0(r6)
  216.         lfs     f18,4(r6)
  217.         lfs     f19,8(r6)
  218.         lxa     r6,vpn
  219.         lfs     f20,0(r6)
  220.         lfs     f12,4(r6)
  221.         lfs     f13,8(r6)
  222.         lxa     r9,modelorg
  223.         ls      f10,cNEAR_CLIP
  224.  
  225. #        if (r_lastvertvalid)
  226. #        {
  227. #                u0 = r_u1;
  228. #                v0 = r_v1;
  229. #                lzi0 = r_lzi1;
  230. #                ceilv0 = r_ceilv1;
  231. #        }
  232.  
  233.         lw      r6,r_lastvertvalid
  234.         mr.     r6,r6
  235.         beq     .EEelse
  236.         ls      f1,r_u1                 #f1 = u0
  237.         ls      f2,r_v1                 #f2 = v0
  238.         ls      f3,r_lzi1               #f3 = lzi0
  239.         lw      r7,r_ceilv1             #r7 = ceilv0
  240.         b       .EEnext
  241.  
  242. #                world = &pv0->position[0];
  243. #
  244. #                VectorSubtract (world, modelorg, local);
  245. #                TransformVector (local, transformed);
  246. #
  247. #                if (transformed[2] < NEAR_CLIP)
  248. #                        transformed[2] = NEAR_CLIP;
  249. #
  250. #                lzi0 = 1.0 / transformed[2];
  251. #
  252. #                scale = xscale * lzi0;
  253. #                u0 = (xcenter + scale*transformed[0]);
  254. #                if (u0 < r_refdef.fvrectx_adj)
  255. #                        u0 = r_refdef.fvrectx_adj;
  256. #                if (u0 > r_refdef.fvrectright_adj)
  257. #                        u0 = r_refdef.fvrectright_adj;
  258. #
  259. #                scale = yscale * lzi0;
  260. #                v0 = (ycenter - scale*transformed[1]);
  261. #                if (v0 < r_refdef.fvrecty_adj)
  262. #                        v0 = r_refdef.fvrecty_adj;
  263. #                if (v0 > r_refdef.fvrectbottom_adj)
  264. #                        v0 = r_refdef.fvrectbottom_adj;
  265. #
  266. #                ceilv0 = (int) ceil(v0);
  267.  
  268. .EEelse:
  269.  
  270. ######  VectorSubtract (inlined)
  271.  
  272.         lfs     f1,0(r3)
  273.         lfs     f7,0(r9)
  274.         fsubs   f1,f1,f7                #f1 = local[0]
  275.         lfs     f2,4(r3)
  276.         lfs     f8,4(r9)
  277.         fsubs   f2,f2,f8                #f2 = local[1]
  278.         lfs     f3,8(r3)
  279.         lfs     f9,8(r9)
  280.         fsubs   f3,f3,f9                #f3 = local[2]
  281.  
  282. ######  TransformVector (inlined)
  283.  
  284.         fmuls   f7,f1,f14
  285.         fmuls   f8,f1,f17
  286.         fmuls   f9,f1,f20
  287.         fmadds  f7,f2,f15,f7
  288.         fmadds  f8,f2,f18,f8
  289.         fmadds  f9,f2,f12,f9
  290.         fmadds  f7,f3,f16,f7            #f7 = transformed[0]
  291.         fmadds  f8,f3,f19,f8            #f8 = transformed[1]
  292.         fmadds  f9,f3,f13,f9            #f9 = transformed[2]
  293.  
  294. ######  end of TransformVector
  295.  
  296.         fsubs   f1,f9,f10
  297.         ls      f2,xscale
  298.         fsel    f9,f1,f9,f10
  299.         ls      f4,yscale
  300.         fres    f3,f9                   #f3 = lzi0
  301.         ls      f5,ycenter
  302.         fmuls   f7,f7,f3
  303.         fmuls   f8,f8,f3
  304.         ls      f6,xcenter
  305.         lfs     f1,REFDEF_FVRECTX_ADJ(r12)
  306.         fmadds  f7,f2,f7,f6
  307.         lfs     f2,REFDEF_FVRECTY_ADJ(r12)
  308.         fnmsubs f8,f4,f8,f5
  309.         fsubs   f5,f7,f1
  310.         fsubs   f4,f8,f2
  311.         fsel    f7,f5,f7,f1
  312.         fsel    f8,f4,f8,f2
  313.         lfs     f1,REFDEF_FVRECTRIGHT_ADJ(r12)
  314.         fsubs   f5,f1,f7
  315.         lfs     f2,REFDEF_FVRECTBOTTOM_ADJ(r12)
  316.         fsubs   f4,f2,f8
  317.         fsel    f1,f5,f7,f1             #f1 = u0
  318.         fsel    f2,f4,f8,f2             #f2 = v0
  319.         mffs    f7
  320.         mtfsfi  cr7,2
  321.         fctiw   f4,f2
  322.         stfd    f4,local+8(r1)
  323.         lwz     r7,local+12(r1)         #r7 = ceilv0
  324.         mtfsf   1,f7
  325. .EEnext:
  326.  
  327. #        world = &pv1->position[0];
  328. #
  329. #// transform and project
  330. #        VectorSubtract (world, modelorg, local);
  331. #        TransformVector (local, transformed);
  332. #
  333. #        if (transformed[2] < NEAR_CLIP)
  334. #                transformed[2] = NEAR_CLIP;
  335. #
  336. #        r_lzi1 = 1.0 / transformed[2];
  337. #
  338. #        scale = xscale * r_lzi1;
  339. #        r_u1 = (xcenter + scale*transformed[0]);
  340. #        if (r_u1 < r_refdef.fvrectx_adj)
  341. #                r_u1 = r_refdef.fvrectx_adj;
  342. #        if (r_u1 > r_refdef.fvrectright_adj)
  343. #                r_u1 = r_refdef.fvrectright_adj;
  344. #
  345. #        scale = yscale * r_lzi1;
  346. #        r_v1 = (ycenter - scale*transformed[1]);
  347. #        if (r_v1 < r_refdef.fvrecty_adj)
  348. #                r_v1 = r_refdef.fvrecty_adj;
  349. #        if (r_v1 > r_refdef.fvrectbottom_adj)
  350. #                r_v1 = r_refdef.fvrectbottom_adj;
  351.  
  352. ######  VectorSubtract (inlined)
  353.  
  354.         lfs     f4,0(r4)
  355.         lfs     f7,0(r9)
  356.         fsubs   f4,f4,f7                #f4 = local[0]
  357.         lfs     f5,4(r4)
  358.         lfs     f8,4(r9)
  359.         fsubs   f5,f5,f8                #f5 = local[1]
  360.         lfs     f6,8(r4)
  361.         lfs     f9,8(r9)
  362.         fsubs   f6,f6,f9                #f6 = local[2]
  363.  
  364. ######  TransformVector (inlined)
  365.  
  366.         fmuls   f7,f4,f14
  367.         fmuls   f8,f4,f17
  368.         fmuls   f9,f4,f20
  369.         fmadds  f7,f5,f15,f7
  370.         fmadds  f8,f5,f18,f8
  371.         fmadds  f9,f5,f12,f9
  372.         fmadds  f7,f6,f16,f7            #f7 = transformed[0]
  373.         fmadds  f8,f6,f19,f8            #f8 = transformed[1]
  374.         fmadds  f9,f6,f13,f9            #f9 = transformed[2]
  375.  
  376. ######  end of TransformVector
  377.  
  378.         fsubs   f5,f9,f10
  379.         fsel    f9,f5,f9,f10
  380.         ls      f6,ycenter
  381.         fres    f4,f9                   #f4 = r_lzi1
  382.         ls      f5,xscale
  383.         fmuls   f7,f7,f4
  384.         ls      f9,xcenter
  385.         fmuls   f8,f8,f4
  386.         ls      f10,yscale
  387.         fmadds  f7,f5,f7,f9
  388.         fnmsubs f8,f10,f8,f6
  389.         lfs     f10,REFDEF_FVRECTX_ADJ(r12)
  390.         fsubs   f5,f7,f10
  391.         lfs     f9,REFDEF_FVRECTY_ADJ(r12)
  392.         ss      f4,r_lzi1
  393.         fsubs   f6,f8,f9
  394.         fsel    f7,f5,f7,f10
  395.         fsel    f8,f6,f8,f9
  396.         lfs     f9,REFDEF_FVRECTRIGHT_ADJ(r12)
  397.         fsubs   f5,f9,f7
  398.         lfs     f10,REFDEF_FVRECTBOTTOM_ADJ(r12)
  399.         fsubs   f6,f10,f8
  400.         fsel    f5,f5,f7,f9             #f5 = r_u1
  401.         fsel    f6,f6,f8,f10            #f6 = r_v1
  402.         ss      f5,r_u1
  403.         mffs    f7
  404.         mtfsfi  cr7,2
  405.         fctiw   f8,f6
  406.         ss      f6,r_v1
  407.         stfd    f8,local+8(r1)
  408.         lwz     r10,local+12(r1)        #r10 = r_ceilv1
  409.         mtfsf   1,f7
  410.  
  411.  
  412. #        if (r_lzi1 > lzi0)
  413. #                lzi0 = r_lzi1;
  414. #
  415. #        if (lzi0 > r_nearzi)    // for mipmap finding
  416. #                r_nearzi = lzi0;
  417. #
  418. #// for right edges, all we want is the effect on 1/z
  419. #        if (r_nearzionly)
  420. #                return;
  421. #
  422. #        r_emitted = 1;
  423. #
  424. #        r_ceilv1 = (int) ceil(r_v1);
  425.  
  426.         fsubs   f8,f3,f4
  427.         fsel    f3,f8,f3,f4
  428.         ls      f8,r_nearzi
  429.         fsubs   f7,f8,f3
  430.         fsel    f8,f7,f8,f3
  431.         ss      f8,r_nearzi
  432.         lw      r11,r_nearzionly
  433.         mr.     r11,r11
  434.         bne     .EEexit1
  435.         sw      r10,r_ceilv1
  436.         li      r12,1
  437.         sw      r12,r_emitted
  438.  
  439. #        if (ceilv0 == r_ceilv1)
  440. #        {
  441. #        // we cache unclipped horizontal edges as fully clipped
  442. #                if (cacheoffset != 0x7FFFFFFF)
  443. #                {
  444. #                        cacheoffset = FULLY_CLIPPED_CACHED |
  445. #                                        (r_framecount & FRAMECOUNT_MASK);
  446. #                }
  447. #
  448. #                return;         // horizontal edge
  449. #        }
  450.  
  451.         cmpw    r10,r7
  452.         bne     .EEcont13
  453.         lw      r12,cacheoffset
  454.         lis     r11,0x7fffffff@h
  455.         ori     r11,r11,0x7fffffff@l
  456.         cmpw    r11,r12
  457.         beq     .EEexit1
  458.         lw      r11,r_framecount
  459.         lis     r4,FRAMECOUNT_MASK@h
  460.         ori     r4,r4,FRAMECOUNT_MASK@l
  461.         and     r11,r11,r4
  462.         lis     r3,FULLY_CLIPPED_CACHED@h
  463.         ori     r3,r3,FULLY_CLIPPED_CACHED@l
  464.         or      r11,r11,r3
  465.         sw      r11,cacheoffset
  466.         b       .EEexit1
  467.  
  468. #        side = ceilv0 > r_ceilv1;
  469. #
  470. #        edge = edge_p++;
  471. #
  472. #        edge->owner = r_pedge;
  473. #
  474. #        edge->nearzi = lzi0;
  475.  
  476. .EEcont13:
  477.         fsubs   f9,f2,f6
  478.         lw      r9,edge_p
  479.         fsubs   f8,f1,f5
  480.         stfs    f3,EDGE_NEARZI(r9)
  481.         addi    r11,r9,EDGE_SIZEOF
  482.         fneg    f7,f8
  483.         sw      r11,edge_p
  484.         lw      r12,r_pedge
  485.         fsel    f8,f9,f8,f7
  486.         stw     r12,EDGE_OWNER(r9)
  487.         fneg    f7,f9
  488.  
  489. #        if (side == 0)
  490. #        {
  491. #        // trailing edge (go from p1 to p2)
  492. #                v = ceilv0;
  493. #                v2 = r_ceilv1 - 1;
  494. #
  495. #                edge->surfs[0] = surface_p - surfaces;
  496. #                edge->surfs[1] = 0;
  497. #
  498. #                u_step = ((r_u1 - u0) / (r_v1 - v0));
  499. #                u = u0 + ((float)v - v0) * u_step;
  500. #        }
  501.  
  502.         cmpw    r7,r10
  503.         fsel    f9,f9,f9,f7
  504.         lw      r5,surface_p
  505.         bgt     .EEelse2
  506.         mr      r11,r7                  #r11 = v = ceilv0
  507.         lw      r6,surfaces
  508.         fmuls   f7,f9,f9
  509.         subf    r5,r6,r5
  510.         subi    r12,r10,1               #r12 = r_ceilv1 - 1
  511.         slwi    r5,r5,10
  512.         frsqrte f7,f7
  513.         lxa     r10,r_refdef
  514.         stw     r5,EDGE_SURFS(r9)
  515.         fnmsubs f4,f7,f9,f0
  516.     int2dbl    f5,r11,r8,local,f11
  517.         fmuls   f7,f7,f4
  518.         li      r4,1
  519.         lwz     r5,REFDEF_VRECTXR_ADJ_S20(r10)
  520.         fnmsubs f4,f7,f9,f0
  521.         fsubs   f5,f5,f2
  522.         lwz     r10,REFDEF_VRECTX_ADJ_S20(r10)
  523.         fmuls   f7,f7,f4
  524.         slwi    r11,r11,2
  525.         fmuls   f8,f7,f8
  526.         slwi    r12,r12,2
  527.         ls      f9,c16times65536
  528.         fmadds  f7,f5,f8,f1             #f7 = u
  529.         b       .EEcont14
  530.  
  531. #        {
  532. #        // leading edge (go from p2 to p1)
  533. #                v2 = ceilv0 - 1;
  534. #                v = r_ceilv1;
  535. #
  536. #                edge->surfs[0] = 0;
  537. #                edge->surfs[1] = surface_p - surfaces;
  538. #
  539. #                u_step = ((u0 - r_u1) / (v0 - r_v1));
  540. #                u = r_u1 + ((float)v - r_v1) * u_step;
  541. #        }
  542.  
  543. .EEelse2:
  544.         fsel    f9,f9,f9,f7
  545.         mr      r11,r10                 #r11 = v = r_ceilv1
  546.         lw      r6,surfaces
  547.         fmuls   f7,f9,f9
  548.         subf    r5,r6,r5
  549.         subi    r12,r7,1                #r12 = ceilv0 - 1
  550.         srawi   r5,r5,6
  551.         frsqrte f7,f7
  552.         clrlwi  r5,r5,16
  553.         stw     r5,EDGE_SURFS(r9)
  554.         fnmsubs f4,f7,f9,f0
  555.         lxa     r10,r_refdef
  556.     int2dbl    f1,r11,r8,local,f11
  557.         fmuls   f7,f7,f4
  558.         li      r4,0
  559.         lwz     r5,REFDEF_VRECTXR_ADJ_S20(r10)
  560.         fnmsubs f4,f7,f9,f0
  561.         fsubs   f1,f1,f6
  562.         lwz     r10,REFDEF_VRECTX_ADJ_S20(r10)
  563.         fmuls   f7,f7,f4
  564.         slwi    r11,r11,2
  565.         fmuls   f8,f7,f8
  566.         slwi    r12,r12,2
  567.         ls      f9,c16times65536
  568.         fmadds  f7,f1,f8,f5             #f7 = u
  569.  
  570. #        edge->u_step = u_step*0x100000;
  571. #        edge->u = u*0x100000 + 0xFFFFF;
  572.  
  573. .EEcont14:
  574.         fmuls   f8,f8,f9
  575.         lis     r3,0xfffff@h
  576.         ori     r3,r3,0xfffff@l
  577.         fctiwz  f1,f8
  578.         stfd    f1,local+8(r1)
  579.         lwz     r0,local+12(r1)
  580.         stw     r0,EDGE_U_STEP(r9)
  581.         fmuls   f7,f7,f9
  582.         fctiwz  f1,f7
  583.         stfd    f1,local+8(r1)
  584.         lwz     r0,local+12(r1)
  585.         add     r6,r0,r3
  586.  
  587. #        if (edge->u < r_refdef.vrect_x_adj_shift20)
  588. #                edge->u = r_refdef.vrect_x_adj_shift20;
  589. #        if (edge->u > r_refdef.vrectright_adj_shift20)
  590. #                edge->u = r_refdef.vrectright_adj_shift20;
  591.  
  592.         cmpw    r6,r10
  593.         bge     .EEcont15
  594.         mr      r6,r10
  595. .EEcont15:
  596.         cmpw    r6,r5
  597.         ble     .EEcont16
  598.         mr      r6,r5
  599.  
  600. #        u_check = edge->u;
  601. #        if (edge->surfs[0])
  602. #                u_check++;      // sort trailers after leaders
  603. #
  604. #        if (!newedges[v] || newedges[v]->u >= u_check)
  605. #        {
  606. #                edge->next = newedges[v];
  607. #                newedges[v] = edge;
  608. #        }
  609. #        else
  610. #        {
  611. #                pcheck = newedges[v];
  612. #                while (pcheck->next && pcheck->next->u < u_check)
  613. #                        pcheck = pcheck->next;
  614. #                edge->next = pcheck->next;
  615. #                pcheck->next = edge;
  616. #        }
  617.  
  618. .EEcont16:
  619.         lxa     r5,newedges
  620.         stw     r6,EDGE_U(r9)
  621.         lxa     r7,removeedges
  622.         add     r6,r6,r4
  623.         lwzx    r3,r5,r11
  624.         mr.     r3,r3
  625.         beq     .EEcont18
  626.         lwz     r4,EDGE_U(r3)
  627.         cmpw    r6,r4
  628.         bgt     .EEloop
  629. .EEcont18:
  630.         stw     r3,EDGE_NEXT(r9)
  631.         stwx    r9,r5,r11
  632.         b       .EEcont21
  633. .EEloop:
  634.         lwz     r5,EDGE_NEXT(r3)
  635.         mr.     r5,r5
  636.         beq     .EEcont20
  637.         mr      r0,r3
  638.         mr      r3,r5
  639.         lwz     r4,EDGE_U(r5)
  640.         cmpw    r6,r4
  641.         bgt     .EEloop
  642.         mr      r3,r0
  643. .EEcont20:
  644.         stw     r5,EDGE_NEXT(r9)
  645.         stw     r9,EDGE_NEXT(r3)
  646.  
  647. #        edge->nextremove = removeedges[v2];
  648. #        removeedges[v2] = edge;
  649.  
  650. .EEcont21:
  651.         lwzx    r3,r7,r12
  652.         stw     r3,EDGE_NEXTREMOVE(r9)
  653.         stwx    r9,r7,r12
  654.  
  655. .EEexit1:
  656.     lfd    f14,fb+0*8(r1)
  657.     lfd    f15,fb+1*8(r1)
  658.     lfd    f16,fb+2*8(r1)
  659.     lfd    f17,fb+3*8(r1)
  660.     lfd    f18,fb+4*8(r1)
  661.     lfd    f19,fb+5*8(r1)
  662.     lfd    f20,fb+6*8(r1)
  663.     exit
  664.  
  665.     funcend    R_EmitEdge
  666.  
  667.  
  668.  
  669.  
  670. ###########################################################################
  671. #
  672. #       void R_ClipEdge (mvertex_t *pv0, mvertex_t *pv1, clipplane_t *clip)
  673. #
  674. ###########################################################################
  675.  
  676.     funcdef    R_ClipEdge
  677.  
  678.     init    0,16,0,0
  679.     la    r6,local(r1)
  680.  
  681.         mr.     r5,r5
  682.         beq     .CEadd
  683.         ls      f10,c0
  684. .CEloop:
  685.  
  686. #       d0 = DotProduct (pv0->position, clip->normal) - clip->dist;
  687. #       d1 = DotProduct (pv1->position, clip->normal) - clip->dist;
  688.  
  689.         lfs     f1,CLIP_NORMAL(r5)
  690.         lfs     f2,CLIP_NORMAL+4(r5)
  691.         lfs     f3,CLIP_NORMAL+8(r5)
  692.         lfs     f9,CLIP_DIST(r5)
  693.         lfs     f4,0(r3)                #f4 = pv0->position[0]
  694.         fmsubs  f7,f4,f1,f9
  695.         lfs     f5,4(r3)                #f5 = pv0->position[1]
  696.         fmadds  f7,f5,f2,f7
  697.         lfs     f6,8(r3)                #f6 = pv0->position[2]
  698.         fmadds  f7,f6,f3,f7             #f7 = d0
  699.         lfs     f8,0(r4)                #f8 = pv1->position[0]
  700.         fmsubs  f1,f8,f1,f9
  701.         lfs     f9,4(r4)                #f9 = pv1->position[1]
  702.         fmadds  f1,f9,f2,f1
  703.         lfs     f2,8(r4)                #f2 = pv1->position[2]
  704.         fmadds  f1,f2,f3,f1             #f1 = d1
  705.  
  706. #                        if (d0 >= 0)
  707. #                        {
  708. #                        // point 0 is unclipped
  709. #                                if (d1 >= 0)
  710. #                                {
  711. #                                // both points are unclipped
  712. #                                        continue;
  713. #                                }
  714.  
  715.         fcmpo   cr0,f7,f10
  716.         blt     .CEless
  717.         fcmpo   cr0,f1,f10
  718.         bge     .CEloopend
  719.  
  720. #                                cacheoffset = 0x7FFFFFFF;
  721. #
  722. #                                f = d0 / (d0 - d1);
  723. #                                clipvert.position[0] = pv0->position[0] +
  724. #                                                f * (pv1->position[0] - pv0->position[0]);
  725. #                                clipvert.position[1] = pv0->position[1] +
  726. #                                                f * (pv1->position[1] - pv0->position[1]);
  727. #                                clipvert.position[2] = pv0->position[2] +
  728. #                                                f * (pv1->position[2] - pv0->position[2]);
  729.  
  730.         lis     r7,0x7fffffff@h
  731.         ori     r7,r7,0x7fffffff@l
  732.         sw      r7,cacheoffset
  733.         fsubs   f3,f7,f1
  734.         fdivs   f3,f7,f3
  735.         fsubs   f8,f8,f4
  736.         fsubs   f9,f9,f5
  737.         fsubs   f2,f2,f6
  738.         fmadds  f8,f8,f3,f4
  739.         stfs    f8,0(r6)
  740.         fmadds  f9,f9,f3,f5
  741.         stfs    f9,4(r6)
  742.         fmadds  f2,f2,f3,f6
  743.         stfs    f2,8(r6)
  744.  
  745. #                                if (clip->leftedge)
  746. #                                {
  747. #                                        r_leftclipped = true;
  748. #                                        r_leftexit = clipvert;
  749. #                                }
  750.  
  751.         lbz     r7,CLIP_LEFTEDGE(r5)
  752.         mr.     r7,r7
  753.         beq     .CEelse
  754.     li    r0,1
  755.     sw    r0,r_leftclipped
  756.         lxa     r11,r_leftexit
  757.         lwz     r7,0(r6)
  758.         stw     r7,0(r11)
  759.         lwz     r8,4(r6)
  760.         stw     r8,4(r11)
  761.         lwz     r9,8(r6)
  762.         stw     r9,8(r11)
  763.         b       .CEcont
  764.  
  765. #                                else if (clip->rightedge)
  766. #                                {
  767. #                                        r_rightclipped = true;
  768. #                                        r_rightexit = clipvert;
  769. #                                }
  770.  
  771. .CEelse:
  772.     li    r0,1
  773.     sw    r0,r_rightclipped
  774.         lxa     r11,r_rightexit
  775.         lwz     r7,0(r6)
  776.         stw     r7,0(r11)
  777.         lwz     r8,4(r6)
  778.         stw     r8,4(r11)
  779.         lwz     r9,8(r6)
  780.         stw     r9,8(r11)
  781.  
  782. #                                R_ClipEdge (pv0, &clipvert, clip->next);
  783. #                                return;
  784.  
  785. .CEcont:
  786.         mr      r4,r6
  787.         lwz     r5,CLIP_NEXT(r5)
  788.         call    R_ClipEdge
  789.         b       .CEexit
  790.  
  791. #                                if (d1 < 0)
  792. #                                {
  793. #                                // both points are clipped
  794. #                                // we do cache fully clipped edges
  795. #                                        if (!r_leftclipped)
  796. #                                                cacheoffset = FULLY_CLIPPED_CACHED |
  797. #                                                                (r_framecount & FRAMECOUNT_MASK);
  798. #                                        return;
  799. #                                }
  800.  
  801. .CEless:
  802.         fcmpo   cr0,f1,f10
  803.         bge     .CEcont2
  804.         lw      r7,r_leftclipped
  805.         mr.     r7,r7
  806.         bne     .CEexit
  807.         lis     r9,FULLY_CLIPPED_CACHED@h
  808.         ori     r9,r9,FULLY_CLIPPED_CACHED@l
  809.         lis     r7,FRAMECOUNT_MASK@h
  810.         ori     r7,r7,FRAMECOUNT_MASK@l
  811.         lw      r8,r_framecount
  812.         and     r8,r8,r7
  813.         or      r8,r8,r9
  814.         sw      r8,cacheoffset
  815.         b       .CEexit
  816.  
  817. #                                r_lastvertvalid = false;
  818. #
  819. #                        // we don't cache partially clipped edges
  820. #                                cacheoffset = 0x7FFFFFFF;
  821. #
  822. #                                f = d0 / (d0 - d1);
  823. #                                clipvert.position[0] = pv0->position[0] +
  824. #                                                f * (pv1->position[0] - pv0->position[0]);
  825. #                                clipvert.position[1] = pv0->position[1] +
  826. #                                                f * (pv1->position[1] - pv0->position[1]);
  827. #                                clipvert.position[2] = pv0->position[2] +
  828. #                                                f * (pv1->position[2] - pv0->position[2]);
  829.  
  830. .CEcont2:
  831.     li    r0,0
  832.         sw    r0,r_lastvertvalid
  833.         lis     r7,0x7fffffff@h
  834.         ori     r7,r7,0x7fffffff@l
  835.         sw      r7,cacheoffset
  836.         fsubs   f3,f7,f1
  837.         fdivs   f3,f7,f3
  838.         fsubs   f8,f8,f4
  839.         fsubs   f9,f9,f5
  840.         fsubs   f2,f2,f6
  841.         fmadds  f8,f8,f3,f4
  842.         stfs    f8,0(r6)
  843.         fmadds  f9,f9,f3,f5
  844.         stfs    f9,4(r6)
  845.         fmadds  f2,f2,f3,f6
  846.         stfs    f2,8(r6)
  847.  
  848. #                                if (clip->leftedge)
  849. #                                {
  850. #                                        r_leftclipped = true;
  851. #                                        r_leftenter = clipvert;
  852. #                                }
  853.  
  854.         lbz     r7,CLIP_LEFTEDGE(r5)
  855.         mr.     r7,r7
  856.         beq     .CEelse2
  857.     li    r0,1
  858.         sw    r0,r_leftclipped
  859.         lxa     r11,r_leftenter
  860.         lwz     r7,0(r6)
  861.         stw     r7,0(r11)
  862.         lwz     r8,4(r6)
  863.         stw     r8,4(r11)
  864.         lwz     r9,8(r6)
  865.         stw     r9,8(r11)
  866.         b       .CEcont3
  867.  
  868. #                                else if (clip->rightedge)
  869. #                                {
  870. #                                        r_rightclipped = true;
  871. #                                        r_rightenter = clipvert;
  872. #                                }
  873.  
  874. .CEelse2:
  875.     li    r0,1
  876.         sw    r0,r_rightclipped
  877.         lxa     r11,r_rightenter
  878.         lwz     r7,0(r6)
  879.         stw     r7,0(r11)
  880.         lwz     r8,4(r6)
  881.         stw     r8,4(r11)
  882.         lwz     r9,8(r6)
  883.         stw     r9,8(r11)
  884.  
  885. #                                R_ClipEdge (&clipvert, pv1, clip->next);
  886. #                                return;
  887.  
  888. .CEcont3:
  889.         mr      r3,r6
  890.         lwz     r5,CLIP_NEXT(r5)
  891.         call    R_ClipEdge
  892.         b       .CEexit
  893.  
  894. #                } while ((clip = clip->next) != NULL);
  895.  
  896. .CEloopend:
  897.         lwz     r5,CLIP_NEXT(r5)
  898.         mr.     r5,r5
  899.         bne     .CEloop
  900.  
  901. #        R_EmitEdge (pv0, pv1);
  902.  
  903. .CEadd:
  904.         call    R_EmitEdge
  905.  
  906. .CEexit:
  907.     exit
  908.  
  909.     funcend    R_ClipEdge
  910.  
  911.  
  912.  
  913.  
  914. .ifdef    WOS
  915.     .tocd
  916. .else
  917.     .data
  918. .endif
  919.  
  920. lab cNEAR_CLIP
  921.     .float    0.01            #must match the def. in r_local.h
  922. lab c16times65536
  923.     .float    1048576.0
  924.