home *** CD-ROM | disk | FTP | other *** search
/ Tiger Disk 106 / Tiger_Disk_106_20xx_Tiger-Crew-Disk_de_Side_B.d64 / sprite-demo-prg. (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  2KB  |  89 lines
  1. 10 gosub 5000
  2. 18 rem ----------  start  ----------
  3. 19 rem
  4. 20 print "dieses programm zeigt,"
  5. 30 print "wie sprites funktionieren."
  6. 40 print "und es zeigt dabei auch jeweils"
  7. 50 print "die aufgerufenen programmzeilen."
  8. 55 print" vc = 53248"
  9. 60 print:print
  10. 70 print "fertig?"
  11. 80 get a$:if a$="" then 80
  12. 90 print c$d$d$d$d$d$
  13. 95 rem
  14. 96 rem ------ lesen/ausfuehren -----
  15. 97 rem
  16. 100 for n=1 to 17
  17. 110 read x$,y$
  18. 120 printb$x$
  19. 130 printy$
  20. 140 print:print g$" cont"
  21. 145 printb$l$:print"tippe return-";
  22. 150 print"taste zur fortsetzung."
  23. 160 printl$g$u$u$u$u$u$u$u$u$u$u$
  24. 166 rem
  25. 167 rem naechste zeile holt eine return-
  26. 168 rem taste in den eingabepuffer
  27. 169 rem
  28. 170 poke 198,1 : poke 631,13
  29. 180 stop
  30. 190 printd$d$d$d$ : next n
  31. 195 printb$"ende des beispiels." : end
  32. 197 rem
  33. 198 rem ------- daten/befehle --------
  34. 199 rem
  35. 200 data"poke vc+21,1"
  36. 210 data"<sprite 0 einschalten>"
  37. 220 data"poke vc,24 : poke vc+1,50"
  38. 230 data"<bewegen nach x=24 und y=50>"
  39. 240 data"poke vc+39,7"
  40. 250 data"<spritefarbe gelb waehlen>"
  41. 260 data"poke 2040,255"
  42. 270 data"<sprite-zeiger setzen>"
  43. 280 data"poke vc+29,1"
  44. 290 data"<horizontal erweitern>"
  45. 300 data"poke vc+23,1"
  46. 310 data"<vertikal erweitern>"
  47. 320 data"for c=24 to 255:poke vc,c:next"
  48. 330 data"<sprite bewegen>"
  49. 340 data"poke vc+16,1 : poke vc,40"
  50. 350 data"<bewegen jenseits x=255>"
  51. 360 data"for c=50to208:pokevc+1,c:next"
  52. 370 data"<sprite vertikal bewegen>"
  53. 380 data"poke vc+16,0 : poke vc,150"
  54. 390 data"<zurueck , links von x=255>"
  55. 400 data"poke vc+27,1"
  56. 410 data"<hinter den video-text>"
  57. 420 data"poke vc+37,2"
  58. 430 data"rot waehlen als zusatzfarbe #1>"
  59. 440 data"poke vc+38,6"
  60. 450 data"<blau waehlen als zusatzfarbe #2>"
  61. 460 data"poke vc+28,1"
  62. 470 data"<schalten auf mehrfarbig>"
  63. 480 data"poke vc+29,0"
  64. 490 data"<schrumpfen horizontal>"
  65. 500 data"poke vc+23,0"
  66. 510 data"<schrumpfen vertikal>"
  67. 520 data"poke vc+21,0"
  68. 530 data"<sprite ausschalten>"
  69. 4997 rem
  70. 4998 rem -----  sprite aufstellen -----
  71. 4999 rem
  72. 5000 va=1024
  73. 5010 vc=53248
  74. 5040 l$="==================================="
  75. 5050 c$=chr$(147)
  76. 5060 b$=chr$(5)
  77. 5070 g$=chr$(155)
  78. 5080 u$=chr$(145)
  79. 5090 d$=chr$(17)
  80. 5100 poke 53280,12: poke 53281,15
  81. 5110 print b$c$;
  82. 5150 for n=16320 to 16331
  83. 5160 poke n,255 : poke n+111,255
  84. 5170 next n
  85. 5180 for n=16332 to 16368 step3
  86. 5190 poke n,245:poke n+1,66:poke n+2,175
  87. 5195 next n
  88. 5200 return
  89.