home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 5 / FreshFish_July-August1994.bin / bbs / dev / rkrm.lha / RKRM / Workbench / startup2.0 / startup.asm < prev   
Encoding:
Assembly Source File  |  1992-09-03  |  27.7 KB  |  831 lines
  1. *
  2. * Copyright (c) 1990 Commodore-Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Commodore-Amiga, Inc. for 
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Commodore Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. **********************************************************************
  27. *
  28. *------ startup.asm  v 36.13
  29. *
  30. **********************************************************************
  31.  
  32.  
  33. *
  34. * Copyright (c) 1990 Commodore-Amiga, Inc.
  35. *
  36. *
  37. *------
  38. *------ Conditional assembly flags
  39. *------ ASTART:   1=Standard Globals Defined    0=Reentrant Only
  40. *------ WINDOW:   1=AppWindow for WB startup    0=No AppWindow code
  41. *------ XNIL:     1=Remove startup NIL: init    0=Default Nil: WB Output
  42. *------ NARGS:    1=Argv[0] only                0=Normal cmd line arg parse
  43. *------ DEBUG:    1=Set up old statics for Wack 0=No extra statics
  44. *------ QARG:     1=No argv                     0=Passes argc,argv
  45.  
  46. * Include the appropriate startup.i (example rstartup.i) here or in
  47. * your assem line
  48.  
  49.         INCLUDE "allstartup.i"
  50.  
  51. * Flags for  [A]start  AWstart  Rstart  RWstart  RXstart  QStart
  52. * ASTART         1        1       0        0        0       0
  53. * WINDOW         0        1       0        1        0       0
  54. * XNIL           0        0       0        0        1       1
  55. * NARGS          0        0       0        0        0       0
  56. * DEBUG          0        0       0        0        0       0
  57. * QARG           0        0       0        0        0       1
  58.  
  59. ;------   Flag WB output initialization
  60. NNIL      SET    (1-XNIL)
  61. WBOUT     SET   (ASTART!WINDOW!NNIL)
  62.  
  63. ************************************************************************
  64. *
  65. *   startup.asm --- Reentrant C Program Startup/Exit (CLI and WB)
  66. *                   v36.13  011/07/90
  67. *
  68. *   Copyright (c) 1988, 1990 Commodore-Amiga, Inc.
  69. *
  70. *   Title to this software and all copies thereof remain vested in the
  71. *   authors indicated in the above copyright notice.  The object version
  72. *   of this code may be used in software for Commodore Amiga computers.
  73. *   All other rights are reserved.
  74. *
  75. *   NO REPRESENTATIONS OR WARRANTIES ARE MADE WITH RESPECT TO THE
  76. *   ACCURACY, RELIABILITY, PERFORMANCE OR OPERATION OF THIS SOFTWARE,
  77. *   AND ALL SUCH USE IS AT YOUR OWN RISK.  NEITHER COMMODORE NOR THE
  78. *   AUTHORS ASSUME ANY RESPONSIBILITY OR LIABILITY WHATSOEVER WITH
  79. *   RESPECT TO YOUR USE OF THIS SOFTWARE.
  80. *
  81. *
  82. *   RSTARTUP.ASM
  83. *
  84. *  Changes for 2.0 - since commands may now receive a >256 character command
  85. *  line, the argv buffer size is now dynamic, based on DosCmdLen passed in.
  86. *  The argv count is also dynamic, based on number of spaces in the command
  87. *  line.
  88. *
  89. *      This startup dynamically allocates a structure which includes
  90. *   the argv buffers.  If you use this startup, your code must return
  91. *   to this startup when it exits.  Use exit(n) or final curly brace
  92. *   (rts) to return here.  Do not use AmigaDOS Exit( ) function.
  93. *   Due to this dynamic allocation and some code consolidation, this
  94. *   startup can make executables several hundred bytes smaller.
  95. *
  96. *       Because a static initialSP variable can not be used, this
  97. *   code depends on the fact that AmigaDOS places the address of
  98. *   the top of our stack in SP and proc->pr_ReturnAddr right before
  99. *   JSR'ing to us.  This code uses pr_ReturnAddr when restoring SP.
  100. *
  101. *       Most versions of startup will initialize a Workbench process's
  102. *   input and output streams (and stdio globals if present) to NIL:
  103. *   if no other form of Workbench output (like WINDOW) is provided.
  104. *   This should help prevent crashes if a user puts an icon on a CLI
  105. *   program, and will also protect against careless stdio debugging
  106. *   or error messages left in a Workbench program.  The code for
  107. *   initializing Workbench IO streams only be removed by assembling
  108. *   startup with ASTART and WINDOW set to 0, and XNIL set to 1.
  109. *
  110. *
  111. *   Some startups which can be conditionally assembled:
  112. *
  113. *      1. Standard Astartup for non-reentrant code
  114. *      2. Reentrant Rstartup (no unshareable globals)
  115. *      3. Smaller reentrant-only RXstartup (no NIL: WB init code)
  116. *      4. Standard AWstartup (WB output window) for non-reentrant code
  117. *      5. Reentrant RWstartup (WB output window, no unshareable globals)
  118. *      6. Smallest Qstartup  (No argv - argv is ptr to NULL string)
  119. *
  120. *
  121. *   Explanation of conditional assembly flags:
  122. *
  123. *      ASTART (ASTART SET 1) startups will set up and XDEF the
  124. *   global variables _stdin, _stdout, _stderr, _errno and  _WBenchMsg.
  125. *   These startups can be used as smaller replacements for startups
  126. *   like (A)startup.obj and TWstartup.obj.  Startups with ASTART
  127. *   would generally be used for non-reentrant programs, although the
  128. *   startup code itself is still reentrant if the globals are not
  129. *   referenced.
  130. *      Reentrant (ASTART SET 0) startups will NOT set up or
  131. *   XDEF the stdio and WBenchMsg globals.  This not only makes the
  132. *   startup slightly smaller, but also lets you know if your code
  133. *   is referencing these non-reentrant globals (you will get an
  134. *   unresolved external reference when you link).  Programs
  135. *   get their input and output handles from Input( ) and Output( ),
  136. *   and the WBenchMsg is passed in argv on Workbench startup.
  137. *
  138. *      WINDOW (WINDOW SET 1) startups use an XREF'd CON: string
  139. *   named AppWindow, defined in your application, to open a stdio
  140. *   console window when your application is started from Workbench.
  141. *   For non-reentrant programs, this window can be used for normal
  142. *   stdio (printf, getchar, etc).  For reentrant programs the window
  143. *   is Input( ) and Output( ).  WINDOW is useful when adding Workbench
  144. *   capability to a stdio application, and also for debugging other
  145. *   Workbench applications.  To insure that applications requiring
  146. *   a window startup are linked with a window startup, the label
  147. *   _NeedWStartup can be externed and referenced in the application
  148. *   so that a linker error will occur if linked with a standard
  149. *   startup.
  150. *
  151. *       example:   /* Optional safety reference to NeedWStartup */
  152. *                    extern UBYTE  NeedWStartup;
  153. *                    UBYTE  *HaveWStartup = &NeedWStartup;
  154. *                  /* Required window specification */
  155. *                    char AppWindow[] = "CON:30/30/200/150/MyProgram";
  156. *                    ( OR  char AppWindow[] = "\0";  for no window )
  157. *
  158. *
  159. *      XNIL (XNIL SET 1) allows the creation of a smaller startup
  160. *   by removing the code that initializes a Workbench process's
  161. *   output streams to NIL:.  This flag can only remove the code
  162. *   if it is not required for ASTART or WINDOW.
  163. *
  164. *      NARGS (NARGS SET 1) removes the code used to parse command line
  165. *   arguments.  The command name is still passed to _main as argv[0].
  166. *   This option can take about 120 bytes off the size of any program that
  167. *   does not use command line args.
  168. *
  169. *      DEBUG (DEBUG SET 1) will cause the old startup.asm statics
  170. *   initialSP, dosCmdLen and dosCmdBuf to be defined and initialized
  171. *   by the startup code, for use as debugging symbols when using Wack.
  172. *
  173. *      QARG (QARG SET TO 1) will bypass all argument parsing.  A CLI
  174. *   startup is passed argc == 1, and a Workbench startup is passed
  175. *   argc == 0.  Argv[0] will be a pointer to a NULL string rather than
  176. *   a pointer to the command name.  This option creates a very small
  177. *   startup with no sVar structure allocation, and therefore must be used
  178. *   with XNIL (it is incompatible with default or AWindow output options).
  179. *
  180. *
  181. *   RULES FOR REENTRANT CODE
  182. *
  183. *      - Make no direct or indirect (printf, etc) references to the
  184. *        globals _stdin, _stdout, _stderr, _errno, or _WBenchMsg.
  185. *
  186. *      - For stdio use either special versions of printf and getchar
  187. *        that use Input( ) and Output( ) rather than _stdin and _stdout,
  188. *        or use fprintf and fgetc with Input( ) and Output( ) file handles.
  189. *
  190. *      - Workbench applications must get the pointer to the WBenchMsg
  191. *        from argv rather than from a global extern WBenchMsg.
  192. *
  193. *      - Use no global or static variables within your code.  Instead,
  194. *        put all former globals in a dynamically allocated structure, and
  195. *        pass around a pointer to that structure.  The only acceptable
  196. *        globals are constants (message strings, etc) and global copies
  197. *        of Library Bases to resolve Amiga.lib references.  Your code
  198. *        must return all OpenLibrary's into non-global variables,
  199. *        copy the result to the global library base only if successful,
  200. *        and use the non-globals when deciding whether to Close any
  201. *        opened libraries.
  202. *
  203. ************************************************************************
  204.  
  205.  
  206. ******* Included Files *************************************************
  207.  
  208.         INCLUDE "exec/types.i"
  209.         INCLUDE "exec/alerts.i"
  210.         INCLUDE "exec/memory.i"
  211.         INCLUDE "libraries/dos.i"
  212.         INCLUDE "libraries/dosextens.i"
  213.         INCLUDE "workbench/startup.i"
  214.  
  215.  
  216. ******* MACROS *********************************************************
  217.  
  218.     CODE
  219.  
  220. xlib    macro
  221.         xref    _LVO\1
  222.         endm
  223.  
  224. callsys macro
  225.         CALLLIB _LVO\1
  226.         endm
  227.  
  228. ******* Imported *******************************************************
  229.  
  230. ABSEXECBASE     EQU     4
  231.  
  232.         xref    _main           ; C code entry point
  233.  
  234.         IFGT    WINDOW
  235.         xref    _AppWindow      ; CON: spec in application for WB stdio window
  236.         xdef    _NeedWStartup   ; May be externed and referenced in application
  237.         ENDC    WINDOW
  238.  
  239.         xlib    Alert
  240.         xlib    AllocMem
  241.         xlib    FindTask
  242.         xlib    Forbid
  243.         xlib    FreeMem
  244.         xlib    GetMsg
  245.         xlib    OpenLibrary
  246.         xlib    CloseLibrary
  247.         xlib    ReplyMsg
  248.         xlib    Wait
  249.         xlib    WaitPort
  250.  
  251.         xlib    CurrentDir
  252.         xlib    Open
  253.         xlib    Close
  254.         xlib    Input
  255.         xlib    Output
  256.  
  257. ******* Exported *******************************************************
  258.  
  259. *----- These globals are set up for standard startup code only
  260.         IFGT    ASTART
  261.         xdef    _stdin
  262.         xdef    _stdout
  263.         xdef    _stderr
  264.         xdef    _errno
  265.         xdef    _WBenchMsg
  266.         ENDC    ASTART
  267.  
  268. *----- These globals available to normal and reentrant code
  269.  
  270.         xdef    _SysBase
  271.         xdef    _DOSBase
  272.         xdef    _exit           ; standard C exit function
  273.  
  274.  
  275. ***** Startup Variables structure **********************************
  276.  
  277.         IFEQ    QARG
  278.  
  279. ; NOTE - the ArgvArray must be last
  280. ; It and the ArgvBuffer which follow it are dynamically sized/allocated (2.0)
  281.  
  282.  STRUCTURE  SVar,0
  283.     ULONG   sv_Size
  284.     LONG    sv_WbOutput
  285.     ULONG   sv_ArgvBufPtr
  286.     ULONG   sv_MaxArgc
  287.     LABEL   sv_ArgvArray
  288.     LABEL   SV_SIZEOF
  289.         ENDC    QARG
  290.  
  291. ************************************************************************
  292. *   Standard Program Entry Point
  293. ************************************************************************
  294. *
  295. *       Entered with
  296. *           d0  dosCmdLen
  297. *           a0  dosCmdBuf
  298. *       Any registers (except sp) are allowed to be modified
  299. *
  300. *       Calls
  301. *           main (argc, argv)
  302. *               int   argc;
  303. *               char *argv[];
  304. *
  305. *           For Workbench startup, argc=0, argv=WBenchMsg
  306. *
  307. ************************************************************************
  308. startup:
  309.         IFGT    DEBUG
  310.                 move.l  sp,initialSP
  311.                 move.l  d0,dosCmdLen
  312.                 move.l  a0,dosCmdBuf
  313.         ENDC    DEBUG
  314.  
  315.         IFEQ    QARG
  316.                 move.l  d0,d2
  317.                 move.l  a0,a2
  318.         ENDC    QARG
  319.  
  320.         ;------ get Exec library base pointer
  321.                 movea.l ABSEXECBASE,a6
  322.                 move.l  a6,_SysBase
  323.  
  324.         ;------ get the address of our task
  325.                 suba.l  a1,a1           ; clear a1
  326.                 callsys FindTask
  327.                 move.l  d0,a4           ; keep task address in a4
  328.  
  329.         ;------ get DOS library base pointer
  330.                 moveq   #0,d0
  331.                 lea     DOSName(pc),A1  ; dos.library
  332.                 callsys OpenLibrary
  333.  
  334.                 tst.l   d0
  335.                 beq     alertDOS        ; fail on null with alert
  336.                 move.l  d0,_DOSBase     ; Else set the global
  337.  
  338.  
  339.         IFEQ    QARG
  340.         ;------ branch over argv calculations if not a CLI process
  341.                 move.l  pr_CLI(A4),d0
  342.         bne.s    vcnt
  343.         moveq    #2,d4        ; if wb startup alloc 2 argv's
  344.         moveq   #8,d2        ; fake dos cmd line size for alloc
  345.                 bra.s   wbnoargs
  346.  
  347. vcnt:
  348.     ;------ estimate max number of argv's for CLI command line
  349.     ;------ command + number spaces + 1 + null argv
  350.         movea.l    a2,a0        ; dos command line
  351.         moveq    #3,d4        ; start count at 3, add spaces
  352. vcnt1:
  353.         cmp.b    #' ',(a0)
  354.         bne.s    vcnt2
  355.         addq    #1,d4
  356. vcnt2:
  357.         tst.b    (a0)+
  358.         bne.s    vcnt1
  359.  
  360.  
  361.     ;------ branch to here has d4=2, d2=8 for wb startup
  362. wbnoargs:
  363.  
  364.     ;------ d4 now equals at least max number argv's needed
  365.         move.l    d4,d0
  366.         lsl.l    #2,d0        ; convert to bytes needed for argv ptrs
  367.         move.l    d0,d5        ; save in d5
  368.         add.l    d2,d0        ; add dos command line size for buffer
  369.  
  370.                 add.l  #SV_SIZEOF+1,d0    ; add structure size + 1 for null term
  371.  
  372.         ;------ alloc the argument structure    
  373.         move.l    d0,d3        ; save total size for de-allocation
  374.                 move.l  #(MEMF_PUBLIC!MEMF_CLEAR),d1
  375.                 callsys AllocMem
  376.                 tst.l   d0
  377.                 beq     alertMem        ; fail on null with alert
  378.                 move.l  d0,-(sp)        ; save sVar ptr on stack
  379.                 move.l  d0,a5           ; sVar ptr to a5
  380.         move.l    d3,sv_Size(a5)  ; size for de-allocation later (2.0)
  381.         subq.l    #1,d4
  382.         move.l    d4,sv_MaxArgc(a5) ; max argc
  383.         lea.l    sv_ArgvArray(a5),a0
  384.         adda.l    d5,a0
  385.         move.l  a0,sv_ArgvBufPtr(a5)
  386.  
  387.         ENDC    QARG
  388.         IFGT    QARG
  389.                 clr.l   -(sp)
  390.         ENDC    QARG
  391.  
  392.                 clr.l   -(sp)           ; reserve space for WBenchMsg if any
  393.  
  394.         ;------ branch to Workbench startup code if not a CLI process
  395.                 move.l  pr_CLI(A4),d0
  396.                 beq     fromWorkbench
  397.  
  398. ;=======================================================================
  399. ;====== CLI Startup Code ===============================================
  400. ;=======================================================================
  401. ;       d0  process CLI BPTR (passed in), then temporary
  402. ;       d2  dos command length (passed in)
  403. ;       d3  argument count
  404. ;       a0  temporary
  405. ;       a1  argv buffer
  406. ;       a2  dos command buffer (passed in)
  407. ;       a3  argv array
  408. ;       a4  Task (passed in)
  409. ;       a5  SVar structure if not QARG (passed in)
  410. ;       a6  AbsExecBase (passed in)
  411. ;       sp  WBenchMsg (still 0), sVar or 0, then RetAddr (passed in)
  412. ;       sp  argc, argv, WBenchMsg, sVar or 0,RetAddr (at bra domain)
  413.  
  414.         IFEQ    QARG
  415.         ;------ find command name
  416.                 lsl.l   #2,d0           ; pr_CLI bcpl pointer conversion
  417.                 move.l  d0,a0
  418.                 move.l  cli_CommandName(a0),d0
  419.                 lsl.l   #2,d0           ; bcpl pointer conversion
  420.  
  421.                 ;-- start argv array
  422.                 move.l    sv_ArgvBufPtr(a5),a1
  423.                 lea     sv_ArgvArray(a5),a3
  424.  
  425.                 ;-- copy command name
  426.                 move.l  d0,a0
  427.                 moveq.l #0,d0
  428.                 move.b  (a0)+,d0        ; size of command name
  429.                 clr.b   0(a0,d0.l)      ; terminate the command name
  430.                 move.l  a0,(a3)+
  431.                 moveq   #1,d3           ; start counting arguments
  432.  
  433.         IFEQ    NARGS
  434.         ;------ null terminate the arguments, eat trailing control characters
  435.                 lea     0(a2,d2.l),a0
  436. stripjunk:
  437.                 cmp.b   #' ',-(a0)
  438.                 dbhi    d2,stripjunk
  439.  
  440.                 clr.b   1(a0)
  441.  
  442.         ;------ start gathering arguments into buffer
  443. newarg:
  444.                 ;-- skip spaces
  445.                 move.b  (a2)+,d1
  446.                 beq.s   parmExit
  447.                 cmp.b   #' ',d1
  448.                 beq.s   newarg
  449.                 cmp.b   #9,d1           ; tab
  450.                 beq.s   newarg
  451.  
  452.                 ;-- check for argument count overflow
  453.                 cmp.l   sv_MaxArgc(a5),d3
  454.                 beq.s   parmExit
  455.  
  456.                 ;-- push address of the next parameter
  457.                 move.l  a1,(a3)+
  458.                 addq.w  #1,d3
  459.  
  460.                 ;-- process quotes
  461.                 cmp.b   #'"',d1
  462.                 beq.s   doquote
  463.  
  464.                 ;-- copy the parameter in
  465.                 move.b  d1,(a1)+
  466.  
  467. nextchar:
  468.                 ;------ null termination check
  469.                 move.b  (a2)+,d1
  470.                 beq.s   parmExit
  471.                 cmp.b   #' ',d1
  472.                 beq.s   endarg
  473.  
  474.                 move.b  d1,(a1)+
  475.                 bra.s   nextchar
  476.  
  477. endarg:
  478.                 clr.b   (a1)+
  479.                 bra.s   newarg
  480.  
  481. doquote:
  482.         ;------ process quoted strings
  483.                 move.b  (a2)+,d1
  484.                 beq.s   parmExit
  485.                 cmp.b   #'"',d1
  486.                 beq.s   endarg
  487.  
  488.                 ;-- '*' is the BCPL escape character
  489.                 cmp.b   #'*',d1
  490.                 bne.s   addquotechar
  491.  
  492.                 move.b  (a2)+,d1
  493.                 move.b  d1,d2
  494.                 and.b   #$df,d2         ;d2 is temp toupper'd d1
  495.  
  496.                 cmp.b   #'N',d2         ;check for dos newline char
  497.                 bne.s   checkEscape
  498.  
  499.                 ;--     got a *N -- turn into a newline
  500.                 moveq   #10,d1
  501.                 bra.s   addquotechar
  502.  
  503. checkEscape:
  504.                 cmp.b   #'E',d2
  505.                 bne.s   addquotechar
  506.  
  507.                 ;--     got a *E -- turn into a escape
  508.                 moveq   #27,d1
  509.  
  510. addquotechar:
  511.                 move.b  d1,(a1)+
  512.                 bra.s   doquote
  513.  
  514. parmExit:
  515.         ;------ all done -- null terminate the arguments
  516.                 clr.b   (a1)
  517.                 clr.l   (a3)
  518.         ENDC NARGS
  519.  
  520.                 pea     sv_ArgvArray(a5) ; argv
  521.                 move.l  d3,-(sp)         ; argc
  522.         ENDC    QARG
  523.  
  524.         IFGT    QARG
  525.                 pea     nullArgV(pc)    ; pointer to pointer to null string
  526.                 pea     1               ; only one pointer
  527.         ENDC
  528.  
  529.         IFGT    ASTART
  530.                 movea.l _DOSBase,a6
  531.         ;------ get standard input handle:
  532.                 callsys Input
  533.                 move.l  d0,_stdin
  534.  
  535.         ;------ get standard output handle:
  536.                 callsys Output
  537.                 move.l  d0,_stdout
  538.                 move.l  d0,_stderr
  539.                 movea.l ABSEXECBASE,a6
  540.         ENDC ASTART
  541.  
  542.                 bra     domain
  543.  
  544.  
  545. ;=======================================================================
  546. ;====== Workbench Startup Code =========================================
  547. ;=======================================================================
  548. ;       a2  WBenchMsg
  549. ;       a4  Task (passed in)
  550. ;       a5  SVar structure if not QARG (passed in)
  551. ;       a6  AbsExecBase (passed in)
  552. ;       sp  WBenchMsg (still 0), sVar or 0, then RetAddr (passed in)
  553. ;       sp  argc=0,argv=WBenchMsg,WBenchMsg,sVar or 0,RetAddr (at domain)
  554.  
  555. fromWorkbench:
  556.         ;------ get the startup message that workbench will send to us.
  557.         ;       must get this message before doing any DOS calls
  558.                 bsr.s   getWbMsg
  559.  
  560.         ;------ save the message so we can return it later
  561.                 move.l  d0,(sp)
  562.         IFGT    ASTART
  563.                 move.l  d0,_WBenchMsg
  564.         ENDC    ASTART
  565.  
  566.         ;------ push the message on the stack for wbmain (as argv)
  567.                 move.l  d0,-(sp)
  568.                 clr.l   -(sp)           ; indicate run from Workbench (argc=0)
  569.  
  570.         IFNE    (1-QARG)+WBOUT
  571.         ;------ put DOSBase in a6 for next few calls
  572.                 move.l  _DOSBase,a6
  573.         ENDC    (1-QARG)+WBOUT
  574.  
  575.         IFEQ    QARG
  576.         ;------ get the first argument
  577.                 move.l  d0,a2
  578.                 move.l  sm_ArgList(a2),d0
  579.                 beq.s   doCons
  580.  
  581.         ;------ and set the current directory to the same directory
  582.                 move.l  d0,a0
  583.                 move.l  wa_Lock(a0),d1
  584.                 ;should be a  beq.s doCons  here
  585.                 callsys CurrentDir
  586. doCons:
  587.         ENDC    QARG
  588.  
  589.         IFGT    WBOUT
  590.  
  591.         ;------ Open NIL: or AppWindow for WB Input()/Output() handle
  592.         ;       Also for possible initialization of stdio globals
  593.         ;       Stdio used to be initialized to -1
  594.  
  595.  
  596.         IFGT    WINDOW
  597.         ;------ Get AppWindow defined in application
  598.                 lea     _AppWindow,a0
  599.                 cmp.b   #0,(a0)
  600.                 bne.s   doOpen          ; Open if not null string
  601.         ENDC    WINDOW
  602.  
  603.         ;------ Open NIL: if no window provided
  604.         lea     NilName(PC),a0
  605.  
  606. doOpen:
  607.         ;------ Open up the file whose name is in a0
  608.         ;       DOSBase still in a6
  609.                 move.l  a0,d1
  610.                 move.l  #MODE_OLDFILE,d2
  611.                 callsys Open
  612.         ;------ d0 now contains handle for Workbench Output
  613.         ;------ save handle for closing on exit
  614.                 move.l  d0,sv_WbOutput(a5)
  615.                 bne.s   gotOpen
  616.                 moveq.l #RETURN_FAIL,d2
  617.                 bra     exit2
  618. gotOpen:
  619.         IFGT ASTART
  620.         ;------ set the C input and output descriptors
  621.                 move.l  d0,_stdin
  622.                 move.l  d0,_stdout
  623.                 move.l  d0,_stderr
  624.         ENDC ASTART
  625.  
  626.         ;------ set the console task (so Open( "*", mode ) will work
  627.         ;       task pointer still in A4
  628.                 move.l  d0,pr_CIS(A4)
  629.                 move.l  d0,pr_COS(A4)
  630.                 lsl.l   #2,d0
  631.                 move.l  d0,a0
  632.                 move.l  fh_Type(a0),d0
  633.                 beq.s   noConTask
  634.                 move.l  d0,pr_ConsoleTask(A4)
  635. noConTask:
  636.         ENDC WBOUT
  637.  
  638.         ;------ Fall though to common WB/CLI code
  639.  
  640.  
  641. ****************************************************
  642. ** This code now used by both CLI and WB startup  **
  643. ****************************************************
  644.  
  645. domain:
  646.                 jsr     _main
  647.         ;------ main didn't use exit(n) so provide success return code
  648.                 moveq.l #RETURN_OK,d2
  649.                 bra.s   exit2
  650.  
  651.  
  652. ****************************************************
  653. **    subroutines here to allow short branches    **
  654. ****************************************************
  655.  
  656. getWbMsg:
  657.         ;------ a6 = ExecBase
  658.                 lea     pr_MsgPort(A4),a0       ; our process base
  659.                 callsys WaitPort
  660.                 lea     pr_MsgPort(A4),a0       ; our process base
  661.                 callsys GetMsg
  662.                 rts
  663.  
  664. ****************************************************
  665.  
  666. alertDOS:
  667.         ;------ do recoverable alert for no DOS and exit
  668.                 ALERT   (AG_OpenLib!AO_DOSLib)
  669.  
  670.         ;------ do recoverable alert for no memory and exit
  671.         ;------ If we got this far, DOS is open, so close it
  672.         IFEQ QARG
  673.                 bra.s   failExit
  674. alertMem:
  675.                 movea.l _DOSBase,a1
  676.                 callsys CloseLibrary
  677.                 ALERT   AG_NoMemory
  678.         ENDC QARG
  679. failExit:
  680.                 tst.l   pr_CLI(a4)
  681.                 bne.s   fail2
  682.                 bsr.s   getWbMsg
  683.                 movea.l d0,a2
  684.                 bsr.s   repWbMsg
  685. fail2:
  686.                 moveq.l #RETURN_FAIL,d0
  687.                 rts
  688.  
  689. ****************************************************
  690.  
  691. repWbMsg:
  692.         ;------ return the startup message to our parent
  693.         ;       a6 = ExecBase (passed)
  694.         ;       a2 = WBenchMsg (passed)
  695.         ;       we forbid so workbench can't UnLoadSeg() us before we are done
  696.                 callsys Forbid
  697.                 move.l  a2,a1
  698.                 callsys ReplyMsg
  699.                 rts
  700.  
  701.  
  702. *******************************************************
  703. **  C Program exit() Function, return code on stack  **
  704. **                                                   **
  705. **  pr_ReturnAddr points to our RTS addr on stack    **
  706. **  and we use this to calculate our stack ptr:      **
  707. **                                                   **
  708. **      SP ->   WBenchMsg or 0 (CLI)                 **
  709. **              sVar ptr or 0 (QARG)                 **
  710. **              Address for RTS to DOS               **
  711. *******************************************************
  712.  
  713. _exit:
  714.                 move.l  4(sp),d2        ; exit(n) return code to d2
  715.  
  716. exit2:                                  ;exit code in d2
  717.         ;------ restore initial stack ptr
  718.                 ;-- FindTask
  719.                 movea.l ABSEXECBASE,a6
  720.                 suba.l  a1,a1
  721.                 callsys FindTask
  722.                 ;-- get SP as it was prior to DOS's jsr to us
  723.                 move.l  d0,a4
  724.                 move.l  pr_ReturnAddr(a4),a5
  725.                 ;-- subtract 4 for return address, 4 for SVar, 4 for WBenchMsg
  726.                 suba.l  #12,a5
  727.  
  728.                 ;-- restore sp
  729.                 move.l  a5,sp
  730.  
  731.                 ;-- recover WBenchMsg
  732.                 move.l  (sp)+,a2
  733.                 ;-- recover SVar
  734.                 move.l  (sp)+,a5
  735.  
  736.  
  737.         IFGT    WBOUT
  738.         ;------ Close any WbOutput file before closing dos.library
  739.                 move.l  sv_WbOutput(a5),d1
  740.                 beq.s   noWbOut
  741.                 move.l  _DOSBase,a6
  742.                 callsys Close
  743. noWbOut:
  744.         ;------ Restore a6 = ExecBase
  745.                 movea.l ABSEXECBASE,a6
  746.         ENDC    WBOUT
  747.  
  748.         ;------ Close DOS library, if we got here it was opened
  749.         ;       SysBase still in a6
  750.                 movea.l _DOSBase,a1
  751.                 callsys CloseLibrary
  752.  
  753.         ;------ if we ran from CLI, skip workbench reply
  754. checkWB:
  755.                 move.l  a2,d0
  756.                 beq.s   deallocSV
  757.  
  758.                 bsr.s   repWbMsg
  759.  
  760. deallocSV:
  761.         IFEQ    QARG
  762.         ;------ deallocate the SVar structure
  763.                 move.l  a5,a1
  764.                 move.l  sv_Size(a5),d0
  765.                 callsys FreeMem
  766.         ENDC    QARG
  767.  
  768.         ;------ this rts sends us back to DOS:
  769.                 move.l  d2,d0
  770.                 rts
  771.  
  772.  
  773. **********************************************************************
  774.  
  775. ;----- PC relative data
  776.  
  777. DOSName         DOSNAME
  778. NilName         dc.b    'NIL:',0
  779.         IFGT    QARG
  780.         CNOP    0,2
  781. nullArgV        dc.l    nullArg
  782. nullArg         dc.l    0               ; "" & the null entry after nullArgV
  783.         ENDC
  784.  
  785. **********************************************************************
  786.         DATA
  787. **********************************************************************
  788.  
  789. _SysBase        dc.l    0
  790. _DOSBase        dc.l    0
  791.  
  792.         IFGT    ASTART
  793. _WBenchMsg      dc.l    0
  794. _stdin          dc.l    0
  795. _stdout         dc.l    0
  796. _stderr         dc.l    0
  797. _errno          dc.l    0
  798.         ENDC    ASTART
  799.  
  800.         IFGT    DEBUG
  801. initialSP       dc.l    0
  802. dosCmdLen       dc.l    0
  803. dosCmdBuf       dc.l    0
  804.         ENDC    DEBUG
  805.  
  806. VerRev          dc.w    36,13
  807.         IFGT    ASTART
  808.                 dc.b    'A'
  809.         ENDC    ASTART
  810.         IFEQ    ASTART
  811.                 dc.b    'R'
  812.         ENDC    ASTART
  813.         IFGT    WINDOW
  814. _NeedWStartup:
  815.                 dc.b    'W'
  816.         ENDC    WINDOW
  817.         IFEQ    WBOUT
  818.                 dc.b    'X'
  819.         ENDC    WBOUT
  820.         IFGT    NARGS
  821.                 dc.b    'N'
  822.         ENDC    NARGS
  823.         IFGT    DEBUG
  824.                 dc.b    'D'
  825.         ENDC    DEBUG
  826.         IFGT    QARG
  827.                 dc.b    'Q'
  828.         ENDC    QARG
  829.  
  830.         END
  831.