home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib05.dsk / MIRACLES.bas < prev    next >
BASIC Source File  |  2023-02-26  |  9KB  |  330 lines
  1. 11  REM  *******************************
  2. 12  REM  **    >> MIRACLES <<         **
  3. 13  REM  **    BY PAUL RAYMER         **
  4. 14  REM  **  COPYRIGHT (C) 1981 BY    **
  5. 15  REM  **    MICRO-SPARC, INC.      **
  6. 16  REM  **    LINCOLN, MA 01773      **
  7. 17  REM  *******************************
  8. 100  TEXT : HOME : CLEAR : SPEED= 255
  9. 110  DIM N$(100)
  10. 120 :
  11. 130  REM  ORIGINAL CONCEPT BY
  12. 140  REM  PAUL RAYMER
  13. 150  REM  IV/VII/MCMLXXXI
  14. 160  REM  POB 42831
  15. 170  REM  LAS VEGAS NV 89104
  16. 180 :
  17. 190  GOTO 270
  18. 200  REM  DELAY ROUTINES
  19. 210  REM 
  20. 220  FOR M = 1 TO 100: NEXT M: RETURN 
  21. 230  FOR M = 1 TO 200: NEXT M: RETURN 
  22. 240  FOR M = 1 TO 500: NEXT M: RETURN 
  23. 250  FOR M = 1 TO 1000: NEXT M: RETURN 
  24. 260  FOR M = 1 TO 2000: NEXT M: RETURN 
  25. 270  PRINT "MIRACLES"
  26. 280  GOSUB 260: HOME 
  27. 290  VTAB 3: PRINT "1) RED SEA"
  28. 300  PRINT : PRINT "2) DANIEL"
  29. 310  PRINT : PRINT "3) NOAH"
  30. 320  PRINT : PRINT "4) MOSES AND MT. SINAI"
  31. 330  PRINT : PRINT "5) DAVID"
  32. 340  PRINT : PRINT "6) JERICHO"
  33. 350  PRINT : PRINT "7) SODOM AND GOMORRAH"
  34. 360  PRINT : PRINT "8) JONAH"
  35. 370  PRINT : PRINT "9) EXODUS"
  36. 380  PRINT : HTAB 5: PRINT "SELECT BY NUMBER ";: GET A$
  37. 390 A =  VAL(A$)
  38. 400  IF A <1  OR A >9  THEN 290
  39. 410  ON A GOSUB 1000,2000,3000,4000,5000,6000,7000,8000,9000
  40. 420  HOME : GOTO 290
  41. 430  END 
  42. 1000  REM  RED SEA MIRACLE
  43. 1010  REM 
  44. 1020  HOME 
  45. 1030  VTAB 5: PRINT "PARTING OF THE RED SEA"
  46. 1040  GOSUB 260
  47. 1050 A$ = "RED":B$ = "SEA"
  48. 1060  FOR X = 1 TO 10
  49. 1070  VTAB 12: HTAB 16 -X: PRINT A$; SPC( 2 *X);B$
  50. 1080  GOSUB 240
  51. 1090  NEXT X
  52. 1100  GOSUB 9070
  53. 1110  RETURN 
  54. 2000  REM  DANIEL MIRACLE
  55. 2010  REM 
  56. 2020  HOME 
  57. 2030  VTAB 3: HTAB 16: FLASH : PRINT " DANGER ": NORMAL 
  58. 2040  VTAB 5: HTAB 10: PRINT "********************"
  59. 2050  FOR X = 6 TO 15
  60. 2060  HTAB 10: PRINT "*"; SPC( 18);"*"
  61. 2070  NEXT X
  62. 2080  HTAB 10: PRINT "********************"
  63. 2090  VTAB 18: HTAB 15: PRINT "LION'S DEN"
  64. 2100  GOSUB 260
  65. 2110  POKE 34,6: POKE 35,14
  66. 2120  POKE 32,11: POKE 33,16
  67. 2130  SPEED= 100
  68. 2140  HOME : FOR X = 1 TO 23: PRINT "WILD LIONS  ";: NEXT X: PRINT "WILD LIONS";
  69. 2150  GOSUB 240
  70. 2160  VTAB 10: HTAB 4: INVERSE : PRINT "  DANIEL  ": NORMAL 
  71. 2170  SPEED= 200
  72. 2180  GOSUB 260
  73. 2190  HOME 
  74. 2200  FOR X = 1 TO 23: PRINT "PUSSYCATS ";: NEXT X: PRINT "PUSSYCATS";
  75. 2210  VTAB 10: HTAB 4: INVERSE : PRINT "  DANIEL  ": NORMAL 
  76. 2220  POKE 32,0: POKE 33,40: POKE 34,0: POKE 35,24
  77. 2230  SPEED= 255
  78. 2240  VTAB 3: HTAB 16: PRINT " WELCOME "
  79. 2250  GOSUB 9070
  80. 2260  RETURN 
  81. 3000  REM  NOAH MIRACLE
  82. 3010  REM 
  83. 3020  HOME 
  84. 3030  PRINT "WHAT ANIMALS WOULD YOU LIKE TO PUT ON   NOAH'S ARK?"
  85. 3040  PRINT : PRINT "(TYPE SINGULAR WORDS - PRESS RETURN     TO QUIT)": PRINT 
  86. 3050  FOR X = 1 TO 100
  87. 3060  INPUT N$(X)
  88. 3070  IF  LEN(N$(X)) = 0  THEN 3090
  89. 3080  NEXT X
  90. 3090  HOME : SPEED= 100
  91. 3100  VTAB 3: PRINT "WEATHER FORECAST...RAIN!": SPEED= 255
  92. 3110  POKE 34,5
  93. 3120  PRINT : PRINT 
  94. 3130  FOR R = 1 TO 40
  95. 3140  IF R = 25  OR R = 39  THEN  PRINT "DAY NO."R;: HTAB 12: PRINT "STILL RAINING": GOTO 3160
  96. 3150  PRINT "DAY NO.";R;: HTAB 12: PRINT "RAIN TODAY"
  97. 3160  GOSUB 230
  98. 3170  NEXT R
  99. 3180  PRINT : PRINT "LOOK...A RAINBOW!"
  100. 3190  GOSUB 260
  101. 3200  TEXT : HOME : PRINT "...AND DEBARKING FROM THE ARK ARE A"
  102. 3210  SPEED= 100
  103. 3220 XX = X -1
  104. 3230  FOR Z = 1 TO XX
  105. 3240  PRINT "BOY AND GIRL ";N$(Z)
  106. 3250  NEXT Z
  107. 3260 L =  INT(XX * RND(1)) +1
  108. 3270  PRINT : PRINT "...AND A BABY ";N$(L);"!"
  109. 3280  SPEED= 255
  110. 3290  GOSUB 9070
  111. 3300  RETURN 
  112. 4000  REM  TEN COMMANDMENTS
  113. 4010  REM 
  114. 4020  HOME 
  115. 4030  SPEED= 50
  116. 4040  PRINT "M O S E S . . ."
  117. 4050  VTAB 22: HTAB 30: PRINT "YES, SIR?"
  118. 4060  GOSUB 250
  119. 4070  HOME : PRINT "THESE ARE FOR YOU AND ALL MANKIND..."
  120. 4080  SPEED= 255
  121. 4090  FOR C = 1 TO 10: READ C$(C): NEXT C
  122. 4100  FOR X = 1 TO 10
  123. 4110  VTAB X +5: HTAB 10: PRINT C$(X)
  124. 4120  GOSUB 230
  125. 4130  NEXT X
  126. 4140  VTAB 22: HTAB 30: PRINT "THANK YOU."
  127. 4150  GOSUB 260
  128. 4160  GOSUB 9070
  129. 4170  RETURN 
  130. 4180  DATA  I,II,III,IV,V,VI,VII,VIII,IX,X
  131. 5000  REM  DAVID MIRACLE
  132. 5010  REM 
  133. 5020  HOME 
  134. 5030  PRINT "DAVID'S SIDE            GOLIATH'S SIDE": PRINT : PRINT 
  135. 5040  VTAB 20: PRINT "DAVID"
  136. 5050  FOR X = 4 TO 20
  137. 5060  VTAB X: HTAB 20: PRINT "GOLIATH"
  138. 5070  NEXT X
  139. 5080  GOSUB 260
  140. 5090  VTAB 3: HTAB 1: INVERSE : PRINT " THE LORD "
  141. 5100  FLASH 
  142. 5110  FOR X = 4 TO 20
  143. 5120  VTAB X: HTAB 20: PRINT "==ZAP=="
  144. 5130  VTAB X -1: HTAB 20: PRINT "       "
  145. 5140  GOSUB 230
  146. 5150  NEXT X
  147. 5160  NORMAL 
  148. 5170  FOR X = 2 TO 20: VTAB X: HTAB 20: PRINT  SPC( 8): NEXT X
  149. 5180  FOR X = 20 TO 41
  150. 5190  VTAB 20: HTAB 20: CALL  -958: HTAB X: PRINT "GOLIATH"
  151. 5200  GOSUB 230
  152. 5210  NEXT X
  153. 5220  VTAB 20: HTAB 10: PRINT "<- THE WINNER!"
  154. 5230  GOSUB 9070
  155. 5240  RETURN 
  156. 6000  REM  JERICHO MIRACLE
  157. 6010  REM 
  158. 6020  HOME 
  159. 6030  FOR X = 5 TO 20
  160. 6040  VTAB X: HTAB 10: PRINT "********************"
  161. 6050  NEXT X
  162. 6060  PRINT : HTAB 16: PRINT "JERICHO"
  163. 6070  GOSUB 260
  164. 6080  FOR X = 1 TO 7
  165. 6090  VTAB 1: HTAB 10: PRINT "DAY ";X
  166. 6100  PRINT  CHR$(7);
  167. 6110  GOSUB 240
  168. 6120  NEXT X
  169. 6130  FOR ZA = 1 TO 300
  170. 6140 Z =  INT(17 * RND(1)) +5
  171. 6150 ZZ =  INT(20 * RND(1)) +9
  172. 6160  VTAB Z: HTAB ZZ: PRINT "   ";
  173. 6170  NEXT ZA
  174. 6180  PRINT 
  175. 6190  FOR X = 1 TO 20: FOR Y = 10 TO 30: VTAB X: HTAB Y: PRINT " ";: NEXT Y: NEXT X
  176. 6200  SPEED= 50
  177. 6210  VTAB 1: HTAB 1: PRINT "SCORE:"
  178. 6220  PRINT : HTAB 5: PRINT "JOSHUA   1"
  179. 6230  HTAB 5: PRINT "JERICHO  0"
  180. 6240  PRINT : PRINT "========================================"
  181. 6250  SPEED= 255
  182. 6260  GOSUB 9070
  183. 6270  RETURN 
  184. 7000  REM  SODOM AND GOMORRAH
  185. 7010  REM 
  186. 7020  HOME 
  187. 7030  INVERSE 
  188. 7040  FOR X = 13 TO 20
  189. 7050  VTAB X: HTAB 30: PRINT " "
  190. 7060  NEXT X
  191. 7070  VTAB 13: HTAB 25: PRINT " SODOM -> "
  192. 7080  VTAB 15: HTAB 23: PRINT " GOMORRAH -> "
  193. 7090  NORMAL 
  194. 7100  VTAB 19: PRINT "LOT"
  195. 7110  VTAB 18: HTAB 10: PRINT "LOT'S"
  196. 7120  VTAB 19: HTAB 10: PRINT "WIFE"
  197. 7130  VTAB 21: PRINT "<<<      <<<"
  198. 7140  GOSUB 260
  199. 7150  VTAB 21: PRINT "<<<        ? "
  200. 7160  GOSUB 260
  201. 7170  VTAB 21: PRINT "<<<      >>>?"
  202. 7180  GOSUB 260
  203. 7190  VTAB 21: PRINT " NO          "
  204. 7200  GOSUB 260
  205. 7210  VTAB 21: PRINT "          YES"
  206. 7220  GOSUB 260
  207. 7230  VTAB 21: PRINT "<<<       >>>"
  208. 7240  GOSUB 260
  209. 7250  VTAB 21: PRINT "<<<          "
  210. 7260  FOR X = 2 TO 19
  211. 7270  VTAB X -1: HTAB 10: PRINT "     "
  212. 7280  VTAB X: HTAB 10: PRINT " !!!! "
  213. 7290  GOSUB 220
  214. 7300  NEXT X
  215. 7310  FOR X = 19 TO 10  STEP  -1
  216. 7320  VTAB X: HTAB 10: PRINT "=SALT="
  217. 7330  GOSUB 220
  218. 7340  NEXT X
  219. 7350  GOSUB 9070
  220. 7360  RETURN 
  221. 8000  REM  JONAH AND THE WHALE
  222. 8010  REM 
  223. 8020  HOME 
  224. 8030 J$ = "_J_"
  225. 8040 P$ = "!   !":P2$ = "!___!"
  226. 8050  SPEED= 100
  227. 8060  PRINT "J O N A H . . ."
  228. 8070  PRINT "GO TO NINEVEH."
  229. 8080  SPEED= 255
  230. 8090  FOR X = 1 TO 40: VTAB 22: PRINT "_";: NEXT X
  231. 8100  VTAB 20: HTAB 1: PRINT "NINEVEH"
  232. 8110  HTAB 2: PRINT P$: HTAB 2: PRINT P2$
  233. 8120  VTAB 20: HTAB 33: PRINT " JOPPA"
  234. 8130  VTAB 21: HTAB 34: PRINT P$
  235. 8140  VTAB 22: HTAB 34: PRINT P2$
  236. 8150  FOR X = 12 TO 9  STEP  -1
  237. 8160  VTAB 22: HTAB X: PRINT J$
  238. 8170  GOSUB 240
  239. 8180  NEXT X
  240. 8190  GOSUB 260
  241. 8200  FOR X = 9 TO 35
  242. 8210  VTAB 22: HTAB X: PRINT J$
  243. 8220  GOSUB 230
  244. 8230  NEXT X
  245. 8240  GOSUB 260
  246. 8250  HOME : SPEED= 100
  247. 8260  PRINT "SEVERAL DAYS LATER...AFTER LEAVING THE  PORT OF JOPPA WE FIND JONAH ABOARD SHIP SAILING TO DISTANT LANDS"
  248. 8270  SPEED= 255
  249. 8280  GOSUB 260: HOME 
  250. 8290  FOR X = 1 TO 160
  251. 8300  VTAB 14: HTAB X: PRINT "C": NEXT 
  252. 8310  VTAB 14: HTAB 40: PRINT "L";: VTAB 15: HTAB 40: PRINT "A";: VTAB 16: HTAB 40: PRINT "N";: VTAB 17: HTAB 40: PRINT "D"
  253. 8320 J$ = "   J                                 "
  254. 8330 B$ = "=======                                 **SHIP*                                 **SHIP*"
  255. 8340 C$ = J$ +B$
  256. 8350  FOR X = 4 TO 20
  257. 8360  VTAB 10: HTAB X: PRINT C$
  258. 8370  GOSUB 240
  259. 8380  NEXT X
  260. 8390  FOR R = 1 TO 300
  261. 8400 R1 =  INT(40 * RND(1)) +1
  262. 8410 R2 =  INT(13 * RND(1)) +1
  263. 8420  IF R2 >9  AND (R1 >16  AND R1 <25)  THEN 8440
  264. 8430  VTAB R2: HTAB R1: PRINT "'";
  265. 8440  NEXT R
  266. 8450 J$ = " J"
  267. 8460  FOR X = 22 TO 25
  268. 8470  VTAB 10: HTAB X: PRINT J$
  269. 8480  GOSUB 220
  270. 8490  NEXT X
  271. 8500  FOR X = 10 TO 13
  272. 8510  HTAB 25: VTAB X -1: PRINT "  ";
  273. 8520  HTAB 25: VTAB X: PRINT J$;
  274. 8530  GOSUB 220
  275. 8540  NEXT X
  276. 8545  HTAB 26: VTAB 13: PRINT " ": HTAB 26: PRINT "J";
  277. 8550  FOR X = 17 TO 33
  278. 8560  VTAB 11: HTAB X -1: PRINT " ";
  279. 8570  VTAB 11: HTAB X: PRINT B$
  280. 8580  GOSUB 240
  281. 8590  NEXT X
  282. 8600  HOME 
  283. 8610 W$ = "WHALE"
  284. 8620 J$ = "J"
  285. 8630  FOR X = 2 TO 15
  286. 8640  VTAB X -1: HTAB 10: PRINT " "
  287. 8650  VTAB X: HTAB 10: PRINT J$
  288. 8660  GOSUB 220
  289. 8670  NEXT X
  290. 8680  FOR X = 35 TO 10  STEP  -1
  291. 8690  VTAB 15: HTAB X: PRINT W$;"  "
  292. 8700  GOSUB 220
  293. 8710  NEXT X
  294. 8720  FOR D = 1 TO 3
  295. 8730  FOR X = 13 TO 1  STEP  -1
  296. 8740  VTAB X: HTAB 10: PRINT " "
  297. 8750  VTAB X +1: HTAB 10: PRINT " "
  298. 8760  GOSUB 220
  299. 8770  NEXT X
  300. 8780  VTAB 1: HTAB 3: PRINT "DAY NO.";D
  301. 8790  GOSUB 260
  302. 8800  NEXT D
  303. 8810  FOR X = 15 TO 5  STEP  -1
  304. 8820  VTAB X +1: HTAB 10: PRINT "      "
  305. 8830  VTAB X: HTAB 10: PRINT W$
  306. 8840  GOSUB 220
  307. 8850  NEXT X
  308. 8860  GOSUB 250
  309. 8870  FOR X = 1 TO 40: VTAB 6: PRINT "-";: NEXT X
  310. 8880  FOR X = 8 TO 1  STEP  -1
  311. 8890  VTAB 5: HTAB X: PRINT J$;" ";
  312. 8900  GOSUB 250
  313. 8910  NEXT X
  314. 8920  HOME 
  315. 8930  PRINT "WELCOME": GOSUB 240
  316. 8940  PRINT "TO": GOSUB 240
  317. 8950  PRINT "NINEVEH": GOSUB 240
  318. 8960  PRINT : GOSUB 240
  319. 8970  PRINT "JONAH!": GOSUB 260
  320. 8980  GOSUB 9070
  321. 8990  RETURN 
  322. 9000  REM  EXIT PROGRAM
  323. 9010  REM 
  324. 9020  HOME 
  325. 9030  SPEED= 200
  326. 9040  PRINT "MAY WE SUGGEST THAT YOU READ THE BIBLE  TO GET MORE DETAILED INFORMATION ON SOMEOF THE EVENTS DEPICTED HERE."
  327. 9050  SPEED= 255: GOSUB 260: GOSUB 260
  328. 9060  TEXT : HOME : END 
  329. 9070  VTAB 22: INVERSE : PRINT " ********** MIRACLE COMPLETED ********* ": NORMAL 
  330. 9080  FOR M = 1 TO 5000: NEXT M: TEXT : RETURN