Fresh Fish 4/FreshFish_May-June1994.bin/bbs/amigalib/d998/screenselect.lha/ScreenSelect/ScreenSelect.Install

Text File | 1994-04-05 | 6.0 KB | 323 lines

(set #screenselectcopyhelp (cat
    "This is the directory you want ScreenSelect program "
    "to be installed. If you want ScreenSelect always to start "
    "in boot up process then you should install it to "
    "WBStartup-directory.") )


(set #tooltypeshelp (cat
    "These are the commodity tooltypes for "
    "ScreenSelect. If you have made the "
    "installation to WBStartup then you should "
    "set the DONOTWAIT tooltype.\n") )

(set #screenselectprefscopyhelp (cat
    "This is the directory you want ScreenSelect "
       "Preferences setting program to be installed. "
       "For maximum consistency with system preferences "
       "programs you should install it to Prefs-directory.") )

(set #doccopyhelp (cat
    "Select documentation files for ScreenSelect and "
    "ScreenSelectPrefs programs you want to be installed." )
)

(set #stickyask (cat
    "Do you want to install StickySelect?" )
)

(set #cataloghelp (cat
    "Select language catalog files you want to install. "
    "These langauge dirs along with catalog files will "
    "be installed to your LOCALE: directory. "
    "English is a default language." )
)

(set ver (/ (getversion "workbench.library") 65536) )


(complete 0)

(set #destination
        (askdir
            (prompt "Where to install ScreenSelect program?")
            (help #screenselectcopyhelp )
            (default "SYS:WBStartup/")
        )
)

(set @default-dest #destination)

(message "Copy ScreenSelect to " #destination " directory?\n")

(copyfiles (source "ScreenSelect")
           (dest #destination)
           (infos)
)

(complete 30)


(set #tooltypeopts
        (askoptions
            (prompt "Which tooltypes you want to set for ScreenSelect\n")
            (help #tooltypeshelp)
            (choices "CX_POPUP" "CX_PRI" "CX_POPKEY")
            (default 0)
        )
)

(if (IN #tooltypeopts 0)
        (tooltype
            (dest
                    (tackon
                        #destination "ScreenSelect")
                    )
            (settooltype "CX_POPUP" "YES")
            (noposition) )
        (tooltype
            (dest
                    (tackon
                        #destination "ScreenSelect")
                    )
            (settooltype "CX_POPUP" "NO")
            (noposition) ) )

(if (IN #tooltypeopts 1)
        (tooltype
            (dest
                    (tackon
                        #destination "ScreenSelect")
                    )
            (settooltype "CX_PRI"
                    (cat
                            (asknumber
                                    (prompt "ScreenSelect commodity priority?")
                                    (help "")
                                    (range -127 127)
                                    (default 0)
                            )
                    )
            )
            (noposition)
        )
)

(if (IN #tooltypeopts 2)
        (tooltype
            (dest (tackon #destination "ScreenSelect") )
            (settooltype "CX_POPKEY"
                    (askstring
                        (prompt "ScreenSelect popkey string?")
                        (help
                                (cat
                                    "You can also set popkey string with\n"
                                    "ScreenSelectPrefs program.")
                                )
                        (default "shift esc")
                    )
            )
            (noposition)
        )
)

(complete 50)

(set #prefs
        (askdir
            (prompt "Where to install ScreenSelectPrefs program?")
            (help #screenselectprefscopyhelp)
            (default "SYS:Prefs/")
        )
)

(message "Copy ScreenSelectPrefs to " #prefs " directory?\n")

(copyfiles (source "ScreenSelectPrefs")
           (dest #prefs)
           (infos) )

(set #prefsinrightplace (IN (exists "SYS:Prefs/ScreenSelectPrefs" (noreq)) 0))

(if (= 0 #prefsinrightplace)
        (tooltype (dest (tackon #destination "ScreenSelect"))
                  (settooltype "PREFSPROGRAM" (tackon #prefs "ScreenSelectPrefs"))
                  (noposition)
        )
)

(complete 70)

(if (= 1 (askbool
            (prompt #stickyask)
            (help "")
            (default 1)
         )
    )
    (
        (set #stickydir
            (askdir
                (prompt "Where to install StickySelect program?")
                (help "")
                (default "C:")
            )
        )

        (copyfiles
            (source "StickySelect/StickySelect")
            (dest #stickydir)
            (infos)
        )
    )
)


(complete 80)

(set #docfiles
        (askoptions
            (prompt "Which document files you want to install?\n")
            (help #doccopyhelp)
            (choices "ScreenSelect.doc   - ASCII document."
                     "ScreenSelect.guide - AmigaGuide document."
                     "ScreenSelect.dvi   - Document in DVI format."
                     )
            (default 2)
        )
)

(if (= 0 #docfiles)
        (message "No document files installed!\n")
        (
            (set #docdir
                    (askdir
                        (prompt "Where to install document files?")
                        (help "" )
                        (default "WORK:")
                    )
            )

            (complete 83)

            (if (IN #docfiles 0)
                (
                    (copyfiles
                            (source "Docs/ScreenSelect.doc")
                               (dest #docdir)
                               (infos)

                    )

                    (set #docfilename
                            (tackon #docdir "ScreenSelect.doc")
                    )

                    (if (> ver 38)
                            (tooltype
                                (dest #docfilename)
                                (setdefaulttool "MultiView")
                                (noposition)
                            )
                            (tooltype
                                (dest #docfilename)
                                (setdefaulttool "More")
                                (noposition)
                            )
                    )
                )
            )

            (complete 86)

            (if (IN #docfiles 1)
                (
                    (copyfiles
                            (source "Docs/ScreenSelect.guide")
                               (dest #docdir)
                               (infos)

                    )

                    (set #docfilename
                            (tackon #docdir "ScreenSelect.guide")
                    )

                    (if (> ver 38)
                            (tooltype
                                (dest #docfilename)
                                (setdefaulttool "MultiView")
                                (noposition)
                            )
                            (tooltype
                                (dest #docfilename)
                                (setdefaulttool "AmigaGuide")
                                (noposition)
                            )
                    )
                )
            )

            (complete 88)

            (if (IN #docfiles 2)
                    (copyfiles
                            (source "Docs/ScreenSelect.dvi")
                               (dest #docdir)
                               (infos)

                    )
            )
        )
)

(complete 90)

(set #catalogs
        (askoptions
            (prompt "Which additional languages you want to install?\n")
            (help #cataloghelp)
            (choices "suomi   - Finnish."
                     "svenska - Swedish." )
            (default 3)
        )
)

(if (= 0 #catalogs)
        (message "No additional language files installed!\n")
        (
            (set #catalogdir "LOCALE:" )
            (set #suomidir (cat #catalogdir "suomi/") )
            (set #svenskadir (cat #catalogdir "svenska/") )

            (complete 94)

            (if (IN #catalogs 0)
                (
                    (copyfiles
                            (source "Catalogs/suomi/screenselect.catalog")
                               (dest #suomidir )
                               (infos)

                    )
                )
            )

            (complete 97)

            (if (IN #catalogs 1)
                (
                    (copyfiles
                            (source "Catalogs/svenska/screenselect.catalog")
                               (dest #svenskadir )
                               (infos)

                    )
                )
            )
        )
)


(complete 100)