home *** CD-ROM | disk | FTP | other *** search
/ DOS/V Power Report 2001 June / VPR0106A.BIN / OLS / JED194V / JEDDOC.LZH / TABSPC.MCR < prev    next >
Text File  |  1994-05-28  |  3KB  |  116 lines
  1. ;**********************************************************
  2. ;    ＪＥＤ　マクロサンプル
  3. ;    'TABSPC.MCR'
  4. ;    [TAB←→SPACE変換マクロ]
  5. ;    Ver 0.10    Oct.1993 初版
  6. ;        0.11    May 1994 バグ修正
  7. ;
  8. ;    Written by H.Orikawa 1993, 1994
  9. ;
  10. ;　注） "..."形式の文字列内のﾀﾌﾞｺｰﾄﾞについては考慮していない
  11. ;**********************************************************
  12. ;&t
  13.     !01
  14.     (r--) >? {
  15.         &10                    ;TAB->SPACE
  16.         &20                    ;SPACE->TAB
  17.     }
  18.     &d                        ;画面再表示
  19.     &v(1)                    ;ｶｰｿﾙ表示オン
  20.     &b(0)                    ;終了の合図(^^)
  21.     /
  22.  
  23. ;***** ＴＡＢ→スペース
  24. 10:
  25.     (mi) ? #v                ;挿入ﾓｰﾄﾞ
  26.     #^                        ;ﾃｷｽﾄ先頭へ
  27.     &v(0)                    ;ｶｰｿﾙ表示オフ
  28.     &s                        ;変換中の表示抑制
  29. :A
  30.     &k                        ;ｷｰ入力
  31.     (r == $1B) ? .            ;[ESC]が押されたら中断
  32.     (cd == $09) ? {            ;現ｶﾗﾑ位置が[TAB]ｺｰﾄﾞなら
  33.         #d                    ;１文字(１ﾀﾌﾞ分)進めて
  34.         x = lx,                ;そこのｶﾗﾑ位置を記憶
  35.         #h                    ;左１文字([TAB]ｺｰﾄﾞ)を削除
  36.         (x - lx) { ' ' }    ;ｶﾗﾑ数の差分だけ空白を出力する
  37.     } ? {                    ;[TAB]ｺｰﾄﾞ以外なら
  38.         #d                    ;１文字右へ
  39.     }
  40.     (cd == $0D) ? {            ;行末なら
  41.         #d                    ;１文字進め次行の先頭へ
  42.         >A
  43.     }
  44.     (cd == $0A) ? .            ;ﾃｷｽﾄ末尾なら終了
  45.     >A
  46.  
  47.  
  48. ;***** スペース→ＴＡＢ
  49. 20:
  50.     (mi) ? #v                ;挿入ﾓｰﾄﾞ
  51.     #^                        ;ﾃｷｽﾄ先頭へ
  52.     &v(0)                    ;ｶｰｿﾙ表示オフ
  53.     &s                        ;変換中の表示抑制
  54. :A
  55.     &k                        ;ｷｰ入力
  56.     (r == $1B) ? .            ;[ESC]が押されたら中断
  57.     (cd == ' ') ? {            ;現ｶﾗﾑ位置が空白ｺｰﾄﾞなら
  58.         x = lx,                ;最初に見つけたｶﾗﾑ位置を記憶
  59.         &40                    ;[SPACE]->[TAB]変換のﾛｰｶﾙﾏｸﾛ(ｻﾌﾞﾙｰﾁﾝ)ｺｰﾙ
  60.     } ? {                    ;空白ｺｰﾄﾞ以外なら
  61.         (cd == '\"') ? {    ;"xxxxx" 形式の文字列部をｽｷｯﾌﾟする
  62.             &50
  63.         }
  64.         (cd == '\'') ? {    ;'x' 形式の文字定数部をｽｷｯﾌﾟする
  65.             &60
  66.         }
  67.         #d                    ;１文字右へ
  68.     }
  69.     (cd == $0D) ? {            ;行末なら
  70.         #d                    ;１文字進め次行の先頭へ
  71.         >A
  72.     }
  73.     (cd == $0A) ? .            ;ﾃｷｽﾄ末尾なら終了
  74.     >A
  75.  
  76. 40:
  77.     #d                        ;１文字右へ進め
  78.     (cd != ' ') ? {            ;空白ｺｰﾄﾞ以外の文字が現れたら
  79.         .                    ;空白１個の場合なので何もせずﾘﾀｰﾝ
  80.     }
  81. :L    ((lx-1) % ht == 0) ? {    ;ﾀﾌﾞｽﾄｯﾌﾟ位置に来たら
  82.         (lx - x) {            ;空白ｺｰﾄﾞ部分が続く間
  83.             #h                ;[BS]で戻り
  84.         }
  85.         #21                    ;[TAB]ｺｰﾄﾞを挿入して
  86.         .                    ;ﾘﾀｰﾝ
  87.     }
  88.     (cd != ' ') ? .            ;空白ｺｰﾄﾞ以外の文字が現れたら何もせずﾘﾀｰﾝ
  89.     #d                        ;１文字右へ
  90.     >L                        ;空白ｺｰﾄﾞが続く間ﾙｰﾌﾟする
  91.  
  92. 50:
  93. :W    #d                        ;１文字右へ
  94.     (cd == '\\') ? {        ;"...\"...." の場合の例外
  95.         #d #d
  96.     }
  97.     (cd == $0D)  ? .        ;次の["]の前に行末が来たら戻る
  98.     (cd == '\"') ? .        ;文字列終端の["]が来たら戻る
  99.     >W
  100.  
  101. 60:
  102. :S    #d                        ;１文字右へ
  103.     (cd == '\\') ? {        ;'\'' の場合の例外
  104.         #d #d
  105.     }
  106.     (cd == $0D)  ? .        ;次の[']の前に行末が来たら戻る
  107.     (cd == '\'') ? .        ;文字定数終端の[']が来たら戻る
  108.     >S
  109.  
  110.  
  111. ;ポップアップメニュー
  112. 01:    "ＴＡＢ・スペース変換", 22, 2
  113.     "T|ＴＡＢ→スペース"
  114.     "S|スペース→ＴＡＢ"
  115.     .
  116.