home *** CD-ROM | disk | FTP | other *** search
/ Sound Sensations! / sound_sensations.iso / voice / mvc87100 / mvdemo.prg < prev    next >
Text File  |  1990-06-10  |  6KB  |  196 lines
  1. * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  2. * Program  *  MVDEMO.PRG                                                    *
  3. * System   *  Micro/Voice for Clipper Summer '87                            *
  4. * Version  *  Version 1.00                                                  *
  5. * Library  *  MVCLIP87.LIB - 06/10/90 1:00a                                 *
  6. * Author   *  Steve Badaracco                                               *
  7. * Notice   *  (c)1990, DataBlaze Solutions, All Rights Reserved             *
  8. * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  9. *                                                                           *
  10. * This program demonstrates some of the functionality of Micro/Voice.       *
  11. *                                                                           *
  12. * To compile (requires The Clipper Compiler, Summer '87 Version):           *
  13. *     CLIPPER MVDEMO                                                        *
  14. *                                                                           *
  15. * To link for execution (using Microsoft Overlay Linker Version 3.x):       *
  16. *     LINK MVDEMO,,NUL,CLIPPER+EXTEND+MVCLIP87/SE:256                       *
  17. * To link for execution (using Turbo Link Version 1.x):                     *
  18. *     TLINK MVDEMO,,NUL,CLIPPER+EXTEND+MVCLIP87                             *
  19. * To link for execution (using PLINK86plus Version 2.24 for Clipper):       *
  20. *     PLINK86 FI MVDEMO LIB CLIPPER,MVCLIP87,EXTEND                         *
  21. * To link for execution (using Blinker Dynamic Overlay Linker Version 1.x): *
  22. *     BLINKER FI MVDEMO LIB CLIPPER,MVCLIP87,EXTEND                         *
  23. *                                                                           *
  24. * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  25.  
  26. * Exit READ with F2
  27. set function 2 to ""
  28.  
  29. * Initialize Micro/Voice (these settings are for PS/2 Model 60):
  30. if v_init( "system01.dct", "mycustom.dct", 1, 19, 2 ) # 0
  31.    ? 'Voice initialization error: data file(s) not found.'
  32.    ?
  33.    quit
  34. endif
  35.  
  36. first = .t.
  37.  
  38. * Initialize GET variables
  39. phstring = ""       && for a string of phonemes,   e.g. "T-EH-S-T W-UH-N"
  40. acstring = ""       && for an acronym string,      e.g. "IBM" (or "I.B.M.")
  41. wostring = ""       && for a normal text string,   e.g. "TEST ONE"
  42.  
  43. * Main demo loop
  44. do while .t.
  45.  
  46.    clear screen
  47.  
  48.    * Retain any previous values for editing
  49.    phstring = pad( phstring, 60 )
  50.    acstring = pad( acstring, 60 )
  51.    wostring = pad( wostring, 60 )
  52.  
  53.    * Get Micro/Voice current settings
  54.    del = v_setdelay()
  55.    res = v_setres()
  56.    spc = v_setspace()
  57.    snd = v_setsound()
  58.  
  59.    * Display data entry labels and GETs
  60.    @  1, 0 say "Phoneme String:" get phstring
  61.    @  2, 0 say "..or.. Acronym:" get acstring
  62.    @  3, 0 say "..or..    Word:" get wostring
  63.    @  5, 0 say "    SpeedDelay:" get del
  64.    @  6, 0 say "    Resolution:" get res
  65.    @  7, 0 say "   Blank Space:" get spc
  66.    @  8, 0 say "      Sound On:" get snd picture "Y"
  67.  
  68.    @ 10, 0 say "F1 = Talking Help       F2 = Accept Screen       Esc = Quit"
  69.  
  70.    * Display footer on the screen
  71.    set color to n/w
  72.    @ 24, 0 say "   Micro/Voice for Clipper Summer '87  ***  Processing Demonstration Program    "
  73.    set color to
  74.  
  75.    if first
  76.       first = .f.
  77.       v_speak( "w-eh-l-c-uh-m t-oo tz-uh m-i-k-r-oh-v-oh-ee-s d-eh-m-oh" )
  78.    endif
  79.  
  80.    read
  81.  
  82.    * Check for Esc key
  83.    if lastkey() = 27
  84.       exit
  85.    endif
  86.  
  87.    * Update Micro/Voice settings with new choices
  88.    v_setdelay(del)
  89.    v_setres(res)
  90.    v_setspace(spc)
  91.    v_setsound(snd)
  92.  
  93.    * Process ONE of the strings entered (check GETs top-down)
  94.    if ! empty( phstring )
  95.       * A phoneme string
  96.       thestring = trim( phstring )
  97.    elseif ! empty( acstring )
  98.       * An acronym
  99.       thestring = v_unpack( v_apack( acstring ) )
  100.    elseif ! empty( wostring )
  101.       * A string of text
  102.       thestring = v_unpack( v_wpack( wostring ) )
  103.    else
  104.       * Nothing entered
  105.       loop
  106.    endif
  107.  
  108.    * Display phoneme string equivalent
  109.    @ 12,0
  110.    ? 'Phoneme string:'
  111.    ? upper( thestring )
  112.  
  113.    * Say it (if sound is on)
  114.    v_speak( thestring )
  115.  
  116.    ?
  117.    wait
  118.  
  119. enddo
  120.  
  121. * Display final banner and exit
  122. set color to n/w
  123. @ 24, 0 say "     Micro/Voice for Clipper Summer '87  ***  End of Demonstration Program      "
  124. set color to
  125. for x = 1 to 24
  126.    ?
  127. next
  128.  
  129. @ 3, 0
  130. v_setdelay( v_setdelay() - 4 )
  131. v_speak( "b-ah-ee" )
  132. v_setdelay( v_setdelay() + 4 )
  133. v_speak( "b-ah-ee" )
  134.  
  135. quit
  136.  
  137.  
  138. *=============================================================================
  139. procedure help
  140. parameters a, b, c
  141.  
  142. private winbuff, mvar, message, script, mrow, mcol
  143.  
  144. mrow = row()
  145. mcol = col()
  146. winbuff = savescreen( 1, 0, 7, 40 )
  147. @ 1,  0,  7, 40 box "┌─┐│┘─└│ "
  148. @ 7, 10 say "  <Any Key> to return  "
  149.  
  150. mvar    = readvar()
  151.  
  152. do case
  153.  
  154.    case readvar() = "PHSTRING"
  155.       message = "Enter phoneme string (e.g. k-ae-t)."
  156.       script  = "eh-n-t-uh-r uh f-oh-n-ee-m s-t-r-i-n-g"
  157.  
  158.    case readvar() = "ACSTRING"
  159.       message = "Enter acronym string (e.g. C.A.T)."
  160.       script  = "eh-n-t-uh-r uh-n ae-k-r-uh-n-ih-m s-t-r-i-n-g"
  161.  
  162.    case readvar() = "WOSTRING"
  163.       message = " Enter a text string (e.g. cat)."
  164.       script  = "eh-n-t-uh-r uh t-eh-k-s-t s-t-r-i-n-g"
  165.  
  166.    case readvar() = "DEL"
  167.       message = " Speed/delay factor: range 1..100."
  168.       script  = "eh-n-t-uh-r tz-uh s-p-ee-d-d-ee-l-a-ee f-ae-k-t-uh-r"
  169.  
  170.    case readvar() = "RES"
  171.       message = " Resolution factor: 1,2,4,6,or 8."
  172.       script  = "eh-n-t-uh-r tz-uh r-eh-z-uh-l-oo-sh-uh-n f-ae-k-t-uh-r"
  173.  
  174.    case readvar() = "SPC"
  175.       message = "    Space between words: 1..10."
  176.       script  = "eh-n-t-uh-r tz-uh s-p-a-s b-ee-t-w-ee-n w-uh-r-d-z"
  177.  
  178.    case readvar() = "SND"
  179.       message = "   Sound status: Y=ON / N=OFF."
  180.       script  = "eh-n-t-uh-r   eh-n   t-oo t-uh-r-n s-ae-oo-n-d aw-f"
  181.  
  182.    otherwise
  183.       message = "       No help available here."
  184.       script  = "n-oh h-eh-l-p uh-v-a-l-uh-b-l h-ee-r"
  185.  
  186. endcase
  187.  
  188. @ 4, 3 say message
  189. v_speak( script )
  190.  
  191. inkey(0)
  192. restscreen( 1, 0, 7, 40, winbuff )
  193. @ mrow, mcol say ""
  194.  
  195. return
  196.