home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / vid_c2p_ppc.s < prev    next >
Text File  |  2000-06-17  |  11KB  |  546 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. # Chunky2Planar algorithm, originally by James McCoull
  21. # Modified by Peter McGavin for variable size and depth
  22. # and "compare buffer" (hope I didn't slow it down too much)
  23. #
  24. # Ported by Frank Wille (phx) <frank@phoenix.owl.de> to PowerPC (04-Jan-98).
  25. # Using optimized merge-macro by Tim Boescke (phx,26-Jan-98)
  26. # AGA-bug and EHB-palette-change-bug fixed (phx,31-Jan-98)
  27. # WarpOS support (define WarpOS) (phx,22-May-98)
  28. # Deleted all @__name function pointers for WarpOS. They will be
  29. # created by vlink on demand. (phx,08-Jul-98)
  30. #
  31. #     Cpu only solution VERSION 2
  32. #    Not optimized - directly ported from 040-source... (phx)
  33. #    bitplanes are assumed contiguous!
  34. #    analyse instruction offsets to check performance
  35.  
  36. #void c2p_6_ppc (__reg("r3") UBYTE *chunky_data,
  37. #                __reg("r4") PLANEPTR raster,
  38. #                __reg("r5") UBYTE *compare_buffer,
  39. #                __reg("r8") UBYTE *xlate,
  40. #                __reg("r6") ULONG plsiz,
  41. #                __reg("r7") BOOL palette_changed)
  42.  
  43. #void c2p_8_ppc (__reg("r3") UBYTE *chunky_data,
  44. #                __reg("r4") PLANEPTR raster,
  45. #                __reg("r5") UBYTE *compare_buffer,
  46. #                __reg("r6") ULONG plsiz)
  47.  
  48. # r3 -> width*height chunky pixels
  49. # r4 -> contiguous bitplanes
  50. # r5 -> compare buffer
  51. # r6 = width*height/8   (width*height must be a multiple of 32)
  52.  
  53. # GNU-make has some problems with quotes (e.g. in "depth=8"), so this
  54. # is a workaround (phx)
  55. .ifdef    depth8
  56. .set    depth,8
  57. .endif
  58. .ifdef    depth6
  59. .set    depth,6
  60. .endif
  61.  
  62.  
  63. .macro    merge        # in1,in2,tmp3,tmp4,mask,shift
  64. # \1 = abqr
  65. # \2 = ijyz
  66.     srwi    \3,\2,\6
  67.     lis    \4,(\5&0xffff0000)>>16
  68.     ori    \4,\4,\5&0xffff
  69.     xor    \3,\3,\1
  70.     and    \3,\3,\4
  71.     xor    \1,\1,\3
  72.     slwi    \3,\3,\6
  73.     xor    \2,\2,\3
  74. .endm
  75.  
  76. # translate 4 8-bit pixels to 6-bit EHB
  77. .macro    xlate        # offs1,dest2,mem3,xlate4,tmp5
  78.     lbz    \5,\1(\3)
  79.     lbzx    \5,\4,\5
  80.     rlwimi    \2,\5,24,0,7
  81.     lbz    \5,\1+8(\3)
  82.     lbzx    \5,\4,\5
  83.     rlwimi    \2,\5,16,8,15
  84.     lbz    \5,\1+16(\3)
  85.     lbzx    \5,\4,\5
  86.     rlwimi    \2,\5,8,16,23
  87.     lbz    \5,\1+24(\3)
  88.     lbzx    \5,\4,\5
  89.     rlwimi    \2,\5,0,24,31
  90. .endm
  91.  
  92.  
  93.     .text
  94.  
  95. .ifeq    depth-8
  96. .ifdef    WOS
  97.     .global _c2p_8_ppc
  98. _c2p_8_ppc:
  99. .else    # ELF
  100.     .global    c2p_8_ppc
  101. c2p_8_ppc:
  102. .endif
  103.  
  104. .else
  105. .ifeq    depth-6
  106. .ifdef    WOS
  107.     .global _c2p_6_ppc
  108. _c2p_6_ppc:
  109. .else    # ELF
  110.     .global    c2p_6_ppc
  111. c2p_6_ppc:
  112. .endif
  113.  
  114. .else
  115. .fail    "Unsupported depth! Try 6 or 8."
  116. .endif
  117. .endif
  118.  
  119. # Build the stack frame
  120. .ifdef    WOS
  121.     stwu    r1,-96(r1)
  122.     stmw    r14,24(r1)
  123. .else    # ELF
  124.     stwu    r1,-80(r1)
  125.     stmw    r14,8(r1)        # save all non-volatile registers
  126. .endif
  127.  
  128. .ifle depth-6
  129.     mr    r31,r7            # video_palette_changed
  130.     mr    r29,r8            # xlate
  131. .endif
  132.  
  133. # r3 = chunky buffer
  134. # r4 = output area
  135. # r5 = compare buffer
  136. # r6 = plsiz
  137.  
  138.     mr    r12,r6            # r12 = plsiz
  139.  
  140.     slwi    r6,r6,3
  141.     add    r30,r3,r6        # r30 = end of chunky data
  142.  
  143. first_loop:
  144. .ifle depth-6
  145.     cmpwi    r31,0            # palette_changed?
  146.     bne    first_case
  147. .endif
  148.  
  149.     lwz    r6,0(r3)
  150.     lwz    r7,0(r5)
  151.     cmpw    r6,r7
  152.     bne    first_case
  153.     lwz    r6,4(r3)
  154.     lwz    r7,4(r5)
  155.     cmpw    r6,r7
  156.     bne    first_case
  157.     lwz    r6,8(r3)
  158.     lwz    r7,8(r5)
  159.     cmpw    r6,r7
  160.     bne    first_case
  161.     lwz    r6,12(r3)
  162.     lwz    r7,12(r5)
  163.     cmpw    r6,r7
  164.     bne    first_case
  165.     lwz    r6,16(r3)
  166.     lwz    r7,16(r5)
  167.     cmpw    r6,r7
  168.     bne    first_case
  169.     lwz    r6,20(r3)
  170.     lwz    r7,20(r5)
  171.     cmpw    r6,r7
  172.     bne    first_case
  173.     lwz    r6,24(r3)
  174.     lwz    r7,24(r5)
  175.     cmpw    r6,r7
  176.     bne    first_case
  177.     lwz    r6,28(r3)
  178.     lwz    r7,28(r5)
  179.     cmpw    r6,r7
  180.     bne    first_case
  181.  
  182.     addi    r4,r4,4            # skip 32 pixels on output
  183.     addi    r3,r3,32
  184.     addi    r5,r5,32
  185.  
  186.     cmplw    r3,r30
  187.     blt    first_loop
  188.     b    exit            # exit if no changes found
  189.  
  190. first_case:
  191. .ifgt depth-6            # depth 8 code --- no need to xlate pixels
  192. # hint from M68k: d0-d3 -> r8-r11,  d4-d7 -> r14-r17
  193.     lwz    r9,0(r3)
  194.     lwz    r11,4(r3)
  195.     lwz    r8,8(r3)
  196.     lwz    r10,12(r3)
  197.     lwz    r14,2(r3)
  198.     lwz    r15,10(r3)
  199.     lwz    r16,6(r3)
  200.     lwz    r17,14(r3)
  201.  
  202.     stw    r9,0(r5)
  203.     stw    r11,4(r5)
  204.     stw    r8,8(r5)
  205.     stw    r10,12(r5)
  206.  
  207.     lwz    r6,16(r3)
  208.     rlwimi    r9,r6,16,16,31
  209.     rlwimi    r14,r6,0,16,31
  210.     lwz    r6,20(r3)
  211.     rlwimi    r11,r6,16,16,31
  212.     rlwimi    r16,r6,0,16,31
  213.     lwz    r6,24(r3)
  214.     rlwimi    r8,r6,16,16,31
  215.     rlwimi    r15,r6,0,16,31
  216.     lwz    r6,28(r3)
  217.     rlwimi    r10,r6,16,16,31
  218.     rlwimi    r17,r6,0,16,31
  219.  
  220.     sth    r9,16(r5)
  221.     sth    r8,24(r5)
  222.     sth    r11,20(r5)
  223.     sth    r10,28(r5)
  224.     sth    r14,18(r5)
  225.     sth    r15,26(r5)
  226.     sth    r16,22(r5)
  227.     sth    r17,30(r5)
  228.  
  229.     merge    r9,r8,r6,r7,0x00ff00ff,8
  230.     merge    r11,r10,r6,r7,0x00ff00ff,8
  231.     merge    r9,r11,r6,r7,0x0f0f0f0f,4
  232.     merge    r8,r10,r6,r7,0x0f0f0f0f,4
  233.  
  234.     merge    r14,r15,r6,r7,0x00ff00ff,8
  235.     merge    r16,r17,r6,r7,0x00ff00ff,8
  236.     merge    r14,r16,r6,r7,0x0f0f0f0f,4
  237.     merge    r15,r17,r6,r7,0x0f0f0f0f,4
  238.  
  239.     merge    r11,r16,r6,r7,0x33333333,2
  240.     merge    r10,r17,r6,r7,0x33333333,2
  241.     merge    r11,r10,r6,r7,0x55555555,1
  242.     merge    r16,r17,r6,r7,0x55555555,1
  243.  
  244.     mr    r18,r17            # plane0
  245.     mr    r19,r16            # plane1
  246.     mr    r20,r10            # plane2
  247.     mr    r21,r11            # plane3
  248.  
  249.     merge    r9,r14,r6,r7,0x33333333,2
  250.     merge    r8,r15,r6,r7,0x33333333,2
  251.     merge    r9,r8,r6,r7,0x55555555,1
  252.     merge    r14,r15,r6,r7,0x55555555,1
  253.  
  254.     mr    r22,r15            # plane4
  255.     mr    r23,r14            # plane5
  256.     mr    r24,r8            # plane6
  257.     mr    r25,r9            # plane7
  258.  
  259.  
  260. .else                # depth 6 code, xlate from 8-bit to 6-bit EHB
  261.     lwz    r6,0(r3)    # copy to compare buffer
  262.     stw    r6,0(r5)
  263.     lwz    r6,4(r3)
  264.     stw    r6,4(r5)
  265.     lwz    r6,8(r3)
  266.     stw    r6,8(r5)
  267.     lwz    r6,12(r3)
  268.     stw    r6,12(r5)
  269.     lwz    r6,16(r3)
  270.     stw    r6,16(r5)
  271.     lwz    r6,20(r3)
  272.     stw    r6,20(r5)
  273.     lwz    r6,24(r3)
  274.     stw    r6,24(r5)
  275.     lwz    r6,28(r3)
  276.     stw    r6,28(r5)
  277.  
  278.     xlate    0,r9,r3,r29,r7        # does 8-bit to EHB colour translate
  279.     xlate    1,r8,r3,r29,r7        # 4 pixels at a time
  280.     xlate    4,r11,r3,r29,r7
  281.     xlate    5,r10,r3,r29,r7
  282.  
  283.     merge    r9,r11,r6,r7,0x0f0f0f0f,4
  284.     merge    r8,r10,r6,r7,0x0f0f0f0f,4
  285.  
  286.     xlate    2,r14,r3,r29,r7
  287.     xlate    3,r15,r3,r29,r7
  288.     xlate    6,r16,r3,r29,r7
  289.     xlate    7,r17,r3,r29,r7
  290.  
  291.     merge    r14,r16,r6,r7,0x0f0f0f0f,4
  292.     merge    r15,r17,r6,r7,0x0f0f0f0f,4
  293.  
  294.     merge    r11,r16,r6,r7,0x33333333,2
  295.     merge    r10,r17,r6,r7,0x33333333,2
  296.  
  297.     merge    r11,r10,r6,r7,0x55555555,1
  298.     merge    r16,r17,r6,r7,0x55555555,1
  299.  
  300.     mr    r18,r17            # plane0
  301.     mr    r19,r16            # plane1
  302.     mr    r20,r10            # plane2
  303.     mr    r21,r11            # plane3
  304.  
  305.     merge    r9,r14,r6,r7,0x33333333,2
  306.     merge    r8,r15,r6,r7,0x33333333,2
  307.     merge    r14,r15,r6,r7,0x55555555,1
  308.  
  309.     mr    r22,r15            # plane4
  310.     mr    r23,r14            # plane5
  311. .endif
  312.  
  313.     addi    r3,r3,32
  314.     addi    r5,r5,32
  315.     mr    r26,r4            # save output address
  316.     addi    r4,r4,4            # skip 32 pixels on output
  317.  
  318.     cmplw    r3,r30
  319.     bge    final_case
  320.  
  321.  
  322. main_loop:
  323. .ifle depth-6
  324.     cmpwi    r31,0            # palette_changed?
  325.     bne    main_case
  326. .endif
  327.     lwz    r6,0(r3)        # compare next 32 pixels
  328.     lwz    r7,0(r5)
  329.     cmpw    r6,r7
  330.     bne    main_case
  331.     lwz    r6,4(r3)
  332.     lwz    r7,4(r5)
  333.     cmpw    r6,r7
  334.     bne    main_case
  335.     lwz    r6,8(r3)
  336.     lwz    r7,8(r5)
  337.     cmpw    r6,r7
  338.     bne    main_case
  339.     lwz    r6,12(r3)
  340.     lwz    r7,12(r5)
  341.     cmpw    r6,r7
  342.     bne    main_case
  343.     lwz    r6,16(r3)
  344.     lwz    r7,16(r5)
  345.     cmpw    r6,r7
  346.     bne    main_case
  347.     lwz    r6,20(r3)
  348.     lwz    r7,20(r5)
  349.     cmpw    r6,r7
  350.     bne    main_case
  351.     lwz    r6,24(r3)
  352.     lwz    r7,24(r5)
  353.     cmpw    r6,r7
  354.     bne    main_case
  355.     lwz    r6,28(r3)
  356.     lwz    r7,28(r5)
  357.     cmpw    r6,r7
  358.     bne    main_case
  359.  
  360.     addi    r4,r4,4            # skip 32 pixels on output
  361.     addi    r3,r3,32
  362.     addi    r5,r5,32
  363.  
  364.     cmplw    r3,r30
  365.     blt    main_loop
  366.     b    final_case        # exit if no more changes found
  367.  
  368.  
  369. main_case:
  370. .ifgt    depth-6
  371.     lwz    r9,0(r3)
  372.     lwz    r11,4(r3)
  373.     lwz    r8,8(r3)
  374.     lwz    r10,12(r3)
  375.     lwz    r14,2(r3)
  376.     lwz    r15,10(r3)
  377.     lwz    r16,6(r3)
  378.     lwz    r17,14(r3)
  379.  
  380.     stw    r9,0(r5)
  381.     stw    r11,4(r5)
  382.     stw    r8,8(r5)
  383.     stw    r10,12(r5)
  384.  
  385.     lwz    r6,16(r3)
  386.     rlwimi    r9,r6,16,16,31
  387.     rlwimi    r14,r6,0,16,31
  388.     lwz    r6,20(r3)
  389.     rlwimi    r11,r6,16,16,31
  390.     rlwimi    r16,r6,0,16,31
  391.     lwz    r6,24(r3)
  392.     rlwimi    r8,r6,16,16,31
  393.     rlwimi    r15,r6,0,16,31
  394.     lwz    r6,28(r3)
  395.     rlwimi    r10,r6,16,16,31
  396.     rlwimi    r17,r6,0,16,31
  397.  
  398.     sth    r9,16(r5)
  399.     sth    r8,24(r5)
  400.     sth    r11,20(r5)
  401.     sth    r10,28(r5)
  402.     sth    r14,18(r5)
  403.     sth    r15,26(r5)
  404.     sth    r16,22(r5)
  405.     sth    r17,30(r5)
  406.  
  407.     sub    r26,r26,r12
  408.     stwux    r18,r26,r12        # store plane0 (r26 += plsiz)
  409.     merge    r9,r8,r6,r7,0x00ff00ff,8
  410.     merge    r11,r10,r6,r7,0x00ff00ff,8
  411.  
  412.     stwux    r19,r26,r12        # store plane1 (r26 += plsiz)
  413.     merge    r9,r11,r6,r7,0x0f0f0f0f,4
  414.     merge    r8,r10,r6,r7,0x0f0f0f0f,4
  415.  
  416.     stwux    r20,r26,r12        # store plane2 (r26 += plsiz)
  417.     merge    r14,r15,r6,r7,0x00ff00ff,8
  418.     merge    r16,r17,r6,r7,0x00ff00ff,8
  419.  
  420.     stwux    r21,r26,r12        # store plane3 (r26 += plsiz)
  421.     merge    r14,r16,r6,r7,0x0f0f0f0f,4
  422.     merge    r15,r17,r6,r7,0x0f0f0f0f,4
  423.  
  424.     stwux    r22,r26,r12        # store plane4 (r26 += plsiz)
  425.     merge    r11,r16,r6,r7,0x33333333,2
  426.     merge    r10,r17,r6,r7,0x33333333,2
  427.  
  428.     stwux    r23,r26,r12        # store plane5 (r26 += plsiz)
  429.     merge    r11,r10,r6,r7,0x55555555,1
  430.     merge    r16,r17,r6,r7,0x55555555,1
  431.  
  432.     mr    r18,r17            # plane0
  433.     mr    r19,r16            # plane1
  434.     mr    r20,r10            # plane2
  435.     mr    r21,r11            # plane3
  436.  
  437.     stwux    r24,r26,r12        # store plane6 (r26 += plsiz)
  438.     merge    r9,r14,r6,r7,0x33333333,2
  439.     merge    r8,r15,r6,r7,0x33333333,2
  440.  
  441.     stwux    r25,r26,r12        # store plane7 (r26 += plsiz)
  442.     merge    r9,r8,r6,r7,0x55555555,1
  443.     merge    r14,r15,r6,r7,0x55555555,1
  444.  
  445.     mr    r22,r15            # plane4
  446.     mr    r23,r14            # plane5
  447.     mr    r24,r8            # plane6
  448.     mr    r25,r9            # plane7
  449.  
  450.  
  451. .else                # depth 6 code, xlate from 8-bit to 6-bit EHB
  452.     lwz    r6,0(r3)
  453.     stw    r6,0(r5)
  454.     lwz    r6,4(r3)
  455.     stw    r6,4(r5)
  456.     lwz    r6,8(r3)
  457.     stw    r6,8(r5)
  458.     lwz    r6,12(r3)
  459.     stw    r6,12(r5)
  460.     lwz    r6,16(r3)
  461.     stw    r6,16(r5)
  462.     lwz    r6,20(r3)
  463.     stw    r6,20(r5)
  464.     lwz    r6,24(r3)
  465.     stw    r6,24(r5)
  466.     lwz    r6,28(r3)
  467.     stw    r6,28(r5)
  468.  
  469.     xlate    0,r9,r3,r29,r7        # does 8-bit to EHB colour translate
  470.     xlate    1,r8,r3,r29,r7        # 4 pixels at a time
  471.     xlate    4,r11,r3,r29,r7
  472.     xlate    5,r10,r3,r29,r7
  473.  
  474.     sub    r26,r26,r12
  475.     stwux    r18,r26,r12        # store plane0 (r26 += plsiz)
  476.     merge    r9,r11,r6,r7,0x0f0f0f0f,4
  477.     merge    r8,r10,r6,r7,0x0f0f0f0f,4
  478.  
  479.     xlate    2,r14,r3,r29,r7
  480.     xlate    3,r15,r3,r29,r7
  481.     xlate    6,r16,r3,r29,r7
  482.     xlate    7,r17,r3,r29,r7
  483.  
  484.     stwux    r19,r26,r12        # store plane1 (r26 += plsiz)
  485.     merge    r14,r16,r6,r7,0x0f0f0f0f,4
  486.     merge    r15,r17,r6,r7,0x0f0f0f0f,4
  487.  
  488.     stwux    r20,r26,r12        # store plane2 (r26 += plsiz)
  489.     merge    r11,r16,r6,r7,0x33333333,2
  490.     merge    r10,r17,r6,r7,0x33333333,2
  491.  
  492.     stwux    r21,r26,r12        # store plane3 (r26 += plsiz)
  493.     merge    r11,r10,r6,r7,0x55555555,1
  494.     merge    r16,r17,r6,r7,0x55555555,1
  495.  
  496.     mr    r18,r17            # plane0
  497.     mr    r19,r16            # plane1
  498.     mr    r20,r10            # plane2
  499.     mr    r21,r11            # plane3
  500.  
  501.     stwux    r22,r26,r12        # store plane4 (r26 += plsiz)
  502.     merge    r9,r14,r6,r7,0x33333333,2
  503.  
  504.     stwux    r23,r26,r12        # store plane5 (r26 += plsiz)
  505.     merge    r8,r15,r6,r7,0x33333333,2
  506.     merge    r14,r15,r6,r7,0x55555555,1
  507.  
  508.     mr    r22,r15            # plane4
  509.     mr    r23,r14            # plane5
  510. .endif
  511.  
  512.     addi    r3,r3,32
  513.     addi    r5,r5,32
  514.  
  515.     mr    r26,r4            # save output address
  516.     addi    r4,r4,4            # skip 32 pixels on output
  517.  
  518.     cmplw    r3,r30
  519.     blt    main_loop
  520.  
  521.  
  522.  
  523. final_case:
  524.     sub    r26,r26,r12
  525.     stwux    r18,r26,r12        # store plane0 (r26 += plsiz)
  526.     stwux    r19,r26,r12        # store plane1 (r26 += plsiz)
  527.     stwux    r20,r26,r12        # store plane2 (r26 += plsiz)
  528.     stwux    r21,r26,r12        # store plane3 (r26 += plsiz)
  529.     stwux    r22,r26,r12        # store plane4 (r26 += plsiz)
  530.     stwux    r23,r26,r12        # store plane5 (r26 += plsiz)
  531. .ifgt depth-6
  532.     stwux    r24,r26,r12        # store plane6 (r26 += plsiz)
  533.     stwux    r25,r26,r12        # store plane7 (r26 += plsiz)
  534. .endif
  535.  
  536. exit:
  537. # restore non-volatile registers
  538. .ifdef    WOS
  539.     lmw    r14,24(r1)
  540.     addi    r1,r1,96
  541. .else
  542.     lmw    r14,8(r1)
  543.     addi    r1,r1,80
  544. .endif
  545.     blr
  546.