home *** CD-ROM | disk | FTP | other *** search
/ Serving the Web / ServingTheWeb1995.disc1of1.iso / connect / tcpip / crynwr / pktd11b / nb.asm < prev    next >
Assembly Source File  |  1993-06-11  |  20KB  |  850 lines
  1. version equ     4
  2.  
  3.         include defs.asm        ;SEE ENCLOSED COPYRIGHT MESSAGE
  4. NCB_NOWAIT         equ 80h         ;  Command wait flag
  5.  
  6. NCB_RESET          equ 32h         ;  Reset adapter
  7. NCB_CANCEL         equ 35h         ;  Cancel command
  8. NCB_STATUS         equ 33h         ;  Get NETBIOS intf status
  9. NCB_UNLINK         equ 70h         ;  Unlink   (RPL)
  10. NCB_ADDNAME        equ 30h         ;  Add name
  11. NCB_ADDGNAME       equ 36h         ;  Add group name
  12. NCB_DELNAME        equ 31h         ;  Delete name
  13. NCB_FINDNAME       equ 78h         ;  Find name
  14. NCB_CALL           equ 10h         ;  Call
  15. NCB_LISTEN         equ 11h         ;  Listen
  16. NCB_HANGUP         equ 12h         ;  Hang up
  17. NCB_SEND           equ 14h         ;  Send
  18. NCB_CHSEND         equ 17h         ;  Chain send
  19. NCB_RECEIVE        equ 15h         ;  Receive
  20. NCB_RECANY         equ 16h         ;  Receive any
  21. NCB_SESSTATUS      equ 34h         ;  Get session status
  22. NCB_SDATAGRAM      equ 20h         ;  Send datagram
  23. NCB_SBROADCAST     equ 22h         ;  Send broadcast
  24. NCB_RDATAGRAM      equ 21h         ;  Receive datagram
  25. NCB_RBROADCAST     equ 23h         ;  Receive broadcast
  26. NCB_TRACE          equ 79h         ;  Start trace
  27.  
  28. ;
  29. ; Network Control Block structure
  30. ;
  31. ncb             struc
  32. ncb_command     db ?
  33. ncb_retcode     db ?
  34. ncb_lsn         db ?
  35. ncb_num         db ?
  36. ncb_buffer      dd ?
  37. ncb_length      dw ?
  38. ncb_callname    db 16 dup(?)
  39. ncb_name        db 16 dup(?)
  40. ncb_rto         db ?
  41. ncb_sto         db ?
  42. ncb_post        dd ?
  43. ncb_lana_num    db ?
  44. ncb_cmd_cplt    db ?
  45. ncb_reserve     db 14 dup(?)
  46. ncb             ends
  47.  
  48. ;
  49. ; ARP packet structure
  50. ;
  51. arp        struc 
  52. arp_hw        dw ?         ; Hardware address length, bytes 
  53. arp_prot    dw ?         ; Protocol type 
  54. arp_hwalen    db ?         ; hardware address length, bytes 
  55. arp_pralen     db ?         ; Length of protocol address 
  56. arp_opcode      dw ?         ; ARP opcode (request/reply) 
  57. arp_shwaddr    db 6 dup(?)    ; Sender hardware address field 
  58. arp_sprotaddr    dd ?        ; Sender Protocol address field 
  59. arp_thwaddr    db 6 dup(?)    ; Target hardware address field 
  60. arp_tprotaddr    dd ?        ; Target protocol address field 
  61. arp        ends
  62.  
  63. code    segment word public
  64.         assume  cs:code, ds:code
  65. ;***************************************************************
  66. prefix          db "TCPIP"
  67.  
  68.         public  int_no
  69. int_no  db      0,0,0,0
  70. ip_adress       dw      2 dup(0)
  71. rq_size         dw      3
  72. padding         dd      0
  73.  
  74.     public    driver_class, driver_type, driver_name, driver_function, parameter_list
  75. driver_class    db      1,0             ;from the packet spec
  76. driver_type     db      0               ;from the packet spec
  77. driver_name     db      'netbios',0     ;name of the driver.
  78. driver_function    db    2
  79. parameter_list    label    byte
  80.     db    1            ;major rev of packet driver
  81.     db    9            ;minor rev of packet driver
  82.     db    14            ;length of parameter list
  83.     db    EADDR_LEN        ;length of MAC-layer address
  84.     dw    1500            ;MTU, including MAC headers
  85.     dw    MAX_MULTICAST * EADDR_LEN    ;buffer size of multicast addrs
  86.     dw    0            ;(# of back-to-back MTU rcvs) - 1
  87.     dw    0            ;(# of successive xmits) - 1
  88. int_num    dw    0            ;Interrupt # to hook for post-EOI
  89.                     ;processing, 0 == none,
  90.  
  91.     public    rcv_modes
  92. rcv_modes    dw    4        ;number of receive modes in our table.
  93.         dw    0,0,0,rcv_mode_3
  94.  
  95. lana_num        db 0
  96. local_ncb_num   db 0              ; handle returned by add_name
  97.  
  98.  
  99.         public  nbsend, nbrcv1, nbrcv2, rcv_buffer1 ; MAP
  100. nbsend          ncb <>
  101. nbrcv1          ncb <>
  102. nbrcv2          ncb <>
  103.  
  104.  
  105. MAX_DG          equ 1500 
  106. rcv_buffer1     db MAX_DG dup(?)
  107.  
  108.     public bad_command_intercept
  109. bad_command_intercept:
  110. ;called with ah=command, unknown to the skeleton.
  111. ;exit with nc if okay, cy, dh=error if not.
  112.     mov    dh,BAD_COMMAND
  113.     stc
  114.     ret
  115.  
  116.     public    as_send_pkt
  117. ; The Asynchronous Transmit Packet routine.
  118. ; Enter with es:di -> i/o control block, ds:si -> packet, cx = packet length,
  119. ;   interrupts possibly enabled.
  120. ; Exit with nc if ok, or else cy if error, dh set to error number.
  121. ;   es:di and interrupt enable flag preserved on exit.
  122. as_send_pkt:
  123.     ret
  124.  
  125.     public    drop_pkt
  126. ; Drop a packet from the queue.
  127. ; Enter with es:di -> iocb.
  128. drop_pkt:
  129.     assume    ds:nothing
  130.     ret
  131.  
  132.     public    xmit
  133. ; Process a transmit interrupt with the least possible latency to achieve
  134. ;   back-to-back packet transmissions.
  135. ; May only use ax and dx.
  136. xmit:
  137.     assume    ds:nothing
  138.     ret
  139.  
  140.  
  141. ;
  142. ; recv_find() requires a pointer to the Ethernet packet type.  Since
  143. ; the incoming packet does not contain an Ethernet packet type field,
  144. ; memory must be allocated to hold the Ethernet packet type.  Space is
  145. ; required for both IP and ARP types.
  146. ;
  147. ip_type        label    byte
  148.         db    08
  149.         db    00    
  150.  
  151. arp_type    label    byte
  152.         db    08
  153.         db    06    
  154.  
  155. gw_switch    db    00
  156.  
  157.  
  158.         public  send_pkt
  159. send_pkt:
  160.         assume ds: nothing
  161. ;enter with ds:si -> packet, cx = packet length.
  162. ;exit with nc if ok, or else cy if error, dh set to error number.
  163.     cmp    cx,GIANT        ; Is this packet too large?
  164.     ja    send_pkt_toobig
  165.  
  166.         push    es
  167.         push    bx
  168.         push    ds
  169.  
  170. ;strip off Ethernet header
  171.     add    si,12
  172.     mov    ax, word ptr ds:[si]
  173.     add    si,2
  174.     sub    cx,14
  175. ;
  176. ; Check packet type.  If an ARP packet then construct an ARP reply
  177. ; packet. Otherwise, process the incoming IP packet.
  178. ;
  179.     cmp    ax,0608h
  180.     jne    noarp
  181.     call    arp_reply
  182.     jmp    send_ok
  183. noarp:
  184.     
  185.         push    cs
  186.         pop     es
  187. ;
  188. ; Set up NCB for a "SEND DATAGRAM" operation
  189. ;
  190.         mov     bx,offset cs:nbsend
  191.  
  192.         mov     cs:[bx].ncb_buffer.offs,si
  193.         mov     ax,ds
  194.         mov     cs:[bx].ncb_buffer.segm,ds
  195.         mov     cs:[bx].ncb_length,cx
  196.  
  197.         push    bx
  198.         lea     di,cs:nbsend.ncb_callname
  199. ;
  200. ; If gateway switch set then contruct NETBIOS name based on the destination
  201. ; IP address in the IP packet. Otherwise, construct the NETBIOS name
  202. ; based on the destination Ethernet address.
  203. ;
  204.     mov    al,gw_switch
  205.     cmp    al,0
  206.     je    use_hw_addr
  207.     mov    bx, word ptr ds:[si+16]
  208.     mov    dx, word ptr ds:[si+18]
  209.     jmp    conv_addr
  210. use_hw_addr:
  211.     mov    bx, word ptr ds:[si-12]
  212.     mov    dx, word ptr ds:[si-10]
  213. conv_addr:
  214.         push    cs
  215.         pop     ds
  216.         call    ip_to_nbname
  217.         pop     bx
  218. ;
  219. ; Pass "Send Datagram" NCB to NETBIOS
  220. ;
  221.         int     5ch
  222. ;
  223. ; If "Send Datagram" operation is unsuccessful then print return code and
  224. ; set carry bit.  Otherwise, clear the carry bit.
  225. ;
  226.         cmp     al,0
  227.         jz      send_ok
  228.         add     ax,32
  229.         call    tty
  230.         mov     al,'S'
  231.         call    tty
  232.         stc
  233.         jmp     send_done
  234. send_ok:
  235.         clc
  236. send_done:
  237.         pop     ds
  238.         pop     bx
  239.         pop     es
  240.         ret
  241.  
  242. send_pkt_toobig:
  243.     mov    dh,NO_SPACE
  244.     stc
  245.     ret
  246.  
  247. ;
  248. ; Formulate a dummy ARP reply packet.  ds:si points at the incoming
  249. ; IP packet.
  250. ;
  251. arp_reply:
  252. ;
  253. ; Save the registers.  Not sure that we need to but it works and I 
  254. ; don't want to change it right now.
  255. ;
  256.     push    ds
  257.     push    es
  258.     push    si
  259.     push    di
  260.     push    cx
  261. ;
  262. ; Check to see if the ARP request is to find the hardware address
  263. ; of the local host.  If so, then don't formulate a reply packet.
  264. ;
  265.     mov    cx,4
  266.     mov    ax,si
  267.     mov    di,ax
  268.     mov    ax,ds
  269.     mov    es,ax
  270.     add    di,arp_sprotaddr
  271.     add    si,arp_tprotaddr
  272.     repe    cmpsb            ; Compare source and target
  273.                     ; protocol address
  274.     jnz    arp_reply_2
  275.     pop    cx
  276.     pop    di
  277.     pop    si
  278.     pop    es
  279.     pop    ds
  280.     ret
  281. arp_reply_2:
  282. ;
  283. ; Restore registers.
  284. ;
  285.     pop    cx
  286.     pop    di
  287.     pop    si
  288.     push    si
  289.     push    di
  290.     push    cx
  291. ;
  292. ; Restore Ethernet header.
  293. ;
  294.     add    cx,14
  295.     sub    si,14 
  296. ;
  297. ; Ask application layer for a memory buffer in which to store
  298. ; incoming packet.
  299. ;
  300.     push    ds
  301.     push    si            ;save si in case we reject it.
  302.     push    bx
  303.     push    cx
  304.  
  305.     mov    ax,cs
  306.     mov    es,ax
  307.     mov    ds,ax
  308.     mov    di, offset arp_type
  309.     mov    dl,cs:driver_class
  310.     call    recv_find        ;look up our type.
  311.     pop    cx
  312.     pop    bx
  313.     pop    si
  314.     pop    ds
  315.  
  316.     mov    ax,es            ;is this pointer null?
  317.     or    ax,di
  318.     je    arp_reply_1        ;yes - just free the frame.
  319.  
  320.     push    cx
  321.     push    es
  322.     push    di
  323. ;
  324. ; Save si,di for future use.
  325. ;
  326.     mov    bx,si
  327.     mov    dx,di
  328. ;
  329. ; Set up ARP Reply by first copying the ARP Request packet.
  330. ;
  331.     rep    movsb
  332. ;
  333. ; Skip Ethernet header
  334. ;
  335.     add    bx,14
  336.     add     dx,14
  337. ;
  338. ; Swap target and source protocol addresses from ARP request to ARP 
  339. ; reply packet.
  340. ;
  341.     mov    si,bx
  342.     mov    di,dx    
  343.     mov    cx,4
  344.     add    si,arp_tprotaddr
  345.     add    di,arp_sprotaddr
  346.     rep    movsb
  347.  
  348.     mov    si,bx
  349.     mov    di,dx
  350.     mov    cx,4
  351.     add    si,arp_sprotaddr
  352.     add    di,arp_tprotaddr
  353.     rep    movsb
  354. ;
  355. ; Swap target and source hardware addresses from ARP request to ARP 
  356. ; reply packet.
  357. ;
  358.     mov    si,bx
  359.     mov    di,dx
  360.     mov    cx,6
  361.     add    si,arp_shwaddr
  362.     add    di,arp_thwaddr
  363.     rep    movsb
  364. ;
  365. ; Load source hardware address in ARP reply packet.
  366. ;
  367.     mov    si,bx
  368.     mov    di,dx
  369.     add    di,arp_shwaddr
  370.     mov    es:[di],word ptr 0000h
  371.     add    di,2
  372.     mov    cx,4
  373.     add    si,arp_tprotaddr    ; Set Ethernet address in ARP reply
  374.                     ; to target IP address
  375.     rep    movsb
  376. ;
  377. ; Set opcode to REPLY.
  378. ;
  379.     mov    di,dx
  380.     mov    word ptr es:[di].arp_opcode,0200h
  381. ; 
  382. ; Give ARP reply packet that has been constructed to the application
  383. ; layer.
  384. ;
  385.     pop    si
  386.     pop    ds
  387.     pop    cx
  388.     assume    ds:nothing
  389.  
  390.     call    recv_copy
  391.     assume    ds:code
  392.  
  393. arp_reply_1:
  394.  
  395.     pop    cx
  396.     pop    di
  397.     pop    si
  398.     pop    es
  399.     pop    ds
  400.  
  401.     ret
  402.  
  403.  
  404.     public    set_address
  405. set_address:
  406. ;enter with ds:si -> Ethernet address, CX = length of address.
  407. ;exit with nc if okay, or cy, dh=error if any errors.
  408.     assume    ds:nothing
  409.     ret
  410.  
  411.  
  412. rcv_mode_3:
  413. ;receive mode 3 is the only one we support, so we don't have to do anything.
  414.     ret
  415.  
  416.  
  417.     public    set_multicast_list
  418. set_multicast_list:
  419. ;enter with ds:si ->list of multicast addresses, ax = number of addresses,
  420. ;  cx = number of bytes.
  421. ;return nc if we set all of them, or cy,dh=error if we didn't.
  422.     mov    dh,NO_MULTICAST
  423.     stc
  424.     ret
  425.  
  426.  
  427.     public    terminate
  428. terminate:
  429.     ret
  430.  
  431.         public  reset_interface
  432. reset_interface:
  433. ;reset the interface.
  434.         ret
  435.  
  436.  
  437. ;called when we want to determine what to do with a received packet.
  438. ;enter with cx = packet length, es:di -> packet type.
  439.         extrn   recv_find: near
  440.  
  441. ;called after we have copied the packet into the buffer.
  442. ;enter with ds:si ->the packet, cx = length of the packet.
  443.         extrn   recv_copy: near
  444.  
  445.         extrn   count_in_err: near
  446.         extrn   count_out_err: near
  447.         extrn   dwordout: near
  448.         extrn   error: near
  449.  
  450.         public  recv
  451. recv:
  452. ;called from the recv isr.  All registers have been saved, and ds=cs.
  453. ;Upon exit, the interrupt will be acknowledged.
  454.         assume  ds:code
  455.         ret
  456.  
  457.         public nbint  ; MAP
  458. nbint   proc far
  459.         push ds
  460. ;
  461. ; Set data segment to code segment so that we can reference local
  462. ; variables.
  463. ;
  464.         push cs
  465.         pop  ds
  466. ;
  467. ; Retrieve size of received packet
  468. ;
  469.         mov  cx,[bx].ncb_length
  470. ;
  471. ; Check return code.  If there was an error then don't process the
  472. ; packet any further.
  473. ;
  474.         mov  al,[bx].ncb_retcode
  475.         cmp  al,0               ; ok
  476.         jnz  bad_nbint
  477. ;
  478. ; Add Ethernet header.  As well, ensure that minimum packet size is 60
  479. ; bytes; some application packages actually check for minimum packet size.
  480. ;
  481.     add    cx,14 
  482.     cmp    cx,60
  483.     jge    recv_next
  484.     mov    cx,60
  485. recv_next:
  486.     push    si            ;save si in case we reject it.
  487.     push    bx
  488.     push    cx
  489.  
  490.     movseg    es,cs
  491.     mov    di, offset ip_type
  492.     mov    dl,cs:driver_class
  493.     call    recv_find        ;look up our type.
  494.  
  495.     pop    cx
  496.     pop    bx
  497.     pop    si
  498.     mov    ax,es            ;is this pointer null?
  499.     or    ax,di
  500.  
  501.     jne  nb_next 
  502.         jmp  skip_copy 
  503. nb_next:
  504.     push bx
  505.     push cx
  506.     push es
  507.     push di
  508. ;
  509. ; Fix up the Ethernet header added to the incoming packet.
  510. ;
  511.     call    fix_header
  512. ;
  513. ; Copy the received packet into buffer allocated by the application
  514. ; software.
  515. ;
  516.     sub    cx,14
  517.         mov     si,[bx].ncb_buffer.offs
  518.         rep     movsb
  519.     pop si
  520.     pop ds
  521.     pop cx
  522.     assume ds:nothing
  523.         call    recv_copy
  524.     push cs
  525.     pop ds
  526.     assume ds:code
  527.     pop bx
  528. skip_copy:
  529.         mov     [bx].ncb_length,MAX_DG  ; reestablish dg-length
  530. ;
  531. ; Set up to receive another packet.  Construct "receive datagram"
  532. ; NCB.
  533. ;
  534.         push    ds
  535.         pop     es
  536.         int    5ch
  537. ;
  538. ; Check return code.  Print error indication if NETBIOS does not
  539. ; accept NCB.
  540. ;
  541.         mov    al,[bx].ncb_retcode   ; JS added return code
  542.         cmp     al,0ffh
  543.         jz      nbint_pending_ok1
  544.         mov     al,'?'
  545.         call    tty
  546.         add     ax,32
  547.         call    tty
  548.         mov     al,'.'
  549.         call    tty
  550.  
  551. nbint_pending_ok1:
  552.         jmp     short nbint_done
  553.  
  554. bad_nbint:
  555.         add     ax,32
  556.         call    tty
  557.         mov     al,'R'
  558.         call    tty
  559.     jmp    skip_copy
  560.  
  561. nbint_done:
  562.         pop ds
  563.         iret
  564. nbint   endp
  565.  
  566. ;
  567. ; Set destination and source addressess and packet type in an
  568. ; Ethernet header.
  569. ;
  570. fix_header:
  571. ;
  572. ; Set destination address.
  573. ;
  574.     push    cx
  575.     mov    ax,0000h
  576.     stosw
  577.     mov    ax,ip_adress.offs    ;was 0c3c4h
  578.     stosw
  579.     mov    ax,ip_adress.segm    ;was 0c2cch
  580.     stosw
  581. ;
  582. ; Set source address.  NCB callname contains the string "TCPIP" +
  583. ; source host IP address.  Extract host IP address and copy into
  584. ; Ethernet header as the source address.
  585. ;
  586.     mov    ax,0000h
  587.     stosw
  588.     mov    ax,word ptr [bx].ncb_callname+5
  589.     stosw
  590.     mov    ax,word ptr [bx].ncb_callname+7
  591.     stosw
  592. ;
  593. ; Set packet type to IP.
  594. ;
  595.     mov    ax, 0008h
  596.     stosw    
  597.  
  598.     pop    cx
  599.     ret
  600.  
  601.  
  602.  
  603.         public  nb_stop
  604. nb_stop:
  605.         ;                   unregister name
  606.         push    cs
  607.         pop     es
  608.         lea      bx,nbrcv1
  609.         mov     [bx].ncb_command,NCB_DELNAME
  610. ;        mov     al,lana_num
  611. ;        mov     [bx].ncb_lana_num,al
  612.         int     5ch
  613.         cmp     al,0
  614.         jz      good_delete
  615.         add     ax,32
  616.         call    tty
  617.         mov     al,'I'
  618.         call    tty
  619. good_delete:
  620.         ret
  621.  
  622.  
  623.     public tty
  624. tty:
  625.         push    bx
  626.         mov     ah,14
  627.         int     10h
  628.         pop     bx
  629.         ret
  630.  
  631. ip_to_nbname:
  632.         ;      call with es:di = *ncb_name
  633.         ;            bx and dx = ip_address
  634.  
  635.         mov     cx,5
  636.         mov     si,offset prefix
  637.         rep     movsb
  638.  
  639.         mov     [di],bx
  640.         mov     [di+2],dx
  641.         ret
  642.  
  643.     public    timer_isr
  644. timer_isr:
  645. ;if the first instruction is an iret, then the timer is not hooked
  646.     iret
  647.  
  648. ;any code after this will not be kept.  Buffers used by the program, if any,
  649. ;are allocated from the memory between end_resident and end_free_mem.
  650.     public end_resident,end_free_mem
  651. end_resident    label    byte
  652. end_free_mem    label    byte
  653.  
  654.         public  usage_msg
  655. usage_msg       db      "usage: nb [options] <packet_int_no> <ip.ad.dr.ess> [receive queue size]",CR,LF,'$'
  656.  
  657.         public  copyright_msg
  658. copyright_msg   db      "Packet driver for a netbios device, version ",'0'+version,CR,LF,'$'
  659.                 db      "Portions Copyright 1990, Michael Haberler",CR,LF,'$'
  660.  
  661. ip_adress_name  db      "IP Adress ",'$'
  662. rq_size_name    db      "Receive Queue ",'$'
  663. bad_name_msg    db      " bad returncode from nb add_name",CR,LF,'$'
  664. bad_rcv_msg     db      " bad returncode from nb receive dg",CR,LF,'$'
  665. good_name_msg   db      " good returncode from nb add_name",CR,LF,'$'
  666. good_rcv_msg    db      " good returncode from nb receive dg",CR,LF,'$'
  667. temp_dw         dw      ?
  668.         extrn   set_recv_isr: near
  669.  
  670. ;enter with si -> argument string, di -> word to store.
  671. ;if there is no number, don't change the number.
  672.         extrn   get_number: near
  673.     extrn    skip_blanks: near
  674.  
  675. ;-> the assigned Ethernet address of the card.
  676.     extrn    rom_address: byte
  677.  
  678.         public  parse_args
  679. parse_args:
  680. ;exit with nc if all went well, cy otherwise.
  681.     call    skip_blanks
  682.     cmp    al,'-'            ;did they specify a switch?
  683.     jne    not_switch
  684.     cmp    byte ptr [si+1],'g'    ;did they specify '-g'?
  685.     je    got_gw_switch
  686.     stc                ;no, must be an error.
  687.     ret
  688. got_gw_switch:
  689.     mov    gw_switch,1
  690.     add    si,2            ;skip past the switch's characters.
  691.     jmp    parse_args        ;go parse more arguments.
  692. not_switch:
  693.  
  694.         mov     di, offset temp_dw
  695.         mov     bx, offset ip_adress_name
  696.         call    get_number
  697.         mov     ax,temp_dw
  698.         mov     byte ptr ip_adress+0,al
  699.         inc     si
  700.         mov     di, offset temp_dw
  701.         mov     bx, offset ip_adress_name
  702.         call    get_number
  703.         mov     ax,temp_dw
  704.         mov     byte ptr ip_adress+1,al
  705.         inc     si
  706.         mov     di, offset temp_dw
  707.         mov     bx, offset ip_adress_name
  708.         call    get_number
  709.         mov     ax,temp_dw
  710.         mov     byte ptr ip_adress+2,al
  711.         inc     si
  712.         mov     di, offset temp_dw
  713.         mov     bx, offset ip_adress_name
  714.         call    get_number
  715.         mov     ax,temp_dw
  716.         mov     byte ptr ip_adress+3,al
  717.  
  718.         ret
  719.  
  720.  
  721.  
  722.         public  etopen
  723. etopen:
  724. ;if all is okay,
  725. ;        mov     bx,offset nbsend
  726.         lea     bx,nbsend
  727.         mov     [bx].ncb_command,NCB_ADDNAME
  728.         mov     al,lana_num
  729.         mov     [bx].ncb_lana_num,al
  730.  
  731.         push    ds
  732.         push    cs
  733.         push    cs
  734.         pop     ds
  735.         pop     es
  736.  
  737.         push    bx
  738.         lea     di,nbsend.ncb_name
  739.         mov     bx,ip_adress
  740.         mov     dx,ip_adress+2
  741.         call    ip_to_nbname
  742.         pop     bx
  743.  
  744. ;fake up an Ethernet address.
  745.     mov    word ptr rom_address[0],word ptr 0000h
  746.         mov     bx,cs:ip_adress
  747.     mov    word ptr rom_address[4],bx
  748.     mov    bx,cs:ip_adress+2
  749.     mov    word ptr rom_address[2],bx
  750.  
  751. ;    mov    di, offset nbsend.ncb_name
  752. ;    mov    cx,16
  753. ;mike:
  754. ;    mov    al, [di]
  755. ;    call    tty
  756. ;    inc    di
  757. ;    dec    cx
  758. ;    jnz    mike
  759.  
  760.  
  761.         mov     cx,16
  762.         mov     di,offset nbrcv1.ncb_name
  763.         mov     si,offset nbsend.ncb_name
  764.         rep     movsb
  765.         mov     cx,16
  766.         mov     di,offset nbrcv2.ncb_name
  767.         mov     si,offset nbsend.ncb_name
  768.         rep     movsb
  769.  
  770.         int     5ch     ; add_name, -> returns rc in al
  771.         cmp     al,0
  772.         jz      good_name
  773.         mov     dx,0
  774.         mov     ah,0
  775.         call    dwordout
  776.         mov     dx,offset bad_name_msg
  777.         pop     ds
  778.     stc
  779.     ret
  780.  
  781. good_name:
  782. ;        mov     dx,offset good_name_msg
  783. ;        call    say
  784.  
  785.         mov     al,[bx].ncb_num
  786.         mov     local_ncb_num,al
  787.         mov     [bx].ncb_command,NCB_SDATAGRAM  ;set send command code
  788.  
  789.         ;       start receive operations
  790. ;        mov     bx,offset nbrcv1
  791.         lea     bx,nbrcv1
  792.         mov     al,NCB_RDATAGRAM+NCB_NOWAIT  ;set rcv command
  793.         mov     [bx].ncb_command,al
  794.  
  795.         mov     al,local_ncb_num
  796.         mov     [bx].ncb_num,al
  797.  
  798.         mov     ax,MAX_DG
  799.         mov     [bx].ncb_length,ax
  800.  
  801.         mov     ax,ds
  802.         mov     [bx].ncb_buffer.segm,ax
  803.         mov     [bx].ncb_buffer.offs,offset rcv_buffer1
  804.  
  805.         mov     [bx].ncb_post.segm,ax
  806.         mov     [bx].ncb_post.offs,offset nbint
  807.  
  808.         mov     al,lana_num
  809.         mov     [bx].ncb_lana_num,al
  810.         int     5ch
  811.  
  812.         cmp     al,0ffh
  813.         jz      pending_ok1
  814.         cmp     al,00h
  815.         jnz     bad_init
  816.  
  817. pending_ok1:
  818.         mov     dx,offset good_rcv_msg
  819.     mov    ah,9
  820.     int    21h
  821.  
  822.         pop     ds
  823.         clc
  824.         ret
  825. ;if we got an error,
  826. bad_init:
  827.         mov     ah,0
  828.         mov     dx,0
  829.         call    dwordout
  830.         call    nb_stop
  831.         pop     ds
  832.         mov     dx,offset bad_rcv_msg
  833.         stc
  834.         ret
  835.  
  836.     public    print_parameters
  837. print_parameters:
  838.     ret
  839.  
  840. say:
  841.         mov     ah,9
  842.         int     21h
  843.         ret
  844.  
  845.  
  846. code    ends
  847.  
  848.     end
  849.  
  850.