home *** CD-ROM | disk | FTP | other *** search
/ Serving the Web / ServingTheWeb1995.disc1of1.iso / connect / tcpip / crynwr / pktd11a / at&t_lp.asm < prev    next >
Assembly Source File  |  1992-12-04  |  8KB  |  285 lines
  1. version    equ    1
  2.  
  3.     include    defs.asm
  4.  
  5. ;Ported from Tim Krauskopf's micnet.asm, an assembly language
  6. ;driver for the MICOM-Interlan NI5210, by Russell Nelson.  Any bugs
  7. ;are due to Russell Nelson.
  8. ;Updated to version 1.08 Feb. 17, 1989 by Russell Nelson.
  9. ;Updated to support 1500 byte MTU April 27, 1989 By Brad Clements.
  10. ;converted to an AT&T driver Feb 16, 1990 by Russell Nelson
  11. ;modified to support T7231-based AT&T NICs June 1, 1991 by Mark Darby.
  12.  
  13. ;  Copyright, 1988-1992, Russell Nelson
  14.  
  15. ;   This program is free software; you can redistribute it and/or modify
  16. ;   it under the terms of the GNU General Public License as published by
  17. ;   the Free Software Foundation, version 1.
  18. ;
  19. ;   This program is distributed in the hope that it will be useful,
  20. ;   but WITHOUT ANY WARRANTY; without even the implied warranty of
  21. ;   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22. ;   GNU General Public License for more details.
  23. ;
  24. ;   You should have received a copy of the GNU General Public License
  25. ;   along with this program; if not, write to the Free Software
  26. ;   Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  27.  
  28. code    segment    word public
  29.     assume    cs:code, ds:code
  30.  
  31. ;
  32. ;  Equates for controlling the AT&T boards
  33. ;
  34. ;  I/O addresses, writing anything in AL trips these gates
  35. ;
  36. ;  First six addresses are the EPROM board Ether address (read)
  37. ;
  38. IORESET    EQU    0            ; reset the board
  39. IOCA    EQU    1            ; Channel Attention
  40. IOREV    EQU    6            ; Board Revision/Type
  41. IOATTR    EQU    7            ; Attribute Register.
  42.  
  43. ;Attribute register contents:
  44. attr_mem    equ    03h        ;mask for memory size
  45. attr_mem_64    equ    0
  46. attr_mem_16    equ    1
  47. attr_mem_32    equ    2
  48. attr_mem_8    equ    3
  49. ;
  50. attr_bw        equ    04h        ;Bus width (0=8 bit, 1=16 bit)
  51. attr_speed    equ    08h        ;Board speed (0=10 Mhz, 1=1 Mhz)
  52. attr_c        equ    10h        ;Manchester code (0=Manchester, 1=NRZ)
  53. attr_hw        equ    20h        ;Host bus width (0=16, 1=8 bit)
  54. attr_es        equ    40h        ;Ethernet/Starlan (0 = E, 1 = S)
  55. attr_b        equ    80h        ;Boot Rom (0=No ROM, 1=ROM)
  56.  
  57. IOMISC    equ    9
  58. ;
  59. attr_li        equ    02h        ;LI enable (0=no, 1=yes)
  60. attr_md        equ    04h        ;net media (0=AUI, 1=TP)
  61. attr_inen    equ    08h        ;interrupt enable (0=off, 1=on)
  62. attr_bus8    equ    10h        ;force 8-bit mode (0=no, 1=yes)
  63.  
  64. IOINTR    equ    12            ;interrupt select register
  65. ;
  66. ;  Data segment
  67. ;
  68.  
  69.     public    int_no
  70. int_no        db        2,0,0,0        ; interrupt number. 
  71. io_addr        dw        0360h,0        ; I/O address for card (jumpers)
  72. base_addr    dw      0d000h,0    ; base segment for board (jumper set)
  73. media_sel    db        0,0,0,0        ; media select (AUI or TP)
  74. li_enabl    db        0,0,0,0        ; link integrity enable
  75.  
  76.  
  77.     public    driver_class, driver_type, driver_name, driver_function, parameter_list
  78. driver_class    db    BLUEBOOK, IEEE8023, 0        ;from the packet spec
  79. driver_type    db    48        ;from the packet spec
  80. driver_name    db    20 dup(?)    ;name of the driver.
  81. driver_function    db    2
  82. parameter_list    label    byte
  83.     db    1    ;major rev of packet driver
  84.     db    9    ;minor rev of packet driver
  85.     db    14    ;length of parameter list
  86.     db    EADDR_LEN    ;length of MAC-layer address
  87.     dw    GIANT    ;MTU, including MAC headers
  88.     dw    MAX_MULTICAST * EADDR_LEN    ;buffer size of multicast addrs
  89.     dw    0    ;(# of back-to-back MTU rcvs) - 1
  90.     dw    0    ;(# of successive xmits) - 1
  91. int_num    dw    0    ;Interrupt # to hook for post-EOI
  92.             ;processing, 0 == none,
  93.  
  94. enable_network:
  95. ;  connect to network
  96.     ret
  97.  
  98.  
  99. reset_586:
  100. ;  Reset the chip
  101.     loadport
  102.     setport    IORESET
  103.     out    dx,al
  104.     ret
  105.  
  106.  
  107. doca:
  108. ;we may be called from places in which ds is unknown.
  109.     assume    ds:nothing
  110.     loadport
  111.     setport    IOCA
  112.     out    dx,al            ; send it
  113.     ret
  114.     assume    ds:code
  115. ;yet, we really should assume ds==code for the rest of this stuff.
  116.  
  117. ;
  118. ; Here we include the code that is common between T7231 implementations.
  119. ; Everything above this is resident.
  120.     include    t7231.asm
  121. ; Everything below this is discarded upon installation.
  122.  
  123.     public    usage_msg
  124. usage_msg    db    "usage: at&t_lp [options] <packet_int_no> <hardware_irq> <io_addr> <base_addr> <media_sel> <li_enabl>",CR,LF,'$'
  125.  
  126.     public    copyright_msg
  127. copyright_msg    db    "Packet driver for the AT&T LanPACER/StarStation boards, version ",'0'+(majver / 10),'0'+(majver mod 10),".",'0'+version,".",'0'+t7231_version,CR,LF
  128.         db    "Portions Copyright 1988 The Board of Trustees of the University of Illinois",CR,LF,'$'
  129.  
  130. board_name_list    dw    board_04, board_06, board_16, board_08, board_unk
  131.  
  132. board_04    db    04h, "StarStation",0,79
  133. board_06    db    06h, "LanPACER+ NAU",0,77
  134. board_16    db    16h, "LanPACER NAU",0,76
  135. board_08    db  08h, "EVB",0,78
  136. board_unk    db    -1h, "Unknown AT&T",0,77  ;just a guess.
  137.  
  138.     extrn    chrout: near
  139.  
  140. check_board:
  141.     assume    ds:code
  142.     loadport
  143.     setport    IOREV
  144.     in    al,dx
  145.     mov    bx,offset board_name_list
  146. check_board_name:
  147.     mov    si,[bx]            ;get a pointer to a string.
  148.     add    bx,2
  149.     cmp    byte ptr [si],-1    ;is this the end?
  150.     je    check_board_found
  151.     cmp    al,[si]            ;is this the right one?
  152.     jne    check_board_name
  153. check_board_found:
  154.     inc    si            ;skip the board revision number.
  155.  
  156.     mov    dx,offset this_board_msg
  157.     mov    ah,9
  158.     int    21h
  159.  
  160.     mov    ax,ds            ;copy the driver name to where
  161.     mov    es,ax            ;  we need it.
  162.     mov    di,offset driver_name
  163. check_board_copy:
  164.     lodsb
  165.     stosb
  166.     or    al,al
  167.     je    check_board_done_print
  168.     call    chrout            ;print the character.
  169.     jmp    check_board_copy
  170. check_board_done_print:
  171.     lodsb                ;copy the driver type number over
  172.     mov    driver_type,al
  173.     mov    al,CR
  174.     call    chrout
  175.     mov    al,LF
  176.     call    chrout
  177.  
  178.     loadport
  179.     setport    IOATTR
  180.     in    al,dx            ;get the bus width bit into bit zero.
  181.     shr    al,1
  182.     shr    al,1
  183.     not    al
  184.     and    al,1            ;and negate it.
  185.     mov    SCP,al            ;that makes it into the bus width flag.
  186.  
  187.     in    al,dx            ;get the manchester code
  188.     shr    al,1
  189.     shr    al,1
  190.     not    al            ;the bit is flipped.
  191.     and    al,4            ;isolate just the manchester/~nrz bit.
  192.     mov    byte ptr CBCONF_FLAGS,al
  193.  
  194.     mov    dx,io_addr    ; i/o address
  195.     in    al,dx
  196.     mov    bl,al        ; assemble pattern to check
  197.     inc    dx
  198.     in    al,dx
  199.     mov    bh,al
  200.     cmp    bx,0008h    ; pattern known to be there in ROM
  201.     jz    have_att_io
  202.     mov    dx,offset no_att_io_msg
  203.     stc
  204.     ret
  205. have_att_io:
  206.  
  207.     mov    ax,base_addr
  208.     mov    cx,2000h        ;test only what we are going to use.
  209.     call    memory_test
  210.     jz    have_att_mem
  211.     mov    dx,offset no_att_mem_msg
  212.     stc
  213.     ret
  214. have_att_mem:
  215.     clc
  216.     ret
  217.     ret
  218.  
  219.  
  220. this_board_msg    db    "This board is an AT&T ",'$'
  221. no_att_io_msg    db    "No AT&T board found at that I/O address.",CR,LF,'$'
  222. no_att_mem_msg    db    "No AT&T board found at that memory address.",CR,LF,'$'
  223.  
  224. get_address:
  225. ;get the address of the interface.
  226. ;enter with es:di -> place to get the address, cx = size of address buffer.
  227. ;exit with nc, cx = actual size of address, or cy if buffer not big enough.
  228.     assume    ds:code
  229.     mov    dx,io_addr        ; Get our IO base address.
  230.     cld
  231. get_address_1:
  232.     in    al,dx            ; get a byte of the eprom address
  233.     stosb                ; put it away
  234.     inc    dx            ; next register
  235.     loop    get_address_1        ; go back for rest
  236.     ret
  237.  
  238.  
  239.     public    parse_args
  240. parse_args:
  241.     mov    di,offset int_no
  242.     call    get_number
  243.     mov    di,offset io_addr
  244.     call    get_number
  245.     mov    di,offset base_addr
  246.     call    get_number
  247.     mov    di,offset media_sel
  248.     call    get_number
  249.     mov    di,offset li_enabl
  250.     call    get_number
  251.     clc
  252.     ret
  253.  
  254.  
  255. int_no_name    db    "Interrupt number ",'$'
  256. io_addr_name    db    "I/O port ",'$'
  257. base_addr_name    db    "Memory address ",'$'
  258.  
  259.  
  260.     public    print_parameters
  261. print_parameters:
  262.     mov    di,offset int_no
  263.     mov    dx,offset int_no_name
  264.     call    print_number
  265.     mov    di,offset io_addr
  266.     mov    dx,offset io_addr_name
  267.     call    print_number
  268.     mov    ax,memory_begin
  269.     mov    cl,4
  270.     shr    ax,cl
  271.     add    base_addr,ax
  272.     push    ax
  273.     mov    di,offset base_addr
  274.     mov    dx,offset base_addr_name
  275.     call    print_number
  276.     pop    ax
  277.     sub    base_addr,ax
  278.     ret
  279.  
  280.     include    memtest.asm
  281.  
  282. code    ends
  283.  
  284.     end
  285.