Amiga ACS 1998 #2/amigaacscoverdisc1998-021998.iso/utilities/shareware/diskutils/cdrom/discus/install_discus

Text File | 1997-09-22 | 7KB | 279 lines

; Discus Installation Script
; (C) Copyright 1997 Marian Schedenig

(set @app-name "Discus")

(set #path (pathonly @icon))

(if (= @language "deutsch")
    (
        (set #welc "Willkommen zur Installation von Discus !")
        (set #dirprompt
        (   cat "Bitte geben Sie an, in welchem Verzeichnis Discus installiert werden soll. Es wird dann "
                "eine Schublade \"Discus\" angelegt."
        ))
        (set #dirhelp "Eine Schublade namens \"Discus\" wird automatisch erzeugt.\n")
        (set #iftxt "Wollen Sie Discus automatisch beim Systemstart ausführen ?")
        (set #iftxth "Wenn Sie \"Ja\" anwählen, wird ein Aufruf von Discus in Ihre User-Startup-Datei eingetragen")
        (set #iftxt2 "Wollen Sie die vorgefertigten EID-Dateien installieren?")
        (set #iftxt2h
        (   cat "Wenn Sie \"Ja\" anwählen, werden einige vorbereitete EID-Dateien in Ihr Discus-Verzeichnis kopiert. "
                "EID-Dateien enthalten die Titel von CDs, damit diese automatisch angezeigt werden können."
        ))
        (set #filecopy "Dateien werden kopiert...")
        (set #startupprompt "Ändere User-Startup...")
        (set #hstartup "...")
        (set #iftxt3 "Soll die deutsche Katalog-Datei installiert werden?")
        (set #iftxt3h "Die deutsche Katalogdatei wird benötigt, wenn Sie Discus mit deutschen Texten verwenden möchten.")

        (set #iftxt4 "Sollen die benötigten Schriften installiert werden?")
        (set #iftxt4h "Wenn Sie die Schriften nicht installieren, müssen Sie ein Assign auf das Fonts-Verzeichnis in Ihrem Discus-Verzeichnis anlegen.")
        (set #iftxt5 "Für welchen Prozessor soll Discus installiert werden?")
        (set #iftxt6 "Welche Anleitungen wollen Sie installieren?")
        (set #gtxt 1)
        (set #defguide 3)
    )

    (
        (set #welc "Welcome to the Autostart installation script !")
        (set #dirprompt "Please specify a directory to install Autostart to. There will then be created a directory called \"Autostart\".")
        (set #dirhelp "A drawer \"Autostart\" will automatically be created.\n")
        (set #iftxt "Do you want to automatically execute Discus on system startup ?")
        (set #iftxth "If you select \"Yes\", a command to execute Discus will be inserted into your User-Startup file.")
        (set #iftxt2 "Do you want to install the pre-created EID files ?")
        (set #iftxt2h
        (   cat "If you select \"Yes\", some EID files will be copied to your Discus directory. "
                " EID files store the title data of CDs in order to automatically display them while playing the CD."
        ))
        (set #filecopy "Copying files...")
        (set #startupprompt "Modifying User-Startup...")
        (set #hstartup "...")
        (set #iftxt3 "Do you want to install the german catalog file?")
        (set #iftxt3h "You need the german catalog file if you want to use Discus with german texts.")
        (set #iftxt4 "Do you want to install the fonts?")
        (set #iftxt4h "If you do not install the fonts, you will have to create an assign to the Fonts directory in your Discus directory.")
        (set #iftxt5 "For which CPU do you want to install Discus?")
        (set #iftxt6 "Which guides do you want to install?")
        (set #gtxt 0)
        (set #defguide 1)
    )
)


(welcome #welc)
(complete 0)

(set #userstartup 0)
(set #idfilesbool 1)
(set #fonts 1)

(set @default-dest
    (tackon (askdir (prompt #dirprompt)
                    (help (cat #dirhelp @askdir-help))
                    (default @default-dest)
            )
            "Discus")
)

(makedir (@default-dest) (infos))

(complete 10)

(set #n 2)
(set #cpu (database "cpu"))
(if (= #cpu "68000")
    (set #n 0))
(if (= #cpu "68010")
    (set #n 0))
(if (= #cpu "68020")
    (set #n 1))

(set #n
(
    (askchoice  (prompt #iftxt5)
                (help @askchoice-help)
                (choices "68000" "68020" "68030+")
                (default #n)
    )
)
)

(select #n
    (set #fnam "Discus.000")
    (set #fnam "Discus.020")
    (set #fnam "Discus.030")
)

(complete 20)

(copyfiles  (source (tackon #path #fnam))
            (dest @default-dest)
            (newname "Discus")
)

(complete 30)

(copyfiles  (source (tackon #path "Discus.info"))
            (dest @default-dest)
)

(complete 40)

(if (>= @user-level 1)
(
    (set #userstartup
        (askbool (prompt #iftxt)
                 (help (cat #iftxth @askbool-help))
                 (default 1)
        )
    )
)
)

(complete 45)

(if (= #userstartup 1)
(
    (startup "Discus " (prompt #startupprompt)
                        (help #hstartup)
                        (command (cat "RUN <NIL: >NIL: " (tackon @default-dest "Discus")))
    )
)
)

(complete 50)

(makedir (tackon @default-dest "CD_Titles") (infos))
(makedir (tackon @default-dest "Programs") (infos))

(complete 60)

(if (= @user-level 2)
(
    (set #idfilesbool
        (askbool (prompt #iftxt2)
                 (help (cat #iftxt2h @askbool-help))
                 (default 1)
        )
    )
)
)

(complete 65)

(if (= #idfilesbool 1)
(
    (copyfiles  (source (tackon #path "Notes_on_CD_titles.readme"))
                (dest @default-dest)
    )
    (copyfiles  (source (tackon #path "Notes_on_CD_titles.readme.info"))
                (dest @default-dest)
    )
    (copyfiles  (source (tackon #path "CD_Titles"))
                (dest (tackon @default-dest "CD_Titles"))
                (all)
    )
)
)

(complete 70)

(if (>= @user-level 1)
(
    (
        (set #gtxt
            (askbool (prompt #iftxt3)
                     (help (cat #iftxt3h @askbool-help))
                     (default 1)
            )
        )
    )
)
)

(complete 75)

(if (= #gtxt 1)
(
    (makedir (tackon @default-dest "Catalogs"))
    (makedir (tackon @default-dest "Catalogs/Deutsch"))
    (copyfiles (source (tackon #path "Catalogs/Deutsch"))
               (dest (tackon @default-dest "Catalogs/Deutsch"))
               (all)
    )
)
)

(complete 80)

(if (>= @user-level 1)
(
    (
        (set #fonts
            (askbool (prompt #iftxt4)
                     (help (cat #iftxt4h @askbool-help))
                     (default 1)
            )
        )
    )
)
)

(complete 85)

(if (= #fonts 1)
(
    (copyfiles (source (tackon #path "Fonts"))
               (dest "Fonts:")
               (all)
    )
)
)

(complete 90)

(set #guides
    (askoptions (prompt #iftxt6)
                (help @askchoice-help)
                (choices "English" "German")
                (default #defguide)
    )
)

(debug #guides)

(complete 95)

(if (> #guides 0)
(
    (makedir (tackon @default-dest "Guides") (infos))
    (debug "makedir ok")
    (copyfiles  (source (tackon #path "Guides"))
                (dest (tackon @default-dest "Guides"))
                (pattern "#?.Brush")
    )
    (debug "copy ok")
    (if (BITAND #guides 1)
    (
        (copyfiles  (source (tackon #path "Guides"))
                    (dest (tackon @default-dest "Guides"))
                    (pattern "Discus_E.#?")
        )
        (debug "english ok")
    )
    )
    (if (BITAND #guides 2)
    (
        (copyfiles  (source (tackon #path "Guides"))
                    (dest (tackon @default-dest "Guides"))
                    (pattern "Discus_D.#?")
        )
        (debug "deutsch ok")
    )
    )
)
)

(complete 100)