home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 5 / FreshFish_July-August1994.bin / bbs / dev / rkrm.lha / RKRM / Clipboard / hookface.a < prev    next >
Encoding:
Text File  |  1992-09-03  |  4.0 KB  |  114 lines
  1. *
  2. * Copyright (c) 1992 Commodore-Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Commodore-Amiga, Inc. for 
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Commodore Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. *
  27. ****************************************************************************
  28. *
  29. *        Hookface.asm
  30. *        assembly routines for Chtest
  31. *
  32. *        Assemble with Adapt  hx68 hookface.a to hookface.o
  33. *
  34. *        Link with Changehook_Test.o as shown in Changehook_Test.c header
  35. *
  36. ****************************************************************************
  37. *
  38. *       CSECT   hookface                 ;SAS/Lattice ASM command needs this
  39. *
  40.         INCDIR  'include:'               ;HX68 assembler needs this
  41.         INCLUDE 'exec/types.i'
  42.         INCLUDE 'utility/hooks.i'
  43.         xdef    _callHook
  44.         xdef    _callHookPkt
  45.         xdef    _hookEntry
  46.         xdef    _stubReturn
  47.  
  48. ***************************************************************************
  49. * new hook standard
  50. * use struct Hook (with minnode at the top)
  51. *
  52. * *** register calling convention: ***
  53. *       A0 - pointer to hook itself
  54. *       A1 - pointer to parameter packed ("message")
  55. *       A2 - Hook specific address data ("object," e.g, gadget )
  56. *
  57. * ***  C conventions: ***
  58. * Note that parameters are in unusual register order: a0, a2, a1.
  59. * This is to provide a performance boost for assembly language
  60. * programming (the object in a2 is most frequently untouched).
  61. * It is also no problem in "register direct" C function parameters.
  62. *
  63. * calling through a hook
  64. *       callHook( hook, object, msgid, p1, p2, ... );
  65. *       callHookPkt( hook, object, msgpkt );
  66. *
  67. * using a C function:   CFunction( hook, object, message );
  68. *       hook.h_Entry = hookEntry;
  69. *       hook.h_SubEntry = CFunction;
  70. ****************************************************************************
  71.  
  72. * C calling hook interface for prepared message packet
  73. _callHookPkt:
  74.         movem.l a2/a6,-(sp)     ; protect
  75.         move.l  12(sp),a0       ; hook
  76.         move.l  16(sp),a2       ; object
  77.         move.l  20(sp),a1       ; message
  78.         ; ------ now have registers ready, invoke function
  79.         pea.l   hreturn(pc)
  80.         move.l  h_Entry(a0),-(sp)       ; old rts-jump trick
  81.         rts
  82. hreturn:
  83.         movem.l (sp)+,a2/a6
  84.         rts
  85.  
  86. * C calling hook interface for "varargs message packet"
  87. _callHook:
  88.         movem.l a2/a6,-(sp)     ; protect
  89.         move.l  12(sp),a0       ; hook
  90.         move.l  16(sp),a2       ; object
  91.         lea.l   20(sp),a1       ; message
  92.         ; ------ now have registers ready, invoke function
  93.         pea.l   hpreturn(pc)
  94.         move.l  h_Entry(a0),-(sp)       ; old rts-jump trick
  95.         rts
  96. hpreturn:
  97.         movem.l (sp)+,a2/a6
  98.         rts
  99.  
  100. * entry interface for C code (large-code, stack parameters)
  101. _hookEntry:
  102.         move.l  a1,-(sp)
  103.         move.l  a2,-(sp)
  104.         move.l  a0,-(sp)
  105.         move.l  h_SubEntry(a0),a0       ; C entry point
  106.         jsr     (a0)
  107.         lea     12(sp),sp
  108. _stubReturn:
  109.         rts
  110. *
  111. *                                        ;SAS/Lattice ASM command needs this
  112. *       END
  113.  
  114.