Amiga Magazin: Amiga-CD 2000 April & May/AMIGA_2000_04.iso/amiga-magazin/visualengineer/ve-full.lha/arexx/VisualLogoDemo.rexx

OS/2 REXX Batch file | 1999-06-06 | 5KB | 311 lines

/*

   v1.20 Visual Logo Demo

   Marko Seppänen
   [e-mail]

*/


address IMAGEENGINEER

Options results
signal on error            /* Setup a place for errors to go */

if arg()=0 then exit
x=arg(1)

parse var x logo visual arguments
arguments=strip(arguments,B)
space=0

MARK logo PRIMARY
PROJECT_INFO logo WIDTH
picwidth=result
PROJECT_INFO logo HEIGHT
picheight=result




/*
    . THE BEGINNING .
                        */




if visual="" then

do
  if exists("ie:prefs/visuallogod.cfg") == "1" then
    do
      call open("temp","ie:prefs/visuallogod.cfg","R")
      values=readln("temp")
      parse var values ok visual space
      call close("temp")
    end
  else
    do
      visual=3
      space=0
    end


  'FORM "Visual Logo" "Use|Cancel"',
  'CYCLE,"Type","Shiny|Outline|Strong|Raised|Niched|Gradient|Glow|Polka|Color|Lines",'visual'',
  'INTEGER,"Space around",0,100,'space',SLIDER'

  values=result
  parse var values ok visual space
  savedir=strip(savedir,B,'"')

  if ok = 0 then exit

  call open("temp","ie:prefs/visuallogod.cfg","W")
  res=writeln("temp",values)
  call close("temp")

end



/*    . ADD SPACE .     */


if space>0 then do

  if exists("ie:arexx/addspace.rexx") == "0" then do
    'REQUEST "AddSpace.rexx is missing!" "I will get it... sorry"'
    exit
  end
  address command "Sys:Rexxc/rx ie:arexx/AddSpace.rexx" logo GUESS space

  PROJECT_LIST
  xyz=result
  x0=subword(xyz,1,1)

end
else x0=logo



/* ..NOW WE ARE GETTIN' INTO IT.. */



select


  when visual == 2 | upper(visual)=="STRONG" then do

    if arguments="" then do

      if exists("ie:prefs/visuallogodstrong.cfg") == "1" then
        do
          call open("temp","ie:prefs/visuallogodstrong.cfg","R")
          values=readln("temp")
          parse var values ok type .
          call close("temp")
        end
      else
        do
          type=1
        end


      'FORM "Visual Logo - strong" "Use|Cancel"',
      'CYCLE,"Effect style","Outline|Shiny",'type'',

      values=result
      parse var values ok type .

      if ok = 0 then exit

      call open("temp","ie:prefs/visuallogodstrong.cfg","W")
      res=writeln("temp",values)
      call close("temp")

    end

    else parse var arguments type .


    CONVOLVE x0 "IE:Convolves/GaussianBlur5x5"
    x1=result


    CONVOLVE x1 "IE:Convolves/Emboss_High"
    x2=result


    MARK x1 PRIMARY
    MARK x1 ALPHA
    MARK x2 SECONDARY


    if type="0" | upper(type)=="OUTLINE"  then do
      COMPOSITE 1 0 ALPHA
      x3=result
    end
    else do
      COMPOSITE 2 0 MAX
      x3=result
    end


    CLOSE x1
    CLOSE x2

    CONTRAST x3 20
    final=result

    CLOSE x3

  end



  when visual == 3 | upper(visual)=="RAISED" then do

    if arguments="" then do

      if exists("ie:prefs/visuallogodraised.cfg") == "1" then
        do
          call open("temp","ie:prefs/visuallogodraised.cfg","R")
          values=readln("temp")
          parse var values ok outline xplace yplace .
          call close("temp")
        end
      else
        do
          outline=0
          xplace="-3"
          yplace="-3"
        end


      'FORM "Visual Logo - raised" "Use|Cancel"',
      'CYCLE,"Outline","Yes|No",'outline'',
      'INTEGER,"X-place",-20,20,'xplace',SLIDER',
      'INTEGER,"Y-place",-20,20,'yplace',SLIDER'

      values=result
      parse var values ok outline xplace yplace .

      if ok = 0 then exit

      call open("temp","ie:prefs/visuallogodraised.cfg","W")
      res=writeln("temp",values)
      call close("temp")

    end

    else parse var arguments outline xplace yplace .



    CONVOLVE x0 "IE:Convolves/FeatherWhite"
    x1=result

    CONVOLVE x0 "IE:Convolves/GaussianBlur5x5"
    x2=result

    CONVOLVE x2 "IE:Convolves/GaussianBlur5x5"
    x3=result

    CLOSE x2

    CONVOLVE x3 "IE:Convolves/GaussianBlur5x5"
    x4=result

    CLOSE x3

    NEGATIVE x1
    x5=result

    CLOSE x1

    MARK x5 PRIMARY
    MARK x5 ALPHA
    MARK x4 SECONDARY

    COMPOSITE xplace yplace ADD
    x6=result

    CLOSE x4
    CLOSE x5


    if outline=="0" | upper(outline)=="YES" then do

      CONVOLVE x0 "IE:Convolves/GaussianBlur5x5"
      y1=result

      NEGATIVE y1
      y2=result

      MARK y1 PRIMARY
      MARK y1 ALPHA
      MARK y2 SECONDARY
      COMPOSITE 0 0 DIFFERENCE
      y3=result

      CLOSE y1
      CLOSE y2


      MARK y3 PRIMARY
      MARK y3 ALPHA
      MARK x6 SECONDARY

      COMPOSITE xplace yplace MIN
      final=result

      CLOSE y3
      CLOSE x6

    end

  end




otherwise do

   'REQUEST "You can only use Raised and Strong -effects in this demoversion." "Ok"'

  end

end


if space~=0 then CLOSE x0


exit





/*******************************************************************/
/* This is where control goes when an error code is returned by IE */
/* It puts up a message saying what happened and on which line     */
/*******************************************************************/
error:
if RC=5 then do            /* Did the user just cancel us? */
    IE_TO_FRONT
    LAST_ERROR
    'REQUEST "'||RESULT||'"'
    exit
end
else do
    IE_TO_FRONT
    LAST_ERROR
    'REQUEST "Error detected!!!'||D2C(10)||'Image Engineer error message is as follows'||D2C(10)||result||D2C(10)||'Script failed on line '||SIGL||'"' 'Doh!'
    exit
end