home *** CD-ROM | disk | FTP | other *** search
/ Sound Sensations! / sound_sensations.iso / midifile / cmtcmu / break.asm < prev    next >
Assembly Source File  |  1990-06-28  |  9KB  |  369 lines
  1.     title BREAK - handle ctrl-break 
  2. ;***************************************************************************** 
  3. ;        Change Log 
  4. ;  Date        | Change 
  5. ;-----------+----------------------------------------------------------------- 
  6. ; 11-Aug-85 | Created 
  7. ;  1-Sep-85 | Rearranged so _clrctl precedes its call (needed in P model) 
  8. ; 31-Dec-85 | Made special copy for Adagio support.  Stripped out most stuff 
  9. ;        | and handle DOS ctrl-break exit 
  10. ;  1-Jan-86 | Use 1 for control-break and 2 for control-C 
  11. ;  1-Jan-86 | Cause return to skip over sub instruction (forcing ignore code 
  12. ;        | acceptance) on PC/AT 
  13. ;  2-Jan-86 | take out m: from include m:dos.mac 
  14. ;****************************************************************************/ 
  15.     include dos.mac 
  16. debug=0 
  17.     subttl Documentation 
  18. ;***************************************************************************** 
  19. ; This code uses the standard Lattice interface.  The logical device 'm:' 
  20. ; represents the memory model being used.  Supply your own path to dos.mac 
  21. ; 
  22. ; This code is intended to allow me to break out of various perverse 
  23. ; loops in my application code.      
  24. ; 
  25. ;              * * * W A R N I N G * * * 
  26. ; 
  27. ; This code is an extreme *HACK*.  It solves my problem.  It may not solve 
  28. ; yours.  I make no guarantees.     Use at your own risk! 
  29. ; 
  30. ;                 Restrictions 
  31. ; 
  32. ; Failure to clear the handler before exiting the program will lead to 
  33. ; various bizarre behavior.  Calling the initialization more than once 
  34. ; will confuse the world beyond practical recovery. 
  35. ; 
  36. ;                   Abstract 
  37. ; 
  38. ; A procedure is called to establish the existence of the control-break  
  39. ; handler (interrupt 1BH).  If a control-break is taken during program 
  40. ; the flag _CBREAK is set to true 
  41. ; 
  42. ; This code is to be linked into the user's application. 
  43. ; 
  44. ; This code also sets up a handler for the DOS ctrl-brk exit; this is called 
  45. ; if DOS sees a C-C character come by. 
  46. ;  
  47. ;               * * * B E W A R E * * * 
  48. ; 
  49. ; This code is delicate and high-risk.    It works well enough for my one 
  50. ; application.    I may have missed all sorts of bizarre DOS or BIOS hacks. 
  51. ; 
  52. ; It is not guaranteed to be bug-free.    The user assumes all risk in using 
  53. ; it.  This is code that should be used only if you understand enough of 
  54. ; DOS/BIOS hacking to be sure it will work for you. 
  55. ; 
  56. ; 
  57.   
  58.     subttl Interface specifications 
  59. ;----------------------------------------------------------------------------- 
  60. ; extern void _setctl(); 
  61. ;     
  62. ; Effects:  
  63. ;    Establishes a Ctrl-brk abort handler 
  64. ; 
  65. ; Limitations: 
  66. ;    May only be called once; subsequent calls may damage universe 
  67. ;  
  68. ;----------------------------------------------------------------------------- 
  69. ; extern void _clrctl(); 
  70. ; 
  71. ; Effects:  
  72. ;    Resets the Ctrl-brk abort handler 
  73. ; 
  74. ; Limitations: 
  75. ;    Should be called only if _setctl() has been called.  However, if 
  76. ;    _setctl has not already been called, nothing will happen. 
  77. ; 
  78. ;***************************************************************************** 
  79.   
  80.     subttl Working storage 
  81. extrn    _CBREAK:word 
  82. ; This storage is in the data segment 
  83. ;    public    _CBREAK 
  84.     DSEG 
  85.     even 
  86. ;_CBREAK    dw    0 
  87. OLD_BIOS label    DWORD        ; we store former 1BH vector here 
  88. OLD_BIP DW    0        ; 0, not ? 
  89. OLD_BCS DW    0        ; 0, not ? 
  90.  
  91. OLD_DOS label    DWORD        ; we store former 23H vector here 
  92. OLD_DIP DW    0 
  93. OLD_DCS dw    0         
  94.  
  95.     ENDDS 
  96.  
  97.   
  98.     subttl Vector locations 
  99. VECTORS SEGMENT AT 0H 
  100.     ORG    1BH*4        ; BIOS ctrl-brk interrupt vector 
  101. CTLBRK    LABEL    DWORD 
  102. CTLBRK_IP DW    ?        ; IP of BIOS control-break vector 
  103. CTLBRK_CS DW    ?        ; CS of BIOS control-break vector 
  104.  
  105.     ORG    23H*4        ; DOS ctrl-brk interrupt vector 
  106. DOSCBRK LABEL    DWORD 
  107. DOSC_IP     DW    ? 
  108. DOSC_CS     DW    ? 
  109. VECTORS ENDS 
  110.  
  111.  
  112.   
  113.     subttl    Code segment storage  
  114. ; 
  115. ; This is in the code segment because I don't know how to make it addressible 
  116. ; in the data segment 
  117. ; 
  118.     PSEG 
  119.  
  120.   
  121.     subttl    CTLSEEN - CTRL-BREAK handler 
  122. ;----------------------------------------------------------------------------- 
  123. ;                    ctlseen 
  124. ; Inputs: 
  125. ;    None; called as interrupt routine via interrupt 1BH 
  126. ; 
  127. ; Result: 
  128. ;    AL=0FFH 
  129. ; 
  130. ; Effects: 
  131. ;    sets _CBREAK to true.   
  132. ;----------------------------------------------------------------------------- 
  133.  
  134. CTLSEEN PROC FAR 
  135.  
  136.  
  137. if debug 
  138.     int  3 
  139. endif 
  140.     push    ax 
  141.     push    ds 
  142.     mov    ax,seg _CBREAK 
  143.     mov    ds,ax 
  144.     mov    ds:_CBREAK,1 
  145.     pop    ds 
  146.     pop    ax 
  147.     push    es 
  148.     mov    AX,0F000H    ; from the ROM,  
  149.     mov    ES,AX        ; we want pc ID 
  150.     mov    AH,ES:0FFFEH    ; The Peter Norton Programmer's Guide to the 
  151.                 ; IBM PC, page 60 
  152.     cmp    AH,0FCH        ;  PC/AT? 
  153.     jnz    no 
  154. if debug 
  155.     int    3        ; WARNING!  If you have this debug trap 
  156.                 ; enabled, and continue from it, the 
  157.                 ; ctrl-key-up transition is lost (because 
  158.                 ; the key went up to talk to the debugger) 
  159.                 ; this confuses the world; you will have to 
  160.                 ; hit the control-key once to get the 
  161.                 ; world resynchronized. 
  162.  
  163. endif 
  164. ; We increment the return address by 2 
  165. ; 
  166. ;    +-------------------+ 
  167. ;  SS    |      (ES)        |  ES:0[BP] 
  168. ;    +-------------------+ 
  169. ;    |      (BP)        |  ES:2[BP] 
  170. ;    +-------------------+ 
  171. ;    |    IP        |  ES:4[BP] 
  172. ;    +-------------------+ 
  173. ;    |    CS        |  ES:6[BP] 
  174. ;    +-------------------+ 
  175.     mov    AX,SS     
  176.     mov    ES,AX 
  177.     push    BP 
  178.     mov    BP,SP 
  179.     inc    WORD PTR ES:4[BP] 
  180.     inc    WORD PTR ES:4[BP] 
  181.     pop    BP 
  182. no:    mov    AX,-1 
  183.             ; "ignore" character 
  184.             ; PC/XT ref page A-31 lines 2090-2091, page A-33 
  185.             ; lines 2217-2219 
  186.             ; PC/AT ref page 5-118 loc 2AE..285 indicates this 
  187.             ; has no effect for the /AT, which is why we did 
  188.             ; the above hack 
  189.     pop    ES 
  190.     iret                ;return  
  191.  
  192. CTLSEEN ENDP 
  193.  
  194. CTLC    PROC    FAR        ; Control-C handler 
  195.     push    ax 
  196.     push    ds 
  197.     mov    ax,seg _CBREAK 
  198.     mov    ds,ax 
  199.     mov    ds:_CBREAK,2 
  200.     pop    ds 
  201.     pop    ax 
  202.     iret                ;return  
  203. CTLC    ENDP 
  204.   
  205.     subttl    _clrctl - Clear CTL-BRK vector 
  206. ;----------------------------------------------------------------------------- 
  207. ; extern void _clrctl(); 
  208. ; 
  209. ; Resets the ctrl-break interrupt vector 
  210. ;----------------------------------------------------------------------------- 
  211.     PUBLIC    _clrctl 
  212.     IF    LPROG 
  213. _clrctl PROC FAR 
  214.     ELSE 
  215. _clrctl PROC NEAR 
  216.     ENDIF 
  217.  
  218. ; OldES := ES; 
  219.  
  220.     push    ES        ; save old ES 
  221.     push    AX        ; save old AX 
  222.     push    BX 
  223.  
  224. if debug 
  225.     int 3 
  226.     mov    AH,62H 
  227.     int    21H        ; get program segment prefix 
  228.     mov    PSP,BX        ; save it 
  229. endif 
  230.  
  231. ; ES := Segment(&Vectors); 
  232.  
  233.     mov    AX,VECTORS 
  234.     mov    ES,AX         
  235.     ASSUME ES:VECTORS 
  236.  
  237. ; Disable_Interrupts(); 
  238.  
  239.     CLI            ; turn off interrupts 
  240.  
  241. ; if(OLD_BIOS == 0) goto NoVectorStored 
  242.  
  243.     mov    AX,WORD PTR OLD_BIOS 
  244.     cmp    AX,0        ; is it zero? 
  245.     je    NoBIOSStored 
  246.  
  247. ; CTLBRK.IP := OLD_BIOS.IP 
  248.  
  249.     mov    WORD PTR CTLBRK,AX 
  250.  
  251. ; CTLBRK.CS := OLD_BIOS.CS 
  252.  
  253.     mov    AX,WORD PTR OLD_BIOS[2] 
  254.     mov    WORD PTR CTLBRK[2],AX 
  255.  
  256. NoBIOSStored: 
  257.  
  258.     mov    AX,WORD PTR OLD_DOS 
  259.     cmp    AX,0        ; initialized? 
  260.     je    NoDOSStored    ; no, no dos vector 
  261.  
  262. ; DOSCBRK.IP = OLD_DOS.IP 
  263.  
  264.     mov    WORD PTR DOSCBRK,AX 
  265.  
  266. ; DOSCBRK.CS := OLD_DOS.CS 
  267.  
  268.     mov    AX,WORD PTR OLD_DOS[2] 
  269.     mov    WORD PTR DOSCBRK[2],AX 
  270.  
  271. NoDOSStored: 
  272.  
  273. ; Enable_interrupts(); 
  274.  
  275.     STI        ; allow interrupts 
  276.  
  277. ; ES := OldES; 
  278.  
  279.     pop    BX 
  280.     pop    AX 
  281.     pop    ES     
  282.  
  283.     ret        ; return to caller 
  284.  
  285. PSP:    DW    ? 
  286. _clrctl    ENDP 
  287.   
  288.     subttl    _setctl - Set CTL-BRK vector 
  289. ;----------------------------------------------------------------------------- 
  290. ; extern void _setctl() 
  291. ;----------------------------------------------------------------------------- 
  292.  
  293.     PUBLIC    _setctl 
  294.     IF LPROG 
  295. _setctl    PROC    FAR 
  296.     ELSE 
  297. _setctl    PROC NEAR            ; set CTL-BRK interrupt 
  298.     ENDIF 
  299.     push    BP            ; C prolog 
  300.     mov    BP,SP            ; ... 
  301.  
  302. if debug 
  303.     int    3 
  304. endif 
  305.  
  306.     ASSUME ES:VECTORS 
  307.  
  308. ; OldES := ES; 
  309.  
  310.     push    ES        ; save old ES 
  311.     push    AX        ; save old AX 
  312.  
  313. ; ES := Segment(&Vectors); 
  314.  
  315.     mov    AX,VECTORS 
  316.     mov    ES,AX         
  317.  
  318. ; Disable_Interrupts(); 
  319.  
  320.     CLI            ; turn off interrupts 
  321.  
  322. ; OLD_BIOS.IP := CTLBRK.IP 
  323.  
  324.     mov    AX,WORD PTR CTLBRK 
  325.     mov    WORD PTR OLD_BIOS,AX 
  326.  
  327. ; OLD_BIOS.CS := CTLBRK.CS 
  328.  
  329.     mov    AX,WORD PTR CTLBRK[2] 
  330.     mov    WORD PTR OLD_BIOS[2],AX 
  331.  
  332. ; CTLBRK := &CTLSEEN 
  333.  
  334.     mov    CTLBRK_IP,OFFSET CTLSEEN 
  335.     mov    CTLBRK_CS,CS 
  336.  
  337. ; OLD_DOS.IP := DOSCBRK.IP 
  338.  
  339.     mov    AX,WORD PTR DOSCBRK 
  340.     mov    WORD PTR OLD_DOS,AX 
  341.  
  342. ; OLD_DOS.CS := DOSCBRK.CS 
  343.  
  344.     mov    AX,WORD PTR DOSCBRK[2] 
  345.     mov    WORD PTR OLD_DOS[2],AX 
  346.  
  347. ; DOSCBRK := &CTLC 
  348.  
  349.     mov    DOSC_IP,OFFSET CTLC 
  350.     mov    DOSC_CS,CS 
  351.  
  352. ; Enable_interrupts(); 
  353.  
  354.     STI        ; allow interrupts 
  355.  
  356. ; ES := OldES; 
  357.  
  358.     pop    AX 
  359.     pop    ES     
  360.  
  361. ; return; 
  362.     pop    BP    ; C epilog 
  363.     ret        ; return to caller 
  364.  
  365. _setctl    ENDP 
  366.  
  367.     ENDPS 
  368.     END 
  369.