home *** CD-ROM | disk | FTP | other *** search
/ PC-Online 1998 February / PCOnline_02_1998.iso / filesbbs / os2 / netrexx.arj / NETREXX.ZIP / NetRexx / qtime.nrx < prev    next >
Encoding:
Text File  |  1996-09-08  |  3.7 KB  |  87 lines
  1. /*----------------------------------------------------------*/
  2. /* QTIME.  This program displays the time in real English.  */
  3. /* If "?" is given as the first argument word then the      */
  4. /* program displays a description of itself.                */
  5. /*----------------------------------------------------------*/
  6.  
  7. /*--------- First process any argument words ---------------*/
  8. parse arg parm .             /* get the first argument word */
  9. select
  10.   when parm='?' then tell                 /* say what we do */
  11.   when parm=''  then nop          /* OK (no first argument) */
  12.   otherwise
  13.     say 'The only valid argument to QTIME is "?".  The word'
  14.     say 'that you supplied ("'parm'") has been ignored.'
  15.     tell         /* usually helpful to describe the program */
  16.   end
  17.  
  18. /*--------- Now start processing in earnest ----------------*/
  19. /* Nearness phrases - using associative array lookup        */
  20. near=''                                          /* default */
  21. near[0]=''                                         /* exact */
  22. near[1]=' just gone';  near[2]=' just after'       /* after */
  23. near[3]=' nearly';     near[4]=' almost'          /* before */
  24.  
  25. /* Extract the hours, minutes, and seconds from the time.   */
  26. /* Use the Java Date class as Rexx.Date not yet implemented */
  27. parse Date() . . . now .             /* time is fourth word */
  28. parse now hour':'min':'sec
  29.  
  30. if sec>29 then min=min+1                /* round up minutes */
  31. mod=min//5              /* where we are in 5 minute bracket */
  32. out="It's"near[mod]            /* start building the result */
  33. if min>32 then hour=hour+1         /* we are TO the hour... */
  34. min=min+2     /* shift minutes to straddle a 5-minute point */
  35.  
  36. /* Now special-case the result for Noon and Midnight hours  */
  37. if hour//12=0 & min//60<=4 then do
  38.   if hour=12 then say out 'Noon.'
  39.              else say out 'Midnight.'
  40.   exit                              /* we are finished here */
  41.   end
  42.  
  43. min=min-(min//5)                     /* find nearest 5 mins */
  44. if hour>12
  45.  then hour=hour-12              /* get rid of 24-hour clock */
  46.  else
  47.   if hour=0 then hour=12       /* .. and allow for midnight */
  48.  
  49. /* Determine the phrase to use for each 5-minute segment    */
  50. select
  51.   when min=0  then nop               /* add "o'clock" later */
  52.   when min=60 then min=0                           /* ditto */
  53.   when min= 5 then out=out 'five past'
  54.   when min=10 then out=out 'ten past'
  55.   when min=15 then out=out 'a quarter past'
  56.   when min=20 then out=out 'twenty past'
  57.   when min=25 then out=out 'twenty-five past'
  58.   when min=30 then out=out 'half past'
  59.   when min=35 then out=out 'twenty-five to'
  60.   when min=40 then out=out 'twenty to'
  61.   when min=45 then out=out 'a quarter to'
  62.   when min=50 then out=out 'ten to'
  63.   when min=55 then out=out 'five to'
  64.   end
  65.  
  66. numbers='one two three four five six'-    /* (continuation) */
  67.   'seven eight nine ten eleven twelve '
  68. out=out numbers.word(hour)           /* add the hour number */
  69. if min=0 then out=out "o'clock"  /* .. and o'clock if exact */
  70.  
  71. say out'.'                      /* display the final result */
  72. exit
  73.  
  74. /*----------------------------------------------------------*/
  75. /* Subroutine that describes the purpose of the program     */
  76. /*----------------------------------------------------------*/
  77. method tell static
  78.  say 'QTIME will display the current time in real English.'
  79.  say 'Call without any arguments to display the time, or with'
  80.  say '"?" to display this information.'
  81.  say 'British English idioms are used in this program.'
  82.  say /* blank line - we are about to continue and show time */
  83.  return
  84.  
  85. /* Mike Cowlishaw,  December 1979 - January 1985            */
  86. /* NetRexx version March 1996                               */
  87.