home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 5 / FreshFish_July-August1994.bin / bbs / dev / rkrm.lha / RKRM / Input / Inputhandler.a next >
Encoding:
Text File  |  1992-09-03  |  5.6 KB  |  135 lines
  1. *
  2. * Copyright (c) 1992 Commodore-Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Commodore-Amiga, Inc. for  
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Commodore Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. ****************************************************************************
  27. *
  28. *       InputHandler.a
  29. *
  30. * InputHandler that does a Left/Right mouse button swap...
  31. *
  32. *
  33. * See Swap_Buttons.c for details on how to compile/assemble/link...
  34. *
  35. ************************************************************************
  36. *
  37. * Required includes...
  38. *
  39. *       CSECT   InputHandler             ;SAS/Lattice ASM command requires this
  40. *
  41.         INCDIR  "include:"               ;HX68 requires this
  42.         INCLUDE "exec/types.i"
  43.         INCLUDE "exec/io.i"
  44.         INCLUDE "devices/inputevent.i"
  45. *
  46. ************************************************************************
  47. *
  48. * Make the entry point external...
  49. *
  50.         xdef    _ButtonSwap
  51. *
  52. ************************************************************************
  53. *
  54. * This is the input handler that will swap the
  55. * mouse buttons for left handed use.
  56. *
  57. * The event list gets passed to you in  a0.
  58. * The is_Data field is passed to you in a1.
  59. * This example does not use the is_Data field...
  60. *
  61. * On exit you must return the event list in d0.  In this way
  62. * you could add or remove items from the event list.
  63. *
  64. ************************************************************************
  65. *
  66. * The handler gets called here...
  67. *
  68. _ButtonSwap:    move.l  a0,-(sp)        ; Save the event list
  69. *
  70. * Since the event list could be a linked list, we start a loop
  71. * here to handle all of the events passed to us.
  72. *
  73. CheckLoop:      move.w  ie_Qualifier(a0),d1             ; Get qualifiers...
  74.                 move.w  d1,d0                           ; Two places...
  75. *
  76. * Since we are changing left and right mouse buttons, we need to make
  77. * sure that we change the qualifiers on all of the messages.  The
  78. * left and right mouse buttons are tracked in the message qualifiers
  79. * for use in such things as dragging.  To make sure that we continue
  80. * to drag correctly, we change the qualifiers.
  81. *
  82. CheckRight:     btst    #IEQUALIFIERB_RBUTTON,d1        ; Check for right
  83.                 beq.s   NoRight
  84.                 bset    #IEQUALIFIERB_LEFTBUTTON,d0     ; Set the left...
  85.                 beq.s   CheckLeft
  86. NoRight:        bclr    #IEQUALIFIERB_LEFTBUTTON,d0     ; Clear the left...
  87. *
  88. CheckLeft:      btst    #IEQUALIFIERB_LEFTBUTTON,d1     ; Check for left
  89.                 beq.s   NoLeft
  90.                 bset    #IEQUALIFIERB_RBUTTON,d0        ; Set the right...
  91.                 beq.s   SaveQual
  92. NoLeft:         bclr    #IEQUALIFIERB_RBUTTON,d0        ; Clear the right...
  93. *
  94. SaveQual:       move.w  d0,ie_Qualifier(a0)             ; Save back...
  95. *
  96. * The actual button up/down events are transmitted as the
  97. * code field in RAWMOUSE events.  The code field must the be
  98. * checked and modified when needed on RAWMOUSE events.  If the
  99. * event is not a RAWMOUSE, we are done with it.
  100. *
  101.                 cmp.b   #IECLASS_RAWMOUSE,ie_Class(a0)  ; Check for mouse
  102.                 bne.s   NextEvent                       ; If not, next...
  103. *
  104.                 move.w  ie_Code(a0),d0                  ; Get code...
  105.                 move.w  d0,d1                           ; Save...
  106.                 and.w   #$7F,d0                         ; Mask UP_PREFIX
  107.                 cmp.w   #IECODE_LBUTTON,d0              ; Check for Left...
  108.                 beq.s   SwapThem                        ; If so, swap...
  109.                 cmp.w   #IECODE_RBUTTON,d0              ; Check for Right...
  110.                 bne.s   NextEvent                       ; If not, next...
  111. *
  112. SwapThem:       eor.w   #1,d1                           ; Flip bottom bit
  113.                 move.w  d1,ie_Code(a0)                  ; Save it...
  114. *
  115. * The event list is linked via a pointer to the next event
  116. * in the first element of the structure.  That is why it is not
  117. * nessesary to use:  move.l ie_NextEvent(a0),d0
  118. *
  119. * The reason I move to d0 first is that this also checks for zero.
  120. * The last event in the list will have a NULL ie_NextEvent field.
  121. * This is NOT as standard EXEC list where the node after the last
  122. * node is NULL.  Input events are single-linked for performance.
  123. *
  124. NextEvent:      move.l  (a0),d0                         ; Get next event
  125.                 move.l  d0,a0                           ; into a0...
  126.                 bne.s   CheckLoop                       ; Do some more.
  127. *
  128. * All done, just return the event list...  (in d0)
  129. *
  130.                 move.l  (sp)+,d0        ; Get event list back...
  131.                 rts                     ; return from handler...
  132. *
  133. *                                       ; SAS/Lattice ASM command requires this
  134. *               END
  135.