home *** CD-ROM | disk | FTP | other *** search
/ Transactor / Transactor_24_1988_Transactor_Publishing.d64 / sd4.bud < prev    next >
Text File  |  2023-02-26  |  22KB  |  1,047 lines
  1. ;**************************************
  2. ;*                sdir                *
  3. ;*                                    * 
  4. ;*         universal scrolling        *
  5. ;*          directory reader          *
  6. ;*           for c-128 and            *
  7. ;*         1541, 1571 or 1581         *
  8. ;*                                    *
  9. ;*               ver 4.0              *      
  10. ;*                                    *
  11. ;*       <c> 1987 m. garamszeghy      *
  12. ;*              87-09-01              *
  13. ;*                                    *
  14. ;**************************************
  15. ;
  16. ;--- boot entry = SYS 4864 ($1300)= init
  17. ;
  18. ;--- activate from basic by
  19. ;    sd "pattern",u<disk device#>,p<printer device#>,w<printer width>
  20. ;
  21. ;
  22. ;------------   zero page pointers
  23. ;
  24. p1 =$fa  
  25. p2 =$fc
  26. p3 =$fe
  27. ;
  28. ;------------  addresses
  29. ;
  30. bottom =$e4   ; screen windows
  31. top    =$e5
  32. left   =$e6
  33. right  =$e7
  34. ;
  35. flag80  =$00d7  ; screen width flag =40 or 80
  36. basbuf  =$0200  ; basic input buffer
  37. icrunch =$0304  ; crunch basic command line
  38. eof     =$1210  ; end of basic text pointer
  39. bashi   =$1212  ; top of basic pointer
  40. ocrunch =$430d  ; normal basic crunch vector
  41. ;
  42. ; --- work space storage
  43. ;
  44. dirent =$0d00  ; number of directory entries
  45. prn    =$0d02  ; printer device
  46. psec   =$0d03  ; printer secondary address
  47. width  =$0d04  ; printer width
  48. drive  =$0d05  ; disk drive device number
  49. ;
  50. scrollp =$0d06 ; scroll pointer
  51. dirp    =$0d07 ; directory pointer
  52. lastkey =$0d09 ; last key press
  53. ;
  54. ;
  55. dirbuf  =$c000   ; directory buffer 
  56. combuf  =$0c00   ; disk command and error buffer
  57. nambuf  =$0d60   ; disk name buffer
  58. pattern =$0d20   ; directory pattern
  59. frebuf  =$0db8   ; blocks free buffer             
  60. filbuf  =$0da0   ; files found buffer
  61. ;
  62. work1 =$0d10 ; temporary storage
  63. work2 =$0d12
  64. work3 =$0d14
  65. work4 =$0d16
  66. work5 =$0d18
  67. ;
  68. comlen =$0d0a   ; length of disk command
  69. errlen =$0d0b   ; length of error message
  70. stat   =$0d0c   ; error status flag
  71. len    =$0d0d   ; file name length
  72. ;
  73. mmu =$ff00   ; registers
  74. ;
  75. setlfs   =$ffba ; kernal routines
  76. setnam   =$ffbd
  77. open     =$ffc0
  78. close    =$ffc3
  79. closeall =$ffe7                
  80. chkin    =$ffc6
  81. chkout   =$ffc9
  82. clrchn   =$ffcc
  83. chrin    =$ffcf
  84. getin    =$ffe4
  85. chrout   =$ffd2
  86. status   =$ffb7
  87. write    =$ff7d
  88. plot     =$fff0
  89. stop     =$ffe1
  90. setbank  =$ff68
  91. kload    =$ffd5
  92. pfkey    =$ff65
  93. ;
  94. convfp   =$84c9 ; basic rom routines
  95. convasc  =$8e44
  96. ;
  97. ;
  98. ;
  99. ;
  100.    .org $1300     ; unused bank 0 ram
  101.    .obj "0:sd4"
  102.    .fast
  103.     jmp init      ; bypass defaults
  104. ;
  105. ; 
  106. ; default system values
  107. ;
  108. unit    =*
  109.      .byt 8           ; default disk drive device number
  110. prtr    =*
  111.      .byt 4           ; default device number for printer
  112. prtrsec =*
  113.      .byt 4           ; default printer sec address (CARDCO, transparent)
  114. cols    =*
  115.      .byt 96          ; default printer width in increments of 32
  116. compress =*
  117.      .byt 15          ; set compressed print       (values for EPSON printer)
  118. compoff  =*
  119.      .byt 18          ; turn off compressed print
  120. expand   =*
  121.      .byt 14          ; set expanded print
  122. exoff    =*
  123.      .byt 20          ; expanded off
  124. ;
  125. ;
  126. init =*     ; boot entry point
  127.      ldx #0           ; clear screen  
  128.      stx p1+2
  129.      jsr setwindow                  
  130.      jsr bootmessage  ; and greetings
  131.      lda #$cf         ; set top of basic to $bfff
  132.      sta bashi+1
  133.      lda #$ff
  134.      sta bashi
  135.      lda <sdir        ; set basic crunch pointer
  136.      sta icrunch      ; to point to custom routine
  137.      lda >sdir
  138.      sta icrunch+1
  139.      jsr write
  140.      .byt 13,13
  141.      .asc "syntax:  sd ":.byt 34:.asc "pattern":.byt 34:.asc ",u<device#>"
  142.      .byt 13,0
  143.      lda <key         ; redefine <f3> key
  144.      sta p1         
  145.      lda >key
  146.      sta p1+1
  147.      lda #p1
  148.      ldy #4
  149.      ldx #3
  150.      jmp pfkey        ; go back to basic
  151. ;
  152. key =*
  153.      .byt 13:.asc "sd":.byt 13   ; redefine f3
  154. ;
  155. bootmessage =*
  156.      jsr write
  157.      .asc "sdir 4.0  <c>1987 m. garamszeghy"
  158.      .byt 0
  159.      rts
  160. ;
  161. endsdir =*  ; exit routine and return to basic
  162.       lda #0
  163.       sta mmu
  164.       jsr closeall ; close all channels
  165. end2 =*
  166.       ldx #0        ; clear screen, reset window
  167.       jmp setwindow ; and bye
  168. ;
  169. pat =*
  170.     .asc "$0:"      ; default directory pattern
  171. ;
  172.    sdir =*          ; main entry point
  173.      lda basbuf     ; check for sdir command
  174.      cmp #"s"
  175.      bne notsdir    ; exit to normal basic crunch if no match
  176.      lda basbuf+1
  177.      cmp #"d"
  178.      beq letsgo     ; complete match
  179. ;
  180. notsdir =*          ; exit to main basic crunch routine
  181.      jmp ocrunch
  182. ;
  183. letsgo =*
  184.       lda #0        
  185.       sta mmu        ; make sure in bank 15
  186.       tay
  187. z1    sta dirent,y   ; clear all pointers
  188.       iny
  189.       bne z1
  190. ;
  191.       jsr clrchn     ; reset default i/o
  192.       jsr closeall
  193.       ldx #0
  194.       jsr setwindow  ; clear screen
  195.       ldx #3
  196.       jsr setwindow  ; title block
  197.       jsr bootmessage
  198.       ldx #1
  199.       jsr setwindow  ; data window
  200. ;
  201. ; -- set defaults
  202. ;
  203.       lda unit     ; default disk drive device #
  204.       sta drive                    
  205.       lda cols     ; # printer columns
  206.       sta width
  207.       lda prtr     ; printer device #
  208.       sta prn
  209.       lda prtrsec  ; printer secondary address
  210.       sta psec
  211. ;
  212.       ldy #0        ; default dir pattern
  213. -     lda pat,y   
  214.       sta pattern,y
  215.       iny          
  216.       cpy #3 
  217.       bne -        
  218.       dey            ; default pattern length
  219.       sty len
  220. ;
  221.       ldy #0         ; re-set index        
  222. z3    lda basbuf,y   ; parse rest of command buffer for parameters
  223.       bne +          ; end of command on 0
  224.       jmp nomatch
  225. +     cmp #34        ; check for quote
  226.       beq match 
  227.       cmp #"u"       ; check for "u"  
  228.       beq chkunit    ; get unit number
  229.       cmp #"p"       ; check for "p"
  230.       beq chkprn     ; get printer #
  231.       cmp #"w"       ; check for "w"
  232.       beq chkwid     ; get printer width
  233. ;
  234. nb =*
  235.       iny            ; next byte
  236.       bne z3         ; and try again
  237.       beq nomatch
  238. ;
  239. chkunit =*           ; check for unit number
  240.       jsr nparse     ; parse ascii string
  241.       bne z4         ; valid value
  242.       lda unit       ; else get default
  243. z4    sta drive
  244.       bne nb         ; go back for more
  245. ;
  246. chkprn =*            ; check for printer number
  247.       jsr nparse
  248.       bne z5
  249.       lda prtr      ; default
  250. z5    sta prn
  251.       bne nb
  252. ;
  253. chkwid =*            ; check printer column width
  254.       jsr nparse
  255.       and #7         ; mask lo bits
  256.       tax                            
  257.       lda widths,x   ; look in table
  258.       sta width      ; and save it    
  259.       jmp nb
  260. ;
  261. widths =*            ; width table
  262.       .byt 64, 64, 64, 96, 128, 160, 192, 64
  263. ;
  264. nparse =*            ; parse ascii number to hex digit
  265.       iny
  266.       lda basbuf,y   ; get next char
  267.       and #15        ; mask lo nibble
  268.       cmp #1   
  269.       bne eparse     ; single digit
  270.       iny
  271.       lda basbuf,y   ; second digit
  272.       and #3         ; isolate low 2 bits
  273.       clc
  274.       adc #10        ; make into teen
  275. eparse =*
  276.       rts            ; return
  277. ;
  278. match =*
  279.       ldx #0         ; reset filename pointer
  280. getnext =*
  281.       iny
  282.       lda basbuf,y    ; transfer match to pattern buffer
  283.       sta work3
  284.       beq eol         ; end of line
  285.       cmp #34         ; end of quote
  286.       beq eol
  287.       sta pattern+3,x
  288.       inx
  289.       bne getnext
  290. eol =*
  291.       cpx #0        ; check for valid pattern length
  292.       beq nomatch
  293.       inx           ; increase by 1
  294.       txa      
  295.       clc
  296.       adc len       ; new pattern length
  297.       sta len
  298.       lda work3
  299.       bne nb
  300. ;
  301. nomatch =*
  302.       lda #0
  303.       sta basbuf       ; clear keyboard buffer
  304. ;
  305.       lda #14
  306.       ldx drive
  307.       ldy #15        ; open command channel
  308.       jsr setlfs
  309.       lda #0
  310.       jsr setnam
  311.       jsr open  
  312.       bcc dir
  313.       jmp error1    ; abort on error
  314. ;
  315. ;---- execute directory
  316. ;
  317. dir =*
  318.    lda #"i"     ; send "i0" command to drive
  319.    sta combuf
  320.    lda #"0"
  321.    sta combuf+1
  322.    lda #2
  323.    sta comlen
  324.    jsr sendcom
  325.    lda stat     ; abort on error
  326.    beq d1
  327.    jmp endsdir
  328. d1 jsr readcom ; read error channel
  329.    lda combuf
  330.    cmp #"0"
  331.    beq cont
  332. x1 jsr error1    ; abort on error
  333.    jmp endsdir
  334. ;
  335. cont =*
  336.    jsr setdir       ; init buffer pointers
  337.    ldx #1
  338.    jsr setwindow    ; set display window
  339.    jsr write
  340.    .asc "working..." ; status message
  341.    .byt 0
  342. ;
  343.       lda #1
  344.       ldx drive
  345.       ldy #0
  346.       jsr setlfs    ; open directory channel as #1
  347.       lda len
  348.       ldx <pattern
  349.       ldy >pattern
  350.       jsr setnam
  351.       lda #0
  352.       tax
  353.       jsr setbank
  354.       jsr open
  355.       jsr readcom   ; check errors
  356.       lda combuf
  357.       cmp #"0"
  358.       bne x1
  359. ;
  360.       ldx #1        ; set input channel
  361.       jsr chkin
  362.       ldy #0        ; reset pointer
  363.       sty dirent    ; clear # of filenames
  364.       sty dirent+1
  365. ;
  366. readnam =*           ; read disk name
  367. r1    jsr readbyte   ; get a disk byte
  368.       bcc r2
  369.       jmp getout     ; exit if no more, else
  370. ;
  371. r2    cmp #34        ; check for quote
  372.       bne r1         ; and wait
  373. ;
  374. nextnam =*           ; read name bytes
  375.    jsr readbyte
  376.    cmp #34        ; check for closing quote
  377.    beq nextnam    ; skip
  378.    sta nambuf,y   ; stash disk name
  379.    iny
  380.    cpy #22        ; check for end of header
  381.    bne nextnam
  382. ;
  383. nextfil =*        ; read filenames
  384.    lda #32        ; fill entry position with spaces
  385.    ldy #0
  386. n1 jsr stashbyte
  387.    iny
  388.    cpy #32
  389.    bne n1
  390. n2 jsr readbyte
  391.    bcc n3
  392.    jmp getout     ; end of dir
  393. n3 bne n2         ; looking for zero byte
  394.    jsr readbyte   ; bypass 2 bytes
  395.    jsr readbyte
  396.    bcc n4
  397.    jmp getout
  398. n4 jsr readbyte   ; get lo byte of file length
  399.    sta work4
  400.   jsr readbyte    ; get hi byte
  401.    ldx work4      ; recover lo byte
  402.    jsr convert
  403.    ldy #22
  404. n5 lda 234,y      ; get # blocks in ascii
  405.    beq n6         ; end on zero byte
  406.    jsr stashbyte  ; save byte in bank 0 buffer
  407.       iny         ; next byte
  408.       bne n5
  409. n6    ldy #0      ; set to dir entry position
  410. n7    jsr readbyte
  411.       bcc n8
  412.       jmp getout
  413. n8    cmp #34     ; check for leading quote
  414.       bne n7
  415. n9    jsr readbyte; get another char
  416.       bcc n10
  417.       jmp getout
  418. n10   cmp #34
  419.       beq n9      ; skip trailing quote
  420.       jsr stashbyte
  421.       iny
  422.       cpy #22    ; read 22 bytes
  423.       bne n9
  424.       jsr add32  ; increment p2 by 32 bytes
  425.       inc dirent ; increment # of dir entries lo byte
  426.       bne n11    
  427.       inc dirent+1 ; and hi byte if required
  428. n11   jmp nextfil ; get next file
  429. ;
  430. free =*
  431.      .asc "blocks free "
  432. ;
  433. ;
  434. getout =*            ; end dir read
  435.       jsr clrchn     ; restore i/o
  436.       lda #1         ; close directory channel
  437.       jsr close
  438.       ldy #22
  439. g1    jsr getbyte    ; move blocks free to blocks free buffer
  440.       sta frebuf-22,y
  441.       iny
  442.       cpy #32
  443.       bne g1
  444.       ldy #0
  445. g2    lda free,y      ; blocks free message to buffer
  446.       sta frebuf+5,y
  447.       iny
  448.       cpy #12
  449.       bne g2
  450.       lda #$ff        ; end of dir marker
  451.       ldy #0
  452.       jsr stashbyte
  453. ;
  454. exitdir =*
  455.     ldx #3
  456.     jsr setwindow
  457.     jsr bootmessage
  458.     ldx #4
  459.     jsr setwindow     ; set to disk name window
  460.     ldy #0
  461. g3  lda nambuf,y       ; print disk name
  462.     jsr chrout
  463.     iny
  464.     cpy #24
  465.     bne g3
  466.     lda dirent+1       ; calc # of files found
  467.     ldx dirent
  468.     jsr convert
  469.     ldy #0             ; reset counter
  470.     jsr carret
  471. g4  lda $100,y
  472.     beq g5
  473.     sta filbuf,y       ; save for later
  474.     jsr chrout
  475.     iny
  476.     bne g4
  477. g5  ldy #0
  478. g6  lda flifnd,y
  479.     beq g7
  480.     jsr chrout
  481.     sta filbuf+5,y
  482.     iny
  483.     bne g6
  484. flifnd =* 
  485.    .asc "  files"
  486.    .byt 32,32,32,32,0
  487. ;
  488. g7  tay     
  489. g8  lda frebuf,y    ; print blocks free
  490.     jsr chrout
  491.     iny
  492.     cpy #18
  493.     bne g8
  494. ;
  495.     ldx #1
  496.     lda dirent      ; check for no files found
  497.     bne g9
  498.     lda dirent+1
  499.     bne g9
  500.     jsr setwindow   ; set display window
  501.     jsr write
  502.     .asc "no files found"
  503.     .byt 13,0
  504.     jsr presskey    ; exit if no files
  505.     jmp endsdir
  506. ;
  507. g9 inx             ; menu window
  508.    lda flag80      ; check for 80 column
  509.    bne g10     
  510.    jmp dispdir
  511. g10 jsr setwindow
  512.    jsr write
  513.    .byt 176
  514.    .asc "{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}": .byt 174,13
  515.    .asc "{SHIFT--} <up>,<dn> - scroll list     {SHIFT--}": .byt 13
  516.    .asc "{SHIFT--}    <home> - top of list     {SHIFT--}": .byt 13
  517.    .asc "{SHIFT--}     <esc> - exit to basic   {SHIFT--}": .byt 13
  518.    .asc "{SHIFT--}  <return> - bload prg       {SHIFT--}": .byt 13          
  519.    .asc "{SHIFT--}           - read seq        {SHIFT--}": .byt 13
  520.    .asc "{SHIFT--}           - change 1581 dir {SHIFT--}": .byt 13
  521.    .asc "{SHIFT--}      c= m - merge seq       {SHIFT--}": .byt 13   
  522.    .asc "{SHIFT--}      c= p - print dir       {SHIFT--}": .byt 13    
  523.    .asc "{SHIFT--}      c= r - 1581 root dir   {SHIFT--}": .byt 13    
  524.    .asc "{SHIFT--}      c= s - scratch file    {SHIFT--}": .byt 13     
  525.    .asc "{SHIFT--}      c= v - validate disk   {SHIFT--}": .byt 13,173 
  526.    .asc "{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}": .byt 189,0 
  527. ;
  528. ;
  529. dispdir =*          ; display and scroll directory
  530.    jsr setdir      ; set pointers to directory buffer    
  531. ;
  532. dirmenu =*         ; directory menu
  533.    ldx #0
  534.    stx work2
  535.    stx scrollp
  536.    stx dirp
  537.    stx dirp+1
  538.    inx                 ; display window
  539.    jsr setwindow
  540. dispmore =*
  541.    ldy #0
  542. w1 jsr getbyte ; display a filename
  543.    cmp #$ff
  544.    bne w2     
  545.    jmp dm   
  546. w2 jsr chrout
  547.    iny
  548.    cpy #28
  549.    bne w1
  550.    jsr add32     ; point to next filename
  551.    inc work2        ; increment pointer
  552.    lda work2
  553.    cmp #20          ; check for full screen
  554.    beq dm
  555.    jsr carret       ; carriage return
  556.    jmp dispmore
  557. dm =*
  558.    jsr setdir 
  559.    jsr downout
  560.    jmp kloop2
  561. ;
  562. downout =*
  563. printrvs =*
  564.    lda #18     ; set <rvs> on
  565.    jsr chrout
  566. printnorm =*
  567.    ldy #0
  568.    ldx scrollp
  569.    clc
  570.    jsr plot         ; go to start of line
  571.    ldy #0
  572. w4 jsr getbyte ; get from bank 0
  573.    jsr chrout
  574.    iny
  575.    cpy #31
  576.    bne w4
  577.    lda #146     ; set <rvs> off
  578.    jmp chrout
  579. ;
  580. scrolldown =*
  581.    jsr printnorm    ; display normally       
  582.    ldx dirp         ; check lo byte of counter
  583.    inx
  584.    cpx dirent
  585.    bne q1         
  586.    jmp downout      ; dont do anything
  587. q1 stx dirp
  588.    ldx scrollp
  589.    cpx #19
  590.    beq q2  
  591.    inx
  592.    stx scrollp
  593.    jmp q3
  594. q2 jsr carret
  595. q3 jsr add32
  596.    jmp downout
  597. ;
  598. ;
  599. kloop2 =*      ; main key loop
  600. k0 jsr getin   ; get a key
  601.    beq k0
  602.    sta lastkey
  603.    cmp #27     ; <esc> to exit
  604.    bne k1
  605.    jmp endsdir
  606. k1 cmp #19     ; <home> to start
  607.    bne k2
  608.    jmp dispdir
  609. k2 cmp #13     ; <return> to load, etc
  610.    bne k3
  611.    jmp load
  612. k3 cmp #167    ; C= m  to merge seq file
  613.    bne k4
  614.    jmp load
  615. k4 cmp #175    ; C= p to print dir
  616.    bne k5
  617.    jmp printdir
  618. k5 cmp #145    ; <cursor up>
  619.    beq up
  620.    cmp #17     ; <cursor down>
  621.    bne k6        
  622.    jmp down
  623. k6 cmp #174    ; C= s to delete file
  624.    bne k7
  625.    jmp load 
  626. k7 cmp #178    ; C= r for 1581 root dir
  627.    bne k8
  628.    ldx #2      ; reset and go again
  629.    stx len
  630.    jmp dir    
  631. k8 cmp #190    ; c= v for validate
  632.    bne k9
  633.    jmp val 
  634. k9 jmp kloop2
  635.  
  636. ;
  637. up =*
  638.    jsr scrollup
  639.    jmp kloop2 
  640. ;
  641. down =*
  642.    jsr scrolldown
  643.    jmp kloop2
  644. ;
  645. scrollup =*
  646.    jsr printnorm
  647.    ldx dirp
  648.    dex             ; check lo byte of counter
  649.    cpx #$ff
  650.    bne s1
  651.    jmp downout
  652. s1 stx dirp
  653.    ldx scrollp
  654.    beq s2
  655.    dex
  656.    stx scrollp
  657.    jmp s3
  658. s2 lda #27         ; escape insert line sequence
  659.    jsr chrout
  660.    lda "i"
  661.    jsr chrout
  662. s3 sec
  663.    lda p2
  664.    sbc #32
  665.    sta p2
  666.    bcs s4
  667.    dec p2+1
  668. s4 jmp downout
  669. ;
  670. load =*
  671.    ldy #16         ; calc len of filename
  672. s5 jsr getbyte 
  673.    and #$7f
  674.    cmp #32
  675.    bne s6
  676.    dey
  677.    bne s5
  678. s6 iny
  679.    sty work1 ; save fn len
  680.    lda lastkey    ; check for C= s to scratch
  681.    cmp #174
  682.    bne s7
  683.    ldy #0
  684. s8 lda scratch,y   ; set up scratch command
  685.    sta combuf,y
  686.    iny
  687.    cpy #3
  688.    bne s8
  689.    jmp transfer   ; transfer filename and execute
  690. ;
  691. s7 ldy #17
  692.    jsr getbyte     ; look for cbm partition on 1581
  693.    cmp "c"
  694.    bne notsubdir
  695. root =*
  696.    ldy #0 
  697. s9 lda subdir,y    ; set up "/0:" command
  698.    sta combuf,y
  699.    iny
  700.    cpy #3 
  701.    bne s9
  702.    dey             ; reset directory pattern
  703.    sty len
  704. ;
  705. transfer =*
  706.    ldy #0          ; transfer filename to combuf
  707. t1 jsr getbyte 
  708.    sta combuf+3,y
  709.    iny
  710.    cpy work1
  711.    bne t1
  712.    clc
  713.    lda work1       ; set command length
  714.    adc #3
  715.    sta comlen
  716.    jsr sendcom     ; send command
  717.    jmp cont        ; and read dir over again
  718. ;
  719. subdir =*
  720.    .asc "/0:"      ; dos command prefix for change subdir
  721. ;
  722. ;
  723. scratch =*
  724.    .asc "s0:"      ; dos command prefix for scratch
  725. ;
  726. validate =*
  727.    .asc "v0:"      ; dos validate command
  728. val =*
  729.    ldy #0
  730. v1 lda validate,y
  731.    sta combuf,y
  732.    iny
  733.    cpy #3
  734.    bne v1
  735.    sty comlen
  736.    jsr sendcom
  737.    jmp cont
  738. ;
  739. notsubdir =*
  740.    ldx #0
  741.    jsr setwindow
  742.    lda #1
  743.    ldx drive
  744.    ldy #3   
  745.    jsr setlfs ; open file for load
  746.    lda work1  ; filename length
  747.    ldx p2
  748.    ldy p2+1
  749.    jsr setnam ; set filename
  750.    lda #0
  751.    tax    
  752.    jsr setbank ; set bank
  753.    ldy #17
  754.    jsr getbyte 
  755.    cmp #"p" ; check for program file
  756.    bne readsq      ; and read file if not
  757.    clc
  758.    lda #0
  759.    jsr kload   ; load file
  760.    stx eof    ; save eof pointers
  761.    sty eof+1
  762.    bcs ns1
  763.    jmp endsdir
  764. ;  
  765. ns1 jsr readcom
  766.     jmp dispdir
  767. ;
  768. readsq =*   ; read or merge seq file
  769.    jsr open
  770.    ldx #1
  771.    jsr chkin
  772.    lda lastkey
  773.    cmp #167   ; check for C= M to merge a file
  774.    bne go
  775.    ldy #17
  776.    jsr getbyte 
  777.    cmp #"s"
  778.    bne go
  779.    jmp end2   ; merge then exit
  780. go =*
  781.    jsr chrin  ; display file
  782.    jsr chrout
  783.    jsr stop   ; test stop key
  784.    bpl nogo   ; abort if pressed
  785.    jsr status
  786.    beq go
  787. nogo =*
  788.    jsr clrchn
  789.    lda #1
  790.    jsr close
  791.    jsr presskey
  792.    ldx #0       ; clear screen
  793.    jsr setwindow
  794.    jmp exitdir  ; back to main menu
  795. ;
  796. ;---- print hard copy of directory
  797. ;
  798. printdir =*
  799.     lda #6
  800.     ldx prn        ; printer device#
  801.     ldy psec       ; printer secondary address               
  802.     jsr setlfs     ; open printer file
  803.     lda #0
  804.     jsr setnam
  805.     jsr open
  806.     clc
  807.     ldx #6
  808.     jsr chkout  ; select printer for output
  809.     bcc pd1
  810.     jmp endprint ; end if error
  811. pd1 jsr setdir 
  812.     lda expand   ; set expanded print
  813.     jsr chrout
  814.     ldy #0
  815. pd2 lda nambuf,y
  816.     jsr chrout
  817.     iny
  818.     cpy #32
  819.     bne pd2
  820.     jsr carret
  821.     jsr carret
  822.     lda exoff     ; turn off expanded
  823.     jsr chrout
  824.     lda compress  ; set compressed print                  
  825.     jsr chrout
  826.     ldy width
  827.     jsr preq
  828.     jsr carret
  829. ;
  830. nexttwo =*        ; print file names , width/32 to a line
  831.     ldy #0
  832. nt1 jsr getbyte   ; get a byte
  833.     cmp #$ff
  834.     beq exitloop
  835.     jsr chrout
  836.     iny
  837.     cpy width  ; check screen width
  838.     bne nt1
  839.     jsr carret
  840.     clc
  841.     lda p2
  842.     adc width
  843.     sta p2
  844.     bcc nexttwo
  845.     inc p2+1
  846.     jmp nexttwo
  847. ;
  848. exitloop =*     ; end print out
  849.     jsr carret
  850.     ldy width
  851.     jsr preq
  852.     jsr carret
  853.     lda compoff ; turn off compressed print
  854.     jsr chrout
  855.     ldy #0
  856. el1 lda filbuf,y ; number of files found and bytes free
  857.     jsr chrout
  858.     iny
  859.     cpy #48
  860.     bne el1
  861.     jsr carret
  862. ;
  863. endprint =*
  864.     jsr clrchn
  865.     lda #6
  866.     jsr close
  867.     jmp dispdir
  868. ;
  869. setdir =*            ; reset dir pointers
  870.     lda <dirbuf
  871.     sta p2
  872.     sta p3    
  873.     lda >dirbuf
  874.     sta p2+1
  875.     sta p3+1
  876.     rts
  877. ;
  878. ;
  879. ;
  880. ;--------- subroutines
  881. ;
  882. ;
  883. ;
  884. ;---- convert digit to ascii string 
  885. ;
  886. convert =*       ; convert 2 digit integer to ascii
  887.     sta $64       ; before calling lda with high byte
  888.     stx $65       ; ldx with low byte
  889.     ldx #$90
  890.     sec
  891.     jsr $8c75
  892.     jsr $8e44    ; ascii will be at $100 ended by 0 byte
  893.     rts
  894. ;
  895. ;---- set screen windows      
  896. ;
  897. setwindow =* ; window with <clear>
  898.   lda bottoms,x
  899.   sta bottom
  900.   lda tops,x
  901.   sta top     
  902.   lda flag80  ; check screen width
  903.   beq sw1     ; skip rest if 40 col
  904.   lda lefts,x
  905.   sta left
  906.   lda rights,x
  907.   sta right
  908. ;
  909. sw1   lda #147                       ; clear screen
  910.       jmp chrout
  911.                                  ; ldx with window number
  912. ;                                ; before calling
  913. bottoms =*
  914.   .byt 24,22,24,24,2              ; 0= full screen
  915. tops =*                          ; 1= data window
  916.   .byt 0,3,5,24,0                ; 2= menu window
  917. lefts =*                         ; 3= title window
  918.   .byt 0,0,45,0,0                ; 4= status window
  919. rights =*
  920.   .byt 79,44,79,44,44
  921. ;
  922. ;
  923. ;---- write prompt messages
  924. ;
  925. error1 =*
  926.    jsr clrchn
  927.    ldx #1
  928.    jsr setwindow
  929.     jsr write
  930.    .byt 13,13
  931.    .asc "error:"
  932.    .byt 13,0
  933.    lda errlen
  934.    beq er2
  935.    ldy #0
  936. er1 lda combuf,y
  937.    jsr chrout
  938.    iny
  939.    cpy errlen
  940.    bne er1
  941. er2 lda #64 
  942.    sta stat       ; error flag        
  943. ;                                      
  944. presskey =*
  945.    jsr write
  946.    .byt 13,13
  947.    .asc "press a key ..."
  948.    .byt 13,0
  949. pk1 jsr getin
  950.    beq pk1
  951.    rts
  952. ;
  953. ;
  954. ;
  955. ;------------ disk i/o routines
  956. ;
  957. ;---- read error channel
  958. ;
  959. ; error message will be returned in combuf
  960. ; length of message in errlen
  961. ;
  962. readcom =*
  963.    clc
  964.    ldx #14     ; command channel
  965.    jsr chkin
  966.    bcs error1    ; abort on error
  967.    ldy #0
  968. rc1 jsr chrin
  969.    sta combuf,y
  970.    cmp #13
  971.    beq rc2
  972.    iny
  973.    bne rc1
  974. rc2 sty errlen
  975.    jsr clrchn
  976.    rts
  977. ;
  978. ;---- send disk command
  979. ;
  980. ; before calling:
  981. ;
  982. ; sta comlen with length of command string
  983. ;     (combuf) with command
  984. ;
  985. sendcom =*
  986.    ldx #14   ;  file #
  987.    clc
  988.    jsr chkout
  989.    bcs diskerror  ; abort on error 
  990.    ldy #0
  991. sc1 lda combuf,y
  992.    jsr chrout
  993.    iny
  994.    cpy comlen
  995.    bne sc1
  996.    jmp clrchn
  997. ;
  998. diskerror =*
  999.   jsr clrchn
  1000.   jmp error1   
  1001. ;
  1002. ;--- read a disk byte
  1003. ;
  1004. readbyte =*           ; read a disk byte
  1005.      sec
  1006.      jsr status       ; read disk status byte
  1007.      bne rb1          ; not 0, then abort with carry set
  1008.      clc              ; clear carry for byte ok
  1009.      jsr chrin        ; read byte and
  1010. rb1  rts              ; return
  1011. ;
  1012. stashbyte =*          ; save a byte in bank 0
  1013.      ldx #$3f       
  1014.      stx mmu          ; go to bank 0
  1015.      sta (p2),y       ; save data
  1016.      ldx #0    
  1017.      stx mmu          ; back to default bank
  1018.      rts              ; and return
  1019. ;
  1020. getbyte =*          ; get a byte from bank 0
  1021.      ldx #$3f       
  1022.      stx mmu          ; go to bank 0
  1023.      lda (p2),y       ; get data
  1024.      ldx #0    
  1025.      stx mmu          ; back to default bank
  1026.      rts              ; and return
  1027. ;
  1028. add32 =*            ; add 32 to zero page pointers
  1029.     clc
  1030.     lda p2
  1031.     adc #32
  1032.     sta p2
  1033.     bcc a1
  1034.     inc p2+1
  1035. a1  rts
  1036. ;
  1037. carret =*         ; send carriage return
  1038.     lda #13
  1039.     jmp chrout
  1040. ;
  1041. preq =*          ; print .y = signs
  1042.     lda "="
  1043.     jsr chrout
  1044.     dey
  1045.     bne preq
  1046.     rts
  1047.