home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / sh3x / sh34c.d64 / bruchrechnen (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  7KB  |  188 lines
  1. 10 FORX=0TO29:READ Y:POKE49152+X,Y:NEXTX
  2. 15 REM MASCHINENPROGRAMM FUER SYSPR
  3. 20 PRINT"[147]":PR=49152:X=0:GOTO130
  4. 25 REM BLDSCHRM LOESCHEN, BESTIMMUNG VONPR, SPRUNG UEBER UNTERROUTINEN
  5. 30 SYSPR,ZE,SP,"FALSCH":FA=FA+1:FORI=1TO500:NEXTI
  6. 35 REM UNTERPROGRAMM FALSCHEINGABE
  7. 40 SYSPR,ZE,SP,"       ":RETURN
  8. 50 FORI=1TOL:SYSPR,9,1,CHR$(148):FORX=1TO10:NEXTX
  9. 55 REM UNTERPROGRAMM FUER VERSCHIEBUNG NACH RECHTS
  10. 60 SYSPR,10,1,CHR$(148):FORX=1TO10:NEXTX
  11. 70 SYSPR,11,1,CHR$(148):FORX=1TO8:NEXTX:NEXTI
  12. 80 RETURN
  13. 90 FORI=1TOL:SYSPR,09,1,CHR$(20):FORX=1TO10:NEXTX
  14. 95 REM UNTERPROGRAMM FUER VERSCHIEBUNG NACH LINKS
  15. 100 SYSPR,10,1,CHR$(20):FORX=1TO10:NEXTX
  16. 110 SYSPR,11,1,CHR$(20):FORX=1TO8:NEXTX:NEXTI:POKE1424,32
  17. 120 RETURN
  18. 130 FORI=1TO20:FORX=1TO100:NEXTX:SYSPR,10,10,"BRUCHRECHNEN"
  19. 135 REM ANFANGSBLDS.VIELLEICHT NICHT NOETIG JEDOCH KONZENTRATIONSVORBEREITUNG
  20. 140 SYSPR,12,10,"FUER CAROLIN"
  21. 150 SYSPR,14,9,"VON IHREM PAPA"
  22. 160 FORX=1TO100:NEXTX
  23. 165 REM HIER KANN DER FANTASIE FREIEN LAUF GELASSEN WERDEN
  24. 170 SYSPR,12,10,"             ":NEXTI
  25. 180 FOR AZ=1TO10:TI$="000000":R$=CHR$(43):IFAZ>5THENR$=CHR$(45)
  26. 182 REM UHR AUF NULL STELLEN
  27. 185 REM AZ=ANZAHL DER DURCHGAENGE, R$ FUER + ODER - NACH 5 DURCHLAEUFEN
  28. 190 A=INT(RND(0)*10):IFA=1ORA=0THEN190
  29. 195 REM BESTIMMUNG DES ERSTEN NENNERS, UNINTERESSANT WENN 1 ODER NULL
  30. 200 FORI=1TO A:NEXTI:B=INT(RND(0)*10):IFB=0ORB=1THEN200
  31. 205 REM BESTIMMUNG DES 2. NENNERS
  32. 210 FORI=1TOA:C=INT(RND(0)*10):IFC=0THEN210
  33. 215 REM BESTIMMUNG DES ERSTEN ZAEHLERS, KANN AUCH EINS SEIN
  34. 220 FORI=1TOA:D=INT(RND(0)*10):IFD=0THEN220
  35. 225 REM BESTIMMUNG DES 2. ZAEHLERS
  36. 230 IFA=CTHEN190
  37. 235 REM WENN NENNER GLEICH ZAEHLER UNINTERESSANT
  38. 240 IFB=DTHEN190
  39. 245 REM DAS GLEICHE
  40. 250 IFA=BTHEN190
  41. 255 REM WENN BEIDE NENNER GLEICH UNINTERESSANT
  42. 260 IFAZ>5AND(C/A)<(D/B)THEN190
  43. 265 REM NUR BEI - ERGEBNIS WIRD KUERZEN SCHWIERIG, WER KANN DAS LOESEN?
  44. 266 REM IN DEN ZEILEN AB 860 KOENNTE ENTSPRECHENDE ROUTINE EINGEBAUT WERDEN
  45. 270 PRINT"[147]":SYSPR,3,12,"BRUCHRECHNEN[154]"
  46. 275 REM ARBEITSBILDSCHIRM
  47. 280 SYSPR,10,3,"[192][192][192][192][192] ";R$;" [192][192][192][192][192]  ="
  48. 285 REM AUSGABE DER BRUCHSTRICHE UND DES RECHENZEICHEN
  49. 290 SYSPR,10,21,"[192][192][192][192][192] ";R$;" [192][192][192][192][192]"
  50. 295 REM AUSGABE DES ARBEISBRUCHSTRICHES
  51. 300 SYSPR,9,4,C
  52. 305 REM AUSGABE DER ZAHLEN
  53. 310 SYSPR,9,12,D
  54. 320 SYSPR,11,4,A
  55. 330 SYSPR,11,12,B
  56. 340 F=0:Y=0
  57. 345 REM ZURUECKSTELLEN DER VARIABLEN
  58. 350 F=F+B:Y=Y+1:X=F/A:Z=INT(X+0.5):IFX=ZTHEN370
  59. 355 REM BESTIMMUNG DES HAUPTNENNERS, AUF DIESEM WEG WIRD DER NIEDRIGSTE GENOMMEN
  60. 360 GOTO 350
  61. 365 REM FALLS BEDINGUNG X=0 NOCHMALIGER DURCHLAUF
  62. 370 N=0
  63. 380 POKE214,11:POKE211,21:SYS58640:INPUTN
  64. 385 REM ABFRAGE DES HAUPTNENNERS
  65. 390 IFN<>FTHENZE=11:SP=20:GOSUB 30:GOTO380
  66. 395 REM FALLS UNRICHTIGE ANTWORT
  67. 400 SYSPR,11,20,"     ":SYSPR,11,22,F:SYSPR,11,30,F
  68. 405 REM WENN RICHTIG AUSGABE DES HAUPTNENNERS
  69. 410 POKE214,9:POKE211,21:SYS58640:INPUTN
  70. 415 REM ABFRAGE DES 1. ZAEHLERS
  71. 420 IFN<>F/A*CTHEN ZE=9:SP=20:GOSUB 30:GOTO 410
  72. 425 REM UEBERPRUEFUNG UND FALS FALSCH
  73. 440 SYSPR,9,20,"     ":SYSPR,9,22,N
  74. 445 REM ANTWORT RICHTIG UND AUSGABE
  75. 450 POKE214,9:POKE211,29:SYS58640:INPUTN
  76. 455 REM ABFRAGE DES 2. ZAEHLERS
  77. 460 IFN<>Y*DTHEN ZE=9:SP=29:GOSUB 30:GOTO 450
  78. 465 REM UEBERPRUEFUNG DES 2. ZAEHLERS UND FALS FALSCH FEHLERMELDUNG
  79. 470 SYSPR,9,27,"        ":SYSPR,9,30,N
  80. 475 REM ANTWORT RICHTIG UND AUSGABE
  81. 480 L=18:GOSUB90:L=0
  82. 485 REM RECHNUNG NACH LINKS WEGSCROLLEN
  83. 490 SYSPR,10,17,"= [192][192][192][192][192][192]":SYSPR,11,19,F
  84. 495 REM AUSGABE DES NAECHSTEN ARBEITSBRUCHSTRICHES UND HAUPTNENNERS
  85. 500 POKE214,9:POKE211,18:SYS58640:INPUTN
  86. 505 REM EINGABE DES GEMEINSAMEN ZAEHLERS
  87. 510 IFR$=CHR$(43)THEN GOTO 950
  88. 515 REM SPRUNG IN UNTERROUTINE +
  89. 520 IFN=F/A*C-Y*DTHEN540
  90. 525 REM WENN RICHTIG DANN WEITER
  91. 530 ZE=9:SP=17:GOSUB30:GOTO500
  92. 535 REM WENN FALSCH
  93. 540 SYSPR,9,18,"        ":SYSPR,9,19,N
  94. 550 L=18:GOSUB90:L=8:GOSUB50:L=0
  95. 555 REM VERSCHIEBEN
  96. 560 Z=N:G=N:E=F
  97. 570 R=G-INT(G/E)*E:G=E:E=R:IFR>0THEN570
  98. 575 REM KANN MAN KUERZEN? WENN NICHT UEBER KUERZROUTINE SPRINGEN
  99. 580 ZA=Z/G:NE=F/G
  100. 585 REM BESTIMMUNG VON ZAEHLER UND NENNER
  101. 590 POKE214,14:POKE211,5:SYS58640:INPUT"KANN MAN KUERZEN (J/N)";F$
  102. 600 IFF$=CHR$(74)ORF$=CHR$(78)THEN620
  103. 605 REM FALLS EINE ANDERE ANTWORT MIT FOLGENDER ZEILE RICHTIGE ANTWORT ERZWINGEN
  104. 610 GOTO 590
  105. 620 IF F$=CHR$(74)ANDG>1THEN680
  106. 630 IF F$=CHR$(74)ANDG=1THEN660
  107. 640 IF F$=CHR$(78)ANDG>1THEN660
  108. 650 IF F$=CHR$(78)ANDG=1THEN FORI=1TO300:NEXTI:GOTO810
  109. 655 REM ENTSPRECHEND DER ANTWORT UND RICHTIGKEIT VERZWEIGEN
  110. 660 SYSPR,14,5,"DU HAST DICH GEIRRT!       ":FORI=1TO600:NEXTI:FA=FA+1
  111. 670 SYSPR,14,5,"                    ":GOTO 590
  112. 675 REM UNRICHTIGE ANTWORT
  113. 680 SYSPR,14,5,"                           "
  114. 685 REM RICHTIGE ANTWORT, LOESCHEN DER FRAGE
  115. 690 POKE214,14:POKE211,5:SYS58640:INPUT"MIT WELCHEM WERT";W
  116. 695 REM ABFRAGE WELCHER WERT GENOMMEN WERDEN KANN
  117. 700 IF W=G THEN730
  118. 705 REM RICHTIGE ANTWORT
  119. 710 SYSPR,14,5,"ES GIBT EINEN BESSEREN!":FORI=1TO500:NEXTI:FA=FA+1
  120. 715 REM FALSCHE ANTWORT
  121. 720 SYSPR,14,5,"                          ":GOTO 680
  122. 725 REM LOESCHEN UND NEUABFRAGE
  123. 730 SYSPR,10,14," = [192][192][192][192][192]"
  124. 735 REM AUSGABE DES NAECHSTEN BRUCHSTRICHES
  125. 740 SYSPR,14,5,"                    "
  126. 745 REM LOESCHEN DER FRAGE
  127. 750 POKE214,9:POKE211,17:SYS58640:INPUTN:IFN=ZATHEN 770
  128. 755 REM ABFRAGE DES ZAELERS. WENN RICHTIG SPRUNG
  129. 760 SYSPR,9,16,"FALSCH":FORI=1TO200:NEXTI:SYSPR,9,16,"      ":GOTO750
  130. 765 REM ANTWORT FALSCH
  131. 770 SYSPR,9,16,"      ":SYSPR,9,18,N
  132. 780 POKE214,11:POKE211,17:SYS58640:INPUTN:IFN=NE THEN800
  133. 785 REM ABFRAGE DES NENNERS. WENN RICHTIG SPRUNG
  134. 790 ZE=11:SP=16:GOSUB 30:GOTO780
  135. 795 REM ANTWORT FALSCH
  136. 800 SYSPR,11,16,"    ":SYSPR,11,18,N
  137. 805 REM AUSGABE DES RICHTIGEN NENNERS
  138. 810 G=INT(ZA/NE):IFG>0THENN=ZA-G*NE
  139. 815 REM BESTIMMUNG DER GANZZAHL
  140. 820 SYSPR,16,10,"PRIMA GEMACHT":FORI=1TO500:NEXTI
  141. 825 REM ZWISCHENBELOBIGUNG
  142. 830 IFG=0THEN GOTO 930
  143. 835 REM WENN GANZZAHL NULL WEITERARBEIT UNINTERESSANT
  144. 840 SYSPR,10,23,"=     [192][192][192][192]":X=N:Y=NE
  145. 845 REM AUSGABE DES NAECHSTEN BRUCHSTRICHES
  146. 850 POKE214,10:POKE211,24:SYS58640:INPUTN$:X$=LEFT$(N$,2):A=VAL(X$)
  147. 855 REM DA DIE EINGABE DES BRUCHSTRICHES WG NICHT NUMMERISCH ERFOLGEN KANN MUSS
  148. 856 REM DIE EINGABE UMGEWANDELT WERDEN VON STRING IN NUMMERISCH
  149. 860 IFA=G THEN880
  150. 865 REM WERT STIMMMT UND SPRUNG
  151. 870 ZE=10:SP=24:GOSUB30:GOTO840
  152. 875 REM FALSCHE ANTWORT
  153. 880 POKE1448,32:SYSPR,11,28,Y
  154. 885 REM DAS FRAGEZEICHEN WEG UND AUSGABE DES NENNERS
  155. 890 N=0: POKE211,28:POKE214, 9:SYS58640:INPUTN
  156. 895 REM ABFRAGE DES ZAEHLERS
  157. 900 IFN=XTHEN930
  158. 905 REM WENN RICHTIG SPRUNG
  159. 910 ZE=9:SP=27:GOSUB30:GOTO890
  160. 915 REM FALSCHEINGABE
  161. 920 :
  162. 930 GOSUB980:NEXTAZ:SYSPR,14,10," E N D E [146]":WAIT198,1
  163. 935 REM WENN DER ZEHNTE DURCHLAUF NICHT ERREICHT IST WIEDER AN DEN ANFANG
  164. 936 REM VORHER NOCH AUSGABE DER FEHLER UND VERBRAUCHTEN ZEIT
  165. 940 GOTO 1020
  166. 950 IFN=Y*D+F/A*CTHEN970
  167. 955 REM UNTERPROGRAMM FUER PLUSRECHNUNG
  168. 960 ZE=9:SP=18:GOSUB30:GOTO500
  169. 970 GOTO540
  170. 975 REM RUECKSPRUNG DA VON HIERAN EGAL OB PLUS ODER MINUSRECHNUG
  171. 980 FORI=1TO500:NEXTI:PRINT"[147]":SYSPR,10,2,"DU HAST ";FA;"[146] FEHLER GEMACHT"
  172. 985 REM AUSGABE DER FEHLER UND VERBRAUCHTEN ZEIT
  173. 990 MI$=MID$(TI$,3,2):SE$=MID$(TI$,5,2)
  174. 995 REM DA NUR SEC UND MIN INTERESSANT AUCH NUR DIESE AUSGABE
  175. 1000 SYSPR,12,2,"UND ";MI$;"[146] MIN, ";SE$;"[146] SEK. GEBRAUCHT!":FA=0
  176. 1010 WAIT198,1:FORI=0TO9:POKE631+I,0:NEXTI:RETURN
  177. 1015 REM AUF TASTENDRUCK WARTEN UND DIE EINGABE IM TASTATURPUFFER LOESCHEN
  178. 1020 FORI=1TO1000:NEXTI:PRINT"[147]":SYSPR,10, 6,"WILLST DU NOCHMAL? (J/N)";
  179. 1030 INPUTN$:IFN$=CHR$(74)THENAZ=0:FA=0:GOTO 20
  180. 1035 REM WENN NOCHMAL NATUERLICH DIE FEHLER LOESCHEN UND AN DEN ANFANG OHNE
  181. 1036 REM DAS MASCHINENPROGRAMM NEU ZU SCHREIBEN
  182. 1040 DATA32,253,174,32,158,183,138,72,32
  183. 1045 REM DAS MASCHINENPROGRAMM IN DATAS
  184. 1050 END
  185. 1060 DATA 253,174,32,158,183,138,168,104,170
  186. 1070 DATA 24,32,240,255,32,253,174,76,160
  187. 1080 DATA 170,0,0
  188.