home *** CD-ROM | disk | FTP | other *** search
/ Brotikasten / BROTCD01.iso / geos / geos67.d64 / geocheck (.txt) < prev    next >
Commodore BASIC  |  1995-08-15  |  2KB  |  62 lines
  1. 100 REM *** GEOCHECK ***
  2. 120 REM *** AUS 64ER SONDERHEFT 28 ***
  3. 130 REM *** ALLES UEBER GEOS ***
  4. 140 :
  5. 150 CLR:DIM IB$(256)
  6. 160 PRINTCHR$(14)"[147]GEO[195]HECK     (INSTALLIERT [199][197][207][211]-[204]ISTINGS)"
  7. 170 PRINT"  VON [198]LORIAN [205]UELLER ([205]ARKT&[212]ECHNIK)"
  8. 210 PRINT"[194]ITTE EINE [196]ISKETTE MIT [208]ROGRAMM  UND"
  9. 220 PRINT"'CHECK SCRAP' EINLEGEN."
  10. 230 PRINT"<SHIFT>":POKE653,0:WAIT 653,1:PRINT"[147]"
  11. 240 OPEN1,8,0,"CHECK SCRAP,P,R"
  12. 250 GET#1,FG$,DY$,DM$,DD$,DH$,MI$,B1$,B2$
  13. 251 FG=ASC(FG$+CHR$(0)):DY=ASC(DY$+CHR$(0)):DM=ASC(DM$+CHR$(0))
  14. 252 DD=ASC(DD$+CHR$(0)):DH=ASC(DH$+CHR$(0)):MI=ASC(MI$+CHR$(0))
  15. 253 B1=ASC(B1$+CHR$(0)):B2=ASC(B2$+CHR$(0))
  16. 260 PRINT"GEOS-FILETYP #"FG
  17. 270 IFFG=5THENPRINT"= HILFSMITTEL (DESK ACCESSORY)"
  18. 280 IFFG=6THENPRINT"= ANWENDUNG (APPLICATION)"
  19. 290 IFFG=9THENPRINT"DRUCKERTREIBER"
  20. 300 PRINT"DATUM:"DD"."DM"."1900+DY
  21. 310 PRINT"UHRZEIT:"DH"UHR"MI
  22. 320 :
  23. 330 FORF=1TO256:GET#1,IB$(F)
  24. 333 IFIB$(F)=""THENIB$(F)=CHR$(0)
  25. 335 NEXT
  26. 340 CLOSE1
  27. 350 PRINT"[206]UN KANN DAS [200]AUPTPROGRAMM MIT ALLEN"
  28. 360 PRINT"[199][197][207][211]-SPEZIFISCHEN [196]ATEN VERSEHEN WERDEN."
  29. 370 PRINT"[196][193][211] [200][193][213][208][212][208][210][207][199][210][193][205][205][160][205][213][211][211] [211][201][195][200] [201][205][160][196][201][210][197][195][212][207][210][217]"
  30. 380 PRINT"[193][206] [193][204][204][197][210][197][210][211][212][197][210][146] [208][207][211][201][212][201][207][206] [194][197][198][201][206][196][197][206]!"
  31. 390 PRINT"[215]EITER = <[210][197][212][213][210][206]>, <[210][213][206]/[211][212][207][208]> = [193]BBRUCH"
  32. 400 POKE198,0
  33. 410 GETA$:IFA$<>CHR$(13)THEN410
  34. 420 PRINT"JETZT WIRD DER INFO-SEKTOR AUF DISKETTE"
  35. 430 PRINT"UNTERGEBRACHT."
  36. 440 OPEN1,8,15,"I":OPEN2,8,2,"#"
  37. 450 IT=1:IS=0
  38. 460 PRINT#1,"B-A 0";IT;IS:INPUT#1,A,B$,IT,IS
  39. 470 IFA=0THENIT=1:IS=0:GOTO510
  40. 480 IFIT=18THENIT=19:IS=0:PRINT#1,"B-A 0";IT;IS:INPUT#1,A,B$,IT,IS
  41. 490 IFA=65AND IT=0THENPRINT"KEIN PLATZ FUER INFO-BLOCK":STOP
  42. 500 IFA=65THENPRINT#1,"B-A 0";IT;IS
  43. 510 PRINT"INFO-BLOCK KOMMT AUF SPUR"IT"/SEKTOR"IS
  44. 520 PRINT#1,"B-P 2 0":FORF=1TO256
  45. 525 IFIB$(F)<>""THENPRINT#2,IB$(F);:GOTO527
  46. 526 PRINT#2,CHR$(0);
  47. 527 NEXT
  48. 530 PRINT#1,"U2:2 0";IT;IS
  49. 540 PRINT#1,"U1 2 0 18 1"
  50. 550 PRINT#1,"B-P 2 21":PRINT#2,CHR$(IT);CHR$(IS);CHR$(0);CHR$(FG);
  51. 560 PRINT#2,CHR$(DY);CHR$(DM);CHR$(DD);CHR$(DH);CHR$(MI);
  52. 570 PRINT#1,"U2:2 0 18 1"
  53. 572 PRINT#1,"U1 2 0 17 0":PRINT#1,"B-P 2 2":PRINT#2,CHR$(B1);CHR$(B2);
  54. 573 PRINT#1,"U2 2 0 17 0"
  55. 580 CLOSE1:CLOSE2
  56. 590 PRINT"INSTALLATION FERTIG. JETZT UNTER DESKTOP"
  57. 600 PRINT"DIE FUNKTION 'VALIDATE' (AUFRAEUMEN)"
  58. 610 PRINT"ANWAEHLEN UND DIE INSTALLIERTE DATEI"
  59. 620 PRINT"UMKOPIEREN."
  60. 630 PRINT"GEOCHECK"
  61. 640 END
  62.