home *** CD-ROM | disk | FTP | other *** search
/ Brotikasten / BROTCD01.iso / games / dis915.d64 / zwergenstadt (.txt) < prev   
Commodore BASIC  |  1995-07-31  |  6KB  |  131 lines
  1. 10 CLR:DIMB$(25),D$(36),F$(25),B%(36,3),G$(14),C%(25),D%(13),E%(25),G%(36):GOTO70
  2. 18 DATA 0,1,1,2,1,0,4,3,1,1,5,2,6,1,1,7,1,1,1,1,8,1,14,2,1,1,9,10,11,1,12
  3. 19 DATA 13,13,13,13,13,13
  4. 20 DATA 78,76,83,79,65,89,73,90,81,86,72,70,71,87
  5. 21 DATA1,1,4,27,50,19,12,50,22,16,2,50,14,50,29,50,21,7,30,50,8,13,1,18,50,3
  6. 22 DATA0,0,1,0,5,0,1,0,3,1,0,0,1,0,2,1,1,5,4,0,0,0,0,1,0,0
  7. 23 DATA2,50,50,5,3,1,50,50,13,2,50,0,10,2,8,1,50,1,0,0,0,50,0,0,50,6,0,0,9
  8. 24 DATA4,19,6,50,10,17,8,0,3,9,4,15,13,12,0,0,11,0,0,50,50,11,3,50,50,15,0,49,49,49
  9. 25 DATA11,50,15,17,9,18,16,50,9,36,16,50,17,18,17,35,7,48,29,23,14,24,14,25,15,26
  10. 26 DATA50,23,0,27,50,24,20,28,23,25,21,28,24,50,50,28,30,27,47,0,0,0,23,50,24,32,25
  11. 27 DATA50,0,14,0,0,0,50,0,34,31,32,32,31,31,33,28,34,32,35,35,31,33,35,34,33,33
  12. 28 DATA34,35,36,25,35,36
  13. 30 DATA"AXT","BEIL","CIRCEN-DIAMANT","DYNAMIT","EIER","FETT","GOLD"
  14. 31 DATA"","INDUSOPAL","JUWELEN","KAEFIG","","MUENZEN","","OPAL-RING","PRLE"
  15. 32 DATA"QUITTENBLUETE","RUBIN","SILBER","","URNE","VOGEL","WASSER","XERXEN-VASE"
  16. 33 DATA"","ZAUBERSTAB"
  17. 35 DATA"ANGREIFEN","N","W","O","S","FETTEN","GIESSEN","HILFE","INVENTAR","",""
  18. 36 DATA"LEGEN","","NEHMEN","OEFFNEN","","QUITTIREN","","SPRENGEN","",""
  19. 37 DATA"VERSTAND","WERFEN","","Y!","ZAUBERN"
  20. 40 DATA"HAUS","FLUUR","ZAUBAER-R","DIAMANTEN-R","NICHTS","TRUEMMER-R","RUBIN-R"
  21. 41 DATA"MUSCHEL-R","STOP","NEBEL-H-NORD","NEBEL-H-SUED","GOLD-R","VOGEL-R"
  22. 42 DATA"SCHATZ-R","MT.KING","JUWELEN-R","KLEINE KREUZUNG","ORIENT-R","FETT-R"
  23. 43 DATA"GEHEIM-R","SILBER-R","MEER-R","FLIESSEN-R","KOMPLEXE KREUZUNG","BACH"
  24. 44 DATA"EIER-R","LANGE-H","Y","TEPPICH-R","NIERGENS","IRR","IRR","IRR","IRR"
  25. 45 DATA"IRR","IRR"
  26. 60 DATA"","AUF ALLEN SEITEN HAT ES WEGE","IM O,W,S HAT ES WEGE"
  27. 61 DATA"IM W,S HAT ES WEGE","NACH W GEHT EIN WEG:IM N,O HAT ES VERSCHUETTETE WEGE"
  28. 62 DATA"IM O,W,N HAT ES WEGE","DER AUSGANG IST IM WESTEN"
  29. 63 DATA"EINE GROSSE VIPPER VERSPERRT DIER DEN   WEG"
  30. 64 DATA"EIN DRACHEN VERSPERRT DIER DEN WEG","IM S,O,N HAT ES WEGE"
  31. 65 DATA"HIER IST EINE PFLANZE DIE NACH WASSER SCHREIT","AN DER WAND IST EIN Y"
  32. 66 DATA"KEIN AUSWEG:IETZT SOLLTE MAN ZAUBERN KOENNEN"
  33. 67 DATA"ALLE RAEUME SEHEN GLEICH AUS","HIER HAT ES EINEN TRESOR"
  34. 70 FORI=0TO36:READG%(I):NEXT
  35. 72 FORI=0TO13:READD%(I):NEXT
  36. 74 FORI=0TO25:READC%(I):NEXT
  37. 76 FORI=0TO25:READE%(I):NEXT
  38. 78 FORI=1TO36:FORY=0TO3:READB%(I,Y):NEXTY:NEXTI
  39. 80 FORI=0TO25:READB$(I):NEXT
  40. 82 FORI=0TO25:READF$(I):NEXT
  41. 84 FORI=1TO36:READD$(I):NEXT
  42. 86 FORI=0TO14:READG$(I):NEXT
  43. 88 S=1
  44. 90 FORI=1TO5:Q$=Q$+CHR$(INT(RND(TI)*26)+65):NEXT:D$(35)="IRR "+Q$
  45. 99 GOTO350
  46. 100 IFRND(TI)>.97ORT=1THENT=1:GOSUB200
  47. 105 IFRND(TI)<.03THENGOSUB250
  48. 110 H=H+1:PRINT"INPUT: ";:GOSUB3000:IFVAL(A$)<>0THEN300
  49. 120 PRINTF$(ASC(A$)-65)"":FORI=1TO14:IFA$=CHR$(D%(I-1))THEN160
  50. 140 NEXT:PRINT"WIE BITTE":GOTO100
  51. 160 ONIGOTO400,405,500,600,700,800,900,1000,1100,1200,1300,1400,1500,1600
  52. 200 PRINT"EIN ZWERG IST BEI DIR":IFRND(TI)<.5THENRETURN
  53. 210 PRINT"ER WIRFT EIN MESSER"
  54. 220 IFRND(TI)<.1THENPRINT"ER HAT DICH GETROFFEN DU BIST TOT":GOTO1100
  55. 230 PRINT"ER HAT DICH NICHT GETROFFEN":IFR>.9THENT=0
  56. 240 RETURN
  57. 250 PRINT"BUMM!!,DAS MONSTER HAT WIEDER EINEN GANG ZERSTOERT"
  58. 260 U=INT(RND(TI)*30)+1:X=INT(RND(TI)*4):B%(U,X)=46:RETURN
  59. 300 G=VAL(A$)/2-1:PRINTF$(G+1)""
  60. 305 IFB%(S,G)=0THENPRINT"KEIN WEG IN DIESE RICHTUNG":GOTO100
  61. 310 IFB%(S,G)=50THENPRINT"EINBAHNSTRASSE":GOTO100
  62. 312 IFB%(S,G)=49THENPRINTG$(7)"":GOTO100
  63. 314 IFB%(S,G)=48THENPRINTG$(8)"":GOTO100
  64. 316 IFB%(S,G)=47THENPRINT"EINE TUERE VERSPERRT DIER DEN WEGQ":GOTO100
  65. 318 IFB%(S,G)=46THENPRINT"DAS MONSTER HAT DIESEN WEG ZERSTOERT":GOTO100
  66. 320 IFS=8ANDC%(20)=0THENPRINT"DIE URNE IST ZU GROSS":GOTO100
  67. 330 IFB%(S,G)=7ANDC%(25)=0THENPRINT"GEHT NICHT":GOTO100
  68. 340 S=B%(S,G)
  69. 350 PRINT"DU BIST IM :"D$(S)"":PRINTG$(G%(S))"":GOSUB4010:PRINT"":GOTO100
  70. 400 X=0:U=S:GOTO410
  71. 405 X=S:U=0
  72. 410 GOSUB5000:IFR=1THEN100
  73. 415 PRINT"WAS ?";:GOSUB3000:P=ASC(A$)-65:PRINTB$(P)"":IFC%(P)<>UTHENPRINT"WIE BITTE":GOTO100
  74. 420 IFA$="W"ANDX=STHENC%(22)=25:PRINT"DAS WASSER VERSICKERT":GOTO100
  75. 425 IFS=15ANDA$="V"THENPRINT"VOGEL VERTREIBT VIPPER":GOSUB495:C%(21)=50:GOTO100
  76. 430 IFC%(10)<>00ANDA$="V"ANDX=0THENPRINT"GEHT NICHT":GOTO100
  77. 435 C%(P)=X:GOTO100
  78. 495 B%(15,0)=21:B%(15,1)=14:B%(15,2)=16:B%(14,3)=13:B%(29,3)=13:G%(15)=1:RETURN
  79. 500 IF C%(3)<>0THENPRINT"DU HAST KEIN DYNAMIT":GOTO100
  80. 510 C%(3)=50:PRINT"WO ?":GOSUB3000:IFVAL(A$)=0THEN510
  81. 520 R=VAL(A$)/2-1:PRINT"BUMM":IFS<>6OR(R<>3ANDR<>2)THENB%(S,R)=50:GOTO100
  82. 530 B%(6,2)=7:IFR=3THENB%(6,2)=0:B%(6,3)=5:B%(5,0)=6
  83. 540 GOTO100
  84. 600 IFS=26THENPRINT"TUERE VERROSTET":GOTO100
  85. 605 IFS=22ANDL=0THENGOSUB650
  86. 610 IFC%(20)<>0THENPRINT"WAS":GOTO100
  87. 620 IFC%(1)<>0THENPRINT"DU HAST NICHTS GENUG STARKES BEI DIR":GOTO100
  88. 630 PRINT"OFFEN PERLE IST DA":C%(15)=8:GOTO100
  89. 650 PRINT"KOMBINATION 5-ZEICHEN?":H$="":FORI=1TO5:GOSUB3000:H$=H$+A$:PRINTA$;:NEXT:PRINT""
  90. 660 IFH$=Q$THENPRINT"TRESOR OFFEN":L=1:C%(4)=26:RETURN
  91. 670 PRINT"FALSCHE KOMBINATION,DIE RICHTIGE FINDEST DU IM IRR":RETURN
  92. 700 PRINT"MIT BLOSSEN HAENDEN ?":GOSUB3000:IFA$="N"THEN100
  93. 710 IFS=15ANDG%(15)=7THENPRINT"VIPPER HAT DICH GETOETET":GOTO1100
  94. 720 IFS<>20ORG%(20)=5THENPRINT"WAS":GOTO100
  95. 730 PRINT"DU HAST DEN DRACHEN GESCHLAGEN":B%(20,1)=29:G%(20)=5:GOTO100
  96. 800 IFS=28THENS=1:GOTO350
  97. 810 IFS=1THENS=28
  98. 820 GOTO350
  99. 900 GOSUB4000:GOTO100
  100. 1000 IFC%(25)<>0THENPRINT"OHNE ZAUBERSTAB":GOTO100
  101. 1005 C%(25)=50
  102. 1010 PRINT"EIN GEIST ERSCHEINT UND FRAGT,WOHIN DU  WILLST ?2-BUCHSTABEN":GOSUB3000
  103. 1020 H$=A$:PRINTA$;:GOSUB3000:H$=H$+A$:PRINTA$
  104. 1025 FORI=1TO30:IFH$<>LEFT$(D$(I),2)THENNEXT:GOTO100
  105. 1030 S=I:GOTO350
  106. 1100 FORI=0TO25:IFC%(I)=1THENP=P+E%(I)
  107. 1110 NEXT:R=INT(P*10-N-H/10)
  108. 1120 PRINT"PUNKTE"R,"SCHRITTE"H:END
  109. 1200 FORI=0TO25:IFI<1ORI>4THENPRINTCHR$(I+65)"="F$(I):NEXT:GOTO100
  110. 1210 NEXT
  111. 1300 IFM<3THENPRINT"DU KOMMST INS HAUS FUER -50 PUNKTE":S=1:M=M+1:N=N+50:GOTO350
  112. 1310 PRINT"HILF DIR SELBER":GOTO100
  113. 1400 IFC%(5)=0ANDS=26THENPRINT"TUERE OFFEN":B%(26,3)=22:GOTO100
  114. 1410 PRINT"WAS":GOTO100
  115. 1500 IFC%(22)<>0ORS<>27THENPRINT"WAS":GOTO100
  116. 1510 C%(22)=25:IFZ=0THENPRINT"PFLANZE WAECHST UND RUFT WASSER":Z=1:GOTO100
  117. 1520 PRINT"PFLANZE WAECHST WEITER:GANG OEFFNET SICH IM W":B%(27,1)=26:GOTO100
  118. 1600 IFC%(0)<>0THENPRINT"OHNE AXT":GOTO100
  119. 1610 C%(0)=S:IFT=0THENPRINT"OK":GOTO100
  120. 1620 IFRND(TI)>0.4THENPRINT"ZWERG IST GETROFFEN":T=0:GOTO100
  121. 1640 PRINT"ZWERG VERFEHLT":GOTO100
  122. 3000 GETA$:IFA$=""THEN3000
  123. 3020 RETURN
  124. 4000 B=0:GOTO4020
  125. 4010 B=S
  126. 4020 PRINT"HIER HAT ES :":FORI=0TO25:IFC%(I)=BTHENPRINTB$(I)
  127. 4030 NEXT:RETURN
  128. 5000 FORI=0TO25:IFC%(I)=0THENR=R+1
  129. 5010 NEXT:IFR<7ORX=STHENR=0:RETURN
  130. 5020 PRINT"DU KANNST NICHTS MEHR TRAGEN":R=1:RETURN
  131.