home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 2 / FFMCD02.bin / new / text / font / metafont / inputs / cm / greeku.mf < prev    next >
Encoding:
Text File  |  1993-12-21  |  11.5 KB  |  256 lines
  1. % Computer Modern Greek caps, analogous to the uppercase Roman letters.
  2.  
  3. % Character codes \0000 through \0012 are generated,
  4. % using plain \TeX's standard text font layout conventions.
  5.  
  6. cmchar "Uppercase Greek Gamma";
  7. beginchar(oct"000",11u#-width_adj#,cap_height#,0);
  8. italcorr cap_height#*slant-beak_jut#-.25u#;
  9. adjust_fit(cap_serif_fit#,0);
  10. h:=vround(h-stem_corr);
  11. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  12. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  13. filldraw stroke z1e--z2e; % stem
  14. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  15. top y3r=h; x3=x1; rt x4r=hround(w-.75u); y4=good.y(y3l-beak)-eps;
  16. arm(3,4,e,beak_darkness,beak_jut);  % arm and beak
  17. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  18.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,1.25cap_jut); fi  % lower serif
  19. math_fit(0,ic#-2.5u#); penlabels(1,2,3,4); endchar;
  20.  
  21. cmchar "Uppercase Greek Delta";
  22. beginchar(oct"001",15u#,cap_height#,0);
  23. adjust_fit(0,0);
  24. numeric left_stem,alpha;
  25. left_stem=cap_hair if hefty: -3stem_corr fi;
  26. x1l=w-x4r=.75u; y1=y4=0;
  27. x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
  28. alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  29. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  30. penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
  31. fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle;  % triangle
  32. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  33. y5=y6=cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
  34. if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  35.  unfill z0+.5right{down}...{z4-z3}z6--z5{z2-z1}
  36.   ...{up}z0+.5left--cycle; % counter
  37. else: unfill z0--z5--z6--cycle; fi  % counter
  38. penlabels(0,1,2,3,4,5,6); endchar;
  39.  
  40. cmchar "Uppercase Greek Theta";
  41. beginchar(oct"002",14u#,cap_height#,0);
  42. italcorr .7cap_height#*slant-.5u#;
  43. adjust_fit(0,0);
  44. numeric light_curve; light_curve=hround(cap_curve-2stem_corr);
  45. penpos1(vair,90); penpos3(vround(vair+.5vair_corr),-90);
  46. penpos2(light_curve,180); penpos4(light_curve,0);
  47. if monospace: x2r=hround 1.5u;
  48.  interim superness:=sqrt superness;  % make |"O"|, not |"0"|
  49. else: x2r=hround u; fi
  50. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y2=y4=.5h-vair_corr; y3r=-o;
  51. penstroke pulled_super_arc.e(1,2)(.5superpull)
  52.  & pulled_super_arc.e(2,3)(.5superpull)
  53.  & pulled_super_arc.e(3,4)(.5superpull)
  54.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  % bowl
  55. pickup crisp.nib; pos5(cap_vstem,90); pos6(cap_vstem,90);
  56. lft x5=w-rt x6=hround(x2l+u)+1; y5=y6=.5[y1l,y3l];
  57. filldraw stroke z5e--z6e;  % bar
  58. if serifs: pos7(hair,0); pos8(hair,0); pos9(hair,0); pos10(hair,0);
  59.  x7l=x8l=x5; x9r=x10r=x6;
  60.  y7-y5r=y9-y6r=y5l-y8=y6l-y10=vround .05h;
  61.  filldraw stroke z7e--z8e;  % left serif
  62.  filldraw stroke z9e--z10e; fi  % right serif
  63. math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#);
  64. penlabels(1,2,3,4,5,6,7,8,9,10); endchar;
  65.  
  66. cmchar "Uppercase Greek Lambda";
  67. beginchar(oct"003",12u#,cap_height#,0);
  68. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  69. numeric left_stem,outer_jut,alpha;
  70. left_stem=cap_hair if hefty: -3stem_corr fi;
  71. outer_jut=.7cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
  72. x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
  73. alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  74. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  75. penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
  76. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  77. if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  78.   fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  79.     --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  80.     ...{up}z0+.5left--cycle; % left and right diagonals
  81. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  82.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  83. if serifs: numeric inner_jut; pickup tiny.nib;
  84.  prime_points_inside(1,2); prime_points_inside(4,3);
  85.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  86.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  87.  dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark);  % left serif
  88.  dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi  % right serif
  89. penlabels(0,1,2,3,4,5,6); endchar;
  90.  
  91. cmchar "Uppercase Greek Xi";
  92. beginchar(oct"004",12u#,cap_height#,0);
  93. italcorr cap_height#*slant-.35u#;
  94. adjust_fit(0,0);
  95. h:=vround(h-2stem_corr);
  96. numeric shaved_stem; shaved_stem=hround .9[vair,.85cap_stem];
  97. if shaved_stem<crisp.breadth: shaved_stem:=crisp.breadth; fi
  98. pickup crisp.nib; pos1(shaved_stem,90); pos2(hair,0);
  99. top y1r=h; x1=.5w; rt x2r=hround(w-.85u); y2=good.y(y1l-4/9beak)-eps;
  100. arm(1,2,a,.4beak_darkness,.3beak_jut);  % upper right arm and beak
  101. pos3(hair,180); x3=w-x2; y3=y2;
  102. arm(1,3,b,.4beak_darkness,-.3beak_jut);  % upper left arm and beak
  103. pos4(shaved_stem,-90); pos5(hair,0);
  104. bot y4r=0; x4=.5w; rt x5r=hround(w-.75u); y5=good.y(y4l+.5beak)+eps;
  105. arm(4,5,c,.4beak_darkness,.3beak_jut);  % lower right arm and beak
  106. pos6(hair,180); x6=w-x5; y6=y5;
  107. arm(4,6,d,.4beak_darkness,-.3beak_jut);  % lower left arm and beak
  108. pos7(shaved_stem,90); pos8(shaved_stem,90);
  109. lft x7=w-rt x8=hround if serifs: 2.5 else: 2 fi\\ u;
  110. top y7r=top y8r=vround(.52h+.5shaved_stem);
  111. filldraw stroke z7e--z8e;  % middle bar
  112. if serifs: numeric xjut;
  113.  if bot y2>top y7r+.75cap_jut: xjut=.5cap_jut;
  114.  else: bot y2=top y7r+1.5xjut; fi
  115.  pos11(hair,0); pos12(hair,0); y11=y12;
  116.  pos13(hair,0); pos14(hair,0); y13=y14;
  117.  lft x11l=lft x13l=w-rt x12r=w-rt x14r=hround 2.5u;
  118.  top y11-bot y13=shaved_stem+2xjut; .5[y11,y13]=y7;
  119.  filldraw stroke z11e--z13e; filldraw stroke z12e--z14e; fi  % middle serifs
  120. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,11,12,13,14); endchar;
  121.  
  122. cmchar "Uppercase Greek Pi";
  123. beginchar(oct"005",13u#+width_adj#,cap_height#,0);
  124. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  125. adjust_fit(cap_serif_fit#,cap_serif_fit#); pickup tiny.nib;
  126. h:=vround(h-stem_corr);
  127. pos1(cap_stem,0); pos2(cap_stem,0); pos3(cap_stem,0); pos4(cap_stem,0);
  128. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  129. top y1=top y3=h; bot y2=bot y4=0;
  130. filldraw stroke z1e--z2e; % left stem
  131. filldraw stroke z3e--z4e; % right stem
  132. penpos5(cap_bar,90); penpos6(cap_bar,90);
  133. x5=x1; x6=x3; y5r=y6r=h;
  134. fill stroke z5e--z6e;  % bar
  135. if serifs: numeric inner_jut;
  136.  if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
  137.  else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
  138.  nodish_serif(1,2,a,1/3,cap_jut,b,1/3,eps);  % upper left serif
  139.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); % lower left serif
  140.  nodish_serif(3,4,e,1/3,eps,f,1/3,cap_jut);  % upper right serif
  141.  dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi  % lower right serif
  142. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  143.  
  144. cmchar "Uppercase Greek Sigma";
  145. beginchar(oct"006",13u#,cap_height#,0);
  146. italcorr cap_height#*slant-beak_jut#-.5u#;
  147. adjust_fit(0,0);
  148. numeric bot_arm_thickness;
  149. bot_arm_thickness=Vround .25[slab,cap_vstem];
  150. pickup tiny.nib; lft x1l=hround u; x1l=x2l=x4l;
  151. top y1=h; bot y2=h-slab-eps; bot y4=0; x3l-x1l=4/11(w-2u); y3=.5h;
  152. numeric alpha[]; alpha1=((x3l-x1l)++(y2-y3))/(y2-y3);
  153. penpos1(alpha1*(cap_stem-tiny),0); penpos2(alpha1*(cap_stem-tiny),0);
  154. penpos3(alpha1*(cap_stem-tiny),0);
  155. alpha2=diag_ratio(1,cap_hair-tiny,y3-y4,x3r-x4l);
  156. penpos4(alpha2*(cap_hair-tiny),0);
  157. z0=whatever[z2l,z3l]=z4l+whatever*(z3r-z4r);
  158. filldraw z1l--z2l--z0--z4l--z4r--z3r--z2r--z1r--cycle;  % diagonals
  159. pickup crisp.nib; pos5(slab,90); pos6(hair,0);
  160. top y5r=h; x5=x1; rt x6r=hround(w-u); y6=good.y(y5l-beak)-eps;
  161. arm(5,6,a,beak_darkness,beak_jut);  % upper arm and beak
  162. pos7(bot_arm_thickness,-90); pos8(hair,0);
  163. bot y7r=0; z7l=whatever[z4,z3]; x7r:=x4; x8=x6; y8=good.y(y7l+beak)+eps;
  164. arm(7,8,b,beak_darkness,beak_jut);  % lower arm and beak
  165. math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8); endchar;
  166.  
  167. cmchar "Uppercase Greek Upsilon";
  168. beginchar(oct"007",14u#,cap_height#,0);
  169. italcorr .8cap_height#*slant-.5u#;
  170. adjust_fit(0,0);
  171. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  172. lft x1l=lft x2l=hround(.5w-.5cap_stem); y1=.5h; bot y2=0;
  173. filldraw stroke z1e--z2e; % stem
  174. penpos3(.6cap_stem,0); penpos4(.75cap_curve,90); penpos5(cap_hair,180);
  175. z3l=lft z1l; x5r=hround u; y5=bot .8h; x4=.61803[x3l,x5l]; y4r=h+o;
  176. penpos5'(cap_hair,180); x5'=x5; y5'=h;
  177. fill z3r{up}...z4r{left}...{down}diag_end(5'r,5r,1,1,5l,5'l){up}
  178.  ...{right}z4l...{down}z3l--cycle;  % left arc
  179. penpos6(.6cap_stem,0); penpos7(.75cap_curve,-90); penpos8(cap_hair,-180);
  180. z6r=rt z1r; x8=w-x5; y8=y5; x7=w-x4; y7=y4;
  181. penpos8'(cap_hair,-180); x8'=x8; y8'=h;
  182. fill z6r{up}...z7r{right}...{down}diag_end(8'r,8r,1,1,8l,8'l){up}
  183.  ...{left}z7l...{down}z6l--cycle;  % right arc
  184. if serifs: dish_serif(2,1,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut); fi  % serif
  185. math_fit(-.8cap_height#*slant-.5u#,ic#-2.5u#);
  186. penlabels(1,2,3,4,5,6,7,8); endchar;
  187.  
  188. cmchar "Uppercase Greek Phi";
  189. beginchar(oct"010",13u#,cap_height#,0);
  190. italcorr .5cap_height#*slant-.5u#;
  191. adjust_fit(0,0);
  192. numeric shaved_stem,light_curve;
  193. shaved_stem=cap_stem-hround 2stem_corr;
  194. light_curve=cap_curve-hround stem_corr;
  195. pickup tiny.nib; pos1(shaved_stem,0); pos2(shaved_stem,0);
  196. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  197. filldraw stroke z1e--z2e; % stem
  198. penpos3(vair,90); penpos5(vair,-90);
  199. penpos4(light_curve,180); penpos6(light_curve,0);
  200. x4r=hround u; x6r=w-x4r; x3=x5=.5w;
  201. y3r=vround(.85h if serifs:-slab fi); y4=y6=.5[y3,y5];
  202. y5r=vround(.15h if serifs:+slab fi);
  203. penstroke pulled_arc.e(3,4) & pulled_arc.e(4,5)
  204.  & pulled_arc.e(5,6) & pulled_arc.e(6,3) & cycle;  % bowl
  205. if serifs: dish_serif(1,2,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut);  % upper serif
  206.  dish_serif(2,1,c,1/3,1.25cap_jut,d,1/3,1.25cap_jut); fi  % lower serif
  207. math_fit(-.5cap_height#*slant-.5u#,ic#); penlabels(1,2,3,4,5,6); endchar;
  208.  
  209. cmchar "Uppercase Greek Psi";
  210. beginchar(oct"011",14u#,cap_height#,0);
  211. italcorr .8cap_height#*slant-.5u#;
  212. adjust_fit(0,0);
  213. numeric shaved_stem;
  214. shaved_stem=cap_stem-hround 2stem_corr;
  215. pickup tiny.nib; pos1(shaved_stem,0); pos2(shaved_stem,0);
  216. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  217. filldraw stroke z1e--z2e; % stem
  218. pos3(shaved_stem,-180); pos4(shaved_stem,-180);
  219. pos5(vair,-90); x5=x1; bot y5r=vround(.15h if serifs:+slab fi);
  220. pos6(shaved_stem,0); pos7(shaved_stem,0);
  221. lft x3r=hround u; x7=w-x3; lft x4r=hround(3u-.5shaved_stem); x6=w-x4;
  222. pos3'(vair,90); pos7'(vair,90); z3'r=z3r; z7'r=z7r;
  223. y3=y7; y4=y6=.6h; y3=good.y(y3+.84h if serifs:-slab fi-y3');
  224. interim superness:=more_super;
  225. filldraw z3'l{right}...z4r{down} & super_arc.r(4,5)
  226.  & super_arc.r(5,6) & z6r{up}...z7'l{right}
  227.  --z7r---z7l...z6l{down} & super_arc.l(6,5)
  228.  & super_arc.l(5,4) & z4l{up}...z3l---z3r--cycle;  % stroke
  229. if serifs: dish_serif(1,2,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut);  % upper serif
  230.  dish_serif(2,1,c,1/3,1.25cap_jut,d,1/3,1.25cap_jut); fi  % lower serif
  231. math_fit(-.8cap_height#*slant-.5u#,.4cap_height#*slant-1.25u#);
  232. penlabels(1,2,3,4,5,6,7); endchar;
  233.  
  234. cmchar "Uppercase Greek Omega";
  235. beginchar(oct"012",13u#,cap_height#,0);
  236. italcorr .75cap_height#*slant-.5u#;
  237. adjust_fit(0,0);
  238. pickup tiny.nib; pos1(vair,90); pos2(cap_curve,180);
  239. pos3(vair,180); pos4(cap_curve,0); pos5(vair,0);
  240. x1=.5w; top y1r=h+o; lft x2r=hround u; y2=y4=2/3h; x4=w-x2;
  241. rt x3l=hround(1/3(w+.5u)+.5hair); bot y3=bot y5=0; x5=w-x3;
  242. filldraw stroke z3e{up}...{up}z2e
  243.  & pulled_super_arc.e(2,1)(.5superpull)
  244.  & pulled_super_arc.e(1,4)(.5superpull)
  245.  & z4e{down}...{down}z5e;  % bowl
  246. numeric arm_thickness; path p; p=z3{up}...{up}z2;
  247. arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
  248. pickup crisp.nib; pos6(arm_thickness,-90); pos7(fudged.hair,-180);
  249. bot y6r=0; x6=x3; lft x7r=hround .8u; y7=good.y(y6l+.5beak)+eps;
  250. (x,y)=p intersectionpoint((0,y6l)--(w,y6l)); x6l:=x;
  251. arm(6,7,a,.5beak_darkness,-1.2beak_jut);  % left arm and beak
  252. pos8(arm_thickness,-90); pos9(fudged.hair,0);
  253. y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
  254. arm(8,9,b,.5beak_darkness,1.2beak_jut);  % right arm and beak
  255. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
  256.