home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 December (Special) / PCWorld_2005-12_Special_cd.bin / Bezpecnost / lsti / lsti.exe / framework-2.5.exe / Encode.pm < prev    next >
Text File  |  2005-01-27  |  24KB  |  799 lines
  1. #
  2. # $Id: Encode.pm,v 2.8 2004/10/24 12:32:06 dankogai Exp $
  3. #
  4. package Encode;
  5. use strict;
  6. our $VERSION = do { my @r = (q$Revision: 2.8 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
  7. sub DEBUG () { 0 }
  8. use XSLoader ();
  9. XSLoader::load(__PACKAGE__, $VERSION);
  10.  
  11. require Exporter;
  12. use base qw/Exporter/;
  13.  
  14. # Public, encouraged API is exported by default
  15.  
  16. our @EXPORT = qw(
  17.   decode  decode_utf8  encode  encode_utf8
  18.   encodings  find_encoding clone_encoding
  19. );
  20.  
  21. our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22.             PERLQQ HTMLCREF XMLCREF);
  23. our @FB_CONSTS = qw(FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  24.             FB_PERLQQ FB_HTMLCREF FB_XMLCREF);
  25.  
  26. our @EXPORT_OK =
  27.     (
  28.      qw(
  29.        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  30.        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  31.       ),
  32.      @FB_FLAGS, @FB_CONSTS,
  33.     );
  34.  
  35. our %EXPORT_TAGS =
  36.     (
  37.      all          =>  [ @EXPORT, @EXPORT_OK ],
  38.      fallbacks    =>  [ @FB_CONSTS ],
  39.      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  40.     );
  41.  
  42. # Documentation moved after __END__ for speed - NI-S
  43.  
  44. our $ON_EBCDIC = (ord("A") == 193);
  45.  
  46. use Encode::Alias;
  47.  
  48. # Make a %Encoding package variable to allow a certain amount of cheating
  49. our %Encoding;
  50. our %ExtModule;
  51. require Encode::Config;
  52. eval { require Encode::ConfigLocal };
  53.  
  54. sub encodings
  55. {
  56.     my $class = shift;
  57.     my %enc;
  58.     if (@_ and $_[0] eq ":all"){
  59.     %enc = ( %Encoding, %ExtModule );
  60.     }else{
  61.     %enc = %Encoding;
  62.     for my $mod (map {m/::/o ? $_ : "Encode::$_" } @_){
  63.         DEBUG and warn $mod;
  64.         for my $enc (keys %ExtModule){
  65.         $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  66.         }
  67.     }
  68.     }
  69.     return
  70.     sort { lc $a cmp lc $b }
  71.              grep {!/^(?:Internal|Unicode|Guess)$/o} keys %enc;
  72. }
  73.  
  74. sub perlio_ok{
  75.     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  76.     $obj->can("perlio_ok") and return $obj->perlio_ok();
  77.     return 0; # safety net
  78. }
  79.  
  80. sub define_encoding
  81. {
  82.     my $obj  = shift;
  83.     my $name = shift;
  84.     $Encoding{$name} = $obj;
  85.     my $lc = lc($name);
  86.     define_alias($lc => $obj) unless $lc eq $name;
  87.     while (@_){
  88.     my $alias = shift;
  89.     define_alias($alias, $obj);
  90.     }
  91.     return $obj;
  92. }
  93.  
  94. sub getEncoding
  95. {
  96.     my ($class, $name, $skip_external) = @_;
  97.  
  98.     ref($name) && $name->can('renew') and return $name;
  99.     exists $Encoding{$name} and return $Encoding{$name};
  100.     my $lc = lc $name;
  101.     exists $Encoding{$lc} and return $Encoding{$lc};
  102.  
  103.     my $oc = $class->find_alias($name);
  104.     defined($oc) and return $oc;
  105.     $lc ne $name and $oc = $class->find_alias($lc);
  106.     defined($oc) and return $oc;
  107.  
  108.     unless ($skip_external)
  109.     {
  110.     if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
  111.         $mod =~ s,::,/,g ; $mod .= '.pm';
  112.         eval{ require $mod; };
  113.         exists $Encoding{$name} and return $Encoding{$name};
  114.     }
  115.     }
  116.     return;
  117. }
  118.  
  119. sub find_encoding($;$)
  120. {
  121.     my ($name, $skip_external) = @_;
  122.     return __PACKAGE__->getEncoding($name,$skip_external);
  123. }
  124.  
  125. sub resolve_alias($){
  126.     my $obj = find_encoding(shift);
  127.     defined $obj and return $obj->name;
  128.     return;
  129. }
  130.  
  131. sub clone_encoding($){
  132.     my $obj = find_encoding(shift);
  133.     ref $obj or return;
  134.     eval { require Storable };
  135.     $@ and return;
  136.     return Storable::dclone($obj);
  137. }
  138.  
  139. sub encode($$;$)
  140. {
  141.     my ($name, $string, $check) = @_;
  142.     return undef unless defined $string;
  143.     return undef if ref $string;
  144.     $check ||=0;
  145.     my $enc = find_encoding($name);
  146.     unless(defined $enc){
  147.     require Carp;
  148.     Carp::croak("Unknown encoding '$name'");
  149.     }
  150.     my $octets = $enc->encode($string,$check);
  151.     $_[1] = $string if $check;
  152.     return $octets;
  153. }
  154.  
  155. sub decode($$;$)
  156. {
  157.     my ($name,$octets,$check) = @_;
  158.     return undef unless defined $octets;
  159.     return undef if ref $octets;
  160.     $check ||=0;
  161.     my $enc = find_encoding($name);
  162.     unless(defined $enc){
  163.     require Carp;
  164.     Carp::croak("Unknown encoding '$name'");
  165.     }
  166.     my $string = $enc->decode($octets,$check);
  167.     $_[1] = $octets if $check;
  168.     return $string;
  169. }
  170.  
  171. sub from_to($$$;$)
  172. {
  173.     my ($string,$from,$to,$check) = @_;
  174.     return undef unless defined $string;
  175.     $check ||=0;
  176.     my $f = find_encoding($from);
  177.     unless (defined $f){
  178.     require Carp;
  179.     Carp::croak("Unknown encoding '$from'");
  180.     }
  181.     my $t = find_encoding($to);
  182.     unless (defined $t){
  183.     require Carp;
  184.     Carp::croak("Unknown encoding '$to'");
  185.     }
  186.     my $uni = $f->decode($string,$check);
  187.     return undef if ($check && length($string));
  188.     $string =  $t->encode($uni,$check);
  189.     return undef if ($check && length($uni));
  190.     return defined($_[0] = $string) ? length($string) : undef ;
  191. }
  192.  
  193. sub encode_utf8($)
  194. {
  195.     my ($str) = @_;
  196.     utf8::encode($str);
  197.     return $str;
  198. }
  199.  
  200. sub decode_utf8($;$)
  201. {
  202.     my ($str, $check) = @_;
  203.     if ($check){
  204.     return decode("utf8", $str, $check);
  205.     }else{
  206.     return undef unless utf8::decode($str);
  207.     return $str;
  208.     }
  209. }
  210.  
  211. predefine_encodings(1);
  212.  
  213. #
  214. # This is to restore %Encoding if really needed;
  215. #
  216.  
  217. sub predefine_encodings{
  218.     use Encode::Encoding;
  219.     no warnings 'redefine';
  220.     my $use_xs = shift;
  221.     if ($ON_EBCDIC) {
  222.     # was in Encode::UTF_EBCDIC
  223.     package Encode::UTF_EBCDIC;
  224.     push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
  225.     *decode = sub{
  226.         my ($obj,$str,$chk) = @_;
  227.         my $res = '';
  228.         for (my $i = 0; $i < length($str); $i++) {
  229.         $res .=
  230.             chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
  231.         }
  232.         $_[1] = '' if $chk;
  233.         return $res;
  234.     };
  235.     *encode = sub{
  236.         my ($obj,$str,$chk) = @_;
  237.         my $res = '';
  238.         for (my $i = 0; $i < length($str); $i++) {
  239.         $res .=
  240.             chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
  241.         }
  242.         $_[1] = '' if $chk;
  243.         return $res;
  244.     };
  245.     $Encode::Encoding{Unicode} =
  246.         bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
  247.     } else {
  248.     package Encode::Internal;
  249.     push @Encode::Internal::ISA, 'Encode::Encoding';
  250.     *decode = sub{
  251.         my ($obj,$str,$chk) = @_;
  252.         utf8::upgrade($str);
  253.         $_[1] = '' if $chk;
  254.         return $str;
  255.     };
  256.     *encode = \&decode;
  257.     $Encode::Encoding{Unicode} =
  258.         bless {Name => "Internal"} => "Encode::Internal";
  259.     }
  260.  
  261.     {
  262.     # was in Encode::utf8
  263.     package Encode::utf8;
  264.     push @Encode::utf8::ISA, 'Encode::Encoding';
  265.     # 
  266.     if ($use_xs){
  267.         Encode::DEBUG and warn __PACKAGE__, " XS on";
  268.         *decode = \&decode_xs;
  269.         *encode = \&encode_xs;
  270.     }else{
  271.         Encode::DEBUG and warn __PACKAGE__, " XS off";
  272.         *decode = sub{
  273.         my ($obj,$octets,$chk) = @_;
  274.         my $str = Encode::decode_utf8($octets);
  275.         if (defined $str) {
  276.             $_[1] = '' if $chk;
  277.             return $str;
  278.         }
  279.         return undef;
  280.         };
  281.         *encode = sub {
  282.         my ($obj,$string,$chk) = @_;
  283.         my $octets = Encode::encode_utf8($string);
  284.         $_[1] = '' if $chk;
  285.         return $octets;
  286.         };
  287.     }
  288.     *cat_decode = sub{ # ($obj, $dst, $src, $pos, $trm, $chk)
  289.         my ($obj, undef, undef, $pos, $trm) = @_; # currently ignores $chk
  290.         my ($rdst, $rsrc, $rpos) = \@_[1,2,3];
  291.         use bytes;
  292.         if ((my $npos = index($$rsrc, $trm, $pos)) >= 0) {
  293.         $$rdst .= substr($$rsrc, $pos, $npos - $pos + length($trm));
  294.         $$rpos = $npos + length($trm);
  295.         return 1;
  296.         }
  297.         $$rdst .= substr($$rsrc, $pos);
  298.         $$rpos = length($$rsrc);
  299.         return '';
  300.     };
  301.     $Encode::Encoding{utf8} =
  302.         bless {Name => "utf8"} => "Encode::utf8";
  303.     }
  304. }
  305.  
  306. 1;
  307.  
  308. __END__
  309.  
  310. =head1 NAME
  311.  
  312. Encode - character encodings
  313.  
  314. =head1 SYNOPSIS
  315.  
  316.     use Encode;
  317.  
  318. =head2 Table of Contents
  319.  
  320. Encode consists of a collection of modules whose details are too big
  321. to fit in one document.  This POD itself explains the top-level APIs
  322. and general topics at a glance.  For other topics and more details,
  323. see the PODs below:
  324.  
  325.   Name                    Description
  326.   --------------------------------------------------------
  327.   Encode::Alias         Alias definitions to encodings
  328.   Encode::Encoding      Encode Implementation Base Class
  329.   Encode::Supported     List of Supported Encodings
  330.   Encode::CN            Simplified Chinese Encodings
  331.   Encode::JP            Japanese Encodings
  332.   Encode::KR            Korean Encodings
  333.   Encode::TW            Traditional Chinese Encodings
  334.   --------------------------------------------------------
  335.  
  336. =head1 DESCRIPTION
  337.  
  338. The C<Encode> module provides the interfaces between Perl's strings
  339. and the rest of the system.  Perl strings are sequences of
  340. B<characters>.
  341.  
  342. The repertoire of characters that Perl can represent is at least that
  343. defined by the Unicode Consortium. On most platforms the ordinal
  344. values of the characters (as returned by C<ord(ch)>) is the "Unicode
  345. codepoint" for the character (the exceptions are those platforms where
  346. the legacy encoding is some variant of EBCDIC rather than a super-set
  347. of ASCII - see L<perlebcdic>).
  348.  
  349. Traditionally, computer data has been moved around in 8-bit chunks
  350. often called "bytes". These chunks are also known as "octets" in
  351. networking standards. Perl is widely used to manipulate data of many
  352. types - not only strings of characters representing human or computer
  353. languages but also "binary" data being the machine's representation of
  354. numbers, pixels in an image - or just about anything.
  355.  
  356. When Perl is processing "binary data", the programmer wants Perl to
  357. process "sequences of bytes". This is not a problem for Perl - as a
  358. byte has 256 possible values, it easily fits in Perl's much larger
  359. "logical character".
  360.  
  361. =head2 TERMINOLOGY
  362.  
  363. =over 2
  364.  
  365. =item *
  366.  
  367. I<character>: a character in the range 0..(2**32-1) (or more).
  368. (What Perl's strings are made of.)
  369.  
  370. =item *
  371.  
  372. I<byte>: a character in the range 0..255
  373. (A special case of a Perl character.)
  374.  
  375. =item *
  376.  
  377. I<octet>: 8 bits of data, with ordinal values 0..255
  378. (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
  379.  
  380. =back
  381.  
  382. =head1 PERL ENCODING API
  383.  
  384. =over 2
  385.  
  386. =item $octets  = encode(ENCODING, $string [, CHECK])
  387.  
  388. Encodes a string from Perl's internal form into I<ENCODING> and returns
  389. a sequence of octets.  ENCODING can be either a canonical name or
  390. an alias.  For encoding names and aliases, see L</"Defining Aliases">.
  391. For CHECK, see L</"Handling Malformed Data">.
  392.  
  393. For example, to convert a string from Perl's internal format to
  394. iso-8859-1 (also known as Latin1),
  395.  
  396.   $octets = encode("iso-8859-1", $string);
  397.  
  398. B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then $octets
  399. B<may not be equal to> $string.  Though they both contain the same data, the utf8 flag
  400. for $octets is B<always> off.  When you encode anything, utf8 flag of
  401. the result is always off, even when it contains completely valid utf8
  402. string. See L</"The UTF-8 flag"> below.
  403.  
  404. encode($valid_encoding, undef) is harmless but warns you for 
  405. C<Use of uninitialized value in subroutine entry>. 
  406. encode($valid_encoding, '') is harmless and warnless.
  407.  
  408. =item $string = decode(ENCODING, $octets [, CHECK])
  409.  
  410. Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
  411. internal form and returns the resulting string.  As in encode(),
  412. ENCODING can be either a canonical name or an alias. For encoding names
  413. and aliases, see L</"Defining Aliases">.  For CHECK, see
  414. L</"Handling Malformed Data">.
  415.  
  416. For example, to convert ISO-8859-1 data to a string in Perl's internal format:
  417.  
  418.   $string = decode("iso-8859-1", $octets);
  419.  
  420. B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
  421. B<may not be equal to> $octets.  Though they both contain the same data,
  422. the utf8 flag for $string is on unless $octets entirely consists of
  423. ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
  424. below.
  425.  
  426. decode($valid_encoding, undef) is harmless but warns you for 
  427. C<Use of uninitialized value in subroutine entry>. 
  428. decode($valid_encoding, '') is harmless and warnless.
  429.  
  430. =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
  431.  
  432. Converts B<in-place> data between two encodings. The data in $octets
  433. must be encoded as octets and not as characters in Perl's internal
  434. format. For example, to convert ISO-8859-1 data to Microsoft's CP1250
  435. encoding:
  436.  
  437.   from_to($octets, "iso-8859-1", "cp1250");
  438.  
  439. and to convert it back:
  440.  
  441.   from_to($octets, "cp1250", "iso-8859-1");
  442.  
  443. Note that because the conversion happens in place, the data to be
  444. converted cannot be a string constant; it must be a scalar variable.
  445.  
  446. from_to() returns the length of the converted string in octets on
  447. success, I<undef> on error.
  448.  
  449. B<CAVEAT>: The following operations look the same but are not quite so;
  450.  
  451.   from_to($data, "iso-8859-1", "utf8"); #1
  452.   $data = decode("iso-8859-1", $data);  #2
  453.  
  454. Both #1 and #2 make $data consist of a completely valid UTF-8 string
  455. but only #2 turns utf8 flag on.  #1 is equivalent to
  456.  
  457.   $data = encode("utf8", decode("iso-8859-1", $data));
  458.  
  459. See L</"The UTF-8 flag"> below.
  460.  
  461. =item $octets = encode_utf8($string);
  462.  
  463. Equivalent to C<$octets = encode("utf8", $string);> The characters
  464. that comprise $string are encoded in Perl's internal format and the
  465. result is returned as a sequence of octets. All possible
  466. characters have a UTF-8 representation so this function cannot fail.
  467.  
  468.  
  469. =item $string = decode_utf8($octets [, CHECK]);
  470.  
  471. equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
  472. The sequence of octets represented by
  473. $octets is decoded from UTF-8 into a sequence of logical
  474. characters. Not all sequences of octets form valid UTF-8 encodings, so
  475. it is possible for this call to fail.  For CHECK, see
  476. L</"Handling Malformed Data">.
  477.  
  478. =back
  479.  
  480. =head2 Listing available encodings
  481.  
  482.   use Encode;
  483.   @list = Encode->encodings();
  484.  
  485. Returns a list of the canonical names of the available encodings that
  486. are loaded.  To get a list of all available encodings including the
  487. ones that are not loaded yet, say
  488.  
  489.   @all_encodings = Encode->encodings(":all");
  490.  
  491. Or you can give the name of a specific module.
  492.  
  493.   @with_jp = Encode->encodings("Encode::JP");
  494.  
  495. When "::" is not in the name, "Encode::" is assumed.
  496.  
  497.   @ebcdic = Encode->encodings("EBCDIC");
  498.  
  499. To find out in detail which encodings are supported by this package,
  500. see L<Encode::Supported>.
  501.  
  502. =head2 Defining Aliases
  503.  
  504. To add a new alias to a given encoding, use:
  505.  
  506.   use Encode;
  507.   use Encode::Alias;
  508.   define_alias(newName => ENCODING);
  509.  
  510. After that, newName can be used as an alias for ENCODING.
  511. ENCODING may be either the name of an encoding or an
  512. I<encoding object>
  513.  
  514. But before you do so, make sure the alias is nonexistent with
  515. C<resolve_alias()>, which returns the canonical name thereof.
  516. i.e.
  517.  
  518.   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
  519.   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
  520.   Encode::resolve_alias($name) eq $name  # true if $name is canonical
  521.  
  522. resolve_alias() does not need C<use Encode::Alias>; it can be
  523. exported via C<use Encode qw(resolve_alias)>.
  524.  
  525. See L<Encode::Alias> for details.
  526.  
  527. =head1 Encoding via PerlIO
  528.  
  529. If your perl supports I<PerlIO> (which is the default), you can use a PerlIO layer to decode
  530. and encode directly via a filehandle.  The following two examples
  531. are totally identical in their functionality.
  532.  
  533.   # via PerlIO
  534.   open my $in,  "<:encoding(shiftjis)", $infile  or die;
  535.   open my $out, ">:encoding(euc-jp)",   $outfile or die;
  536.   while(<$in>){ print $out $_; }
  537.  
  538.   # via from_to
  539.   open my $in,  "<", $infile  or die;
  540.   open my $out, ">", $outfile or die;
  541.   while(<$in>){
  542.     from_to($_, "shiftjis", "euc-jp", 1);
  543.     print $out $_;
  544.   }
  545.  
  546. Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
  547. if your encoding is supported by PerlIO by calling the C<perlio_ok>
  548. method.
  549.  
  550.   Encode::perlio_ok("hz");             # False
  551.   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
  552.  
  553.   use Encode qw(perlio_ok);            # exported upon request
  554.   perlio_ok("euc-jp")
  555.  
  556. Fortunately, all encodings that come with Encode core are PerlIO-savvy
  557. except for hz and ISO-2022-kr.  For gory details, see
  558. L<Encode::Encoding> and L<Encode::PerlIO>.
  559.  
  560. =head1 Handling Malformed Data
  561.  
  562. The optional I<CHECK> argument is used as follows.  When you omit it,
  563. Encode::FB_DEFAULT ( == 0 ) is assumed.
  564.  
  565. =over 2
  566.  
  567. =item B<NOTE:> Not all encoding suppport this feature
  568.  
  569. Some encodings ignore I<CHECK> argument.  For example,
  570. L<Encode::Unicode> ignores I<CHECK> and it always croaks on error.
  571.  
  572. =back
  573.  
  574. Now here is the list of I<CHECK> values available
  575.  
  576. =over 2
  577.  
  578. =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
  579.  
  580. If I<CHECK> is 0, (en|de)code will put a I<substitution character> in
  581. place of a malformed character.  When you encode to UCM-based encodings,
  582. E<lt>subcharE<gt> will be used.  When you decode from UCM-based
  583. encodings, the code point C<0xFFFD> is used.  If the data is supposed
  584. to be UTF-8, an optional lexical warning (category utf8) is given.
  585.  
  586. =item I<CHECK> = Encode::FB_CROAK ( == 1)
  587.  
  588. If I<CHECK> is 1, methods will die on error immediately with an error
  589. message.  Therefore, when I<CHECK> is set to 1,  you should trap the
  590. error with eval{} unless you really want to let it die.
  591.  
  592. =item I<CHECK> = Encode::FB_QUIET
  593.  
  594. If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
  595. return the portion of the data that has been processed so far when an
  596. error occurs. The data argument will be overwritten with everything
  597. after that point (that is, the unprocessed part of data).  This is
  598. handy when you have to call decode repeatedly in the case where your
  599. source data may contain partial multi-byte character sequences,
  600. (i.e. you are reading with a fixed-width buffer). Here is a sample
  601. code that does exactly this:
  602.  
  603.   my $data = ''; my $utf8 = '';
  604.   while(defined(read $fh, $buffer, 256)){
  605.     # buffer may end in a partial character so we append
  606.     $data .= $buffer;
  607.     $utf8 .= decode($encoding, $data, Encode::FB_QUIET);
  608.     # $data now contains the unprocessed partial character
  609.   }
  610.  
  611. =item I<CHECK> = Encode::FB_WARN
  612.  
  613. This is the same as above, except that it warns on error.  Handy when
  614. you are debugging the mode above.
  615.  
  616. =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
  617.  
  618. =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
  619.  
  620. =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
  621.  
  622. For encodings that are implemented by Encode::XS, CHECK ==
  623. Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
  624.  
  625. When you decode, C<\xI<HH>> will be inserted for a malformed character,
  626. where I<HH> is the hex representation of the octet  that could not be
  627. decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
  628. where I<HHHH> is the Unicode ID of the character that cannot be found
  629. in the character repertoire of the encoding.
  630.  
  631. HTML/XML character reference modes are about the same, in place of
  632. C<\x{I<HHHH>}>, HTML uses C<&#I<NNNN>;> where I<NNNN> is a decimal digit and
  633. XML uses C<&#xI<HHHH>;> where I<HHHH> is the hexadecimal digit.
  634.  
  635. =item The bitmask
  636.  
  637. These modes are actually set via a bitmask.  Here is how the FB_XX
  638. constants are laid out.  You can import the FB_XX constants via
  639. C<use Encode qw(:fallbacks)>; you can import the generic bitmask
  640. constants via C<use Encode qw(:fallback_all)>.
  641.  
  642.                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
  643.  DIE_ON_ERR    0x0001             X
  644.  WARN_ON_ERR   0x0002                               X
  645.  RETURN_ON_ERR 0x0004                      X        X
  646.  LEAVE_SRC     0x0008
  647.  PERLQQ        0x0100                                        X
  648.  HTMLCREF      0x0200
  649.  XMLCREF       0x0400
  650.  
  651. =back
  652.  
  653. =head2 Unimplemented fallback schemes
  654.  
  655. In the future, you will be able to use a code reference to a callback
  656. function for the value of I<CHECK> but its API is still undecided.
  657.  
  658. The fallback scheme does not work on EBCDIC platforms.
  659.  
  660. =head1 Defining Encodings
  661.  
  662. To define a new encoding, use:
  663.  
  664.     use Encode qw(define_encoding);
  665.     define_encoding($object, 'canonicalName' [, alias...]);
  666.  
  667. I<canonicalName> will be associated with I<$object>.  The object
  668. should provide the interface described in L<Encode::Encoding>.
  669. If more than two arguments are provided then additional
  670. arguments are taken as aliases for I<$object>.
  671.  
  672. See L<Encode::Encoding> for more details.
  673.  
  674. =head1 The UTF-8 flag
  675.  
  676. Before the introduction of utf8 support in perl, The C<eq> operator
  677. just compared the strings represented by two scalars. Beginning with
  678. perl 5.8, C<eq> compares two strings with simultaneous consideration
  679. of I<the utf8 flag>. To explain why we made it so, I will quote page
  680. 402 of C<Programming Perl, 3rd ed.>
  681.  
  682. =over 2
  683.  
  684. =item Goal #1:
  685.  
  686. Old byte-oriented programs should not spontaneously break on the old
  687. byte-oriented data they used to work on.
  688.  
  689. =item Goal #2:
  690.  
  691. Old byte-oriented programs should magically start working on the new
  692. character-oriented data when appropriate.
  693.  
  694. =item Goal #3:
  695.  
  696. Programs should run just as fast in the new character-oriented mode
  697. as in the old byte-oriented mode.
  698.  
  699. =item Goal #4:
  700.  
  701. Perl should remain one language, rather than forking into a
  702. byte-oriented Perl and a character-oriented Perl.
  703.  
  704. =back
  705.  
  706. Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
  707. was born and many features documented in the book remained
  708. unimplemented for a long time.  Perl 5.8 corrected this and the introduction
  709. of the UTF-8 flag is one of them.  You can think of this perl notion as of a
  710. byte-oriented mode (utf8 flag off) and a character-oriented mode (utf8
  711. flag on).
  712.  
  713. Here is how Encode takes care of the utf8 flag.
  714.  
  715. =over 2
  716.  
  717. =item *
  718.  
  719. When you encode, the resulting utf8 flag is always off.
  720.  
  721. =item *
  722.  
  723. When you decode, the resulting utf8 flag is on unless you can
  724. unambiguously represent data.  Here is the definition of
  725. dis-ambiguity.
  726.  
  727. After C<$utf8 = decode('foo', $octet);>,
  728.  
  729.   When $octet is...   The utf8 flag in $utf8 is
  730.   ---------------------------------------------
  731.   In ASCII only (or EBCDIC only)            OFF
  732.   In ISO-8859-1                              ON
  733.   In any other Encoding                      ON
  734.   ---------------------------------------------
  735.  
  736. As you see, there is one exception, In ASCII.  That way you can assue
  737. Goal #1.  And with Encode Goal #2 is assumed but you still have to be
  738. careful in such cases mentioned in B<CAVEAT> paragraphs.
  739.  
  740. This utf8 flag is not visible in perl scripts, exactly for the same
  741. reason you cannot (or you I<don't have to>) see if a scalar contains a
  742. string, integer, or floating point number.   But you can still peek
  743. and poke these if you will.  See the section below.
  744.  
  745. =back
  746.  
  747. =head2 Messing with Perl's Internals
  748.  
  749. The following API uses parts of Perl's internals in the current
  750. implementation.  As such, they are efficient but may change.
  751.  
  752. =over 2
  753.  
  754. =item is_utf8(STRING [, CHECK])
  755.  
  756. [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
  757. If CHECK is true, also checks the data in STRING for being well-formed
  758. UTF-8.  Returns true if successful, false otherwise.
  759.  
  760. As of perl 5.8.1, L<utf8> also has utf8::is_utf8().
  761.  
  762. =item _utf8_on(STRING)
  763.  
  764. [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
  765. B<not> checked for being well-formed UTF-8.  Do not use unless you
  766. B<know> that the STRING is well-formed UTF-8.  Returns the previous
  767. state of the UTF-8 flag (so please don't treat the return value as
  768. indicating success or failure), or C<undef> if STRING is not a string.
  769.  
  770. =item _utf8_off(STRING)
  771.  
  772. [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
  773. Returns the previous state of the UTF-8 flag (so please don't treat the
  774. return value as indicating success or failure), or C<undef> if STRING is
  775. not a string.
  776.  
  777. =back
  778.  
  779. =head1 SEE ALSO
  780.  
  781. L<Encode::Encoding>,
  782. L<Encode::Supported>,
  783. L<Encode::PerlIO>,
  784. L<encoding>,
  785. L<perlebcdic>,
  786. L<perlfunc/open>,
  787. L<perlunicode>,
  788. L<utf8>,
  789. the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
  790.  
  791. =head1 MAINTAINER
  792.  
  793. This project was originated by Nick Ing-Simmons and later maintained
  794. by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
  795. list of people involved.  For any questions, use
  796. E<lt>perl-unicode@perl.orgE<gt> so we can all share.
  797.  
  798. =cut
  799.