home *** CD-ROM | disk | FTP | other *** search
/ Chip 2001 January / Chip_2001-01_cd1.bin / tema / mysql / mysql-3.23.28g-win.exe / DATA1.CAB / Examples / scripts / mysqlhotcopy.pl < prev    next >
Perl Script  |  2000-11-22  |  19KB  |  692 lines
  1. #!/my/gnu/bin/perl5
  2.  
  3. use strict;
  4. use Getopt::Long;
  5. use Data::Dumper;
  6. use File::Basename;
  7. use File::Path;
  8. use DBI;
  9.  
  10. =head1 NAME
  11.  
  12. mysqlhotcopy - fast on-line hot-backup utility for local MySQL databases
  13.  
  14. =head1 SYNOPSIS
  15.  
  16.   mysqlhotcopy db_name
  17.  
  18.   mysqlhotcopy --suffix=_copy db_name_1 ... db_name_n
  19.  
  20.   mysqlhotcopy db_name_1 ... db_name_n /path/to/new_directory
  21.  
  22.   mysqlhotcopy db_name./regex/
  23.  
  24.   mysqlhotcopy db_name./^\(foo\|bar\)/
  25.  
  26.   mysqlhotcopy db_name./~regex/
  27.  
  28.   mysqlhotcopy db_name_1./regex_1/ db_name_1./regex_2/ ... db_name_n./regex_n/ /path/to/new_directory
  29.  
  30.   mysqlhotcopy --method='scp -Bq -i /usr/home/foo/.ssh/identity' --user=root --password=secretpassword \
  31.          db_1./^nice_table/ user@some.system.dom:~/path/to/new_directory
  32.  
  33. WARNING: THIS IS VERY MUCH A FIRST-CUT ALPHA. Comments/patches welcome.
  34.  
  35. =cut
  36.  
  37. # Documentation continued at end of file
  38.  
  39. my $VERSION = "1.8";
  40.  
  41. my $OPTIONS = <<"_OPTIONS";
  42.  
  43. Usage: $0 db_name [new_db_name | directory]
  44.  
  45.   -?, --help           display this helpscreen and exit
  46.   -u, --user=#         user for database login if not current user
  47.   -p, --password=#     password to use when connecting to server
  48.   -P, --port=#         port to use when connecting to local server
  49.   -S, --socket=#       socket to use when connecting to local server
  50.  
  51.   --allowold           don't abort if target already exists (rename it _old)
  52.   --keepold            don't delete previous (now renamed) target when done
  53.   --indices            include index files in copy
  54.   --method=#           method for copy (only "cp" currently supported)
  55.  
  56.   -q, --quiet          be silent except for errors
  57.   --debug              enable debug
  58.   -n, --dryrun         report actions without doing them
  59.  
  60.   --regexp=#           copy all databases with names matching regexp
  61.   --suffix=#           suffix for names of copied databases
  62.   --checkpoint=#       insert checkpoint entry into specified db.table
  63.   --flushlog           flush logs once all tables are locked 
  64.  
  65.   Try 'perldoc $0 for more complete documentation'
  66. _OPTIONS
  67.  
  68. sub usage {
  69.     die @_, $OPTIONS;
  70. }
  71.  
  72. my %opt = (
  73.     user    => getpwuid($>),
  74.     indices    => 1,    # for safety
  75.     allowold    => 0,    # for safety
  76.     keepold    => 0,
  77.     method    => "cp",
  78.     flushlog    => 0,
  79. );
  80. Getopt::Long::Configure(qw(no_ignore_case)); # disambuguate -p and -P
  81. GetOptions( \%opt,
  82.     "help",
  83.     "user|u=s",
  84.     "password|p=s",
  85.     "port|P=s",
  86.     "socket|S=s",
  87.     "allowold!",
  88.     "keepold!",
  89.     "indices!",
  90.     "method=s",
  91.     "debug",
  92.     "quiet|q",
  93.     "mv!",
  94.     "regexp=s",
  95.     "suffix=s",
  96.     "checkpoint=s",
  97.     "flushlog",
  98.     "dryrun|n",
  99. ) or usage("Invalid option");
  100.  
  101. # @db_desc
  102. # ==========
  103. # a list of hash-refs containing:
  104. #
  105. #   'src'     - name of the db to copy
  106. #   't_regex' - regex describing tables in src
  107. #   'target'  - destination directory of the copy
  108. #   'tables'  - array-ref to list of tables in the db
  109. #   'files'   - array-ref to list of files to be copied
  110. #
  111.  
  112. my @db_desc = ();
  113. my $tgt_name = undef;
  114.  
  115. if ( $opt{regexp} || $opt{suffix} || @ARGV > 2 ) {
  116.     $tgt_name   = pop @ARGV unless ( exists $opt{suffix} );
  117.     @db_desc = map { s{^([^\.]+)\./(.+)/$}{$1}; { 'src' => $_, 't_regex' => ( $2 ? $2 : '.*' ) } } @ARGV;
  118. }
  119. else {
  120.     usage("Database name to hotcopy not specified") unless ( @ARGV );
  121.  
  122.     $ARGV[0] =~ s{^([^\.]+)\./(.+)/$}{$1};
  123.     @db_desc = ( { 'src' => $ARGV[0], 't_regex' => ( $2 ? $2 : '.*' ) } );
  124.  
  125.     if ( @ARGV == 2 ) {
  126.     $tgt_name   = $ARGV[1];
  127.     }
  128.     else {
  129.     $opt{suffix} = "_copy";
  130.     }
  131. }
  132.  
  133. my $mysqld_help;
  134. my %mysqld_vars;
  135. my $start_time = time;
  136. $0 = $1 if $0 =~ m:/([^/]+)$:;
  137. $opt{quiet} = 0 if $opt{debug};
  138. $opt{allowold} = 1 if $opt{keepold};
  139.  
  140. # --- connect to the database ---
  141. my $dsn = ";host=localhost";
  142. $dsn .= ";port=$opt{port}" if $opt{port};
  143. $dsn .= ";mysql_socket=$opt{socket}" if $opt{socket};
  144.  
  145. my $dbh = DBI->connect("dbi:mysql:$dsn;mysql_read_default_group=mysqlhotcopy",
  146.                         $opt{user}, $opt{password},
  147. {
  148.     RaiseError => 1,
  149.     PrintError => 0,
  150.     AutoCommit => 1,
  151. });
  152.  
  153. # --- check that checkpoint table exists if specified ---
  154. if ( $opt{checkpoint} ) {
  155.     eval { $dbh->do( qq{ select time_stamp, src, dest, msg 
  156.              from $opt{checkpoint} where 1 != 1} );
  157.        };
  158.  
  159.     die "Error accessing Checkpoint table ($opt{checkpoint}): $@"
  160.       if ( $@ );
  161. }
  162.  
  163. # --- get variables from database ---
  164. my $sth_vars = $dbh->prepare("show variables like 'datadir'");
  165. $sth_vars->execute;
  166. while ( my ($var,$value) = $sth_vars->fetchrow_array ) {
  167.     $mysqld_vars{ $var } = $value;
  168. }
  169. my $datadir = $mysqld_vars{'datadir'}
  170.     || die "datadir not in mysqld variables";
  171. $datadir =~ s:/$::;
  172.  
  173.  
  174. # --- get target path ---
  175. my ($tgt_dirname, $to_other_database);
  176. $to_other_database=0;
  177. if ($tgt_name =~ m:^\w+$: && @db_desc <= 1)
  178. {
  179.     $tgt_dirname = "$datadir/$tgt_name";
  180.     $to_other_database=1;
  181. }
  182. elsif ($tgt_name =~ m:/: || $tgt_name eq '.') {
  183.     $tgt_dirname = $tgt_name;
  184. }
  185. elsif ( $opt{suffix} ) {
  186.     print "copy suffix $opt{suffix}\n" unless $opt{quiet};
  187. }
  188. else {
  189.     die "Target '$tgt_name' doesn't look like a database name or directory path.\n";
  190. }
  191.  
  192. # --- resolve database names from regexp ---
  193. if ( defined $opt{regexp} ) {
  194.     my $sth_dbs = $dbh->prepare("show databases");
  195.     $sth_dbs->execute;
  196.     while ( my ($db_name) = $sth_dbs->fetchrow_array ) {
  197.     push @db_desc, { 'src' => $db_name } if ( $db_name =~ m/$opt{regexp}/o );
  198.     }
  199. }
  200.  
  201. # --- get list of tables to hotcopy ---
  202.  
  203. my $hc_locks = "";
  204. my $hc_tables = "";
  205. my $num_tables = 0;
  206. my $num_files = 0;
  207.  
  208. foreach my $rdb ( @db_desc ) {
  209.     my $db = $rdb->{src};
  210.     eval { $dbh->do( "use $db" ); };
  211.     die "Database '$db' not accessible: $@"  if ( $@ );
  212.     my @dbh_tables = $dbh->func( '_ListTables' );
  213.  
  214.     ## generate regex for tables/files
  215.     my $t_regex = $rdb->{t_regex};        ## assign temporary regex
  216.     my $negated = $t_regex =~ tr/~//d;    ## remove and count negation operator: we don't allow ~ in table names
  217.     $t_regex = qr/$t_regex/;              ## make regex string from user regex
  218.  
  219.     ## filter (out) tables specified in t_regex
  220.     print "Filtering tables with '$t_regex'\n" if $opt{debug};
  221.     @dbh_tables = ( $negated 
  222.             ? grep { $_ !~ $t_regex } @dbh_tables 
  223.             : grep { $_ =~ $t_regex } @dbh_tables );
  224.  
  225.     ## get list of files to copy
  226.     my $db_dir = "$datadir/$db";
  227.     opendir(DBDIR, $db_dir ) 
  228.       or die "Cannot open dir '$db_dir': $!";
  229.  
  230.     my %db_files;
  231.     map { ( /(.+)\.\w+$/ ? { $db_files{$_} = $1 } : () ) } readdir(DBDIR);
  232.     unless( keys %db_files ) {
  233.     warn "'$db' is an empty database\n";
  234.     }
  235.     closedir( DBDIR );
  236.  
  237.     ## filter (out) files specified in t_regex
  238.     my @db_files = sort ( $negated 
  239.               ? grep { $db_files{$_} !~ $t_regex } keys %db_files
  240.               : grep { $db_files{$_} =~ $t_regex } keys %db_files );
  241.  
  242.     ## remove indices unless we're told to keep them
  243.     unless ($opt{indices}) {
  244.     @db_files = grep { not /\.(ISM|MYI)$/ } @db_files;
  245.     }
  246.  
  247.     $rdb->{files}  = [ @db_files ];
  248.     my @hc_tables = map { "$db.$_" } @dbh_tables;
  249.     $rdb->{tables} = [ @hc_tables ];
  250.  
  251.     $hc_locks .= ", "  if ( length $hc_locks && @hc_tables );
  252.     $hc_locks .= join ", ", map { "$_ READ" } @hc_tables;
  253.     $hc_tables .= ", "  if ( length $hc_tables && @hc_tables );
  254.     $hc_tables .= join ", ", @hc_tables;
  255.  
  256.     $num_tables += scalar @hc_tables;
  257.     $num_files  += scalar @{$rdb->{files}};
  258. }
  259.  
  260. # --- resolve targets for copies ---
  261.  
  262. my @targets = ();
  263.  
  264. if (length $tgt_name ) {
  265.     # explicit destination directory specified
  266.  
  267.     # GNU `cp -r` error message
  268.     die "copying multiple databases, but last argument ($tgt_dirname) is not a directory\n"
  269.       if ( @db_desc > 1 && !(-e $tgt_dirname && -d $tgt_dirname ) );
  270.  
  271.     if ($to_other_database)
  272.     {
  273.       foreach my $rdb ( @db_desc ) {
  274.     $rdb->{target} = "$tgt_dirname";
  275.       }
  276.     }
  277.     elsif ($opt{method} =~ /^scp\b/) 
  278.     {   # we have to trust scp to hit the target
  279.     foreach my $rdb ( @db_desc ) {
  280.         $rdb->{target} = "$tgt_dirname/$rdb->{src}";
  281.     }
  282.     }
  283.     else
  284.     {
  285.       die "Last argument ($tgt_dirname) is not a directory\n"
  286.     if (!(-e $tgt_dirname && -d $tgt_dirname ) );
  287.       foreach my $rdb ( @db_desc ) {
  288.     $rdb->{target} = "$tgt_dirname/$rdb->{src}";
  289.       }
  290.     }
  291.   }
  292. else {
  293.   die "Error: expected \$opt{suffix} to exist" unless ( exists $opt{suffix} );
  294.  
  295.   foreach my $rdb ( @db_desc ) {
  296.     $rdb->{target} = "$datadir/$rdb->{src}$opt{suffix}";
  297.   }
  298. }
  299.  
  300. print Dumper( \@db_desc ) if ( $opt{debug} );
  301.  
  302. # --- bail out if all specified databases are empty ---
  303.  
  304. die "No tables to hot-copy" unless ( length $hc_locks );
  305.  
  306. # --- create target directories ---
  307.  
  308. my @existing = ();
  309. foreach my $rdb ( @db_desc ) {
  310.     push @existing, $rdb->{target} if ( -d  $rdb->{target} );
  311. }
  312.  
  313. die "Can't hotcopy to '", join( "','", @existing ), "' because already exist and --allowold option not given.\n"
  314.   if ( @existing && !$opt{allowold} );
  315.  
  316. retire_directory( @existing ) if ( @existing );
  317.  
  318. foreach my $rdb ( @db_desc ) {
  319.     my $tgt_dirpath = $rdb->{target};
  320.     if ( $opt{dryrun} ) {
  321.     print "mkdir $tgt_dirpath, 0750\n";
  322.     }
  323.     elsif ($opt{method} =~ /^scp\b/) {
  324.     ## assume it's there?
  325.     ## ...
  326.     }
  327.     else {
  328.     mkdir($tgt_dirpath, 0750)
  329.       or die "Can't create '$tgt_dirpath': $!\n";
  330.     }
  331. }
  332.  
  333. ##############################
  334. # --- PERFORM THE HOT-COPY ---
  335. #
  336. # Note that we try to keep the time between the LOCK and the UNLOCK
  337. # as short as possible, and only start when we know that we should
  338. # be able to complete without error.
  339.  
  340. # read lock all the tables we'll be copying
  341. # in order to get a consistent snapshot of the database
  342.  
  343. if ( $opt{checkpoint} ) {
  344.     # convert existing READ lock on checkpoint table into WRITE lock
  345.     unless ( $hc_locks =~ s/$opt{checkpoint}\s+READ/$opt{checkpoint} WRITE/ ) {
  346.     $hc_locks .= ", $opt{checkpoint} WRITE";
  347.     }
  348. }
  349.  
  350. my $hc_started = time;    # count from time lock is granted
  351.  
  352. if ( $opt{dryrun} ) {
  353.     print "LOCK TABLES $hc_locks\n";
  354.     print "FLUSH TABLES /*!32323 $hc_tables */\n";
  355.     print "FLUSH LOGS\n" if ( $opt{flushlog} );
  356. }
  357. else {
  358.     my $start = time;
  359.     $dbh->do("LOCK TABLES $hc_locks");
  360.     printf "Locked $num_tables tables in %d seconds.\n", time-$start unless $opt{quiet};
  361.     $hc_started = time;    # count from time lock is granted
  362.  
  363.     # flush tables to make on-disk copy uptodate
  364.     $start = time;
  365.     $dbh->do("FLUSH TABLES /*!32323 $hc_tables */");
  366.     printf "Flushed tables ($hc_tables) in %d seconds.\n", time-$start unless $opt{quiet};
  367.     $dbh->do( "FLUSH LOGS" ) if ( $opt{flushlog} );
  368. }
  369.  
  370. my @failed = ();
  371.  
  372. foreach my $rdb ( @db_desc ) {
  373.     my @files = map { "$datadir/$rdb->{src}/$_" } @{$rdb->{files}};
  374.     next unless @files;
  375.     eval { copy_files($opt{method}, \@files, $rdb->{target} ); };
  376.  
  377.     push @failed, "$rdb->{src} -> $rdb->{target} failed: $@"
  378.       if ( $@ );
  379.  
  380.     if ( $opt{checkpoint} ) {
  381.     my $msg = ( $@ ) ? "Failed: $@" : "Succeeded";
  382.  
  383.     eval {
  384.         $dbh->do( qq{ insert into $opt{checkpoint} (src, dest, msg) 
  385.               VALUES ( '$rdb->{src}', '$rdb->{target}', '$msg' )
  386.             } ); 
  387.     };
  388.  
  389.     if ( $@ ) {
  390.         warn "Failed to update checkpoint table: $@\n";
  391.     }
  392.     }
  393. }
  394.  
  395. if ( $opt{dryrun} ) {
  396.     print "UNLOCK TABLES\n";
  397.     if ( @existing && !$opt{keepold} ) {
  398.     my @oldies = map { $_ . '_old' } @existing;
  399.     print "rm -rf @oldies\n" 
  400.     }
  401.     $dbh->disconnect();
  402.     exit(0);
  403. }
  404. else {
  405.     $dbh->do("UNLOCK TABLES");
  406. }
  407.  
  408. my $hc_dur = time - $hc_started;
  409. printf "Unlocked tables.\n" unless $opt{quiet};
  410.  
  411. #
  412. # --- HOT-COPY COMPLETE ---
  413. ###########################
  414.  
  415. $dbh->disconnect;
  416.  
  417. if ( @failed ) {
  418.     # hotcopy failed - cleanup
  419.     # delete any @targets 
  420.     # rename _old copy back to original
  421.  
  422.     print "Deleting @targets \n" if $opt{debug};
  423.     rmtree([@targets]);
  424.     if (@existing) {
  425.     print "Restoring @existing from back-up\n" if $opt{debug};
  426.         foreach my $dir ( @existing ) {
  427.         rename("${dir}_old", $dir )
  428.           or warn "Can't rename ${dir}_old to $dir: $!\n";
  429.     }
  430.     }
  431.  
  432.     die join( "\n", @failed );
  433. }
  434. else {
  435.     # hotcopy worked
  436.     # delete _old unless $opt{keepold}
  437.  
  438.     if ( @existing && !$opt{keepold} ) {
  439.     my @oldies = map { $_ . '_old' } @existing;
  440.     print "Deleting previous copy in @oldies\n" if $opt{debug};
  441.     rmtree([@oldies]);
  442.     }
  443.  
  444.     printf "$0 copied %d tables (%d files) in %d second%s (%d seconds overall).\n",
  445.         $num_tables, $num_files,
  446.         $hc_dur, ($hc_dur==1)?"":"s", time - $start_time
  447.     unless $opt{quiet};
  448. }
  449.  
  450. exit 0;
  451.  
  452.  
  453. # ---
  454.  
  455. sub copy_files {
  456.     my ($method, $files, $target) = @_;
  457.     my @cmd;
  458.     print "Copying ".@$files." files...\n" unless $opt{quiet};
  459.  
  460.     if ($method =~ /^s?cp\b/) { # cp or scp with optional flags
  461.     @cmd = ($method);
  462.     # add option to preserve mod time etc of copied files
  463.     # not critical, but nice to have
  464.     push @cmd, "-p" if $^O =~ m/^(solaris|linux|freebsd)$/;
  465.  
  466.     # add recursive option for scp
  467.     push @cmd, "-r" if $^O =~ /m^(solaris|linux|freebsd)$/ && $method =~ /^scp\b/;
  468.  
  469.     # add files to copy and the destination directory
  470.     push @cmd, @$files, $target;
  471.     }
  472.     else {
  473.     die "Can't use unsupported method '$method'\n";
  474.     }
  475.  
  476.     if ( $opt{dryrun} ) {
  477.     print "@cmd\n";
  478.     next;
  479.     }
  480.  
  481.     ## for some reason system fails but backticks works ok for scp...
  482.     print "Executing '@cmd'\n" if $opt{debug};
  483.     my $cp_status = system @cmd;
  484.     if ($cp_status != 0) {
  485.     warn "Burp ('scuse me). Trying backtick execution...\n" if $opt{debug}; #'
  486.     ## try something else
  487.     `@cmd` && die "Error: @cmd failed ($cp_status) while copying files.\n";
  488.     }
  489. }
  490.  
  491. sub retire_directory {
  492.     my ( @dir ) = @_;
  493.  
  494.     foreach my $dir ( @dir ) {
  495.     my $tgt_oldpath = $dir . '_old';
  496.     if ( $opt{dryrun} ) {
  497.         print "rmtree $tgt_oldpath\n" if ( -d $tgt_oldpath );
  498.         print "rename $dir, $tgt_oldpath\n";
  499.         next;
  500.     }
  501.  
  502.     if ( -d $tgt_oldpath ) {
  503.         print "Deleting previous 'old' hotcopy directory ('$tgt_oldpath')\n" unless $opt{quiet};
  504.         rmtree([$tgt_oldpath])
  505.     }
  506.     rename($dir, $tgt_oldpath)
  507.       or die "Can't rename $dir=>$tgt_oldpath: $!\n";
  508.     print "Existing hotcopy directory renamed to '$tgt_oldpath'\n" unless $opt{quiet};
  509.     }
  510. }
  511.  
  512. __END__
  513.  
  514. =head1 DESCRIPTION
  515.  
  516. mysqlhotcopy is designed to make stable copies of live MySQL databases.
  517.  
  518. Here "live" means that the database server is running and the database
  519. may be in active use. And "stable" means that the copy will not have
  520. any corruptions that could occur if the table files were simply copied
  521. without first being locked and flushed from within the server.
  522.  
  523. =head1 OPTIONS
  524.  
  525. =over 4
  526.  
  527. =item --checkpoint checkpoint-table
  528.  
  529. As each database is copied, an entry is written to the specified
  530. checkpoint-table.  This has the happy side-effect of updating the
  531. MySQL update-log (if it is switched on) giving a good indication of
  532. where roll-forward should begin for backup+rollforward schemes.
  533.  
  534. The name of the checkpoint table should be supplied in database.table format.
  535. The checkpoint-table must contain at least the following fields:
  536.  
  537. =over 4
  538.  
  539.   time_stamp timestamp not null
  540.   src varchar(32)
  541.   dest varchar(60)
  542.   msg varchar(255)
  543.  
  544. =back
  545.  
  546. =item --suffix suffix
  547.  
  548. Each database is copied back into the originating datadir under
  549. a new name. The new name is the original name with the suffix
  550. appended. 
  551.  
  552. If only a single db_name is supplied and the --suffix flag is not
  553. supplied, then "--suffix=_copy" is assumed.
  554.  
  555. =item --allowold
  556.  
  557. Move any existing version of the destination to a backup directory for
  558. the duration of the copy. If the copy successfully completes, the backup 
  559. directory is deleted - unless the --keepold flag is set.  If the copy fails,
  560. the backup directory is restored.
  561.  
  562. The backup directory name is the original name with "_old" appended.
  563. Any existing versions of the backup directory are deleted.
  564.  
  565. =item --keepold
  566.  
  567. Behaves as for the --allowold, with the additional feature 
  568. of keeping the backup directory after the copy successfully completes.
  569.  
  570. =item --flushlog
  571.  
  572. Rotate the log files by executing "FLUSH LOGS" after all tables are
  573. locked, and before they are copied.
  574.  
  575. =item --regexp pattern
  576.  
  577. Copy all databases with names matching the pattern
  578.  
  579. =item db_name./pattern/
  580.  
  581. Copy only tables matching pattern. Shell metacharacters ( (, ), |, !,
  582. etc.) have to be escaped (e.g. \). For example, to select all tables
  583. in database db1 whose names begin with 'foo' or 'bar':
  584.  
  585.     mysqlhotcopy --indices --method=cp db1./^\(foo\|bar\)/
  586.  
  587. =item db_name./~pattern/
  588.  
  589. Copy only tables not matching pattern. For example, to copy tables
  590. that do not begin with foo nor bar:
  591.  
  592.     mysqlhotcopy --indices --method=cp db1./~^\(foo\|bar\)/
  593.  
  594. =item -?, --help
  595.  
  596. Display helpscreen and exit
  597.  
  598. =item -u, --user=#         
  599.  
  600. user for database login if not current user
  601.  
  602. =item -p, --password=#     
  603.  
  604. password to use when connecting to server
  605.  
  606. =item -P, --port=#         
  607.  
  608. port to use when connecting to local server
  609.  
  610. =item -S, --socket=#         
  611.  
  612. UNIX domain socket to use when connecting to local server
  613.  
  614. =item  --indices          
  615.  
  616. include index files in copy
  617.  
  618. =item  --method=#           
  619.  
  620. method for copy (only "cp" currently supported). Alpha support for
  621. "scp" was added in November 2000. Your experience with the scp method
  622. will vary with your ability to understand how scp works. 'man scp'
  623. and 'man ssh' are your friends.
  624.  
  625. The destination directory _must exist_ on the target machine using
  626. the scp method. Liberal use of the --debug option will help you figure
  627. out what's really going on when you do an scp.
  628.  
  629. Note that using scp will lock your tables for a _long_ time unless
  630. your network connection is _fast_. If this is unacceptable to you,
  631. use the 'cp' method to copy the tables to some temporary area and then
  632. scp or rsync the files at your leisure.
  633.  
  634. =item -q, --quiet              
  635.  
  636. be silent except for errors
  637.  
  638. =item  --debug
  639.  
  640. Debug messages are displayed 
  641.  
  642. =item -n, --dryrun
  643.  
  644. Display commands without actually doing them
  645.  
  646. =back
  647.  
  648. =head1 WARRANTY
  649.  
  650. This software is free and comes without warranty of any kind. You
  651. should never trust backup software without studying the code yourself.
  652. Study the code inside this script and only rely on it if I<you> believe
  653. that it does the right thing for you.
  654.  
  655. Patches adding bug fixes, documentation and new features are welcome.
  656.  
  657. =head1 TO DO
  658.  
  659. Extend the individual table copy to allow multiple subsets of tables
  660. to be specified on the command line:
  661.  
  662.   mysqlhotcopy db newdb  t1 t2 /^foo_/ : t3 /^bar_/ : +
  663.  
  664. where ":" delimits the subsets, the /^foo_/ indicates all tables
  665. with names begining with "foo_" and the "+" indicates all tables
  666. not copied by the previous subsets.
  667.  
  668. newdb is either another not existing database or a full path to a directory
  669. where we can create a directory 'db'
  670.  
  671. Add option to lock each table in turn for people who don't need
  672. cross-table integrity.
  673.  
  674. Add option to FLUSH STATUS just before UNLOCK TABLES.
  675.  
  676. Add support for other copy methods (eg tar to single file?).
  677.  
  678. Add support for forthcoming MySQL ``RAID'' table subdirectory layouts.
  679.  
  680. Add option to only copy the first 65KB of index files. That simplifies
  681. recovery (recovery with no index file at all is complicated).
  682.  
  683. =head1 AUTHOR
  684.  
  685. Tim Bunce
  686.  
  687. Martin Waite - added checkpoint, flushlog, regexp and dryrun options
  688.  
  689. Ralph Corderoy - added synonyms for commands
  690.  
  691. Scott Wiersdorf - added table regex and scp support
  692.