Fresh Fish 2/FFMCD02.bin/new/comm/fido/spot/rexx/areafixman.spot

Text File | 1993-12-21 | 6KB | 207 lines

/*
 *
 * AFM: AreaFix Manager © 1993 PSR Software
 *          Makes AreaFix calls much simpler!
 * Freeware.  May not be altered or modified without permission!
 *
 * $VER: AreaFixMan.spot v2.6 (19.9.93)
 *
 */

PREF = 'AreaFixMan.prefs'
FILE = 'ENV:' || PREF
FILESAVE = 'ENVARC:' || PREF
TEMP = 'T:Spot.AreaFixMan.temp'
LF = '0d'x

COUNT=0

Address SPOT
Options Results

'IsIconified'
If RC=0 Then 'UnIconify'

'IsAreaList'
If RC=0 Then Do
   'RequestNotify PROMPT "Do not use from Area List"'
   Exit
End

'GetAreaName'
REAL_NAME=Result

If ~(Left(REAL_NAME,3)='NET') Then Do
   Do Forever
      'RequestResponse PROMPT "This is not a matrix area.'LF'Do you wish to proceed?" GADGETS "_Continue|_Help|_Abort"'
      If RC=0 Then Exit
      If RC=1 Then Leave
      If RC=2 Then 'RequestNotify PROMPT "Messages to AreaFix should be in your Matrix areas.'LF'If you send it in any other area, other people may see'LF'your password and assume your identity."'
   End
End

If Open('Prefs',FILE,'r') Then Do
   FORMAT=ReadLn('Prefs')
   If ~(FORMAT='FORMAT 2.6') Then Do
      'RequestNotify TITLE "Sorry!" PROMPT "Prefs file is not compatible with this version of AFM.'LF'Delete the prefs files and set up again...Sorry!"'
      'RequestResponse TITLE "Delete?" PROMPT "Auto delete prefs files?" GADGETS "Delete|Cancel"'
      If RC=1 Then Do
         Call Close('Prefs')
         Address Command
         Delete "ENV:AreaFixMan.prefs"
         Delete "ENVARC:AreaFixMan.prefs"
         Address SPOT
         'RequestNotify PROMPT "Call AFM again now."'
         Exit
         End
      If RC=0 Then Exit
      End
   Do Until Eof('Prefs')
      AREA=Strip(ReadLn('Prefs'),'L')
      ADDRESS=Strip(ReadLn('Prefs'),'L')
      PASS=Strip(ReadLn('Prefs'),'L')
      AREAFIX=Strip(ReadLn('Prefs'),'L')

      COMMENT=Strip(ReadLn('Prefs'),'L')
      If Length(COMMENT)=0 Then Do
         COMMENT='Options'
         End
      Else Do
         /* Extra prefs will be inserted here as they are though of! */
         DUMMY=ReadLn('Prefs')
      End

      If AREA=REAL_NAME Then Do
         Call Close('Prefs')
         Signal DOAF
         End
      End
   Call Close('Prefs')
   If ~Open('Prefs',FILE,'a') Then Do
      'RequestNotify PROMPT "Cannot open prefs file: 'FILE'."'
      Exit
      End
   End
Else If ~Open('Prefs',FILE,'w') Then Do
      'RequestNotify PROMPT "Cannot create prefs file: 'FILE'."'
      Exit
      End
   Else 'RequestNotify PROMPT "New prefs file has been created"'

'RequestString TITLE "Boss" PROMPT "Enter the address of the boss'LF'for this area.  i.e 2:253/516"'
If RC>0 Then Exit
ADDRESS=Result

'RequestString TITLE "Password" PROMPT "Enter your password for this boss."'
If RC>0 Then Exit
PASS=Result

'RequestString TITLE "AreaFix" PROMPT "Enter name of the AreaFix handler'LF'for this boss or leave unaltered." DEFAULT "Areafix"'
If RC>0 Then Exit
AREAFIX=Result

'RequestString TITLE "Comment" PROMPT "Enter optional comment or reminder for this area"'
COMMENT=Result
If Length(COMMENT)=0 Then COMMENT="Options"

/* Further prefs will be added here as they are thought of */

'RequestResponse PROMPT "You have changed the prefs." GADGETS "_Save|_Use|_Cancel"'


If ~(RC=0) Then Do
   Call WriteLn('Prefs','FORMAT 2.6')
   Call WriteLn('Prefs',REAL_NAME)
   Call WriteLn('Prefs',ADDRESS)
   Call WriteLn('Prefs',PASS)
   Call WriteLn('Prefs',AREAFIX)
   Call WriteLn('Prefs',COMMENT)
   Call WriteLn('Prefs','')
   Call Close('Prefs')
   If RC=1 Then Address Command 'Copy 'FILE FILESAVE
   End

DOAF:

Address Command 'Delete >NIL: "Ram:T/Spot.AreaFixMan.temp"'

If ~Open('File','RAM:T/Spot.AreaFixMan.temp','w') Then Do
   'RequestNotify PROMPT "Cannot open temporary file!"'
   Exit
End

Do Forever

   TEXT=''
   If COUNT>0 Then Do c=1 To COUNT
      TEXT=TEXT || ENTRY.c || LF
      End

   If COUNT<15 Then Do
      If COUNT>0 Then 'RequestResponse TITLE "'COMMENT'" PROMPT "'TEXT'" GADGETS "_Attach|_Detach|_Erase|_OKAY|_CANCEL"'
      Else 'RequestResponse TITLE "'COMMENT'" PROMPT "'TEXT'" GADGETS "_Attach|_Detach|_OKAY|_CANCEL"'
      End
   Else 'RequestResponse TITLE "'COMMENT'" PROMPT "'TEXT'" GADGETS "_Erase|_OKAY|_CANCEL"'

   If RC=0 Then Exit

   If RC=1 Then Do Forever
      If COUNT>14 Then RC=3
      If COUNT>14 Then Break
      'RequestString TITLE "Attach" PROMPT "Enter area to attach to.'LF'Select CANCEL for menu."'
      If RC>0 Then Break

      ATTATCH=Result
      If Length(ATTATCH)=0 Then Break

      COUNT=COUNT+1
      ENTRY.COUNT='+' || Upper(ATTATCH)
      If COUNT=15 Then Break
      End

   If RC=2 Then Do Forever
      If COUNT>14 Then RC=4
      If COUNT>14 Then Break
      'RequestString TITLE "Detach" PROMPT "Enter area to detach from.'LF'Select CANCEL for menu."'
      If RC>0 Then Break

      DETATCH=Result
      If Length(DETATCH)=0 Then Break

      COUNT=COUNT+1
      ENTRY.COUNT='-' || Upper(DETATCH)
      If COUNT=15 Then Break
      End

   If RC=3 Then Do
     If COUNT=0 Then Do
        RC=4
        End
     Else COUNT=COUNT-1
     End

   If RC=4 Then Do
      If COUNT>0 Then Do c=1 TO COUNT
         Call WriteLn('File',ENTRY.c)
         End
      Call WriteLn('File','--- AFM')
      Call Close('File')

      'RequestResponse TITLE "Arealist etc." PROMPT "Request Arealist?" GADGETS "_Yes|_Other|_No"'
      If RC=1 Then PASS=PASS || ' -L'
      If RC=2 Then Do
         TEMPPASS=PASS
         Do Forever
            'RequestString TITLE "Other options" PROMPT "Enter options eg. -L -H" DEFAULT "'PASS'"'
            If RC>0 Then Exit
            PASS=Result
            Break
            End
         End
      'Write TO "'AREAFIX'" TOADDR "'ADDRESS'" SUBJECT "'PASS'" FILE "'TEMP'" REFLOW=OFF NOSIG NOEDIT NOGUI'
      'LastMessage'
      Exit
      End

   End