home *** CD-ROM | disk | FTP | other *** search
/ The Amiga Demo Collection / TheAmigaDemoCollectionCDCUE.img / S / showtime05 / Bonus / BScreen.lha / Blitterscreen / BScreen.i < prev    next >
Text File  |  1992-12-20  |  17KB  |  726 lines
  1. *Routines:
  2.  
  3. *BScreenInit    inizializza copperlist
  4. *BScreenConvert    converte lo schermo chunky su schermo fisico
  5. *BScreenWait    aspetta che il processo di conversione
  6. *        fatto partire da BScreenConvert o BScreenReStart finisca
  7. *BScreenReStart    rifa' la conversione usando gli schermi usati
  8. *        l'ultima volta da BScreenConvert
  9.  
  10. *mk2xY  usata per inizializzare da BScreenInit
  11. *c2bs    usata per effettuare la conversione da BScreenConvert
  12.  
  13.  
  14. ;Costanti globali
  15. BScreenPlaneW        equ    320
  16. BScreenPlaneH        equ    256
  17. BScreenPlaneSize    equ    (BScreenPlaneW/8)*BScreenPlaneH
  18.  
  19. BScreenChunkyW        equ    160    ;Width of chunky screen
  20. BScreenChunkyH        equ    128    ;Height of chunky screen
  21. BScreenChunkySize    equ    BScreenChunkyW*BScreenChunkyH
  22.  
  23. BScreenYStart        equ    $28
  24.  
  25.  
  26.  
  27. ;**************
  28. ;Little macro to reduce code redundancies
  29. BScreenStartMacro    macro
  30.     move.w    #1,bltbsy    ;in case of calc faster than conversion
  31. .waitblt\@
  32.     btst.b    #6,$dff002
  33.     bne.s    .waitblt\@
  34.     move.w    #$8040,$dff09c    ;activate blit intreq
  35.     endm
  36.  
  37.  
  38. * -----------
  39.  
  40. ;****** Global variables ******
  41. bltpc dc.l 0  ;pointer to blitterinstructions to be done
  42. bltbsy dc.w 0 ;this is 0 if all blitter-passes are done
  43.  
  44.  
  45.  
  46. *******************************
  47. *Inizializza la copperlist (usare quella fatta apposta)
  48. *in base alle variabili settate all'inizio del modulo
  49. BScreenInit
  50.     movem.l    d2-d7/a2-a6,-(sp)
  51.  
  52. *--- Copy the Common Coplist section to the two buffers (do not touch a1)
  53.  
  54.     lea.l    BScreenCoplist,a0
  55.     lea.l    BScreenCoplist0,a2
  56.     lea.l    BScreenCoplist1,a3
  57.     lea.l    BScreenCoplist_End,a4
  58. .coploop
  59.     COLOR0    $a00
  60.     move.w    (a0),(a2)+        ;coplist 0
  61.     move.w    (a0)+,(a3)+        ;coplist 1
  62.     COLOR0    $000
  63.     cmpa.l    a0,a4            ;alla fine???
  64.     bne.s    .coploop
  65.  
  66.     move.l    a2,.cop0free
  67.     move.l    a3,.cop1free
  68.  
  69.  
  70. *--- Initialize the coptable used in Int3
  71.  
  72.     move.l    #BScreenCoplist0,BScreenCopTable
  73.     move.l    #BScreenCoplist1,BScreenCopTable+4
  74.  
  75.  
  76. *--- fill the two copperlists
  77.  
  78.     move.l    #BScreenYStart,d2    ;ystart 
  79.     move.l    #BScreenChunkyH,d3    ;anz lines
  80.     move.l    #BScreenPlaneW/8,d5    ;linesize
  81.  
  82.     move.l    #$01020010,d1        ;value for make bitplanes (first time)
  83.     move.l    .cop0free(PC),a0
  84.     lea.l    BScreenSpriteData0,a1
  85.     lea.l    BScreenSpriteBuffer0,a2    ;buffer per gli sprites di copertura
  86.     bsr    mk2xY            ;effettua i precalcoli e fa partire il blitter
  87.     move.l    #$fffffffe,(a0)+    ;istruzione di fine coplist
  88.  
  89.  
  90.     move.l    #$01020021,d1        ;value for make bitplanes (first time)
  91.     move.l    .cop1free(PC),a0
  92.     lea.l    BScreenSpriteData1,a1
  93.     lea.l    BScreenSpriteBuffer1,a2    ;buffer per gli sprites di copertura
  94.     bsr    mk2xY            ;effettua i precalcoli e fa partire il blitter
  95.     move.l    #$fffffffe,(a0)+    ;istruzione di fine coplist
  96.  
  97.  
  98.     movem.l    (sp)+,d2-d7/a2-a6
  99.     rts
  100.  
  101. .cop0free    ds.l    1
  102. .cop1free    ds.l    1
  103.  
  104.  
  105.  
  106.  
  107. ;**************************
  108. ;Converte schermo chunky su schermo fisico in formato speciale
  109. ;bisogna aver chiamato prima BScreenInit e settato la routine 
  110. ;di interrupt livello 3 predefinita
  111. ;IN:
  112. ;    a0    ^Schermo chunky da convertire
  113. ;    a1    ^Schermo planare su cui convertire inizializzato in BScreenInit
  114. BScreenConvert
  115.     movem.l d0-d7/a0-a6,-(sp)
  116.  
  117.     lea.l    BScreenList,a6
  118.  
  119.     lea.l    BScreenBuffer,a2
  120.     lea.l    BScreenScrambleBuffer,a3
  121.  
  122.     move.l    #BScreenChunkySize,d0
  123.     move.l    #BScreenPlaneSize,d1
  124.  
  125.     jsr c2bs            ;hehehe =:)) adios copperscreen...
  126.     movem.l (sp)+,d0-d7/a0-a6
  127.     rts
  128.  
  129.  
  130.  
  131.  
  132. ******************************************
  133. ;Io la richiamo in BScreenInit con i parametri gia' a posto
  134. *** 2xY: Make a special 2x2 or 2x1 screen ***
  135.  
  136. * NOTE: 2x2 or 2x1 depends on the modulo/doublescan-bit you chose
  137. * in header coplist! Also make sure sprites are 64bit, highest
  138. * pri, and chose the spritebank that got a dark color at offset 1
  139. * (col 1,17,33....)
  140.  
  141. * IN: ALL BUFFERS IN CHIPMEM!!!
  142.  
  143. * ^spritebuffer: A2 (size: 312*4*2*8)
  144. * ^Sprite data to use: A1
  145. * ^Coplist: A0
  146.  
  147. * first value of shift for coplist: D1.l    ($1020001 or $1020021)
  148. * Ystart: D2.l   number of lines (0-127): D3.w
  149. * linesize: D5.w
  150.  
  151.  
  152. mk2xY
  153.  
  154.     bsr    BScreen_mspr    ;gen cover-sprites in (a2)+ and copmoves in (a0)+
  155.  
  156.     bsr    BScreen_mbpl    ;gen planes ptr and lines shifters
  157.  
  158.     rts
  159. *
  160. * installa i puntatori ai bitplanes e tutti i waits sfasati
  161. * IN:
  162. * a0    ^coplist
  163. * d1.l    first value of shift (#$01020010 first time,#$01020021 the second)
  164. * d2.l    YStart
  165. * d3.w    num of lines
  166. * d5.w    linesize
  167. * OUT:
  168. * a0  ^primo byte libero della coplist dopo i dati installati
  169. *
  170. BScreen_mbpl
  171.     movem.l    d0-d7/a1-a6,-(sp)
  172.  
  173.     ext.l    d5 
  174.  
  175. * Generate waits and shifts with $102
  176.     and.l    #$ff,d2     ;maschera Y Start a modulo 256
  177.     sub.b    #1,d2         ;sub #1: prev line 
  178.     ror.l    #8,d2        ; $YY000000 
  179.     move.l    #$00e1fffe,d4     ;last X-Wait valid for copper
  180.     or.l    d2,d4        ; $YYe1fffe  Wait for copper
  181. *
  182.     move.w    d3,d0        ;num of lines
  183.     subq.w    #1,d0        ;ok for cicle
  184. .mf256yanz
  185. ;    move.l    #$01020010,d7    ;costant :  NOW d1 is used as input for this
  186.     move.w    #2-1,d6        ;two times
  187. .mf256do2
  188.     move.l    d4,(a0)+ 
  189.     add.l    #$01000000,d4    ;cwait
  190.     move.l    d1,(a0)+ 
  191.     eor.l    #$00000031,d1    ;horiz shift
  192.                      ;             ^---- 3: 1 -> 2 -> 1 -> 2 ....
  193.     dbra    d6,.mf256do2
  194.  
  195.     dbra    d0,.mf256yanz
  196.  
  197.     movem.l    (sp)+,d0-d7/a1-a6
  198.     rts
  199.  
  200. .mfloffs    dc.l    0
  201.  
  202.  
  203. *
  204. * Sprites that mask out doubleplane-data-rubbish
  205. * IN:
  206. * a0    coplist to cover
  207. * a1    ^ to sprite datas to insert (BScreenSpriteData0 the first time, BScreenSpriteData1 the second)
  208. * a2    sprite buffer (COPLIST: FMODE=$F, $dff104=$003f!)
  209. * OUT:
  210. * a0   first byte clear over the filled coplist
  211. * mksprites into sprbuf=(a2)+ and according coppermoves in (a0)+
  212. *
  213. BScreen_mspr
  214.     movem.l    d0-d7/a1-a6,-(sp)    ;no a0! coz *copl
  215.  
  216.     move.l    #$00968020,(a0)+    ;rehash sprites (for safety)
  217.  
  218.                 ;allinea sprbuf a multiplo di 16
  219.     move.l    a2,d0            ;indirizzo buffers per sprites
  220.     add.l    #15,d0            ;15 bytes dopo
  221.     and.l    #$fffffff0,d0        ;machero
  222.     move.l    d0,a2            ;align
  223.  
  224.     move.w    #$0120,d1        ;spr0pth
  225.  
  226.     move.w    #8-1,d7            ;sprcnt, numero sprites usati
  227. .mf2mkspr
  228. * cmoves for sprptr in copl
  229.  
  230.     move.l    a2,d0            ;indirizzo buffer
  231.     move.w    d1,(a0)+        ;registro in coplist ($120,$124,...)
  232.     addq.w    #2,d1            ;hiptr -> loptr
  233.     swap    d0            ;bit piu' significativi
  234.     move.w    d0,(a0)+        ;in coplist.
  235.     swap    d0            ;hiwd, bit meno significativi
  236.     move.w    d1,(a0)+        ;reg incoplist ($122,$126,...)
  237.     addq.w    #2,d1            ;next sprptr
  238.     move.w    d0,(a0)+        ;indirizzo basso on coplist
  239.  
  240. * make sprbuf    ;a1 ^sprdata    a2 ^coplist
  241.     move.l    (a1)+,(a2)+        ;ctl1    (vstart+hstart+null.w)
  242.     move.l    #0,(a2)+        ;dummy for 64bit fetchmode
  243.     move.l    (a1)+,(a2)+        ;ctl2    (vstop+ctrl+null.w)
  244.     move.l    #0,(a2)+        ;dummy for 64bit fetchmode
  245.  
  246.     move.l    (a1)+,d2        ;plane data 0
  247.     move.l    (a1)+,d3        ;plane data 1
  248.     move.l    d2,d4
  249.     ror.l    #1,d4            ;plane data 0 >> 1
  250.     move.l    d3,d5
  251.     ror.l    #1,d5            ;plane data 1 >> 1 (but!!! is ever 0!!!)
  252.  
  253.     move.w    #128-1,d6        ;number of lines to fill
  254. .mf2mksprdat
  255.     move.l    d2,(a2)+        ;plane data 0
  256.     move.l    d2,(a2)+        ;again (a line is 64 bit wide)
  257.     move.l    d3,(a2)+        ;plane data 1
  258.     move.l    d3,(a2)+        ;again
  259. ;2nd line, now fill the shifted line
  260.     move.l    d4,(a2)+        ;plane data 0
  261.     move.l    d4,(a2)+
  262.     move.l    d5,(a2)+        ;plane data 1
  263.     move.l    d5,(a2)+        ;2nd plane
  264.  
  265.     dbra d6,.mf2mksprdat        ;fill all lines
  266.  
  267.     move.l #$0,(a2)+        ;8 words nulle per fine sprite
  268.     move.l #$0,(a2)+
  269.     move.l #$0,(a2)+
  270.     move.l #$0,(a2)+
  271.  
  272.     dbra    d7,.mf2mkspr        ;do all sprites
  273.  
  274.     movem.l    (sp)+,d0-d7/a1-a6    ;ohne a0! weil *copl
  275.     rts
  276.  
  277. * 
  278. * ctl 1, ctl 2, plane 0, plane 1 (to be lsr'd for 2nd line)
  279. BScreenSpriteData0
  280.    dc.l $28400000,$a7020000,$aaaaaaaa,$00000000
  281.    dc.l $28600000,$a7020000,$aaaaaaaa,$00000000 ;1 & 2 nonattached, col 1 :)
  282.    dc.l $28800000,$a7020000,$aaaaaaaa,$00000000
  283.    dc.l $28800000,$a7820000,$00000000,$00000000
  284.    dc.l $28a00000,$a7020000,$aaaaaaaa,$00000000
  285.    dc.l $28a00000,$a7820000,$00000000,$00000000
  286.    dc.l $28c00000,$a7020000,$aaaaaaaa,$00000000
  287.    dc.l $28c00000,$a7820000,$00000000,$00000000
  288.  
  289. BScreenSpriteData1
  290.    dc.l $28400000,$a7020000,$55555555,$00000000
  291.    dc.l $28600000,$a7020000,$55555555,$00000000 ;1 & 2 nonattached, col 1 :)
  292.    dc.l $28800000,$a7020000,$55555555,$00000000
  293.    dc.l $28800000,$a7820000,$00000000,$00000000
  294.    dc.l $28a00000,$a7020000,$55555555,$00000000
  295.    dc.l $28a00000,$a7820000,$00000000,$00000000
  296.    dc.l $28c00000,$a7020000,$55555555,$00000000
  297.    dc.l $28c00000,$a7820000,$00000000,$00000000
  298.  
  299.  
  300.  
  301.  
  302. **************************************
  303. ;Io la richiamo in BScreenConvert
  304. *** non-scrambled chunky-to-planar ***
  305. * not really c2p (!), destination is special 2x2 or 2x1 screen
  306. *
  307. * IN: ALL BUFFERS IN CHIPMEM *except blitterlist (a6)*  !!!
  308. *
  309. *  a3: scramble-buffer at size of chunky buffer
  310. *
  311. * other regs identical to sc2bs ! they are:
  312. *
  313. *  a6: blitter-list buffer (size: less than 2k)
  314. *  a0: chunky buffer  a1: screen  a2: pass-buffer (half size of chunky buffer)
  315. *  d0.l: number of chunky pixels  d1.l: planeoffset
  316.  
  317. c2bs
  318.     tst.w    bltbsy 
  319.     bne.s    c2bs    ;for the very unlikely case your mapping-
  320.             ;engine renders faster than blitterc2p ;)
  321.                                                       
  322.     move.l    a6,bltpc    ;handler starts at bltpc
  323.  
  324.     movem.l    d0-d1/a0-a3,-(sp)
  325.     move.l    a3,a4        ;well....
  326.  
  327. *** init values
  328.  
  329.    move.l #$04000096,(a6)+
  330.    move.l #$80400096,(a6)+
  331.  
  332.    move.l #$ffff0044,(a6)+
  333.    move.l #$ffff0046,(a6)+
  334.  
  335. *** scrambling passes
  336. ;subpass 1
  337.   lea (a0),a3
  338.    move.l a3,(a6)+ 
  339.  move.w #$004c,-2(a6) ;B
  340.    move.w a3,(a6)+ 
  341.  move.w #$004e,(a6)+
  342.   lea 4(a0),a3
  343.    move.l a3,(a6)+ 
  344.  move.w #$0050,-2(a6) ;A
  345.    move.w a3,(a6)+ 
  346.  move.w #$0052,(a6)+
  347.   lea (a4),a3
  348.    move.l a3,(a6)+ 
  349.  move.w #$0054,-2(a6) ;D
  350.    move.w a3,(a6)+ 
  351.  move.w #$0056,(a6)+
  352.  
  353.    move.l #$8de40040,(a6)+
  354.    move.l #$00000042,(a6)+
  355.    move.l #$00ff0070,(a6)+ ;cdat
  356.  
  357.    move.l #$00060064,(a6)+ 
  358.  move.l #$00060062,(a6)+ ;a/b mod
  359.    move.l #$00060066,(a6)+ ;d mod
  360.  
  361.    move.l d0,d6 
  362.  lsr.l #3,d6 ;1/4 of scr, words => /8
  363.    move.w d6,(a6)+
  364.    move.w #$5C,(a6)+       ;SIZV
  365.  
  366.    move.l #$0001005E,(a6)+ ;SIZH+start
  367.  
  368. ;subpass2
  369.   lea 2(a0),a3
  370.    move.l a3,(a6)+ 
  371.  move.w #$004c,-2(a6) ;B
  372.    move.w a3,(a6)+ 
  373.  move.w #$004e,(a6)+
  374.   lea 6(a0),a3
  375.    move.l a3,(a6)+ 
  376.  move.w #$0050,-2(a6) ;A
  377.    move.w a3,(a6)+ 
  378.  move.w #$0052,(a6)+
  379.   lea 2(a4),a3
  380.    move.l a3,(a6)+ 
  381.  move.w #$0054,-2(a6) ;D
  382.    move.w a3,(a6)+ 
  383.  move.w #$0056,(a6)+
  384.  
  385.    move.l #$8de40040,(a6)+
  386.    move.l #$00000042,(a6)+
  387.    move.l #$00ff0070,(a6)+ ;cdat
  388.  
  389.    move.l #$00060064,(a6)+ 
  390.  move.l #$00060062,(a6)+ ;a/b mod
  391.    move.l #$00060066,(a6)+ ;d mod
  392.  
  393.    move.l d0,d6 
  394.  lsr.l #3,d6 ;1/4 of scr, words => /8
  395.    move.w d6,(a6)+
  396.    move.w #$5C,(a6)+       ;SIZV
  397.  
  398.    move.l #$0001005E,(a6)+ ;SIZH+start
  399.  
  400. ;subpass 3
  401.   lea -4(a0,d0.l),a3
  402.    move.l a3,(a6)+ 
  403.  move.w #$004c,-2(a6) ;B
  404.    move.w a3,(a6)+ 
  405.  move.w #$004e,(a6)+
  406.   lea -8(a0,d0.l),a3
  407.    move.l a3,(a6)+ 
  408.  move.w #$0050,-2(a6) ;A
  409.    move.w a3,(a6)+ 
  410.  move.w #$0052,(a6)+
  411.   lea -4(a4,d0.l),a3
  412.    move.l a3,(a6)+ 
  413.  move.w #$0054,-2(a6) ;D
  414.    move.w a3,(a6)+ 
  415.  move.w #$0056,(a6)+
  416.  
  417.    move.l #$8de40040,(a6)+
  418.    move.l #$00020042,(a6)+
  419.    move.l #$ff000070,(a6)+ ;cdat
  420.  
  421.    move.l #$00060064,(a6)+ 
  422.  move.l #$00060062,(a6)+ ;a/b mod
  423.    move.l #$00060066,(a6)+ ;d mod
  424.  
  425.    move.l d0,d6 
  426.  lsr.l #3,d6 ;1/4 of scr, words => /8
  427.    move.w d6,(a6)+
  428.    move.w #$5C,(a6)+       ;SIZV
  429.  
  430.    move.l #$0001005E,(a6)+ ;SIZH+start
  431.  
  432. ;subpass 4
  433.   lea -2(a0,d0.l),a3
  434.    move.l a3,(a6)+ 
  435.  move.w #$004c,-2(a6) ;B
  436.    move.w a3,(a6)+ 
  437.  move.w #$004e,(a6)+
  438.   lea -6(a0,d0.l),a3
  439.    move.l a3,(a6)+ 
  440.  move.w #$0050,-2(a6) ;A
  441.    move.w a3,(a6)+ 
  442.  move.w #$0052,(a6)+
  443.   lea -2(a4,d0.l),a3
  444.    move.l a3,(a6)+ 
  445.  move.w #$0054,-2(a6) ;D
  446.    move.w a3,(a6)+ 
  447.  move.w #$0056,(a6)+
  448.  
  449.    move.l #$8de40040,(a6)+
  450.    move.l #$00020042,(a6)+
  451.    move.l #$ff000070,(a6)+ ;cdat
  452.  
  453.    move.l #$00060064,(a6)+ 
  454.  move.l #$00060062,(a6)+ ;a/b mod
  455.    move.l #$00060066,(a6)+ ;d mod
  456.  
  457.    move.l d0,d6 
  458.  lsr.l #3,d6 ;1/4 of scr, words => /8
  459.    move.w d6,(a6)+
  460.    move.w #$5C,(a6)+       ;SIZV
  461.  
  462.    move.l #$0001005E,(a6)+ ;SIZH+start
  463.  
  464.  
  465. ***
  466.    movem.l (sp)+,d0-d1/a0-a3
  467.  
  468.    move.l a3,a0                  ;scrambled data is now there
  469.    bra sc2bsenter
  470.  
  471. *** scrambled chunky-to-planar =:) ***
  472.  
  473. sc2bs
  474.  
  475.     tst.w bltbsy 
  476.     bne sc2bs
  477.  
  478.     move.l a6,bltpc
  479.  
  480. sc2bsenter:
  481.  
  482. * IN: IN: ALL BUFFERS IN CHIPMEM *except blitterlist (a6)*  !!!
  483. *
  484. *  a6: blitter-list buffer (size: less than 2k)
  485. *  a0: chunky buffer  a1: screen  a2: pass-buffer (half size of chunky buffer)
  486. *  d0.l: number of chunky pixels  d1.l: planeoffset
  487.  
  488. *** init values
  489.    move.l #$04000096,(a6)+
  490.    move.l #$80400096,(a6)+
  491.  
  492.    move.l #$ffff0044,(a6)+
  493.    move.l #$ffff0046,(a6)+
  494.  
  495. ;offsets to end of buffers for blitter DESCing
  496.    move.l d0,d6                   ;len of chscr
  497.    move.l d6,d5 
  498.  lsr.l #1,d5     ;len of buf2
  499.    move.l d6,d4 
  500.  lsr.l #2,d4     ;len of 1 plane = 320*128/8, ok.
  501.  
  502. *** Pass 1, planes 7654
  503.  
  504.   lea (a0),a3
  505.    move.l a3,(a6)+ 
  506.  move.w #$004c,-2(a6) ;B
  507.    move.w a3,(a6)+ 
  508.  move.w #$004e,(a6)+
  509.   lea 2(a0),a3
  510.    move.l a3,(a6)+ 
  511.  move.w #$0050,-2(a6) ;A
  512.    move.w a3,(a6)+ 
  513.  move.w #$0052,(a6)+
  514.  
  515.    move.l a2,(a6)+ 
  516.  move.w #$0054,-2(a6) ;D
  517.    move.w a2,(a6)+ 
  518.  move.w #$0056,(a6)+
  519.  
  520.    move.l #$4de40040,(a6)+
  521.    move.l #$00000042,(a6)+
  522.    move.l #$0f0f0070,(a6)+ ;cdat
  523.  
  524.    move.l #$00020064,(a6)+ 
  525.  move.l #$00020062,(a6)+ ;a/b mod
  526.    move.l #$00000066,(a6)+ ;d mod
  527.  
  528.    move.w d4,(a6)+         ;d4: nr_pix/4 (words!)
  529.    move.w #$5C,(a6)+       ;SIZV
  530.  
  531.    move.l #$0001005E,(a6)+ ;SIZH+start
  532.  
  533. *** Pass 2, planes 76
  534.  
  535.   lea (a2),a3
  536.    move.l a3,(a6)+ 
  537.  move.w #$004c,-2(a6) ;B
  538.    move.w a3,(a6)+ 
  539.  move.w #$004e,(a6)+
  540.   lea 2(a2),a3
  541.    move.l a3,(a6)+ 
  542.  move.w #$0050,-2(a6) ;A
  543.    move.w a3,(a6)+ 
  544.  move.w #$0052,(a6)+
  545.   lea (a1),a3
  546.    add.w d1,a3 
  547.  add.w d1,a3 
  548.  add.w d1,a3   ;4th "doubleplane"
  549.    move.l a3,(a6)+ 
  550.  move.w #$0054,-2(a6) ;D
  551.    move.w a3,(a6)+ 
  552.  move.w #$0056,(a6)+
  553.  
  554.    move.l #$2de40040,(a6)+
  555.    move.l #$00000042,(a6)+
  556.    move.l #$33330070,(a6)+ ;cdat
  557.  
  558.    move.l #$00020064,(a6)+ 
  559.  move.l #$00020062,(a6)+ ;a/b mod
  560.    move.l #$00000066,(a6)+ ;d mod
  561.  
  562.    move.w d4,d0 
  563.  lsr.w #1,d0
  564.    move.w d0,(a6)+         ;d4: nr_pix/8 (words!)
  565.    move.w #$5C,(a6)+       ;SIZV
  566.  
  567.    move.l #$0001005E,(a6)+ ;SIZH+start
  568.  
  569. *** Pass 2, planes 54
  570.  
  571.   lea -2(a2,d5.l),a3
  572.    move.l a3,(a6)+ 
  573.  move.w #$004c,-2(a6) ;B
  574.    move.w a3,(a6)+ 
  575.  move.w #$004e,(a6)+
  576.   lea -4(a2,d5.l),a3
  577.    move.l a3,(a6)+ 
  578.  move.w #$0050,-2(a6) ;A
  579.    move.w a3,(a6)+ 
  580.  move.w #$0052,(a6)+
  581.   lea -2(a1,d4.l),a3
  582.   add.w d1,a3 
  583.  add.w d1,a3   ;3rd "doubleplane"
  584.    move.l a3,(a6)+ 
  585.  move.w #$0054,-2(a6) ;D
  586.    move.w a3,(a6)+ 
  587.  move.w #$0056,(a6)+
  588.  
  589.    move.l #$2de40040,(a6)+
  590.    move.l #$00020042,(a6)+                ;DESC
  591.    move.l #$cccc0070,(a6)+ ;cdat
  592.  
  593.    move.l #$00020064,(a6)+ 
  594.  move.l #$00020062,(a6)+ ;a/b mod
  595.    move.l #$00000066,(a6)+ ;d mod
  596.  
  597.    move.w d4,d0 
  598.  lsr.w #1,d0
  599.    move.w d0,(a6)+         ;d4: nr_pix/8 (words!)
  600.    move.w #$5C,(a6)+       ;SIZV
  601.  
  602.    move.l #$0001005E,(a6)+ ;SIZH+start
  603.  
  604. *** Pass 1, planes 3210
  605.  
  606.   lea -2(a0,d6.l),a3
  607.    move.l a3,(a6)+ 
  608.  move.w #$004c,-2(a6) ;B
  609.    move.w a3,(a6)+ 
  610.  move.w #$004e,(a6)+
  611.   lea -4(a0,d6.l),a3
  612.    move.l a3,(a6)+ 
  613.  move.w #$0050,-2(a6) ;A
  614.    move.w a3,(a6)+ 
  615.  move.w #$0052,(a6)+
  616.   lea -2(a2,d5.l),a3
  617.    move.l a3,(a6)+ 
  618.  move.w #$0054,-2(a6) ;D
  619.    move.w a3,(a6)+ 
  620.  move.w #$0056,(a6)+
  621.  
  622.    move.l #$4de40040,(a6)+
  623.    move.l #$00020042,(a6)+
  624.    move.l #$f0f00070,(a6)+ ;cdat
  625.  
  626.    move.l #$00020064,(a6)+ 
  627.  move.l #$00020062,(a6)+ ;a/b mod
  628.    move.l #$00000066,(a6)+ ;d mod
  629.  
  630.    move.w d4,(a6)+         ;d4: nr_pix/4 (words!)
  631.    move.w #$5C,(a6)+       ;SIZV
  632.  
  633.    move.l #$0001005E,(a6)+ ;SIZH+start
  634.  
  635. *** Pass 2, planes 32
  636.  
  637.   lea (a2),a3
  638.    move.l a3,(a6)+ 
  639.  move.w #$004c,-2(a6) ;B
  640.    move.w a3,(a6)+ 
  641.  move.w #$004e,(a6)+
  642.   lea 2(a2),a3
  643.    move.l a3,(a6)+ 
  644.  move.w #$0050,-2(a6) ;A
  645.    move.w a3,(a6)+ 
  646.  move.w #$0052,(a6)+
  647.   lea (a1),a3
  648.    add.w d1,a3   ;2nd "doubleplane"
  649.    move.l a3,(a6)+ 
  650.  move.w #$0054,-2(a6) ;D
  651.    move.w a3,(a6)+ 
  652.  move.w #$0056,(a6)+
  653.  
  654.    move.l #$2de40040,(a6)+
  655.    move.l #$00000042,(a6)+
  656.    move.l #$33330070,(a6)+ ;cdat
  657.  
  658.    move.l #$00020064,(a6)+ 
  659.  move.l #$00020062,(a6)+ ;a/b mod
  660.    move.l #$00000066,(a6)+ ;d mod
  661.  
  662.    move.w d4,d0 
  663.  lsr.w #1,d0
  664.    move.w d0,(a6)+         ;d4: nr_pix/8 (words!)
  665.    move.w #$5C,(a6)+       ;SIZV
  666.  
  667.    move.l #$0001005E,(a6)+ ;SIZH+start
  668.  
  669. *** Pass 2, planes 10
  670.  
  671.   lea -2(a2,d5.l),a3
  672.    move.l a3,(a6)+ 
  673.  move.w #$004c,-2(a6) ;B
  674.    move.w a3,(a6)+ 
  675.  move.w #$004e,(a6)+
  676.   lea -4(a2,d5.l),a3
  677.    move.l a3,(a6)+ 
  678.  move.w #$0050,-2(a6) ;A
  679.    move.w a3,(a6)+ 
  680.  move.w #$0052,(a6)+
  681.   lea -2(a1,d4.l),a3
  682.      ;1st "doubleplane"
  683.    move.l a3,(a6)+ 
  684.  move.w #$0054,-2(a6) ;D
  685.    move.w a3,(a6)+ 
  686.  move.w #$0056,(a6)+
  687.  
  688.    move.l #$2de40040,(a6)+
  689.    move.l #$00020042,(a6)+                ;DESC
  690.    move.l #$cccc0070,(a6)+ ;cdat
  691.  
  692.    move.l #$00020064,(a6)+ 
  693.  move.l #$00020062,(a6)+ ;a/b mod
  694.    move.l #$00000066,(a6)+ ;d mod
  695.  
  696.    move.w d4,d0 
  697.  lsr.w #1,d0
  698.    move.w d0,(a6)+         ;d4: nr_pix/8 (words!)
  699.    move.w #$5C,(a6)+       ;SIZV
  700.  
  701.    move.l #$0001005E,(a6)+ ;SIZH+start
  702.  
  703. *** end of initblit
  704.    move.l #0,(a6)+
  705.  
  706.     BScreenStartMacro
  707.     rts
  708.  
  709.  
  710. ;******************************
  711. ;Wait for previous phase of blitscreen to finish
  712. BScreenWait
  713. .loop
  714.     tst.w    bltbsy
  715.     bne.s    .loop
  716.     rts
  717.  
  718. ;******************************
  719. ;Start the conversion inizialized with c2bs another time
  720. ;with the same buffers
  721. BScreenReStart
  722.     move.l    #BScreenList,bltpc
  723.     BScreenStartMacro
  724.     rts
  725.  
  726.