home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1997 #2 / amigaacscoverdisc / games / alienbreed3d2 / source_4000 / newhireswall.s < prev    next >
Text File  |  1997-01-31  |  32KB  |  2,235 lines
  1. leftclip: dc.w 0
  2. rightclip: dc.w 0
  3. deftopclip: dc.w 0
  4. defbotclip: dc.w 0
  5. leftclipandlast: dc.w 0
  6.  
  7. SCALE MACRO
  8.  dc.w 64*0
  9.  dc.w 64*1
  10.  dc.w 64*1
  11.  dc.w 64*2
  12.  dc.w 64*2
  13.  dc.w 64*3
  14.  dc.w 64*3
  15.  dc.w 64*4
  16.  dc.w 64*4
  17.  dc.w 64*5
  18.  dc.w 64*5
  19.  dc.w 64*6
  20.  dc.w 64*6
  21.  dc.w 64*7
  22.  dc.w 64*7
  23.  dc.w 64*8
  24.  dc.w 64*8
  25.  dc.w 64*9
  26.  dc.w 64*9
  27.  dc.w 64*10
  28.  dc.w 64*10
  29.  dc.w 64*11
  30.  dc.w 64*11
  31.  dc.w 64*12
  32.  dc.w 64*12
  33.  dc.w 64*13
  34.  dc.w 64*13
  35.  dc.w 64*14
  36.  dc.w 64*14
  37.  dc.w 64*15
  38.  dc.w 64*15
  39.  dc.w 64*16
  40.  dc.w 64*16
  41.  dc.w 64*17
  42.  dc.w 64*17
  43.  dc.w 64*18
  44.  dc.w 64*18
  45.  dc.w 64*19
  46.  dc.w 64*19
  47.  dc.w 64*20
  48.  dc.w 64*20
  49.  dc.w 64*21
  50.  dc.w 64*21
  51.  dc.w 64*22
  52.  dc.w 64*22
  53.  dc.w 64*23
  54.  dc.w 64*23
  55.  dc.w 64*24
  56.  dc.w 64*24
  57.  dc.w 64*25
  58.  dc.w 64*25
  59.  dc.w 64*26
  60.  dc.w 64*26
  61.  dc.w 64*27
  62.  dc.w 64*27
  63.  dc.w 64*28
  64.  dc.w 64*28
  65.  dc.w 64*29
  66.  dc.w 64*29
  67.  dc.w 64*30
  68.  dc.w 64*30
  69.  dc.w 64*31
  70.  dc.w 64*31
  71.  dc.w 64*31
  72.  dc.w 64*31
  73.  dc.w 64*31
  74.  dc.w 64*31
  75.  dc.w 64*31
  76.  dc.w 64*31
  77.  dc.w 64*31
  78.  dc.w 64*31
  79.  dc.w 64*31
  80.  dc.w 64*31
  81.  dc.w 64*31
  82.  dc.w 64*31
  83.  dc.w 64*31
  84.  dc.w 64*31
  85.  dc.w 64*31
  86.  dc.w 64*31
  87.  dc.w 64*31
  88.  dc.w 64*31
  89.  ENDM
  90.  
  91. *********************************** 
  92.  
  93. * The screendivide routine is simpler
  94. * using a0=left pixel
  95. * a2= right pixel
  96. * d0= left dist
  97. * d2= right dist
  98. * d4 = left strip
  99. * d5 = right strip
  100.  
  101. * (a0)=leftx
  102. * 2(a0)=rightx
  103.  
  104. * 4(a0)=leftbm
  105. * 6(a0)=rightbm
  106.  
  107. * 8(a0)=leftdist
  108. * 10(a0)=rightdist
  109.  
  110. * 12(a0)=lefttop
  111. * 14(a0)=righttop
  112.  
  113. * 16(a0)=leftbot
  114. * 18(a0)=rightbot
  115.  
  116.  
  117. Doleftend:
  118.  
  119.  move.w leftclip,d0
  120.  sub.w #1,d0
  121.  move.w d0,leftclipandlast
  122.  
  123.  
  124.  move.w (a0),d0
  125.  move.w 2(a0),d1
  126.  sub.w d0,d1
  127.  bge.s sometodraw
  128.  rts
  129. sometodraw:
  130.  move.w itertab(pc,d1.w*4),d7
  131.  swap d0
  132.  move.w itertab+2(pc,d1.w*4),d6
  133.  clr.w d0
  134.  swap d1
  135.  clr.w d1
  136.  asr.l d6,d1
  137.  move.l d1,(a0)
  138.  
  139.  bra pstit
  140.  
  141. itertab:
  142.  incbin "iterfile"
  143.  
  144. pstit:
  145.  
  146.  moveq #0,d1
  147.  move.w 4(a0),d1
  148.  moveq #0,d2
  149.  move.w 6(a0),d2
  150.  sub.w d1,d2
  151.  swap d1
  152.  swap d2
  153.  asr.l d6,d2
  154.  move.l d2,4(a0)
  155.  
  156.  moveq #0,d2
  157.  move.w 8(a0),d2
  158.  moveq #0,d3
  159.  move.w 10(a0),d3
  160.  sub.w d2,d3
  161.  swap d2
  162.  swap d3
  163.  asr.l d6,d3
  164.  move.l d3,8(a0)
  165.  
  166.  moveq #0,d3
  167.  move.w 12(a0),d3
  168.  moveq #0,d4
  169.  move.w 14(a0),d4
  170.  sub.w d3,d4
  171.  swap d3
  172.  swap d4
  173.  asr.l d6,d4
  174.  move.l d4,12(a0)
  175.  
  176.  moveq #0,d4
  177.  move.w 16(a0),d4
  178.  moveq #0,d5
  179.  move.w 18(a0),d5
  180.  sub.w d4,d5
  181.  swap d4
  182.  swap d5
  183.  asr.l d6,d5
  184.  move.l d5,16(a0)
  185.  
  186.  
  187. *** Gouraud shading ***
  188.  moveq #0,d5
  189.  move.w 26(a0),d5
  190.  sub.w 24(a0),d5
  191.  add.w d5,d5
  192.  swap d5
  193.  asr.l d6,d5
  194.  move.l d5,28(a0)
  195.  moveq #0,d5
  196.  move.w 24(a0),d5
  197.  add.w d5,d5
  198.  swap d5
  199.  
  200.  bra screendivide
  201.  
  202. itercount: dc.w 0
  203.  
  204. screendividethru:
  205.  
  206. .scrdrawlop:
  207.  
  208.  move.w (a0)+,d0
  209.  move.l FASTBUFFER,a3
  210.  move.l (a0)+,d1
  211.  
  212.  bra .pastscrinto
  213.  
  214. .scrintocop:
  215.  incbin "XTOCOPX"
  216.  
  217. .pastscrinto 
  218.  
  219.  swap d1
  220.  
  221.  move.w d1,d6
  222.  and.w HORAND,d6
  223.  move.l (a0)+,d2
  224.  swap d2
  225.  add.w fromtile(pc),d6
  226.  add.w d6,d6
  227.  move.w d6,a5
  228.  move.l (a0)+,d3
  229.  swap d3
  230.  add.l #divthreetab,a5
  231.  move.w (a5),StripData
  232.  
  233.  move.l ChunkAddr,a5
  234.  moveq #0,d6
  235.  move.b StripData,d6
  236.  add.w d6,d6
  237.  move.w VALSHIFT,d4
  238.  asl.w d4,d6
  239.  add.w d6,a5
  240.  move.l (a0)+,d4
  241.  swap d4
  242.  move.w d2,d6
  243. ***************************
  244. * old version
  245.  asr.w #7,d6
  246. ***************************
  247. ; asr.w #3,d6
  248. ; sub.w #4,d6
  249. ; cmp.w #6,d6
  250. ; blt.s tstbrbr
  251. ; move.w #6,d6
  252. ;tstbrbr:
  253. ***************************
  254.  add.w angbright(pc),d6
  255.  bge.s .brnotneg
  256.  moveq #0,d6
  257. .brnotneg
  258.  cmp.w #32,d6
  259.  blt.s .brnotpos
  260.  move.w #32,d6
  261. .brnotpos
  262.  move.l PaletteAddr,a2
  263.  move.l a2,a4
  264.  add.w .ffscrpickhowbright(pc,d6*2),a2
  265. ; and.b #$fe,d6
  266. ; add.w .ffscrpickhowbright(pc,d6*2),a4
  267.  
  268. ; btst #0,d0
  269. ; beq .nobrightswap
  270. ; exg a2,a4
  271. ;.nobrightswap:
  272.  
  273.  move.w d7,-(a7)
  274.  bsr ScreenWallstripdrawthru
  275.  move.w (a7)+,d7
  276.  
  277.  dbra d7,.scrdrawlop
  278.  rts
  279.  
  280. .ffscrpickhowbright:
  281.  SCALE
  282.  
  283.  
  284. ***************************
  285.  
  286. screendivide:
  287.  
  288.  or.l #$ffff0000,d7
  289.  move.w leftclipandlast(pc),d6
  290.  move.l #WorkSpace,a2
  291.  
  292.  move.l (a0),a3
  293.  move.l 4(a0),a4
  294.  move.l 8(a0),a5
  295.  move.l 12(a0),a6
  296.  move.l 16(a0),a1
  297.  move.l 28(a0),a0
  298.  
  299. scrdivlop:
  300.  
  301.  swap d0
  302.  cmp.w d6,d0
  303.  bgt scrnotoffleft
  304.  swap d0
  305.  add.l a4,d1
  306.  add.l a5,d2
  307.  add.l a6,d3
  308.  add.l a1,d4
  309.  add.l a3,d0
  310.  add.l a0,d5
  311.  dbra d7,scrdivlop
  312.  rts
  313.  
  314. scrnotoffleft:
  315.  
  316.  move.w d0,d6
  317.  
  318.  cmp.w rightclip(pc),d0
  319.  bge.s outofcalc
  320.  
  321. scrnotoffright:
  322.  
  323.  
  324.  move.w d0,(a2)+
  325.  move.l d1,(a2)+
  326.  move.l d2,(a2)+
  327.  move.l d3,(a2)+
  328.  move.l d4,(a2)+
  329.  move.l d5,(a2)+
  330.  swap d0
  331.  add.l a3,d0
  332.  add.l a4,d1
  333.  add.l a5,d2
  334.  add.l a6,d3
  335.  add.l a1,d4
  336.  add.l a0,d5
  337.  add.l #$10000,d7
  338.  dbra d7,scrdivlop
  339.  
  340. outofcalc:
  341.  swap d7
  342.  tst.w d7
  343.  bge.s .somethingtodraw
  344.  rts
  345. .somethingtodraw:
  346.  
  347.  move.l #consttab,a1
  348.  move.l #WorkSpace,a0
  349.  
  350.  tst.b FULLSCR
  351.  bne screendivideFULL
  352.  
  353. ; tst.b seethru
  354. ; bne screendividethru
  355.  
  356. scrdrawlop:
  357.  
  358.  move.w (a0)+,d0
  359.  move.l FASTBUFFER,a3
  360.  lea (a3,d0.w),a3
  361.  move.l (a0)+,d1
  362.  
  363. ; bra pastscrinto
  364. ;
  365. ; 
  366. ;pastscrinto 
  367.  
  368.  swap d1
  369.  
  370.  move.w d1,d6
  371.  and.w HORAND,d6
  372.  move.l (a0)+,d2
  373.  swap d2
  374.  add.w fromtile(pc),d6
  375.  add.w d6,d6
  376.  move.w d6,a5
  377.  move.l (a0)+,d3
  378.  swap d3
  379.  add.l #divthreetab,a5
  380.  move.w (a5),StripData
  381.  
  382.  move.l ChunkAddr,a5
  383.  moveq #0,d6
  384.  move.b StripData,d6
  385.  add.w d6,d6
  386.  move.w VALSHIFT,d4
  387.  asl.w d4,d6
  388.  add.w d6,a5
  389.  move.l (a0)+,d4
  390.  swap d4
  391.  move.w d2,d6
  392. ***************************
  393. * old version
  394.  asr.w #7,d6
  395. ***************************
  396. ; asr.w #3,d6
  397. ; sub.w #4,d6
  398. ; cmp.w #6,d6
  399. ; blt.s tstbrbr
  400. ; move.w #6,d6
  401. ;tstbrbr:
  402. ***************************
  403.  move.l (a0)+,d5
  404.  swap d5
  405.  ext.w d5
  406.  add.w d5,d6
  407.  bge.s .brnotneg
  408.  moveq #0,d6
  409. .brnotneg
  410.  cmp.w #64,d6
  411.  blt.s .brnotpos
  412.  move.w #64,d6
  413. .brnotpos
  414.  move.l PaletteAddr,a2
  415.  move.l a2,a4
  416.  add.w ffscrpickhowbright(pc,d6*2),a2
  417.  and.b #$fe,d6
  418.  add.w ffscrpickhowbright(pc,d6*2),a4
  419.  
  420.  btst #0,d0
  421.  beq .nobrightswap
  422.  exg a2,a4
  423. .nobrightswap:
  424.  
  425.  move.w d7,-(a7)
  426.  bsr ScreenWallstripdraw
  427.  move.w (a7)+,d7
  428.  
  429. toosmall:
  430.  
  431.  dbra d7,scrdrawlop
  432.  
  433.  rts
  434.  
  435. middleline:
  436.  dc.w 0
  437.  
  438. ;scrintocop:
  439. ; incbin "XTOCOPX"
  440. prot4: dc.w 0
  441.  
  442. fromtile: dc.l 0
  443. fromquartertile: dc.l 0
  444. swapbrights: dc.w 0
  445. angbright: dc.w 0
  446.  
  447. leftside: dc.b 0
  448. rightside: dc.b 0
  449. firstleft: dc.w 0
  450.  
  451. ffscrpickhowbright:
  452.  SCALE
  453.  
  454. screendivideFULL:
  455.  
  456. scrdrawlopFULL:
  457.  
  458.  move.w (a0)+,d0
  459.  move.l FASTBUFFER,a3
  460.  lea (a3,d0.w),a3
  461.  move.l (a0)+,d1
  462.  
  463. ; bra pastscrinto
  464. ;
  465. ; 
  466. ;pastscrinto 
  467.  
  468.  swap d1
  469.  
  470.  move.w d1,d6
  471.  and.w HORAND,d6
  472.  move.l (a0)+,d2
  473.  swap d2
  474.  add.w fromtile(pc),d6
  475.  add.w d6,d6
  476.  move.w d6,a5
  477.  move.l (a0)+,d3
  478.  swap d3
  479.  add.l #divthreetab,a5
  480.  move.w (a5),StripData
  481.  
  482.  move.l ChunkAddr,a5
  483.  moveq #0,d6
  484.  move.b StripData,d6
  485.  add.w d6,d6
  486.  move.w VALSHIFT,d4
  487.  asl.w d4,d6
  488.  add.w d6,a5
  489.  move.l (a0)+,d4
  490.  swap d4
  491.  move.w d2,d6
  492. ***************************
  493. * old version
  494.  asr.w #7,d6
  495. ***************************
  496. ; asr.w #3,d6
  497. ; sub.w #4,d6
  498. ; cmp.w #6,d6
  499. ; blt.s tstbrbr
  500. ; move.w #6,d6
  501. ;tstbrbr:
  502. ***************************
  503.  move.l (a0)+,d5
  504.  swap d5
  505.  ext.w d5
  506.  add.w d5,d6
  507.  bge.s .brnotneg
  508.  moveq #0,d6
  509. .brnotneg
  510.  cmp.w #64,d6
  511.  blt.s .brnotpos
  512.  move.w #64,d6
  513. .brnotpos
  514.  move.l PaletteAddr,a2
  515.  move.l a2,a4
  516.  add.w ffscrpickhowbrightFULL(pc,d6*2),a2
  517.  and.b #$fe,d6
  518.  add.w ffscrpickhowbrightFULL(pc,d6*2),a4
  519.  
  520.  btst #0,d0
  521.  beq .nobrightswap
  522.  exg a2,a4
  523. .nobrightswap:
  524.  
  525.  move.w d7,-(a7)
  526.  bsr ScreenWallstripdrawBIG
  527.  move.w (a7)+,d7
  528.  
  529.  dbra d7,scrdrawlopFULL
  530.  
  531.  rts
  532.  
  533. ffscrpickhowbrightFULL:
  534.  SCALE
  535.  
  536. divthreetab:
  537. val SET 0
  538.  REPT 130
  539.  dc.b val,0
  540.  dc.b val,1
  541.  dc.b val,2
  542. val SET val+1
  543.  ENDR
  544.  
  545. StripData: dc.w 0
  546.  
  547. * using a0=left pixel
  548. * a2= right pixel
  549. * d0= left height
  550. * d2= right height
  551. * d4 = left strip
  552. * d5 = right strip
  553.  
  554.  
  555. * Routine to draw a wall;
  556. * pass it X and Z coords of the endpoints
  557. * and the start and end length, and a number
  558. * representing the number of the wall.
  559.  
  560. * a0=x1 d1=z1 a2=x2 d3=z2
  561. * d4=sl d5=el
  562. * a1 = strip buffer
  563.  
  564. store: ds.l 500
  565.  
  566. ******************************************************************
  567.  
  568. * Curve drawing routine. We have to know:
  569. * The top and bottom of the wall
  570. * The point defining the centre of the arc
  571. * the point defining the starting point of the arc
  572. * the start and end angles of the arc
  573. * The start and end positions along the bitmap of the arc
  574. * Which bitmap to use for the arc
  575.  
  576. xmiddle: dc.w 0
  577. zmiddle SET 2
  578.  dc.w 0
  579. xradius SET 4
  580.  dc.w 0
  581. zradius SET 6
  582.  dc.w 0
  583. startbitmap SET 8
  584.  dc.w 0
  585. bitmapcounter SET 10
  586.  dc.w 0
  587. brightmult SET 12
  588.  dc.w 0
  589. angadd SET 14
  590.  dc.l 0
  591. xmiddlebig SET 18
  592.  dc.l 0
  593. basebright SET 22
  594.  dc.w 0
  595. shift SET 24
  596.  dc.w 0
  597. count SET 26
  598.  dc.w 0
  599.  
  600. subdividevals:
  601.  dc.w 2,4
  602.  dc.w 3,8
  603.  dc.w 4,16
  604.  dc.w 5,32
  605.  dc.w 6,64
  606.  
  607. CurveDraw:
  608.  
  609.  move.w (a0)+,d0    ; centre of rotation
  610.  move.w (a0)+,d1    ; point on arc
  611.  move.l #Rotated,a1
  612.  move.l #xmiddle,a2
  613.  move.l (a1,d0.w*8),d2
  614.  move.l d2,18(a2)
  615.  asr.l #7,d2
  616.  move.l (a1,d1.w*8),d4
  617.  asr.l #7,d4
  618.  sub.w d2,d4
  619.  move.w d2,(a2)
  620.  move.w d4,4(a2)
  621.  move.w 6(a1,d0.w*8),d2
  622.  move.w 6(a1,d1.w*8),d4
  623.  sub.w d2,d4
  624.  move.w d2,2(a2)
  625.  asr.w #1,d4
  626.  move.w d4,6(a2)
  627.  move.w (a0)+,d4    ; start of bitmap
  628.  move.w (a0)+,d5    ; end of bitmap
  629.  move.w d4,8(a2)
  630.  sub.w d4,d5
  631.  move.w d5,10(a2)
  632.  move.w (a0)+,d4
  633.  ext.l d4
  634.  move.l d4,14(a2)
  635.  move.w (a0)+,d4
  636.  move.l #subdividevals,a3
  637.  move.l (a3,d4.w*4),shift(a2)
  638.  
  639.  move.l #walltiles,a3
  640.  add.l (a0)+,a3
  641.  adda.w wallyoff,a3
  642.  move.l a3,fromtile
  643.  move.w (a0)+,basebright(a2)
  644.  move.w (a0)+,brightmult(a2)
  645.  move.l (a0)+,topofwall
  646.  move.l (a0)+,botofwall
  647.  move.l yoff,d6
  648.  sub.l d6,topofwall
  649.  sub.l d6,botofwall
  650.  
  651.  move.l #databuffer,a1
  652.  move.l #SineTable,a3
  653.  lea 2048(a3),a4
  654.  moveq #0,d0
  655.  moveq #0,d1
  656.  move.w count(a2),d7
  657. DivideCurve
  658.  move.l d0,d2
  659.  move.w shift(a2),d4
  660.  asr.l d4,d2
  661.  move.w (a3,d2.w*2),d4
  662.  move.w d4,d5
  663.  move.w (a4,d2.w*2),d3
  664.  move.w d3,d6
  665.  muls.w 4(a2),d3
  666.  muls.w 6(a2),d4
  667.  muls.w 4(a2),d5
  668.  muls.w 6(a2),d6
  669.  sub.l d4,d3
  670.  add.l d6,d5
  671.  asl.l #2,d5
  672.  asr.l #8,d3
  673.  add.l 18(a2),d3
  674.  swap d5
  675.  move.w basebright(a2),d6
  676.  move.w brightmult(a2),d4
  677.  muls d5,d4
  678.  swap d4
  679.  add.w d4,d6
  680.  
  681.  add.w 2(a2),d5
  682.  move.l d3,(a1)+
  683.  move.w d5,(a1)+
  684.  move.w d1,d2
  685.  move.w shift(a2),d4
  686.  asr.w d4,d2
  687.  add.w 8(a2),d2
  688.  move.w d2,(a1)+
  689.  move.w d6,(a1)+
  690.  
  691.  add.l 14(a2),d0  
  692.  add.w 10(a2),d1
  693.  dbra d7,DivideCurve
  694.  
  695.  move.l a0,-(a7)
  696.  
  697. ; move.w #31,d6
  698. ; move.l #0,d3
  699. ; move.l #stripbuffer,a4
  700. ;.emptylop:
  701. ; move.l d3,(a4)+
  702. ; dbra d6,.emptylop
  703.  
  704.  bsr curvecalc
  705.  
  706.  move.l (a7)+,a0
  707.  
  708.  rts
  709.  
  710. prot3: dc.w 0
  711.  
  712. curvecalc:
  713.  move.l #databuffer,a1
  714.  move.w count(a2),d7
  715.  subq #1,d7
  716. .findfirstinfront:
  717.  move.l (a1)+,d1
  718.  move.w (a1)+,d0
  719.  bgt.s .foundinfront
  720.  move.w (a1)+,d4
  721.  move.w (a1)+,d6
  722.  dbra d7,.findfirstinfront
  723. ; CACHE_ON d2
  724.  rts    ; no two points were in front
  725.  
  726. .foundinfront:
  727.  move.w (a1)+,d4
  728.  move.w (a1)+,d6
  729.  ; d1=left x, d4=left end, d0=left dist
  730.  ; d6=left angbright 
  731.  
  732.  divs d0,d1
  733.  add.w MIDDLEX,d1
  734.  
  735.  move.l topofwall(pc),d5
  736.  divs d0,d5
  737.  add.w MIDDLEY,d5
  738.  move.w d5,strtop
  739.  move.l botofwall(pc),d5
  740.  divs d0,d5
  741.  add.w MIDDLEY,d5
  742.  move.w d5,strbot
  743.  
  744. ; CACHE_OFF d2
  745.  
  746. .computeloop:
  747.  move.w 4(a1),d2
  748.  bgt.s .infront
  749.  
  750. ; addq #8,a1
  751. ; dbra d7,.findfirstinfront
  752.  
  753. ; CACHE_ON d2
  754.  rts
  755.  
  756. .infront:
  757.  move.l #store,a0
  758.  move.l (a1),d3
  759.  move.w 6(a1),d5
  760.  add.w 8(a1),d6
  761.  asr.w #1,d6
  762.  move.w d6,angbright
  763.  divs d2,d3
  764.  add.w MIDDLEX,d3
  765.  move.w strtop(pc),12(a0)
  766.  move.w strbot(pc),16(a0)
  767.  move.l topofwall(pc),d6
  768.  divs d2,d6
  769.  add.w MIDDLEY,d6
  770.  move.w d6,strtop
  771.  move.w d6,14(a0)
  772.  move.l botofwall(pc),d6
  773.  divs d2,d6
  774.  add.w MIDDLEY,d6
  775.  move.w d6,strbot
  776.  move.w d6,18(a0)
  777.  move.w d3,2(a1)
  778.  blt.s .alloffleft
  779.  cmp.w RIGHTX,d1
  780.  bgt.s .alloffleft
  781.  
  782.  cmp.w d1,d3
  783.  blt.s .alloffleft
  784.  
  785.  move.w d1,(a0)
  786.  move.w d3,2(a0)
  787.  move.w d4,4(a0)
  788.  move.w d5,6(a0)
  789.  move.w d0,8(a0)
  790.  move.w d2,10(a0)
  791.  move.w d7,-(a7)
  792.  move.w #maxscrdiv,d7
  793.  bsr Doleftend
  794.  move.w (a7)+,d7
  795.  
  796. .alloffleft:
  797.  
  798.  move.l (a1)+,d1
  799.  move.w (a1)+,d0
  800.  move.w (a1)+,d4
  801.  move.w (a1)+,d6
  802.  
  803.  dbra d7,.computeloop
  804.  
  805. .alloffright:
  806. ; CACHE_ON d2
  807.  rts
  808.  
  809. ;protcheck:
  810. ; sub.l #53624,a3
  811. ; add.l #2345215,a2
  812. ; lea passspace-$30000(pc),a1
  813. ; add.l #$30000,a1
  814. ; lea startpass(pc),a5
  815. ; move.w #endpass-startpass-1,d1
  816. ;copypass:
  817. ; move.b (a5)+,(a1)+
  818. ; dbra d1,copypass
  819. ; sub.l a5,a5
  820. ; lea passspace-$30000(pc),a1
  821. ; add.l #$30000,a1
  822. ; jsr (a1)
  823. ; lea passspace-$30000(pc),a1
  824. ; add.l #$30000,a1
  825. ; lea startpass(pc),a5
  826. ; move.w #(endpass-startpass)/2-1,d1
  827. ;erasepass:
  828. ; move.w -(a5),(a1)+
  829. ; dbra d1,erasepass
  830. ; sub.l a5,a5
  831. ; sub.l a1,a1
  832. ; eor.l #$af594c72,d0
  833. ; sub.l #123453986,a4
  834. ; move.l d0,(a4)
  835. ; add.l #123453986,a4
  836. ; move.l #0,d0
  837. ; sub.l #2345215,a2
  838. ; jsr (a2)
  839. ; sub.l a2,a2
  840. ; eor.l #$af594c72,d0
  841. ; sub.l #123453986,a4
  842. ; move.l (a4),d1
  843. ; add.l #123453986,a4
  844. ; cmp.l d1,d0
  845. ; bne.s notrightt
  846. ; add.l #53624,a3
  847. ; move.w #9,d7
  848. ;sayitsok:
  849. ; move.l (a3)+,a2
  850. ; add.l #78935450,a2
  851. ; st (a2)
  852. ; dbra d7,sayitsok
  853. ;notrightt:
  854. ; sub.l a3,a3
  855. ;nullit:
  856. ; rts
  857. ; 
  858. ; incbin "ab3:includes/protroutencoded"
  859.  
  860. endprot:
  861.  
  862. ******************************************************************
  863.  
  864. iters: dc.w 0
  865. multcount: dc.w 0
  866.  
  867. walldraw:
  868.  
  869.  tst.w d1
  870.  bgt.s oneinfront1
  871.  tst.w d3
  872.  bgt.s oneinfront
  873.  rts
  874.  
  875. oneinfront1
  876.  tst.w d3
  877.  ble.s oneinfront
  878. ; Bothinfront!
  879.  
  880.  nop
  881.  
  882. oneinfront
  883.  
  884.  move.w #32,d7
  885.  move.w #3,d6
  886.  
  887.  move.w d3,d0
  888.  sub.w d1,d0
  889.  bge.s notnegzdiff
  890.  neg.w d0
  891. notnegzdiff
  892. ; cmp.w #1024,d0
  893. ; blt.s nd01
  894. ; add.w d7,d7
  895. ; add.w #1,d6
  896. ;nd01:
  897.  cmp.w #512,d0
  898.  blt.s nd0 
  899.  add.w d7,d7
  900.  add.w #1,d6
  901.  bra nha
  902. nd0:
  903.  
  904.  cmp.w #256,d0
  905.  bgt.s nh1
  906.  asr.w #1,d7
  907.  subq #1,d6
  908. nh1:
  909.  cmp.w #128,d0
  910.  bgt.s nh2
  911.  asr.w #1,d7
  912.  subq #1,d6
  913. nh2:
  914.  
  915. nha:
  916.  
  917.  move.w d3,d0
  918.  cmp.w d1,d3
  919.  blt.s rightnearest
  920.  move.w d1,d0
  921. rightnearest:
  922.  cmp.w #64,d0
  923.  bgt.s nd1
  924.  addq #1,d6
  925.  add.w d7,d7
  926. nd1:
  927.  
  928.  cmp.w #128,d0
  929.  blt.s nh3
  930.  asr.w #1,d7
  931.  subq #1,d6
  932.  blt.s nh3
  933.  cmp.w #256,d0
  934.  blt.s nh3
  935.  asr.w #1,d7
  936.  subq #1,d6
  937. nh3:
  938.  move.w d6,iters
  939.  subq #1,d7
  940.  move.w d7,multcount
  941.  
  942.  move.l #databuffer,a3
  943.  move.l a0,d0
  944.  move.l a2,d2
  945.  
  946.  swap d1
  947.  clr.w d1
  948.  swap d4
  949.  clr.w d4
  950.  swap d5
  951.  clr.w d5
  952.  swap d3
  953.  clr.w d3
  954.  
  955.  move.l d0,(a3)+
  956.  add.l d2,d0
  957.  move.l d1,(a3)+
  958.  asr.l #1,d0
  959.  move.l d4,(a3)+
  960.  
  961.  move.w leftwallbright,d6
  962.  move.w d6,(a3)+
  963.  
  964.  add.l d5,d4
  965.  move.l d0,(a3)+
  966.  add.l d3,d1
  967.  asr.l #1,d1
  968.  move.l d1,(a3)+
  969.  asr.l #1,d4
  970.  move.l d4,(a3)+
  971.  
  972.  add.w rightwallbright,d6
  973.  asr.w #1,d6
  974.  move.w d6,(a3)+
  975.  
  976.  move.l d2,(a3)+
  977.  move.l d3,(a3)+
  978.  move.l d5,(a3)+
  979.  move.w rightwallbright,(a3)+
  980.  
  981.  ; We now have the two endpoints and the midpoint
  982.  ; so we need to perform 1 iteration of the inner
  983.  ; loop, the first time.
  984.  
  985. * Decide how often to subdivide by how far away the wall is, and
  986. * how perp. it is to the player.
  987.  
  988.  move.l #databuffer,a0
  989.  move.l #databuffer2,a1
  990.  
  991.  move.w iters,d6
  992.  blt noiters
  993.  move.l #1,a2
  994.  
  995. iterloop:
  996.  move.l a0,a3
  997.  move.l a1,a4
  998.  move.w a2,d7
  999.  exg a0,a1
  1000.  
  1001.  move.l (a3)+,d0
  1002.  move.l (a3)+,d1
  1003.  move.l (a3)+,d2
  1004.  move.w (a3)+,d3
  1005. middleloop:
  1006.  
  1007.  move.l d0,(a4)+
  1008.  move.l d1,(a4)+
  1009.  move.l d2,(a4)+
  1010.  move.w d3,(a4)+
  1011.  
  1012.  add.l (a3),d0
  1013.  add.l 4(a3),d1
  1014.  add.l 8(a3),d2
  1015.  add.w 12(a3),d3
  1016.  
  1017.  asr.l #1,d0
  1018.  asr.l #1,d1
  1019.  asr.l #1,d2
  1020.  asr.w #1,d3
  1021.  
  1022.  move.l d0,(a4)+
  1023.  move.l d1,(a4)+
  1024.  move.l d2,(a4)+
  1025.  move.w d3,(a4)+
  1026.  
  1027.  move.l (a3)+,d0
  1028.  move.l d0,(a4)+
  1029.  move.l (a3)+,d1
  1030.  move.l d1,(a4)+
  1031.  move.l (a3)+,d2
  1032.  move.l d2,(a4)+
  1033.  move.w (a3)+,d3
  1034.  move.w d3,(a4)+
  1035.  
  1036.  move.l d0,d4
  1037.  move.l (a3)+,d0
  1038.  add.l d0,d4
  1039.  asr.l #1,d4
  1040.  move.l d4,(a4)+
  1041.  move.l d1,d4
  1042.  move.l (a3)+,d1
  1043.  add.l d1,d4
  1044.  asr.l #1,d4
  1045.  move.l d4,(a4)+
  1046.  move.l d2,d4
  1047.  move.l (a3)+,d2
  1048.  add.l d2,d4
  1049.  asr.l #1,d4
  1050.  move.l d4,(a4)+
  1051.  move.w d3,d4
  1052.  move.w (a3)+,d3
  1053.  add.w d3,d4
  1054.  asr.w #1,d4
  1055.  move.w d4,(a4)+
  1056.  
  1057.  
  1058.  subq #1,d7
  1059.  bgt.s middleloop
  1060.  move.l d0,(a4)+
  1061.  move.l d1,(a4)+
  1062.  move.l d2,(a4)+
  1063.  move.w d3,(a4)+
  1064.  
  1065.  add.w a2,a2
  1066.  
  1067.  dbra d6,iterloop
  1068.  
  1069. noiters:
  1070.  
  1071. CalcAndDraw:
  1072.  
  1073. ; CACHE_ON d2
  1074.  
  1075.  move.l a0,a1
  1076.  move.w multcount,d7
  1077. .findfirstinfront:
  1078.  move.l (a1)+,d1
  1079.  move.w (a1)+,d0
  1080.  bgt.s .foundinfront
  1081.  move.l (a1)+,d4
  1082.  dbra d7,.findfirstinfront
  1083.  rts    ; no two points were in front
  1084.  
  1085. .foundinfront:
  1086.  move.w (a1)+,d4
  1087.  move.w (a1)+,lbr
  1088.  ; d1=left x, d4=left end, d0=left dist 
  1089.  
  1090.  divs d0,d1
  1091.  add.w MIDDLEX,d1
  1092.  
  1093.  move.l topofwall(pc),d5
  1094.  divs d0,d5
  1095.  add.w MIDDLEY,d5
  1096.  move.w d5,strtop
  1097.  move.l botofwall(pc),d5
  1098.  divs d0,d5
  1099.  add.w MIDDLEY,d5
  1100.  move.w d5,strbot
  1101.  
  1102. .computeloop:
  1103.  move.w 4(a1),d2
  1104.  bgt.s .infront
  1105.  rts
  1106.  
  1107. .infront:
  1108.  move.l #store,a0
  1109.  move.l (a1),d3
  1110.  divs d2,d3
  1111.  move.w 6(a1),d5
  1112.  add.w MIDDLEX,d3
  1113.  move.w strtop(pc),12(a0)
  1114.  move.l topofwall(pc),d6
  1115.  divs d2,d6
  1116.  move.w strbot(pc),16(a0)
  1117.  add.w MIDDLEY,d6
  1118.  move.w d6,strtop
  1119.  move.w d6,14(a0)
  1120.  move.l botofwall(pc),d6
  1121.  divs d2,d6
  1122.  add.w MIDDLEY,d6
  1123.  move.w d6,strbot
  1124.  move.w d6,18(a0)
  1125.  move.w d3,2(a1)
  1126.  cmp.w leftclip(pc),d3
  1127.  blt .alloffleft
  1128.  cmp.w rightclip(pc),d1
  1129. ; cmp.w #95,d1
  1130.  bge .alloffright
  1131.  
  1132.  movem.l d0/d1/d2/d3/a0,-(a7)
  1133.  
  1134.  moveq #0,d0
  1135.  move.b WALLIDENT,d0
  1136.  blt.s .noputinmap
  1137.  
  1138.  move.b d0,d3
  1139.  and.b #15,d0
  1140.  move.l COMPACTPTR,a0
  1141.  moveq #0,d1
  1142.  move.w d0,d2
  1143.  add.w d0,d0
  1144.  add.w d2,d0
  1145.  bset d0,d1
  1146.  btst #4,d3
  1147.  beq.s .nodoor
  1148.  addq #2,d0
  1149.  bset d0,d1
  1150. .nodoor:
  1151.  
  1152.  or.l d1,(a0)
  1153.  move.l BIGPTR,a0
  1154.  
  1155.  move.w wallleftpt,(a0,d2.w*4) 
  1156.  move.w wallrightpt,2(a0,d2.w*4) 
  1157.  
  1158. .noputinmap
  1159.  
  1160.  movem.l (a7)+,d0/d1/d2/d3/a0
  1161.  
  1162.  bra OTHERHALF
  1163.  
  1164.  
  1165. .alloffleft:
  1166.  
  1167.  move.l (a1)+,d1
  1168.  move.w (a1)+,d0
  1169.  move.w (a1)+,d4
  1170.  move.w (a1)+,lbr
  1171.  
  1172.  dbra d7,.computeloop
  1173.  rts
  1174.  
  1175. .alloffright:
  1176.  rts
  1177.  
  1178. computeloop2:
  1179.  move.w 4(a1),d2
  1180.  bgt.s .infront
  1181.  rts
  1182.  
  1183. .infront:
  1184.  move.l #store,a0
  1185.  move.l (a1),d3
  1186.  divs d2,d3
  1187.  move.w 6(a1),d5
  1188.  add.w MIDDLEX,d3
  1189.  move.w strtop(pc),12(a0)
  1190.  move.l topofwall(pc),d6
  1191.  divs d2,d6
  1192.  move.w strbot(pc),16(a0)
  1193.  add.w MIDDLEY,d6
  1194.  move.w d6,strtop
  1195.  move.w d6,14(a0)
  1196.  move.l botofwall(pc),d6
  1197.  divs d2,d6
  1198.  add.w MIDDLEY,d6
  1199.  move.w d6,strbot
  1200.  move.w d6,18(a0)
  1201.  move.w d3,2(a1)
  1202.  cmp.w leftclip(pc),d3
  1203.  blt.s alloffleft2
  1204.  cmp.w rightclip(pc),d1
  1205. ; cmp.w #95,d1
  1206.  bge.s alloffright2
  1207.  
  1208. OTHERHALF:
  1209.  
  1210.  move.w d1,(a0)
  1211.  move.w d3,2(a0)
  1212.  move.w d4,4(a0)
  1213.  move.w d5,6(a0)
  1214.  move.w d0,8(a0)
  1215.  move.w d2,10(a0)
  1216.  
  1217.  move.w lbr,d5
  1218.  sub.w #300,d5
  1219.  ext.w d5
  1220.  move.w d5,24(a0)
  1221.  move.w 8(a1),d5
  1222.  sub.w #300,d5
  1223.  ext.w d5
  1224.  move.w d5,26(a0)
  1225.  
  1226.  movem.l d7/a1,-(a7)
  1227.  move.w #maxscrdiv,d7
  1228.  bsr Doleftend
  1229.  movem.l (a7)+,d7/a1
  1230.  
  1231. alloffleft2:
  1232.  
  1233.  move.l (a1)+,d1
  1234.  move.w (a1)+,d0
  1235.  move.w (a1)+,d4
  1236.  move.w (a1)+,lbr
  1237.  
  1238.  dbra d7,computeloop2
  1239.  
  1240.  rts
  1241.  
  1242. alloffright2:
  1243.  rts
  1244.  
  1245. lbr: dc.w 0
  1246. tlbr: dc.w 0
  1247. leftwallbright: dc.w 0
  1248. rightwallbright: dc.w 0
  1249. leftwallTOPbright: dc.w 0
  1250. rightwallTOPbright: dc.w 0
  1251. strtop: dc.w 0
  1252. strbot: dc.w 0
  1253.  
  1254. databuffer:
  1255.  ds.l 1600
  1256. databuffer2:
  1257.  ds.l 1600
  1258.  
  1259. ***********************************
  1260.  
  1261. * Need a routine which takes...?
  1262. * Top Y (3d)
  1263. * Bottom Y (3d)
  1264. * distance
  1265. * height of each tile (number and routine addr)
  1266. * And produces the appropriate strip on the
  1267. * screen.
  1268.  
  1269. topofwall: dc.l 0
  1270. botofwall: dc.l 0
  1271.  
  1272. nostripq:
  1273.  rts
  1274.  
  1275. ScreenWallstripdraw:
  1276.  
  1277.  move.w d4,d6
  1278.  cmp.w topclip(pc),d6
  1279.  blt.s nostripq
  1280.  cmp.w botclip(pc),d3
  1281.  bgt.s nostripq
  1282.  
  1283.  cmp.w botclip(pc),d6
  1284.  ble.s noclipbot
  1285.  move.w botclip(pc),d6
  1286. noclipbot:
  1287.  
  1288.  move.w d3,d5
  1289.  cmp.w topclip(pc),d5
  1290.  bge.s nocliptop
  1291.  move.w topclip(pc),d5
  1292.  btst #0,d5
  1293.  beq.s .nsbd
  1294.  exg a2,a4
  1295. .nsbd:
  1296.  
  1297.  sub.w d5,d6    ; height to draw.
  1298.  ble.s nostripq
  1299.  
  1300.  bra gotoend
  1301.  
  1302. nocliptop:
  1303.  
  1304.  btst #0,d5
  1305.  beq.s .nsbd
  1306.  exg a2,a4
  1307. .nsbd:
  1308.  
  1309.  sub.w d5,d6    ; height to draw.
  1310.  ble.s nostripq
  1311.  
  1312.  bra gotoend
  1313.  
  1314. wlcnt: dc.w 0
  1315.  
  1316.  CNOP 0,4
  1317. drawwalldimPACK0:
  1318.  and.w d7,d4
  1319.  move.b 1(a5,d4.w*2),d1
  1320.  and.b #31,d1
  1321.  add.l d3,d4
  1322.  move.b (a4,d1.w*2),(a3)
  1323.  adda.w d0,a3
  1324.  addx.w d2,d4
  1325.  dbra d6,drawwallPACK0
  1326.  rts
  1327.  
  1328.  CNOP 0,128 
  1329. drawwallPACK0:
  1330.  and.w d7,d4
  1331.  move.b 1(a5,d4.w*2),d1
  1332.  and.b #31,d1
  1333.  add.l d3,d4
  1334.  move.b (a2,d1.w*2),(a3)
  1335.  adda.w d0,a3
  1336.  addx.w d2,d4
  1337.  dbra d6,drawwalldimPACK0
  1338.  
  1339. nostrip:
  1340.  rts
  1341.  
  1342.  CNOP 0,4
  1343. drawwalldimPACK1:
  1344.  and.w d7,d4
  1345.  move.w (a5,d4.w*2),d1
  1346.  lsr.w #5,d1
  1347.  and.w #31,d1
  1348.  add.l d3,d4
  1349.  move.b (a4,d1.w*2),(a3)
  1350.  adda.w d0,a3
  1351.  addx.w d2,d4
  1352.  dbra d6,drawwallPACK1
  1353.  rts
  1354.  
  1355.  CNOP 0,4 
  1356. drawwallPACK1:
  1357.  and.w d7,d4
  1358.  move.w (a5,d4.w*2),d1
  1359.  lsr.w #5,d1
  1360.  and.w #31,d1
  1361.  add.l d3,d4
  1362.  move.b (a2,d1.w*2),(a3)
  1363.  adda.w d0,a3
  1364.  addx.w d2,d4
  1365.  dbra d6,drawwalldimPACK1
  1366.  
  1367.  rts
  1368.  
  1369.  CNOP 0,4
  1370. drawwalldimPACK2:
  1371.  and.w d7,d4
  1372.  move.b (a5,d4.w*2),d1
  1373.  lsr.b #2,d1
  1374.  add.l d3,d4
  1375.  move.b (a4,d1.w*2),(a3)
  1376.  adda.w d0,a3
  1377.  addx.w d2,d4
  1378.  dbra d6,drawwallPACK2
  1379.  rts
  1380.  
  1381.  CNOP 0,4 
  1382. drawwallPACK2:
  1383.  and.w d7,d4
  1384.  move.b (a5,d4.w*2),d1
  1385.  lsr.b #2,d1
  1386.  add.l d3,d4
  1387.  move.b (a2,d1.w*2),(a3)
  1388.  adda.w d0,a3
  1389.  addx.w d2,d4
  1390.  dbra d6,drawwalldimPACK2
  1391.  rts
  1392.  
  1393.  
  1394. usesimple:
  1395.  mulu d3,d4
  1396.  
  1397.  add.l d0,d4
  1398.  swap d4
  1399.  add.w totalyoff(pc),d4
  1400.  
  1401. cliptopusesimple
  1402.  move.w VALAND,d7
  1403.  move.w #320,d0
  1404.  moveq #0,d1
  1405.  cmp.l a4,a2
  1406.  blt.s usea2
  1407.  move.l a4,a2
  1408. usea2:
  1409.  
  1410.  and.w d7,d4
  1411.  
  1412.  move.l d2,d5
  1413.  clr.w d5
  1414.  cmp.b #1,StripData+1
  1415.  dbge d6,simplewalliPACK0
  1416.  dbne d6,simplewalliPACK1
  1417.  dble d6,simplewalliPACK2
  1418.  rts
  1419.  
  1420.  CNOP 0,4
  1421. simplewalliPACK0:
  1422.  move.b 1(a5,d4.w*2),d1
  1423.  and.b #31,d1
  1424.  move.b (a2,d1.w*2),d3
  1425. simplewallPACK0:
  1426.  move.b d3,(a3)
  1427.  adda.w d0,a3
  1428.  add.l d2,d4
  1429.  bcc.s .noread
  1430.  addq #1,d4
  1431.  and.w d7,d4
  1432.  move.b 1(a5,d4.w*2),d1
  1433.  and.b #31,d1
  1434.  move.b (a2,d1.w*2),d3
  1435. .noread:
  1436.  dbra d6,simplewallPACK0
  1437.  rts
  1438.  
  1439.  CNOP 0,4
  1440. simplewalliPACK1:
  1441.  move.w (a5,d4.w*2),d1
  1442.  lsr.w #5,d1
  1443.  and.w #31,d1
  1444.  move.b (a2,d1.w*2),d3
  1445. simplewallPACK1:
  1446.  move.b d3,(a3)
  1447.  adda.w d0,a3
  1448.  add.l d5,d4
  1449.  bcc.s .noread
  1450.  addq #1,d4
  1451.  and.w d7,d4
  1452.  move.w (a5,d4.w*2),d1
  1453.  lsr.w #5,d1
  1454.  and.w #31,d1
  1455.  move.b (a2,d1.w*2),d3
  1456. .noread:
  1457.  dbra d6,simplewallPACK1
  1458.  rts
  1459.  
  1460.  CNOP 0,4
  1461. simplewalliPACK2:
  1462.  move.b (a5,d4.w*2),d1
  1463.  lsr.b #2,d1
  1464.  and.b #31,d1
  1465.  move.b (a2,d1.w*2),d3
  1466. simplewallPACK2:
  1467.  move.b d3,(a3)
  1468.  adda.w d0,a3
  1469.  add.l d5,d4
  1470.  bcc.s .noread
  1471.  addq #1,d4
  1472.  and.w d7,d4
  1473.  move.b (a5,d4.w*2),d1
  1474.  lsr.b #2,d1
  1475.  move.b (a2,d1.w*2),d3
  1476. .noread:
  1477.  dbra d6,simplewallPACK2
  1478.  rts
  1479.  
  1480. ;gotoendnomult:
  1481. ; movem.l d0/d1/d2/d3/d4/d7,-(a7)
  1482. ; add.l timeslarge(pc,d5.w*4),a3 
  1483. ; move.w d5,d4
  1484. ; move.l 4(a1,d2.w*8),d0
  1485. ; move.l (a1,d2.w*8),d2
  1486. ; moveq #0,d3
  1487. ; move.w d2,d3
  1488. ; swap d2
  1489. ; tst.w d2
  1490. ; move.w wallyoff(pc),d4
  1491. ; add.w #44,d4
  1492. ; bne.s .notsimple
  1493. ; cmp.l #$b000,d3
  1494. ; ble cliptopusesimple
  1495. ;.notsimple:
  1496. ; bra cliptop
  1497.  
  1498. MIDDLEY: dc.w 120
  1499. BIGMIDDLEY: dc.l 320*120
  1500. TOPOFFSET: dc.w 0
  1501. SMIDDLEY: dc.w 120
  1502. SBIGMIDDLEY: dc.l 320*120
  1503. STOPOFFSET: dc.w 0
  1504.  
  1505. gotoend:
  1506.  
  1507.  add.l timeslarge(pc,d5.w*4),a3 
  1508.  
  1509.  add.w d2,d2
  1510.  
  1511.  move.l 4(a1,d2.w*8),d0
  1512.  add.w TOPOFFSET(pc),d5
  1513.  move.w d5,d4
  1514.  
  1515.  move.l (a1,d2.w*4),d2
  1516. ; moveq #0,d3
  1517. ; move.w d2,d3
  1518. ; swap d2
  1519. ; tst.w d2
  1520. ; bne.s .notsimple
  1521. ; cmp.l #$b000,d3
  1522. ; ble usesimple
  1523. ;.notsimple:
  1524.  
  1525.  ext.l d5
  1526.  move.l d2,d4
  1527.  muls.l d5,d4
  1528.  
  1529.  add.l d0,d4
  1530.  swap d4
  1531.  
  1532. ; mulu d3,d4
  1533. ; muls d2,d5
  1534. ; add.l d0,d4
  1535. ; swap d4
  1536. ; add.w d5,d4
  1537.  add.w totalyoff(pc),d4
  1538.  move.w VALAND,d7
  1539.  and.w d7,d4
  1540.  move.w #320,d0
  1541.  moveq #0,d1
  1542.  
  1543.  swap d2
  1544.  move.l d2,d3
  1545.  clr.w d3
  1546.  
  1547.  cmp.b #1,StripData+1
  1548.  dbge d6,drawwallPACK0
  1549.  dbne d6,drawwallPACK1
  1550.  dble d6,drawwallPACK2
  1551.  rts
  1552.  
  1553. timeslarge:
  1554.  
  1555. val SET 0
  1556.  REPT 256
  1557.  dc.l val
  1558. val SET val+320
  1559.  ENDR
  1560.  
  1561.  ds.l 100
  1562.  
  1563.  
  1564.  
  1565. ScreenWallstripdrawBIG:
  1566.  
  1567.  move.w d4,d6
  1568.  cmp.w topclip(pc),d6
  1569.  blt nostripq
  1570.  cmp.w botclip(pc),d3
  1571.  bgt nostripq
  1572.  
  1573.  cmp.w botclip(pc),d6
  1574.  ble.s .noclipbot
  1575.  move.w botclip(pc),d6
  1576. .noclipbot:
  1577.  
  1578.  move.w d3,d5
  1579.  cmp.w topclip(pc),d5
  1580.  bge.s .nocliptop
  1581.  move.w topclip(pc),d5
  1582.  btst #0,d5
  1583.  beq.s .nsbd
  1584.  exg a2,a4
  1585. .nsbd:
  1586.  
  1587.  sub.w d5,d6    ; height to draw.
  1588.  ble nostripq
  1589.  
  1590.  bra gotoendBIG
  1591.  
  1592. .nocliptop:
  1593.  
  1594.  btst #0,d5
  1595.  beq.s .nsbd2
  1596.  exg a2,a4
  1597. .nsbd2:
  1598.  
  1599.  sub.w d5,d6    ; height to draw.
  1600.  ble nostripq
  1601.  
  1602. gotoendBIG
  1603.  
  1604.  add.l timeslargeBIG(pc,d5.w*4),a3 
  1605.  
  1606.  move.w d2,d4
  1607.  add.w d2,d2
  1608.  add.w d2,d4
  1609.  
  1610.  move.l 4(a1,d4.w*8),d0
  1611.  add.w TOPOFFSET(pc),d5
  1612.  move.w d5,d4
  1613.  
  1614.  move.l (a1,d2.w*4),d2
  1615. ; moveq #0,d3
  1616. ; move.w d2,d3
  1617. ; swap d2
  1618. ; tst.w d2
  1619. ; bne.s .notsimple
  1620. ; cmp.l #$b000,d3
  1621. ; ble usesimple
  1622. ;.notsimple:
  1623.  
  1624.  ext.l d5
  1625.  move.l d2,d4
  1626.  muls.l d5,d4
  1627.  
  1628.  add.l d0,d4
  1629.  swap d4
  1630.  
  1631. ; mulu d3,d4
  1632. ; muls d2,d5
  1633. ; add.l d0,d4
  1634. ; swap d4
  1635. ; add.w d5,d4
  1636.  add.w totalyoff(pc),d4
  1637.  move.w VALAND,d7
  1638.  and.w d7,d4
  1639.  move.w #320,d0
  1640.  moveq #0,d1
  1641.  
  1642.  swap d2
  1643.  move.l d2,d3
  1644.  clr.w d3
  1645.  
  1646.  cmp.b #1,StripData+1
  1647.  dbge d6,drawwallPACK0
  1648.  dbne d6,drawwallPACK1
  1649.  dble d6,drawwallPACK2
  1650.  rts
  1651.  
  1652. timeslargeBIG:
  1653.  
  1654. val SET 0
  1655.  REPT 256
  1656.  dc.l val
  1657. val SET val+320
  1658.  ENDR
  1659.  
  1660. nostripqthru:
  1661.  rts
  1662.  
  1663.  
  1664.  
  1665. ScreenWallstripdrawthru:
  1666.  
  1667.  move.w d4,d6
  1668.  cmp.w topclip(pc),d6
  1669.  blt.s nostripqthru
  1670.  cmp.w botclip(pc),d3
  1671.  bgt.s nostripqthru
  1672.  
  1673.  cmp.w botclip(pc),d6
  1674.  ble.s .noclipbot
  1675.  move.w botclip(pc),d6
  1676. .noclipbot:
  1677.  
  1678.  move.w d3,d5
  1679.  cmp.w topclip(pc),d5
  1680.  bge.s .nocliptop
  1681.  move.w topclip(pc),d5
  1682.  btst #0,d5
  1683.  beq.s .nsbd
  1684.  exg a2,a4
  1685. .nsbd:
  1686.  
  1687.  sub.w d5,d6    ; height to draw.
  1688.  ble.s nostripqthru
  1689.  
  1690.  bra gotoendthru
  1691.  
  1692. .nocliptop:
  1693.  
  1694.  btst #0,d5
  1695.  beq.s .nsbdthru
  1696.  exg a2,a4
  1697. .nsbdthru:
  1698.  
  1699.  sub.w d5,d6    ; height to draw.
  1700.  ble.s nostripqthru
  1701.  
  1702.  bra gotoendthru
  1703.  
  1704.  CNOP 0,4
  1705. drawwalldimthruPACK0:
  1706.  and.w d7,d4
  1707.  move.b 1(a5,d4.w*2),d1
  1708.  and.b #31,d1
  1709.  beq.s .holey
  1710.  move.w (a4,d1.w*2),(a3)
  1711. .holey:
  1712.  adda.w d0,a3
  1713.  add.l d3,d4
  1714.  addx.w d2,d4
  1715.  dbra d6,drawwallthruPACK0
  1716.  rts
  1717.  CNOP 0,4
  1718. drawwallthruPACK0:
  1719.  and.w d7,d4
  1720.  move.b 1(a5,d4.w*2),d1
  1721.  and.b #31,d1
  1722.  beq.s .holey
  1723.  move.w (a2,d1.w*2),(a3)
  1724. .holey:
  1725.  adda.w d0,a3
  1726.  add.l d3,d4
  1727.  addx.w d2,d4
  1728.  dbra d6,drawwalldimthruPACK0
  1729. nostripthru:
  1730.  rts
  1731.  
  1732.  CNOP 0,4
  1733. drawwalldimthruPACK1:
  1734.  and.w d7,d4
  1735.  move.w (a5,d4.w*2),d1
  1736.  lsr.w #5,d1
  1737.  and.w #31,d1
  1738.  beq.s .holey
  1739.  move.w (a4,d1.w*2),(a3)
  1740. .holey:
  1741.  adda.w d0,a3
  1742.  add.l d3,d4
  1743.  addx.w d2,d4
  1744.  dbra d6,drawwallthruPACK1
  1745.  rts
  1746.  CNOP 0,4
  1747. drawwallthruPACK1:
  1748.  and.w d7,d4
  1749.  move.w (a5,d4.w*2),d1
  1750.  lsr.w #5,d1
  1751.  and.w #31,d1
  1752.  beq.s .holey
  1753.  move.w (a2,d1.w*2),(a3)
  1754. .holey:
  1755.  adda.w d0,a3
  1756.  add.l d3,d4
  1757.  addx.w d2,d4
  1758.  dbra d6,drawwalldimthruPACK1
  1759.  rts
  1760.  
  1761.  CNOP 0,4
  1762. drawwalldimthruPACK2:
  1763.  and.w d7,d4
  1764.  move.b (a5,d4.w*2),d1
  1765.  lsr.b #2,d1
  1766.  and.b #31,d1
  1767.  beq.s .holey
  1768.  move.w (a4,d1.w*2),(a3)
  1769. .holey:
  1770.  adda.w d0,a3
  1771.  add.l d3,d4
  1772.  addx.w d2,d4
  1773.  dbra d6,drawwallthruPACK2
  1774.  rts
  1775.  CNOP 0,4
  1776. drawwallthruPACK2:
  1777.  and.w d7,d4
  1778.  move.b (a5,d4.w*2),d1
  1779.  lsr.b #2,d1
  1780.  and.b #31,d1
  1781.  beq.s .holey
  1782.  move.w (a2,d1.w*2),(a3)
  1783. .holey:
  1784.  adda.w d0,a3
  1785.  add.l d3,d4
  1786.  addx.w d2,d4
  1787.  dbra d6,drawwalldimthruPACK2
  1788.  rts
  1789.  
  1790.  
  1791. usesimplethru:
  1792.  mulu d3,d4
  1793.  
  1794.  add.l d0,d4
  1795.  swap d4
  1796.  add.w totalyoff(pc),d4
  1797.  
  1798. cliptopusesimplethru
  1799.  moveq #63,d7
  1800.  move.w #104*4,d0
  1801.  moveq #0,d1
  1802.  cmp.l a4,a2
  1803.  blt.s usea2thru
  1804.  move.l a4,a2
  1805. usea2thru:
  1806.  and.w d7,d4
  1807.  
  1808.  move.l d2,d5
  1809.  clr.w d5
  1810.  
  1811.  cmp.b #1,StripData+1
  1812.  dbge d6,simplewallthruiPACK0
  1813.  dbne d6,simplewallthruiPACK1
  1814.  dble d6,simplewallthruiPACK2
  1815.  rts
  1816.  
  1817.  CNOP 0,4
  1818. simplewallthruiPACK0:
  1819.  move.b 1(a5,d4.w*2),d1
  1820.  and.b #31,d1
  1821.  move.w (a2,d1.w*2),d3
  1822. simplewallthruPACK0:
  1823.  move.w d3,(a3)
  1824.  adda.w d0,a3
  1825.  add.l d5,d4
  1826.  bcc.s noreadthruPACK0
  1827. maybeholePACK0
  1828.  addx.w d2,d4
  1829.  and.w d7,d4
  1830.  move.b 1(a5,d4.w*2),d1
  1831.  and.b #31,d1
  1832.  beq.s holeysimplePACK0
  1833.  move.w (a2,d1.w*2),d3
  1834.  dbra d6,simplewallthruPACK0
  1835.  rts
  1836. noreadthruPACK0:
  1837.  addx.w d2,d4
  1838.  dbra d6,simplewallthruPACK0
  1839.  rts
  1840.  
  1841.  CNOP 0,4
  1842. simplewallholePACK0:
  1843.  adda.w d0,a3
  1844.  add.l d5,d4
  1845.  bcs.s maybeholePACK0
  1846.  addx.w d2,d4
  1847. holeysimplePACK0
  1848.  and.w d7,d4
  1849.  dbra d6,simplewallholePACK0
  1850.  rts
  1851.  
  1852.  CNOP 0,4
  1853. simplewallthruiPACK1:
  1854.  move.w (a5,d4.w*2),d1
  1855.  lsr.w #5,d1
  1856.  and.w #31,d1
  1857.  move.w (a2,d1.w*2),d3
  1858.  simplewallthruPACK1:
  1859.  move.w d3,(a3)
  1860.  adda.w d0,a3
  1861.  add.l d5,d4
  1862.  bcc.s noreadthruPACK1
  1863. maybeholePACK1
  1864.  addx.w d2,d4
  1865.  and.w d7,d4
  1866.  move.w (a5,d4.w*2),d1
  1867.  lsr.w #5,d1
  1868.  and.w #31,d1
  1869.  beq.s holeysimplePACK1
  1870.  move.w (a2,d1.w*2),d3
  1871.  dbra d6,simplewallthruPACK1
  1872.  rts
  1873. noreadthruPACK1:
  1874.  addx.w d2,d4
  1875.  dbra d6,simplewallthruPACK1
  1876.  rts
  1877.  
  1878.  CNOP 0,4
  1879. simplewallholePACK1:
  1880.  adda.w d0,a3
  1881.  add.l d5,d4
  1882.  bcs.s maybeholePACK1
  1883.  addx.w d5,d4
  1884. holeysimplePACK1
  1885.  and.w d7,d4
  1886.  dbra d6,simplewallholePACK1
  1887.  rts
  1888.  
  1889.  
  1890.  CNOP 0,4
  1891. simplewallthruiPACK2:
  1892.  move.b (a5,d4.w*2),d1
  1893.  lsr.b #2,d1
  1894.  and.b #31,d1
  1895.  move.w (a2,d1.w*2),d3
  1896. simplewallthruPACK2:
  1897.  move.w d3,(a3)
  1898.  adda.w d0,a3
  1899.  add.l d5,d4
  1900.  bcc.s noreadthruPACK2
  1901. maybeholePACK2
  1902.  addx.w d2,d4
  1903.  and.w d7,d4
  1904.  move.b (a5,d4.w*2),d1
  1905.  lsr.b #2,d1
  1906.  and.b #31,d1
  1907.  beq.s holeysimplePACK2
  1908.  move.w (a2,d1.w*2),d3
  1909.  dbra d6,simplewallthruPACK2
  1910.  rts
  1911. noreadthruPACK2:
  1912.  addx.w d2,d4
  1913.  dbra d6,simplewallthruPACK2
  1914.  rts
  1915.  
  1916.  CNOP 0,4
  1917. simplewallholePACK2
  1918.  adda.w d0,a3
  1919.  add.l d5,d4
  1920.  bcs.s maybeholePACK2
  1921.  addx.w d2,d4
  1922. holeysimplePACK2
  1923.  and.w d7,d4
  1924.  dbra d6,simplewallholePACK2
  1925.  rts
  1926.  
  1927.  
  1928. gotoendthru:
  1929.  add.l timeslargethru(pc,d5.w*4),a3 
  1930.  move.w d5,d4
  1931.  move.l 4(a1,d2.w*8),d0
  1932.  move.l (a1,d2.w*8),d2
  1933.  moveq #0,d3
  1934.  move.w d2,d3
  1935.  swap d2
  1936.  tst.w d2
  1937.  bne.s .notsimple
  1938.  cmp.l #$b000,d3
  1939.  ble usesimplethru
  1940. .notsimple:
  1941.  
  1942.  mulu d3,d4
  1943.  muls d2,d5
  1944.  add.l d0,d4
  1945.  swap d4
  1946.  add.w d5,d4
  1947.  add.w wallyoff(pc),d4
  1948. cliptopthru
  1949.  moveq #63,d7
  1950.  move.w #104*4,d0
  1951.  moveq #0,d1
  1952.  
  1953.  move.l d2,d3
  1954.  clr.w d3
  1955.  
  1956.  cmp.b #1,StripData+1
  1957.  dbge d6,drawwallthruPACK0
  1958.  dbne d6,drawwallthruPACK1
  1959.  dble d6,drawwallthruPACK2
  1960.  
  1961.  rts
  1962.  
  1963. timeslargethru:
  1964.  
  1965. val SET 104*4
  1966.  REPT 80
  1967.  dc.l val
  1968. val SET val+104*4
  1969.  ENDR
  1970.  
  1971. totalyoff: dc.w 0
  1972. wallyoff: dc.w 0
  1973.  
  1974. ******************************************
  1975. * Wall polygon
  1976. leftend: dc.w 0
  1977. wallbrightoff: dc.w 0
  1978. wallleftpt: dc.w 0
  1979. wallrightpt: dc.w 0
  1980. WHICHPBR: dc.w 0
  1981. WHICHLEFTPT: dc.w 0
  1982. WHICHRIGHTPT: dc.w 0
  1983. OTHERZONE: dc.w 0
  1984.  
  1985. itsawalldraw:
  1986.  
  1987.  move.l #Rotated,a5
  1988.  move.l #OnScreen,a6
  1989.  
  1990.  move.w (a0)+,d0
  1991.  move.w (a0)+,d2
  1992.  
  1993.  move.w d0,wallleftpt
  1994.  move.w d2,wallrightpt
  1995.  
  1996.  move.b (a0)+,WHICHLEFTPT+1
  1997.  move.b (a0)+,WHICHRIGHTPT+1
  1998.  move.w #0,leftend
  1999.  moveq #0,d5
  2000.  move.w (a0)+,d5
  2001.  move.w (a0)+,d1
  2002.  asl.w #4,d1
  2003.  move.w d1,fromtile
  2004.  
  2005.  move.w (a0)+,d1
  2006.  move.w d1,totalyoff
  2007.  
  2008.  move.w (a0)+,d1
  2009.  move.l #walltiles,a3
  2010.  move.l (a3,d1.w*4),a3
  2011.  move.l a3,PaletteAddr
  2012.  add.l #64*32,a3
  2013.  move.l a3,ChunkAddr
  2014.  
  2015.  ;move.w (a0)+,d1
  2016.  ;add.w ZoneBright,d1
  2017.  move.w ZoneBright,angbright
  2018.  ;move.w (a0)+,d1
  2019.  ;move.w (a0)+,d4
  2020.  move.l yoff,d6
  2021.  
  2022.  move.b (a0)+,VALAND+1
  2023.  move.b (a0)+,VALSHIFT+1
  2024.  moveq #0,d1
  2025.  move.b (a0)+,d1
  2026.  move.w d1,HORAND
  2027.  move.b (a0)+,WHICHPBR
  2028.  
  2029.  move.w totalyoff,d1
  2030.  add.w wallyoff,d1
  2031.  and.w VALAND,d1
  2032.  move.w d1,totalyoff
  2033.  
  2034.  move.l (a0)+,topofwall
  2035.  sub.l d6,topofwall
  2036.  move.l (a0)+,botofwall
  2037.  sub.l d6,botofwall
  2038.  
  2039.  
  2040.  move.b (a0)+,wallbrightoff
  2041.  move.b (a0)+,OTHERZONE+1
  2042.  
  2043.  move.l topofwall,d3
  2044.  cmp.l botofwall,d3
  2045.  bge wallfacingaway
  2046.  
  2047.  
  2048.  tst.w 6(a5,d0*8)
  2049.  bgt.s cantell
  2050.  tst.w 6(a5,d2*8)
  2051.  ble wallfacingaway
  2052.  bra cliptotestfirstbehind
  2053. cantell:
  2054.  tst.w 6(a5,d2*8)
  2055.  ble.s cliptotestsecbehind
  2056.  bra pastclip
  2057. cliptotestfirstbehind:
  2058.  
  2059.  move.l (a5,d0*8),d3
  2060.  sub.l (a5,d2*8),d3
  2061.  move.w 6(a5,d0*8),d6
  2062.  sub.w 6(a5,d2*8),d6
  2063.  divs d6,d3
  2064.  muls 6(a5,d2*8),d3
  2065.  neg.l d3
  2066.  add.l (a5,d2*8),d3
  2067.  move.w (a6,d2*2),d6
  2068.  sub.w MIDDLEX,d6
  2069.  ext.l d6
  2070.  cmp.l d6,d3
  2071.  bge wallfacingaway
  2072.  bra cant_tell
  2073.  bra pastclip
  2074.  
  2075. cliptotestsecbehind:
  2076.  
  2077.  move.l (a5,d2*8),d3
  2078.  sub.l (a5,d0*8),d3
  2079.  move.w 6(a5,d2*8),d6
  2080.  sub.w 6(a5,d0*8),d6
  2081.  divs d6,d3
  2082.  muls 6(a5,d0*8),d3
  2083.  neg.l d3
  2084.  add.l (a5,d0*8),d3
  2085.  move.w (a6,d0*2),d6
  2086.  sub.w MIDDLEX,d6
  2087.  ext.l d6
  2088.  cmp.l d6,d3
  2089.  ble wallfacingaway
  2090.  bra cant_tell
  2091.  
  2092. pastclip:
  2093.  
  2094.  move.w (a6,d0*2),d3
  2095.  cmp.w RIGHTX,d3
  2096.  bge wallfacingaway
  2097.  cmp.w (a6,d2*2),d3
  2098.  bge wallfacingaway
  2099.  tst.w (a6,d2*2)
  2100.  blt wallfacingaway
  2101.  
  2102. cant_tell:
  2103.  
  2104. ; move.l a1,a4
  2105. ; move.w #31,d6
  2106. ; move.l #0,d3
  2107. ;.emptylop:
  2108. ; move.l d3,(a4)+
  2109. ; dbra d6,.emptylop
  2110.  
  2111. ; move.w rightclip(pc),d6
  2112. ; st (a1,d6)
  2113. ; move.w leftclip(pc),d6
  2114. ; st -1(a1,d6)
  2115.  
  2116. ; muls sinval(pc),d1
  2117. ; muls cosval(pc),d4
  2118. ; add.l d1,d4
  2119. ; add.l d4,d4
  2120. ; swap d4
  2121. ; neg.w d4
  2122. ; move.w d4,d6
  2123. ; asr.w #1,d4
  2124. ; sub.w d4,angbright
  2125. ; and.b #$fe,d4
  2126. ; asl.w #2,d4
  2127. ; asl.w #2,d6
  2128.  
  2129.  movem.l d7/a0/a5/a6,-(a7)
  2130.  move.l (a5,d0*8),a0
  2131. ; add.l a0,a0
  2132.  move.w 6(a5,d0*8),d1
  2133.  move.l (a5,d2*8),a2
  2134. ; add.l a2,a2
  2135.  move.w 6(a5,d2*8),d3
  2136.  
  2137.  move.l #CurrentPointBrights,a5
  2138.  
  2139.  move.w currzone,d0
  2140.  move.b WHICHPBR,d4
  2141.  btst #3,d4
  2142.  beq.s .nototherzone 
  2143.  move.w OTHERZONE,d0
  2144. .nototherzone
  2145.  
  2146.  and.w #7,d4
  2147.  muls #40,d0
  2148.  add.w d0,d4
  2149.  
  2150.  move.w WHICHLEFTPT,d0
  2151.  asl.w #2,d0
  2152.  add.w d4,d0
  2153.  
  2154.  move.w (a5,d0.w*2),d0
  2155.  add.w #300,d0
  2156.  add.w wallbrightoff,d0
  2157.  move.w d0,leftwallbright
  2158.  
  2159.  move.w WHICHRIGHTPT,d0
  2160.  asl.w #2,d0
  2161.  add.w d4,d0
  2162.  move.w (a5,d0.w*2),d0
  2163.  add.w #300,d0
  2164.  add.w wallbrightoff,d0
  2165.  move.w d0,rightwallbright
  2166.  
  2167.  move.w currzone,d0
  2168.  move.b WHICHPBR,d4
  2169.  lsr.w #4,d4
  2170.  btst #3,d4
  2171.  beq.s .nototherzone2 
  2172.  move.w OTHERZONE,d0
  2173. .nototherzone2
  2174.  
  2175.  and.w #7,d4
  2176.  muls #40,d0
  2177.  add.w d0,d4
  2178.  
  2179.  move.w WHICHLEFTPT,d0
  2180.  asl.w #2,d0
  2181.  add.w d4,d0
  2182.  
  2183.  move.w (a5,d0.w*2),d0
  2184.  add.w #300,d0
  2185.  add.w wallbrightoff,d0
  2186.  move.w d0,leftwallTOPbright
  2187.  
  2188.  move.w WHICHRIGHTPT,d0
  2189.  asl.w #2,d0
  2190.  add.w d4,d0
  2191.  move.w (a5,d0.w*2),d0
  2192.  add.w #300,d0
  2193.  add.w wallbrightoff,d0
  2194.  move.w d0,rightwallTOPbright
  2195.  
  2196.  move.w leftend(pc),d4
  2197.  move.l #max3ddiv,d7
  2198.  
  2199.  move.w rightwallTOPbright,d0
  2200.  cmp.w rightwallbright,d0
  2201.  bne.s gottagour
  2202.  move.w leftwallTOPbright,d0
  2203.  cmp.w leftwallbright,d0
  2204.  bne.s gottagour
  2205.  
  2206.  bsr walldraw
  2207.  bra.s nottagour
  2208.  
  2209. gottagour:
  2210.  bsr walldrawGOUR
  2211. nottagour:
  2212.  movem.l (a7)+,d7/a0/a5/a6
  2213.  
  2214. wallfacingaway:
  2215.  
  2216.  rts
  2217.  
  2218. PointBrightsPtr: dc.l 0
  2219. midpt: dc.l 0
  2220. dist1: dc.l 0
  2221. dist2: dc.l 0
  2222. VALAND: dc.w 0
  2223. VALSHIFT: dc.w 0
  2224. HORAND: dc.w 0
  2225.  
  2226. sinval: dc.w 0
  2227. cosval: dc.w 0
  2228.  
  2229. oldxoff: dc.w 0
  2230. oldzoff: dc.w 0
  2231.  
  2232. topclip: dc.w 0
  2233. botclip: dc.w 0
  2234. seethru: dc.w 0
  2235.