home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / r_sky68k.s < prev    next >
Text File  |  2000-06-17  |  4KB  |  130 lines
  1. * 
  2. * Copyright (C) 1996-1997 Id Software, Inc. 
  3. * 
  4. * This program is free software; you can redistribute it and/or 
  5. * modify it under the terms of the GNU General Public License 
  6. * as published by the Free Software Foundation; either version 2 
  7. * of the License, or (at your option) any later version. 
  8. * 
  9. * This program is distributed in the hope that it will be useful, 
  10. * but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. * 
  13. * See the GNU General Public License for more details. 
  14. * 
  15. * You should have received a copy of the GNU General Public License 
  16. * along with this program; if not, write to the Free Software 
  17. * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. * 
  19.  
  20. **
  21. ** Quake for AMIGA
  22. ** r_sky.c assembler implementations by Frank Wille <frank@phoenix.owl.de>
  23. **
  24.  
  25.         XREF    _r_skymade
  26.         XREF    _bottommask
  27.         XREF    _bottomsky
  28.         XREF    _newsky
  29.         XREF    _skytime
  30.         XREF    _skyspeed
  31.  
  32.  
  33.         XDEF    _R_MakeSky
  34.  
  35. SKYSHIFT                =       7
  36. SKYSIZE                 =       (1 << SKYSHIFT)
  37. SKYMASK                 =       (SKYSIZE - 1)
  38.  
  39.  
  40. ******************************************************************************
  41. *
  42. *       void R_MakeSky (void)
  43. *
  44. *       This function contains unaligned accesses to longwords (supported
  45. *       by 68K)
  46. *
  47. ******************************************************************************
  48.  
  49.         cnop    0,4
  50. _R_MakeSky
  51.  
  52. *        xshift = skytime*skyspeed;
  53. *        yshift = skytime*skyspeed;
  54. *
  55. *        if ((xshift == xlast) && (yshift == ylast))
  56. *                return;
  57. *
  58. *        xlast = xshift;
  59. *        ylast = yshift;
  60. *
  61. *        pnewsky = (unsigned *)&newsky[0];
  62.  
  63.         movem.l d2-d5/a2,-(sp)
  64.         lea     _bottommask,a1
  65.         lea     _bottomsky,a2
  66.         fmove.s _skytime,fp0            ;xshift = skytime*skyspeed
  67.         fmul.s  _skyspeed,fp0
  68.         fmove.l fp0,d0
  69.         cmp.l   _xlast,d0               ;if (xshift==xlast)&&(yshift==ylast)
  70.         bne.b   .cont
  71.         cmp.l   _ylast,d0
  72.         beq.b   .exit                   ;return
  73. .cont
  74.         move.l  d0,_xlast               ;_xlast = xshift
  75.         move.l  d0,_ylast               ;_ylast = yshift
  76.         lea     _newsky,a0              ;pnewsky = (unsigned *)&newsky[0]
  77.  
  78. *        for (y=0 ; y<SKYSIZE ; y++)
  79. *        {
  80. *                baseofs = ((y+yshift) & SKYMASK) * 131;
  81. *
  82. *                for (x=0 ; x<SKYSIZE ; x += 4)
  83. *                {
  84. *                        ofs = baseofs + ((x+xshift) & SKYMASK);
  85. *
  86. *                // PORT: unaligned dword access to bottommask and bottomsky
  87. *
  88. *                        *pnewsky = (*(pnewsky + (128 / sizeof (unsigned))) &
  89. *                                                *(unsigned *)&bottommask[ofs]) |
  90. *                                                *(unsigned *)&bottomsky[ofs];
  91. *                        pnewsky++;
  92. *                }
  93. *
  94. *                pnewsky += 128 / sizeof (unsigned);
  95. *        }
  96. *
  97. *        r_skymade = 1;
  98.  
  99.  
  100.         moveq   #0,d1
  101. .loop
  102.         move.l  d1,d2
  103.         add.l   d0,d2                   ;d2 = y+yshift
  104.         and.l   #SKYMASK,d2             ;d2 = (y+yshift)&SKYMASK
  105.         muls    #131,d2                 ;baseofs = d2 * 131
  106.         moveq   #0,d3
  107. .loop2
  108.         move.l  d3,d4
  109.         add.l   d0,d4                   ;d3 = x+xshift
  110.         and.l   #SKYMASK,d4             ;d3 = (x+xshift)&SKYMASK
  111.         add.l   d2,d4                   ;ofs = baseofs + d3
  112.         move.l  0(a1,d4.l),d5           ;*(unsigned *)&bottommask[ofs]
  113.         and.l   128(a0),d5              ;& (*(pnewsky + (128/sizeof(unsigned)))
  114.         or.l    0(a2,d4.l),d5           ;| *(unsigned *)&bottomsky[ofs]
  115.         move.l  d5,(a0)+                ;*pnewsky = d5; pnewsky++
  116.         addq.l  #4,d3                   ;x += 4
  117.         cmp.l   #SKYSIZE,d3
  118.         blt.b   .loop2
  119.         lea     128(a0),a0              ;pnewsky += 128/sizeof(unsigned)
  120.         addq.l  #1,d1                   ;y++
  121.         cmp.l   #SKYSIZE,d1
  122.         blt.b   .loop
  123.         move.b  #1,_r_skymade           ;r_skymade = 1
  124. .exit
  125.         movem.l (sp)+,d2-d5/a2
  126.         rts
  127.  
  128. _xlast          dc.l    -1
  129. _ylast          dc.l    -1
  130.