home *** CD-ROM | disk | FTP | other *** search
/ ANews 3 / AnewsCD3.iso / atari / GRAPHX / POV / 68030.060 / POV31G30 / POVRAY_3.1G / SCENES / INTERIOR / MEDIA / HOLLOW1.POV < prev    next >
Text File  |  1999-10-30  |  2KB  |  110 lines
  1. // Persistence Of Vision raytracer version 3.1 sample file.
  2. // File by Dieter Bayer.
  3. //
  4. // This scene shows the effect of solid vs. hollow objects.
  5. //
  6. // The left sphere is solid, i.e. it's not filled with fog.
  7. // The right sphere is hollow, i.e. it's filled with fog.
  8. //
  9. // The left sphere doesn't attenuate light passing through it.
  10. // Thus the background seen through it and its shadow is lighter
  11. // than for the right sphere.
  12. //
  13. // The right sphere attenuates light in the same way like fog does
  14. // because it is filled with fog. Thus the background seen through
  15. // it and its shadow is darker.
  16. //
  17.  
  18. global_settings { assumed_gamma 2.2 }
  19.  
  20. #include "colors.inc"
  21.  
  22. camera {
  23.   location <0, 20, -100>
  24. }
  25.  
  26. //
  27. // Standard fog
  28. //
  29.  
  30. fog {
  31.   color rgb<0.5, 0.5, 0.5>
  32.   distance 80
  33. }
  34.  
  35. //
  36. // Put down the beloved famous raytrace green/yellow checkered floor
  37. //
  38.  
  39. plane { y, -10
  40.    pigment {
  41.       checker Yellow, Green
  42.       scale 20
  43.    }
  44.    finish {
  45.       ambient 0.2
  46.       diffuse 0.8
  47.    }
  48.    hollow
  49. }
  50.  
  51. //
  52. // Use beloved famous raytrace green/yellow checkered wall
  53. //
  54.  
  55. plane { z, 50
  56.    pigment {
  57.       checker Yellow, Green
  58.       scale 20
  59.    }
  60.    finish {
  61.       ambient 0.2
  62.       diffuse 0.8
  63.    }
  64.    hollow
  65. }
  66.  
  67. //
  68. // Solid, translucent sphere
  69. //
  70.  
  71. sphere { <-26, 20, 0>, 25
  72.   pigment { rgbt<1, 1, 1, 0.8> }
  73.   finish {
  74.     ambient 0.0
  75.     diffuse 0.0
  76.     phong 1.0
  77.     phong_size 200
  78.   }
  79.   interior { ior 1.05 }
  80.   hollow no
  81. }
  82.  
  83. //
  84. // Hollow, translucent sphere
  85. //
  86.  
  87. sphere { <26, 20, 0>, 25
  88.   pigment { rgbt<1, 1, 1, 0.8> }
  89.   finish {
  90.     ambient 0.0
  91.     diffuse 0.0
  92.     phong 1.0
  93.     phong_size 200
  94.   }
  95.   interior { ior 1.05 }
  96.   hollow yes
  97. }
  98.  
  99. //
  100. // Due to the atmospheric attenuation and the large distance to
  101. // the light source it has to be very bright.
  102. //
  103.  
  104. light_source {
  105.   <500, 600, -200> 
  106.   color 40000 * White
  107.   media_attenuation on
  108. }
  109.  
  110.