home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib34b.dsk / IMAGINATION.bas < prev    next >
BASIC Source File  |  2023-02-26  |  17KB  |  371 lines
  1. 10  REM  **********************
  2. 20  REM  *     IMAGINATION    *
  3. 30  REM  * BY PAUL & VIRGINIA *
  4. 40  REM  *       RAYMER       *
  5. 50  REM  * COPYRIGHT (C) 1988 *
  6. 60  REM  * BY MICROSPARC, INC *
  7. 70  REM  * CONCORD, MA  01742 *
  8. 80  REM  **********************
  9. 90  CLEAR 
  10. 100  TEXT : HOME : PRINT  CHR$(21)
  11. 110 BL$ = "             ": REM  13 SPACES
  12. 120  INVERSE : VTAB 7: HTAB 14: PRINT BL$: HTAB 14: PRINT BL$: HTAB 14: PRINT BL$
  13. 130 A$ = "IMAGINATION"
  14. 140  FOR X = 1 TO 11
  15. 150 R =  INT(20 * RND(1)) +1
  16. 160  IF  CHR$(R +64) < > MID$ (A$,X,1)  THEN  NORMAL : VTAB 8: HTAB 14 +X: PRINT  CHR$(R +64): INVERSE : GOTO 150
  17. 170  VTAB 8: HTAB 14 +X: PRINT  CHR$(R +64)
  18. 180  NEXT X
  19. 190  NORMAL 
  20. 200  PRINT : HTAB 8: PRINT "An interactive story-game": HTAB 12: PRINT "for young people"
  21. 210  VTAB 18: HTAB 7: PRINT "by Virginia and Paul Raymer"
  22. 220  VTAB 20: HTAB 1: PRINT "Copyright (c) 1988 by Microsparc, Inc.": HTAB 12: PRINT "Concord, MA 01742"
  23. 230  VTAB 23: HTAB 10: PRINT "Press Return to start": WAIT 49152,128
  24. 240  POKE 49168,0: HOME 
  25. 250  CLEAR :SL = 1: REM  PRINTER SLOT
  26. 260  REM 
  27. 270  REM "JOSHIE'S IMAGINATION"
  28. 280  REM      A MULTI-STORY
  29. 290  REM  
  30. 300  REM 
  31. 310  REM 
  32. 320  REM 
  33. 330  REM 
  34. 340  REM 
  35. 350  DIM B$(210),J$(28),T$(11):A$ = "a"
  36. 360  FOR X = 0 TO 5: READ L$(X): NEXT 
  37. 370  FOR X = 0 TO 5: READ U$(X): NEXT 
  38. 380  FOR X = 1 TO 210: READ B$(X): NEXT X
  39. 390 P = 39
  40. 400 R =  INT(2 * RND(1)) +1
  41. 410 J$(1) = "Joshie": GOSUB 2370
  42. 420  IF R = 2  THEN J$(1) = "Jennifer": GOSUB 2410
  43. 430  HOME :WW$ = "It seemed that " +J$(1) +" was a little "
  44. 440 WW$ = WW$ +S$ +" who liked to daydream.  But if the"
  45. 450 WW$ = WW$ +" truth were known, it was only that "
  46. 460 WW$ = WW$ +J$(1) +" had a wonderful imagination."
  47. 470 T$(1) = WW$: IF T  THEN WW$ = T$(1):P = 79: PRINT  CHR$(4)"PR#";SL
  48. 480  GOSUB 2450: PRINT 
  49. 490  IF T  THEN 660
  50. 500  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 430
  51. 510  GOSUB 2290
  52. 520  GOSUB 2700
  53. 530  IF AN$ = "G"  OR AN$ = "g"  THEN 620
  54. 540  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 430
  55. 550 A = 1:B = 1: GOSUB 3210
  56. 560 J$(1) = GN$
  57. 570  IF AN$ = "G"  OR AN$ = "g"  THEN P = 39: GOTO 620
  58. 580  VTAB 22: HTAB 1: CALL  -958: PRINT "Is ";J$(1)" a BOY or a GIRL? ";: INPUT "";Q$
  59. 590  IF  LEFT$(Q$,1) = "G"  OR  LEFT$(Q$,1) = "g"  THEN  GOSUB 2410: GOTO 430
  60. 600  IF  LEFT$(Q$,1) = "B"  OR  LEFT$(Q$,1) = "b"  THEN  GOSUB 2370: GOTO 430
  61. 610  GOTO 580
  62. 620  GOSUB 2330:J$(2) = B$(R)
  63. 630  GOSUB 2330:J$(3) = B$(R +10)
  64. 640  GOSUB 2330:J$(4) = B$(R +20)
  65. 650  GOSUB 2330:J$(5) = B$(R +30)
  66. 660 WW$ = "": HOME :WW$ = S1$ +" could close " +S3$ +" eyes and imagine "
  67. 670 V$ = J$(2): GOSUB 2630
  68. 680 WW$ = WW$ +A$ + CHR$(32) +J$(2) + CHR$(32) +J$(3) +" in ":A$ = "a"
  69. 690 V$ = J$(4): GOSUB 2630:WW$ = WW$ +A$ + CHR$(32) +J$(4) +"'s ":A$ = "a"
  70. 700 WW$ = WW$ +J$(5) +".  When " +S2$ +" opened " +S3$ +" eyes,"
  71. 710 WW$ = WW$ +" there it would be!"
  72. 720 T$(2) = WW$: IF T  THEN WW$ = T$(2):P = 79: PRINT  CHR$(4)"PR#";SL
  73. 730  GOSUB 2450: PRINT 
  74. 740  IF T  THEN 830
  75. 750  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 660
  76. 760  GOSUB 2290: GOSUB 2700
  77. 770  IF AN$ = "G"  OR AN$ = "g"  THEN 810
  78. 780  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 660
  79. 790 A = 2:B = 5: GOSUB 3210
  80. 800  GOTO 660
  81. 810  GOSUB 2330:J$(6) = B$(R +40)
  82. 820  GOSUB 2330:J$(7) = B$(R +50)
  83. 830 WW$ = "": HOME :WW$ = S1$ +" could shut " +S3$ +" eyes and imagine "
  84. 840 V$ = J$(6): GOSUB 2630:WW$ = WW$ +A$ + CHR$(32) +J$(6) + CHR$(32) +J$(7) +".  The " +J$(6):A$ = "a"
  85. 850 WW$ = WW$ + CHR$(32) +S2$ +" imagined would be so kind that "
  86. 860 WW$ = WW$ +J$(1) +" would get a magic wish."
  87. 870 T$(3) = WW$: IF T  THEN WW$ = T$(3):P = 79: PRINT  CHR$(4)"PR#";SL
  88. 880  GOSUB 2450: PRINT 
  89. 890  IF T  THEN 980
  90. 900  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 830
  91. 910  GOSUB 2290: GOSUB 2700
  92. 920  IF AN$ = "G"  OR AN$ = "g"  THEN 960
  93. 930  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 830
  94. 940 A = 6:B = 7: GOSUB 3210
  95. 950  GOTO 830
  96. 960  GOSUB 2330:J$(8) = B$(R +60)
  97. 970  GOSUB 2330:J$(9) = B$(R +70)
  98. 980 WW$ = "": HOME :WW$ = J$(1) +" wished for three " +J$(8)
  99. 990 WW$ = WW$ + CHR$(32) +J$(9) +"s.  One " +J$(9) +" was for the "
  100. 1000 WW$ = WW$ +J$(3) +".  One " +J$(9) +" was for the "
  101. 1010 WW$ = WW$ +J$(6) + CHR$(32) +J$(7) +".  The last "
  102. 1020 WW$ = WW$ +J$(9) +" was for " +S4$ +"self."
  103. 1030 T$(4) = WW$: IF T  THEN WW$ = T$(4):P = 79: PRINT  CHR$(4)"PR#";SL
  104. 1040  GOSUB 2450: PRINT 
  105. 1050  IF T  THEN 1180
  106. 1060  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 980
  107. 1070  GOSUB 2290: GOSUB 2700
  108. 1080  IF AN$ = "G"  OR AN$ = "g"  THEN 1120
  109. 1090  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 980
  110. 1100 A = 8:B = 9: GOSUB 3210
  111. 1110  GOTO 980
  112. 1120  GOSUB 2330:J$(10) = B$(R +10): IF J$(10) = J$(3)  THEN 1120
  113. 1130  GOSUB 2330:J$(11) = B$(R +80)
  114. 1140  GOSUB 2330:J$(12) = B$(R): IF J$(12) = J$(2)  THEN 1140
  115. 1150  GOSUB 2330:J$(13) = B$(R +90)
  116. 1160  GOSUB 2330:J$(14) = B$(R +10): IF J$(14) = J$(3)  THEN 1160
  117. 1170  GOSUB 2330:J$(15) = B$(R +100)
  118. 1180 WW$ = "": HOME :WW$ = J$(1) +" could see almost anything "
  119. 1190 WW$ = WW$ +"with " +S3$ +" wonderful imagination. "
  120. 1200  IF J$(13) = B$(91)  OR J$(13) = B$(92)  OR J$(13) = B$(93)  THEN WW$ = WW$ +J$(1) +" could see ":V$ = J$(10): GOSUB 2630:WW$ = WW$ +A$ + CHR$(32) +J$(10) +" on ":A$ = "a":V$ = J$(11): GOSUB 2630:WW$ = WW$ +A$ + CHR$(32):A$ = "a": GOTO 1230
  121. 1210 V$ = J$(10): GOSUB 2630:WW$ = WW$ +J$(1) +" could see " +A$ + CHR$(32) +J$(10) +" in ":A$ = "a"
  122. 1220 V$ = J$(11): GOSUB 2630:WW$ = WW$ +A$ + CHR$(32):A$ = "a"
  123. 1230 WW$ = WW$ +J$(11) + CHR$(32) +J$(12) + CHR$(32) +J$(13) +" or " +J$(14) +"s "
  124. 1240 WW$ = WW$ +J$(15) +"."
  125. 1250 T$(5) = WW$: IF T  THEN WW$ = T$(5):P = 79: PRINT  CHR$(4)"PR#";SL
  126. 1260  GOSUB 2450: PRINT 
  127. 1270  IF T  THEN 1390
  128. 1280  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 1180
  129. 1290  GOSUB 2290: GOSUB 2700
  130. 1300  IF AN$ = "G"  OR AN$ = "g"  THEN 1340
  131. 1310  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 1180
  132. 1320 A = 10:B = 15: GOSUB 3210
  133. 1330  GOTO 1180
  134. 1340  GOSUB 2330:J$(16) = B$(R +110)
  135. 1350  GOSUB 2330:J$(17) = B$(R +80): IF J$(17) = J$(11)  THEN 1350
  136. 1360  GOSUB 2330:J$(18) = B$(R +10): IF J$(18) = J$(3)  THEN 1360
  137. 1370  GOSUB 2330:J$(19) = B$(R): IF J$(19) = J$(12)  OR J$(19) = J$(2)  THEN 1370
  138. 1380  GOSUB 2330:J$(20) = B$(R +120)
  139. 1390 WW$ = "": HOME :WW$ = "One day " +J$(1) +" used " +S3$ +" wonderful"
  140. 1400 V$ = J$(16): GOSUB 2630:WW$ = WW$ +" imagination. " +S1$ +" imagined " +A$ + CHR$(32) +J$(16) + CHR$(32):A$ = "a"
  141. 1410 WW$ = WW$ +J$(17) + CHR$(32) +J$(18) +".  The " +J$(18) +" wore "
  142. 1420 WW$ = WW$ +J$(19) + CHR$(32) +J$(20) +"."
  143. 1430 T$(6) = WW$: IF T  THEN WW$ = T$(6):P = 79: PRINT  CHR$(4)"PR#";SL
  144. 1440  GOSUB 2450: PRINT 
  145. 1450  IF T  THEN 1550
  146. 1460  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 1390
  147. 1470  GOSUB 2290: GOSUB 2700
  148. 1480  IF AN$ = "G"  OR AN$ = "g"  THEN 1520
  149. 1490  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 1390
  150. 1500 A = 16:B = 20: GOSUB 3210
  151. 1510  GOTO 1390
  152. 1520  GOSUB 2330:J$(21) = B$(R +130)
  153. 1530  GOSUB 2330:J$(22) = B$(R +140)
  154. 1540  GOSUB 2330:J$(23) = B$(R +150)
  155. 1550 WW$ = "": HOME :WW$ = "The " +J$(18) +" said, " + CHR$(34) +J$(1) +", if you "
  156. 1560 WW$ = WW$ +"imagine just for fun and do your "
  157. 1570 WW$ = WW$ +"homework and " +J$(21) +", "
  158. 1580 WW$ = WW$ +"it would be just fine to sometimes "
  159. 1590 WW$ = WW$ +"imagine " +J$(22) +" and " +J$(23) +"." + CHR$(34)
  160. 1600 T$(7) = WW$: IF T  THEN WW$ = T$(7):P = 79: PRINT  CHR$(4)"PR#";SL
  161. 1610  GOSUB 2450: PRINT 
  162. 1620  IF T  THEN 1690
  163. 1630  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 1550
  164. 1640  GOSUB 2290: GOSUB 2700
  165. 1650  IF AN$ = "G"  OR AN$ = "g"  THEN 1690
  166. 1660  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 1550
  167. 1670 A = 21:B = 23: GOSUB 3210
  168. 1680  GOTO 1550
  169. 1690 WW$ = "": HOME :WW$ = J$(1) +", looking directly into the "
  170. 1700 WW$ = WW$ +J$(18) +"'s " +J$(19) + CHR$(32) +J$(20) +","
  171. 1710 WW$ = WW$ +" said " + CHR$(34) +"I believe you are correct." + CHR$(34)
  172. 1720 T$(8) = WW$: IF T  THEN WW$ = T$(8):P = 79: PRINT  CHR$(4)"PR#";SL
  173. 1730  GOSUB 2450: PRINT 
  174. 1740  IF T  THEN 1830
  175. 1750  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 1690
  176. 1760  GOSUB 2290: GOSUB 2700
  177. 1770  IF AN$ = "G"  OR AN$ = "g"  THEN 1810
  178. 1780  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 1690
  179. 1790 A = 18:B = 20: GOSUB 3210
  180. 1800  GOTO 1690
  181. 1810  GOSUB 2330:J$(24) = B$(R +160)
  182. 1820  GOSUB 2330:J$(25) = B$(R +170)
  183. 1830 WW$ = "": HOME :WW$ = "The " +J$(6) +", who was listening on "
  184. 1840 WW$ = WW$ +"the " +J$(24) +" in the other room, "
  185. 1850 WW$ = WW$ +J$(25) +", " + CHR$(34) +"Good for you, " +J$(1) +"!" + CHR$(34)
  186. 1860 T$(9) = WW$: IF T  THEN WW$ = T$(9):P = 79: PRINT  CHR$(4)"PR#";SL
  187. 1870  GOSUB 2450: PRINT 
  188. 1880  IF T  THEN 1960
  189. 1890  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 1830
  190. 1900  GOSUB 2290: GOSUB 2700
  191. 1910  IF AN$ = "G"  OR AN$ = "g"  THEN 1950
  192. 1920  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 1830
  193. 1930 A = 24:B = 25: GOSUB 3210
  194. 1940  GOTO 1830
  195. 1950  GOSUB 2330:J$(26) = B$(R +180)
  196. 1960 WW$ = "": HOME :WW$ = "When " +J$(1) +" checked with " +S3$ +" mom "
  197. 1970 WW$ = WW$ +"and dad they both agreed and said, "
  198. 1980 WW$ = WW$ + CHR$(34) +"Not only does our " +J$(1) +" have a "
  199. 1990 WW$ = WW$ +"wonderful imagination, but " +S2$ +" is "
  200. 2000 WW$ = WW$ +J$(26) +" as well.  We are very proud "
  201. 2010 WW$ = WW$ +"of our " +J$(1) +"." + CHR$(34)
  202. 2020 T$(10) = WW$: IF T  THEN WW$ = T$(10):P = 79: PRINT  CHR$(4)"PR#";SL
  203. 2030  GOSUB 2450: PRINT 
  204. 2040  IF T  THEN 2130
  205. 2050  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 1960
  206. 2060  GOSUB 2290: GOSUB 2700
  207. 2070  IF AN$ = "G"  OR AN$ = "g"  THEN 2110
  208. 2080  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 1960
  209. 2090 A = 26:B = 26: GOSUB 3210
  210. 2100  GOTO 1960
  211. 2110  GOSUB 2330:J$(27) = B$(R +190)
  212. 2120  GOSUB 2330:J$(28) = B$(R +200)
  213. 2130 WW$ = "": HOME :WW$ = J$(1) +" finished " +S3$ +" homework and, "
  214. 2140 WW$ = WW$ +"using " +S3$ +" imagination, called for " +S3$
  215. 2150 WW$ = WW$ +" friend the " +J$(6) +" to take " +S4$
  216. 2160 WW$ = WW$ + CHR$(32) +J$(27) + CHR$(32) +J$(28) +"!"
  217. 2170 T$(11) = WW$: IF T  THEN WW$ = T$(11):P = 79: PRINT  CHR$(4)"PR#";SL
  218. 2180  GOSUB 2450: PRINT 
  219. 2190  IF T  THEN  PRINT : PRINT  CHR$(4)"PR#0": PRINT : GOTO 2690
  220. 2200  IF P >40  THEN  PRINT  CHR$(4)"PR#0":P = 39: GOTO 2130
  221. 2210  GOSUB 2290: GOSUB 2700
  222. 2220  IF AN$ = "G"  OR AN$ = "g"  THEN 2690
  223. 2230  IF AN$ = "P"  OR AN$ = "p"  THEN  PRINT : PRINT  CHR$(4)"PR#";SL:P = 79: GOTO 2130
  224. 2240 A = 27:B = 28: GOSUB 3210
  225. 2250  GOTO 2130
  226. 2260  REM 
  227. 2270  REM  DRAW BAR
  228. 2280  REM 
  229. 2290  PRINT "======================================": RETURN : REM 38 EQUAL SIGNS
  230. 2300  REM 
  231. 2310  REM  RANDOMIZER
  232. 2320  REM 
  233. 2330 R =  INT(10 * RND(1)) +1: RETURN 
  234. 2340  REM 
  235. 2350  REM  BOY
  236. 2360  REM 
  237. 2370 S$ = "boy":S1$ = "He":S2$ = "he":S3$ = "his":S4$ = "him": RETURN 
  238. 2380  REM  
  239. 2390  REM  GIRL
  240. 2400  REM 
  241. 2410 S$ = "girl":S1$ = "She":S2$ = "she":S3$ = "her":S4$ = "her": RETURN 
  242. 2420  REM 
  243. 2430  REM  WORD WRAPPER
  244. 2440  REM 
  245. 2450 PP = P
  246. 2460  IF  LEN(WW$) <P  THEN  PRINT : PRINT WW$: GOTO 2590
  247. 2470  FOR W = 1 TO  LEN(WW$)
  248. 2480  IF  MID$ (WW$,P,1) < > CHR$(32)  THEN P = P -1: GOTO 2480
  249. 2490  NEXT W
  250. 2500 WL$ =  LEFT$(WW$,P)
  251. 2510 N$ =  RIGHT$(WW$, LEN(WW$) -P)
  252. 2520  REM 
  253. 2530  REM  PROPER SPACING
  254. 2540  REM  END OF SENTENCE
  255. 2550  REM 
  256. 2560  IF  LEFT$(WL$,1) =  CHR$(32)  THEN WL$ =  RIGHT$(WL$, LEN(WL$) -1): GOTO 2560
  257. 2570  PRINT : PRINT WL$:P = PP
  258. 2580 WW$ = N$: GOTO 2450
  259. 2590  RETURN 
  260. 2600  REM 
  261. 2610  REM  VOWEL TRAP
  262. 2620  REM 
  263. 2630 W$ =  LEFT$(V$,1)
  264. 2640  IF W$ = "A"  OR W$ = "E"  OR W$ = "I"  OR W$ = "O"  OR W$ = "U"  OR W$ = "a"  OR W$ = "e"  OR W$ = "i"  OR W$ = "o"  OR W$ = "u"  THEN A$ = "an"
  265. 2650  RETURN 
  266. 2660  REM 
  267. 2670  REM  PAUL'S GAME MENU
  268. 2680  REM  
  269. 2690  PRINT  CHR$(7) CHR$(7) CHR$(7): VTAB 14: HTAB 16: INVERSE : PRINT " THE END ": NORMAL :K = 3:L$(1) = "See word list":L$(2) = "=============":U$(1) = "SEE WORD LIST":U$(2) = L$(2):L$(5) = "Print complete story":U$(5) = "PRINT COMPLETE STORY":FLAG = 1: GOTO 2710
  270. 2700 K = 1
  271. 2710  FOR X = 1 TO 5: VTAB X +15: HTAB 1: CALL  -868: PRINT X;".  ";L$(X)
  272. 2720  IF X >5  THEN  VTAB X +15: HTAB 20: PRINT LT$(X)
  273. 2730  NEXT X: POKE  -16368,0
  274. 2740  VTAB 22: HTAB 1: PRINT L$(0)
  275. 2750  INVERSE : VTAB K +15: HTAB 4: PRINT "<";U$(K);">": NORMAL 
  276. 2760  VTAB 15 +K: HTAB 1: GET AN$
  277. 2770  IF AN$ =  CHR$(27)  THEN  GOTO 2700
  278. 2780  IF  VAL(AN$) >5  THEN  PRINT  CHR$(7);: GOTO 2760
  279. 2790  VTAB K +15: HTAB 4: PRINT  CHR$(32);L$(K); CHR$(32)
  280. 2800  IF  VAL(AN$)  THEN K =  VAL(AN$)
  281. 2810  IF AN$ =  CHR$(8)  OR AN$ =  CHR$(11)  THEN K = K -1: IF K <1  THEN K = 5
  282. 2820  IF AN$ =  CHR$(21)  OR AN$ =  CHR$(10)  THEN K = K +1: IF K >5  THEN K = 1
  283. 2830  IF AN$ =  CHR$(13)  THEN  PRINT : GOTO 2860
  284. 2840  GOTO 2750
  285. 2850  FOR X = 1 TO 5:LT$(X) = UT$(X): NEXT X: RETURN 
  286. 2860  IF FLAG  THEN  ON K GOTO 3030,2930,2940,3150,2980
  287. 2870  ON K GOTO 2910,2920,2940,3150,3190
  288. 2880  DATA "Arrow or number selects                 Press <RETURN> to RUN selection"
  289. 2890  DATA  "Go ahead","Change words","Start over","Stop game","Print this page only"
  290. 2900  DATA X,GO AHEAD,CHANGE WORDS,START OVER,STOP GAME,PRINT THIS PAGE ONLY
  291. 2910 AN$ = "G":P = 39: RETURN 
  292. 2920 AN$ = "C":P = 39: RETURN 
  293. 2930  PRINT  CHR$(7):K = 3: GOTO 2710
  294. 2940  GOTO 250
  295. 2950  REM 
  296. 2960  REM  FULL STORY PRINT
  297. 2970  REM 
  298. 2980 T = 1
  299. 2990  GOTO 430
  300. 3000  REM 
  301. 3010  REM  WORD LIST PRINTER
  302. 3020  REM 
  303. 3030  HOME : FOR X = 1 TO 210: PRINT X" "B$(X)
  304. 3040  IF  INT(X/20) = X/20  THEN  GOSUB 3120
  305. 3050  NEXT X
  306. 3060  PRINT : PRINT "========== END OF WORD LIST ==========": REM 10 EQUAL SIGNS EACH END
  307. 3070  GOSUB 3120
  308. 3080  PRINT  CHR$(7) CHR$(7): GOTO 2930
  309. 3090  REM 
  310. 3100  REM  NEXT SCREEN ADVANCE
  311. 3110  REM 
  312. 3120  VTAB 23: HTAB 1: PRINT "<SPACE> to go on      <RETURN> to stop ";: GET AN$
  313. 3130  IF AN$ =  CHR$(13)  THEN  HOME : GOTO 2930
  314. 3140  HOME : RETURN 
  315. 3150  HOME : END 
  316. 3160  REM 
  317. 3170  REM  PRINT ROUTINE
  318. 3180  REM 
  319. 3190 AN$ = "P": RETURN 
  320. 3200  REM 
  321. 3210  REM  WORD CHOOSER
  322. 3220  REM 
  323. 3230  FOR C = A TO B
  324. 3240  GOSUB 3340
  325. 3250  VTAB 15: HTAB 1: CALL  -958: PRINT "Press <RETURN> if ": PRINT : PRINT Q$" is OK ... or": FOR W = 1 TO  LEN(Q$): PRINT "=";: NEXT W
  326. 3260  VTAB 22: HTAB 1: CALL  -958: PRINT "Change "; CHR$(34)J$(C) CHR$(34);" to: ";: GOSUB 3640
  327. 3270  IF GN$ = ""  THEN GN$ = J$(C)
  328. 3280 J$(C) = GN$
  329. 3290  NEXT C
  330. 3300  RETURN 
  331. 3310  REM 
  332. 3320  REM  CAPITAL MAKER
  333. 3330  REM 
  334. 3340 Q$ = ""
  335. 3350  FOR Q = 1 TO  LEN(J$(C))
  336. 3360 J =  ASC( MID$ (J$(C),Q,1)): IF J >90  THEN J = J -32
  337. 3370 Q$ = Q$ + CHR$(J)
  338. 3380  NEXT Q
  339. 3390  RETURN 
  340. 3400  REM 
  341. 3410  REM  WORD LIST
  342. 3420  REM 
  343. 3430  DATA  red,orange,yellow,green,blue,brown,purple,white,black,pink
  344. 3440  DATA  dog,cat,elephant,hippo,tiger,giraffe,alligator,kangaroo,panda,bear
  345. 3450  DATA  fireman,policeman,plumber,pilot,carpenter,explorer,doctor,race driver,teacher,sailor
  346. 3460  DATA  jacket,coat,suit,sweater,shirt,T-shirt,pajamas,shorts,jeans,uniform
  347. 3470  DATA  giant,magician,elf,fairy,wizard,warlock,mystic,conjurer,genie,jin
  348. 3480  DATA  in a bathtub,on a chair,on the roof,under a house,in a doghouse,in the playbox,in the garage,on a tent,in a box,in a bottle
  349. 3490  DATA  big,little,tiny,small,sweet,sour,tall,short,fat,thin
  350. 3500  DATA  plum,sweet,cookie,ice cream,fruit,toy,soldier,doll,book,tape
  351. 3510  DATA  long,short,big,little,skinny,fat,high,low,thin,stocky
  352. 3520  DATA  bike,scooter,skateboard,car,boat,bus,plane,train,submarine,camper
  353. 3530  DATA  crying in a tree,sleeping in a bed,jumping on the roof,singing in the bathtub,dancing in the kitchen,climbing up a pole,walking on a fence,reading a book,painting a picture,watching the TV
  354. 3540  DATA  odd,awful,silly,weird,strange,dumb,crazy,dippy,spooky,curious
  355. 3550  DATA  shoes,earrings,stockings,skis,boots,underwear,sunglasses,swim fins,tennis shoes,suspenders
  356. 3560  DATA  household chores,help with the dishes,clean up the table,make your bed,pick up your clothes,put your toys away,take out the trash,feed the goldfish,help do the lawn,help put tools away
  357. 3570  DATA  gorillas,dragons,dinosaurs,rocket ships,elevators,golf balls,eagle eggs,tadpoles,blackboards,TV sets
  358. 3580  DATA  pencil boxes,candy bars,erasers,magazines,newspapers,books,bubble gum,Disneyland,pizza,grasshoppers
  359. 3590  DATA  telephone,tin can,radio,tape player,wall,wire,clothespin,tomato,pickle,radar set
  360. 3600  DATA  shouted,yelled,called,said,stated,mumbled,cried,whooped,howled,roared
  361. 3610  DATA  clever,nice,able,smart,good,brilliant,witty,neat,kind,courteous
  362. 3620  DATA  to the moon,to Disneyland,to get a pizza,to school,to visit Grandpa,to the ballgame,to the desert,to the lake,to the movies,to visit Grandma
  363. 3630  DATA  in a rocket ship,in a new car,on a motorcyle,in a boat,up an elevator,across the street,down by the river,at the circus,with a friend,on a dinosaur
  364. 3640 LL = 0:GN$ = "": POKE  -16368,0
  365. 3650  GET AA$
  366. 3660  IF AA$ =  CHR$(13)  THEN  RETURN 
  367. 3670  IF LL >24  AND AA$ < > CHR$(8)  THEN  PRINT  CHR$(7);: GOTO 3650
  368. 3680  IF AA$ > = " "  AND AA$ < =  CHR$(126)  THEN  PRINT AA$;:GN$ = GN$ +AA$:LL = LL +1: GOTO 3650
  369. 3690  IF AA$ =  CHR$(8)  AND LL >1  THEN LL = LL -1:GN$ =  LEFT$(GN$,LL): CALL  -1008: PRINT " ";: CALL  -1008: GOTO 3650
  370. 3700  IF AA$ =  CHR$(8)  AND LL = 1  THEN  CALL  -1008: PRINT " ";: CALL  -1008: GOTO 3640
  371. 3710  PRINT  CHR$(7);: GOTO 3650