home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / 93xx / 9311a.d64 / stackfill.lst < prev    next >
File List  |  1995-03-30  |  3KB  |  53 lines
  1.  
  2.  
  3. READY.
  4. 5    -           .BASE $0C00
  5. 10   -;------------------------------------------------------------------------
  6. 15   -;ERSTES BEISPIELSPROGRAMM
  7. 20   -;DIESES PROGRAMM FUELLT MITTELS STACKVERSCHIEBUNG DURCH DIE MMU INNERHALB
  8. 25   -;VON 1864 TAKTZYKLEN EINE SPEICHERSEITE, DIE SICH BEI AUFRUF IM YREG BE-
  9. 30   -;Y :PAGENUMMER, X:FUELLBYTE, A:BANKNUMMER (0.BIT RELEVANT)
  10. 35   -;------------------------------------------------------------------------
  11. 40   -;(P) MARK HILLEBRAND* GREETS TO JAN;KAI UND ARMIN HERBERTZ;BROMMUNDT'S
  12. 45   -;------------------------------------------------------------------------
  13. 50   -;------------------------ VARIABLENDEFINITION ---------------------------
  14. 55   -.DEFINE MMUCOPY      = $FF00;ADRESSE DER MMU-KOPIE, DIE IMMER SICHTBAR IST
  15. 60   -.DEFINE MMU          = $D500;MMU-BASISADRESSE, IM I/O-BEREICH
  16. 65   -;------------------------------------------------------------------------
  17. 70   -;--------------------------- HAUPTPROGRAMM ------------------------------
  18. 75   -           SEI            ;VERBIETEN, DA WEGEN MANIPULATION SONST ABSTURZ
  19. 80   -           STX FUELLBYTE+1;MODIFIZIEREN
  20. 85   -           TAX            ;BANKNUMMER RETTEN
  21. 90   -           LDA MMUCOPY    ;KONFIGURATION RETTEN
  22. 95   -           PHA 
  23. 100  -           LDA #$00       ;I/O-BAUSTEINE EINSCHALTEN
  24. 105  -           STA MMUCOPY
  25. 110  -           STA MMU+6      ;COMMON AREA AUSSCHALTEN
  26. 115  -           TXA            ;BANKNUMMER WIEDER HOLEN
  27. 120  -           AND #%00000001 ;RELEVANTEN BITS MASKIEREN
  28. 125  -           STA MMU+10     ;STACK-BANK EINSTELLEN
  29. 130  -           STY MMU+9      ;STACK AUF GEWUENSCHTE SEITE EINSTELLEN
  30. 135  -           TSX            ;STAPELZEIGER HOLEN
  31. 140  -           TXA            ;STAPELZEIGER IM Y-REGISTER SPEICHERN
  32. 145  -           TAY 
  33. 150  -           LDX #$FF       ;NEUEN STAPELZEIGER AUF MAXIMUM
  34. 155  -           TXS 
  35. 160  -FUELLBYTE  LDA #$00       ;FUELLBYTE LADEN (WIRD MODIFIZIERT)
  36. 165  -SCHLEIFE   PHA            ;FUELLEN
  37. 170  -           DEX 
  38. 175  -           BNE SCHLEIFE
  39. 180  -           PHA            ;DAS 256STE MAL
  40. 185  -           STX MMU+10     ;STACK-BANK 0 EINSTELLEN
  41. 190  -           INX            ;DANN ENTHAELT X-REGISTER 1
  42. 195  -           STX MMU+9      ;ALTEN STACK WIEDER EINSTELLEN
  43. 200  -           TYA            ;ALTEN STAPELZEIGER WIEDERHERSTELLEN
  44. 205  -           TAX 
  45. 210  -           TXS 
  46. 215  -           LDA #%00000100 ;ALTE COMMON AREA WIEDERHERSTELLEN
  47. 220  -           STA MMU+6
  48. 225  -           PLA            ;ALTE KONFIGURATION WIEDERHERSTELLEN
  49. 230  -           STA MMUCOPY
  50. 235  -           CLI            ;INTERRUPTS WIEDERZULASSEN
  51. 240  -           RTS            ;UND AB ...
  52. 245  -;------------------------------------------------------------------------
  53.