home *** CD-ROM | disk | FTP | other *** search
/ ANews 3 / AnewsCD3.iso / atari / GRAPHX / POV / 68030.060 / POV31G30 / POVRAY_3.1G / SCENES / INTERIOR / IORTEST.POV < prev    next >
Text File  |  1999-10-30  |  3KB  |  111 lines
  1. // Persistence Of Vision raytracer version 3.1 sample file.
  2. // This file demonstrates the use of the file "ior.inc" and a few other
  3. // interesting and useful tricks.  It can take a bit of time to render,
  4. // (he said, understatingly), because of the transparency and because of
  5. // the 7 element light bank (flourescent tube?).  Eliminating some of the
  6. // lights (and adjusting the brightness color, "Watts", accordingly)
  7. // will help quite a bit.
  8.  
  9. global_settings { max_trace_level 20 assumed_gamma 2.2 }
  10.  
  11. #include "colors.inc"
  12. #include "shapes.inc"
  13. #include "textures.inc"
  14. #include "glass.inc"
  15. #include "consts.inc"              // Index of refraction constants
  16.  
  17. camera {
  18.    location <0, 5, -20>
  19.    direction z
  20.    angle 57
  21.    up  <0.0, 1.0, 0.0>
  22.    right <4/3, 0.0, 0.0>
  23.    look_at <0, 1, 0>
  24. }
  25.  
  26. // Assemble a bank of lights here, on the ground...
  27. #declare Watts = color Gray25;
  28. #declare Light_Distance = -50;
  29.  
  30. union {
  31.     light_source  { <-6, 0, Light_Distance>  color Watts  }
  32.     light_source  { <-4, 0, Light_Distance>  color Watts  }
  33.     light_source  { <-2, 0, Light_Distance>  color Watts  }
  34.     light_source  { < 0, 0, Light_Distance>  color Watts  }
  35.     light_source  { < 2, 0, Light_Distance>  color Watts  }
  36.     light_source  { < 4, 0, Light_Distance>  color Watts  }
  37.     light_source  { < 6, 0, Light_Distance>  color Watts  }
  38.  
  39.     rotate 60*x           // ... and hoist 'em up into the air
  40.  
  41.     pigment { White }  // Doesn't do anything but suppresses a parser warning
  42. }
  43.  
  44.  
  45. // Horozontally striped floor
  46. plane { y, -1
  47.    pigment {
  48.       checker color HuntersGreen color SummerSky
  49.       scale <32000, 1, 2>
  50.    }
  51.    finish {
  52.       ambient 0.1
  53.       diffuse 0.6
  54.    }
  55. }
  56.  
  57.  
  58. #declare Hummer =
  59. union {
  60.    union {
  61.       object { UnitBox }
  62.       object { Disk_Y translate 2*y }
  63.       sphere { <0, 4, 0>, 1 }
  64.       rotate 45*y
  65.     //  interior{I_Glass}
  66.    }
  67.  
  68.    // Let's attach an orange sphere to this thing... off in the distance,
  69.    // so it'll be automatically repeated as we repeat the rest of the
  70.    // object (see below)
  71.    sphere { <0, 5, 20>, 1 
  72.       texture {
  73.          finish { Shiny } 
  74.          pigment {Orange}
  75.       }
  76.  
  77.     }
  78. }
  79.  
  80. // Set up a default texture for all objects that follow that don't already
  81. // have a texture of their own
  82. default { texture { T_Glass1 } }
  83.  
  84.  
  85. // Now lay out five of those Hummers
  86. object { Hummer
  87.    translate -6*x
  88.    interior { ior Diamond_Ior }
  89. }
  90.  
  91. object { Hummer
  92.    translate -3*x
  93.    interior { ior Flint_Glass_Ior }
  94. }
  95.  
  96. object { Hummer
  97.    translate 0*x
  98.    interior { ior Crown_Glass_Ior }
  99. }
  100.  
  101. object { Hummer
  102.    translate 3*x
  103.    interior { ior Water_Ior }
  104. }
  105.  
  106. object { Hummer
  107.    translate 6*x
  108.    interior { ior Air_Ior }
  109. }
  110. // end of file iortest.pov
  111.