home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / sys_timer68k.s < prev    next >
Text File  |  2000-06-17  |  4KB  |  210 lines
  1. * 
  2. * Copyright (C) 1996-1997 Id Software, Inc. 
  3. * 
  4. * This program is free software; you can redistribute it and/or 
  5. * modify it under the terms of the GNU General Public License 
  6. * as published by the Free Software Foundation; either version 2 
  7. * of the License, or (at your option) any later version. 
  8. * 
  9. * This program is distributed in the hope that it will be useful, 
  10. * but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. * 
  13. * See the GNU General Public License for more details. 
  14. * 
  15. * You should have received a copy of the GNU General Public License 
  16. * along with this program; if not, write to the Free Software 
  17. * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. * 
  19.  
  20.  
  21. ; M68k support routines for determining PPC bus clock.
  22. ; Reserves/frees CIA timer for PPC.
  23. ; Based on powerpc.library source by Sam Jordan. Thanks Sam!
  24. ; ** This code is used for the PowerUp port only **
  25.  
  26.  
  27.     include    "exec/interrupts.i"
  28.     include    "devices/timer.i"
  29.     include    "hardware/cia.i"
  30.  
  31.  
  32. ; exec, timer and cia LVOs (PowerUp amiga.lib doesn't include those?)
  33. _LVODisable        =    -120
  34. _LVOEnable        =    -126
  35. _LVOOpenResource    =    -498
  36. _LVOCacheClearU        =    -636
  37. _LVOReadEClock        =    -60
  38. _LVOAddICRVector    =    -6
  39. _LVORemICRVector    =    -12
  40. _LVOAbleICR        =    -18
  41.  
  42. ; The CIAs
  43. CIA_A            =    $bfe001
  44. CIA_B            =    $bfd000
  45.  
  46. ; CIATIMER structure
  47. CIATIMER_RESOURCE    =    0
  48. CIATIMER_INTERRUPT    =    4
  49. CIATIMER_CONTROL    =    8
  50. CIATIMER_LOW        =    12
  51. CIATIMER_HIGH        =    16
  52. CIATIMER_STOPMASK    =    20
  53. CIATIMER_STARTMASK    =    21
  54. CIATIMER_ICRBIT        =    22
  55. CIATIMER_ECLOCK        =    24
  56. CIATIMER_SIZE        =    28
  57.  
  58. ; macros
  59.     macro    CALLSYS
  60.     move.l    SysBase,a6
  61.     jsr    _LVO\1(a6)
  62.     endm
  63.  
  64.  
  65. ; external symbols (from PPC)
  66.  
  67.     xref    SysBase
  68.     xref    TimerBase
  69.  
  70.  
  71.  
  72.     code
  73.  
  74.  
  75.  
  76.     cnop    0,4
  77.     xdef    ReserveCIA
  78. ReserveCIA:
  79. ; Reserves a CIA timer and initializes ciatimer structure.
  80. ; a0 = ciatimer structure pointer
  81. ; -> d0 = success (0=error, -1=success)
  82.  
  83.     movem.l    d1-d7/a0-a6,-(sp)
  84.     move.l    a0,d2
  85.     lea    DummyInt,a3
  86.     lea    DummyIntName(pc),a0
  87.     move.l    a0,LN_NAME(a3)
  88.     clr.l    IS_DATA(a3)
  89.     lea    DummyInterrupt(pc),a0
  90.     move.l    a0,IS_CODE(a3)
  91.     lea    CIA_A,a5
  92.     lea    CIAA_name(pc),a1
  93.     CALLSYS    OpenResource
  94.     tst.l    d0
  95.     beq    .error
  96. .loop:
  97.     move.l    d0,a2
  98.     CALLSYS    Disable
  99.     move.l    #ciacra,d7
  100.     move.l    #ciatalo,d6
  101.     move.l    #ciatahi,d5
  102.     move.b    #CIACRAF_TODIN|CIACRAF_PBON|CIACRAF_OUTMODE|CIACRAF_SPMODE,d4
  103.     move.b    #CIACRAF_START,d3
  104.     move.l    a2,a6
  105.     move.w    #CIAICRB_TA,d0
  106.     move.l    d0,-(sp)
  107.     move.l    a3,a1
  108.     jsr    _LVOAddICRVector(a6)
  109.     move.l    (sp)+,d1
  110.     tst.l    d0
  111.     beq    .timerfound
  112.     move.b    #CIACRBF_ALARM|CIACRBF_PBON|CIACRBF_OUTMODE,d4
  113.     move.b    #CIACRBF_START,d3
  114.     move.l    a2,a6
  115.     move.w    #CIAICRB_TB,d0
  116.     move.l    d0,-(sp)
  117.     move.l    a3,a1
  118.     jsr    _LVOAddICRVector(a6)
  119.     move.l    (sp)+,d1
  120.     tst.l    d0
  121.     beq    .timerfound
  122.     CALLSYS    Enable
  123.     lea    CIA_B,a5
  124.     lea    CIAB_name(pc),a1
  125.     CALLSYS    OpenResource
  126.     tst.l    d0
  127.     beq    .error
  128.     bra    .loop
  129.  
  130. .timerfound:
  131.     move.l    a2,a6
  132.     move.w    d1,d0
  133.     move.l    d1,-(sp)
  134.     CALLSYS    AbleICR
  135.     CALLSYS    Enable
  136.     move.l    (sp)+,d1
  137.     move.l    d2,a0
  138.     add.l    a5,d7
  139.     add.l    a5,d6
  140.     add.l    a5,d5
  141.     move.l    a2,CIATIMER_RESOURCE(a0)
  142.     move.l    a3,CIATIMER_INTERRUPT(a0)
  143.     move.l    d7,CIATIMER_CONTROL(a0)
  144.     move.l    d6,CIATIMER_LOW(a0)
  145.     move.l    d5,CIATIMER_HIGH(a0)
  146.     move.b    d4,CIATIMER_STOPMASK(a0)
  147.     move.b    d3,CIATIMER_STARTMASK(a0)
  148.     move.w    d1,CIATIMER_ICRBIT(a0)
  149.     bsr    GetEClock
  150.     move.l    d0,CIATIMER_ECLOCK(a0)
  151.     CALLSYS    CacheClearU
  152.     moveq    #-1,d0
  153.     bra.b    .end
  154.  
  155. .error:
  156.     moveq    #0,d0
  157. .end:
  158.     movem.l (sp)+,d1-d7/a0-a6
  159.     rts
  160.  
  161. CIAA_name:
  162.     dc.b    "ciaa.resource",0
  163. CIAB_name:
  164.     dc.b    "ciab.resource",0
  165. DummyIntName:
  166.     dc.b    "Quake Bus Clock Measuring",0
  167.  
  168.  
  169.     cnop    0,4
  170.     xdef    FreeCIA
  171. FreeCIA:
  172. ; Release CIA timer.
  173. ; a0 = ciatimer structure pointer
  174.  
  175.     move.l    a6,-(sp)
  176.     move.l    CIATIMER_RESOURCE(a0),a6
  177.     move.w    CIATIMER_ICRBIT(a0),d0
  178.     move.l    CIATIMER_INTERRUPT(a0),a1
  179.     jsr    _LVORemICRVector(a6)
  180.     move.l    (sp)+,a6
  181.     rts
  182.  
  183.  
  184.     cnop    0,4
  185. GetEClock:
  186. ; Evaluate E clock (CIA timer clock)
  187. ; -> d0 = EClock
  188.  
  189.     movem.l    d1-d7/a0-a6,-(sp)
  190.     subq.l    #EV_SIZE,sp
  191.     move.l    TimerBase,a6
  192.     move.l    sp,a0
  193.     jsr    _LVOReadEClock(a6)
  194.     addq.l    #EV_SIZE,sp
  195.     movem.l    (sp)+,d1-d7/a0-a6
  196.     rts
  197.  
  198.  
  199.     cnop    0,4
  200. DummyInterrupt:
  201.     moveq    #0,d0
  202.     rts
  203.  
  204.  
  205.  
  206.     section    DummyInt,bss
  207.  
  208. DummyInt:
  209.     ds.b    IS_SIZE
  210.