home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 5 / FreshFish_July-August1994.bin / bbs / util / isan-1.2.lha / ISAN-1.2 / ISAN.s < prev    next >
Encoding:
Text File  |  1994-03-10  |  55.2 KB  |  1,873 lines
  1. *************************************************************************************
  2. * ISAN: Instruction Stream ANalyzer  v1.2        © Jan 1994 L. Vanhelsuwé
  3. * ---------------------------------------        ------------------------
  4. *
  5. * Usage: ISAN <TASK $tcb_addr|PROCESS procnum>
  6. *
  7. * ISAN Is used to get an idea of which instructions a particular Exec Task or
  8. * AmigaDOS Process is executing.
  9. * This is achieved by adding a TRACE exception handler to the Task which keeps
  10. * track of how many times a particular instruction or group of instructions has
  11. * been executed.
  12. * In parallel another Process (ISAN itself) regularly uses the results produced
  13. * by the exception handler to display the statistics graphically in a Window.
  14. *
  15. * The instructions of interest are listed in a run-time file called ISAN.config.
  16. * This file basically lists the numeric opcodes with a string to be used as
  17. * "label" for this opcode.
  18. *
  19. * History:
  20. * --------
  21. * Tue 17/MAR/92: Started project (coded all initialization first)
  22. * Wed 18/MAR/92: Got first tracing to work, added pattern mask feature
  23. * Thu 19/MAR/92: Added TOTAL option
  24. * Fri 20/MAR/92: Added Topaz font selection for Text output. Cleaned up code/comments.
  25. * Tue 14/APR/92: Added Graphical Opcode Usage Mapping (pixels represent each opcode)
  26. * Tue 21/APR/92: Added counters reset option (by clicking in window)
  27. * Tue 28/APR/92: Fixed 'Task not found' bug. Embarrassing...
  28. * Sat 02/MAY/92: Added task register monitoring option
  29. * Sun 03/MAY/92: Optimized TRACE exception handler by using memory indirect adr modes.
  30. * Tue 05/MAY/92: Fixed OpenWindow() failure bug (SORRY!!)
  31. * Sun 09/JAN/94: Added FILE keyword to command line options
  32. * Sat 22/JAN/94: Added PROFILE keyword for simplistic MODE 2 PC profiling
  33. *
  34. *************************************************************************************
  35.  
  36.         include    std            ;include std macros, equates
  37.         include    hardware/custom.i    ;for intena reg
  38.  
  39.  
  40.         RSRESET    Opcode    ; Opcode Descriptor structure
  41. opc_base_op    RS.W    1        ;base opcode binary pattern (opcode template)
  42. opc_nocare_mask    RS.W    1        ;mask for bits which can be anything
  43. opc_combis    RS.W    1        ;# of combinations that mask gives us
  44. opc_label    RS.L    1        ;ptr to opcode mnemonic string
  45. opc_label_len    RS.W    1        ;length of label string (for Text() )
  46. opc_freq    RS.L    1        ;copy of the counter found in big array
  47. opc_xfreq    RS.L    1        ;normalized frequency
  48. opc_sizeof    rs.w    0
  49.  
  50. CNTS_BLOCKSIZE    equ    65536*4        ;each 680x0 opcode has a LONG counter
  51.  
  52. MAX_PC_HIST    equ    248        ;max number of PCs remembered.
  53.  
  54. CHAR_WIDTH    equ    8        ;for Topaz80
  55. CHAR_HEIGHT    equ    8
  56.  
  57. WINDOW_WIDTH    equ    482        ;width excluding fat right border
  58. PANE_X        equ    6        ;top-left offsets to body of window
  59. PANE_Y        equ    10
  60. HEXNUM_SPACE    equ    8*CHAR_WIDTH    ;width of frequency field
  61. GADG_WIDTH    equ    17        ;width pixels that slider takes up
  62.  
  63. ; Two special illegal opcode words for our "TOTAL" and underline special entries
  64.  
  65. SPECIAL1    equ    $AFFF        ;in the A-line group
  66. SPECIAL2    equ    $AFFE        ;in the A-line group
  67.  
  68. GFXR        MACRO
  69.         move.l    rastport,a1
  70.         GFX    \1
  71.         ENDM
  72.  
  73. _intena        equ    $DFF000+intena    ;for DISABLE/ENABLE macros
  74.  
  75. ;===================================================================================
  76. ;===================================================================================
  77. ;===============                   =================================================
  78. ;=============== START OF PROGRAM  =================================================
  79. ;===============                   =================================================
  80. ;===================================================================================
  81. ;===================================================================================
  82.  
  83. START_ISAN:    move.l    sp,stack_level        ;for clean exits from any call level
  84.         move.l    a0,arg_line        ;remember where CLI arguments are
  85.  
  86.         bsr    init_isan        ;init some vars, ptrs...
  87.  
  88.         bsr    open_libs        ;open DOS,gfx,intui, get stdout
  89.         beq    bail_out        ;quit now if failed.
  90.  
  91.         move.l    4.w,a6            ;check to see that this machine is
  92.         move.w    AttnFlags(a6),d0    ;at least 020 based
  93.         btst    #AFB_68020,d0        ;because I need 020 exception frames
  94.         beq    need_020
  95.  
  96.         bsr    check_args        ;validate argument line
  97.  
  98.         move.l    conf_file,a0        ;attempt to load config file
  99.         bsr    load_file
  100.         beq    cant_find_conf
  101.  
  102.         move.l    d0,conf_size        ;remember config file details
  103.         move.l    a0,conf_buffer        ;for deallocation when exiting
  104.  
  105.         bsr    read_configuration    ;parse config file & create data structs.
  106.  
  107.         move.l    #CNTS_BLOCKSIZE,d0    ;allocate 256K array of 64K LONG
  108.         move.l    #MEMF_CLEAR|MEMF_PUBLIC,d1    ;instruction counters
  109.         EXEC    AllocMem
  110.         move.l    d0,counters
  111.         beq    no_memory        ;exit if failed.
  112.  
  113.         move.l    #MAX_PC_HIST*2*4,d0    ;allocate 2 arrays for PC history
  114.         move.l    #MEMF_CLEAR|MEMF_PUBLIC,d1
  115.         EXEC    AllocMem
  116.         move.l    d0,PC_history_PCs
  117.         beq    no_memory        ;exit if failed.
  118.         add.l    #MAX_PC_HIST*4,d0
  119.         move.l    d0,PC_history_cnts
  120.  
  121.         bsr    open_windows        ;try to get our display window(s)
  122.         beq    cant_get_window        ;error if failed.
  123.  
  124.         tst.l    opcode_map        ;if user also asked for a graphical
  125.         beq    no_map_req        ;view of all opcodes used by Task
  126.  
  127.         bsr    open_screen
  128.         beq    no_screen
  129.  
  130. ;-- At this stage we've got our graphs window, our file, our counters etc...
  131. ;-- Now is the time to do the tricky bit: open heart surgery on an unsuspecting Task!
  132.  
  133. no_map_req    bsr    start_task_traceing    ;enable TRACE mode of selected Task
  134.  
  135. ;---------------
  136. main_loop    move.l    DOS_LIB_PTR,a6        ;depending on slider gadget setting:
  137.         move.l    update_speed,d1
  138.         DOS    Delay            ;slow down graphical stats updating
  139.  
  140.         bsr    scan_stats        ;go through opcode list & stats and
  141.         bsr    update_windows        ;update window graphs
  142.         bsr    update_screen        ;and opcode bitmap (if enabled)
  143.  
  144.         bsr    handle_IDCMP        ;check slider gadget & close gadget
  145.  
  146.         tst.b    close_me        ;user clicked on CLOSE gadget ?
  147.         beq    main_loop        ;no: do main loop again
  148.  
  149.         bsr    stop_task_traceing    ;switch Task back to non-TRACE mode
  150.  
  151. ;-----------------------------------
  152. ; This is the wind-down bit of ISAN:
  153. ; Close and deallocate everything that we got from system
  154. ;-----------------------------------
  155.  
  156. bail_out    move.l    GFX_LIB_PTR,a6        ;doing Graphics closures...
  157.  
  158.         move.l    font_ptr,d0        ;did we successfuly get Topaz font?
  159.         beq    no_font
  160.         move.l    d0,a1
  161.         GFX    CloseFont        ;yes, then release before quiting.
  162. ;---------------
  163. no_font        move.l    INTUI_LIB_PTR,a6    ;doing Intuition closures...
  164.  
  165.         move.l    window,d0        ;if we managed to open our window,
  166.         beq    no_window
  167.         move.l    d0,a0
  168.         INTUI    CloseWindow        ;kill it now.
  169.  
  170. no_window    move.l    regs_window,d0        ;same with registers window
  171.         beq    no_regswindow
  172.         move.l    d0,a0
  173.         INTUI    CloseWindow        ;kill it now.
  174.  
  175. no_regswindow    move.l    prof_window,d0        ;same with PC profiling window
  176.         beq    no_profwindow
  177.         move.l    d0,a0
  178.         INTUI    CloseWindow        ;kill it now.
  179.  
  180. no_profwindow    move.l    map_screen,d0
  181.         beq    no_scr
  182.         move.l    d0,a0
  183.         INTUI    CloseScreen        ;same with opcode map screen
  184. ;---------------
  185. no_scr        move.l    4.w,a6            ;doing Exec closures...
  186.         
  187.         move.l    #MAX_PC_HIST*2*4,d0
  188.         move.l    PC_history_PCs,d1
  189.         beq    no_PC_history
  190.         move.l    d1,a1
  191.         EXEC    FreeMem            ;free PC history if allocated
  192.  
  193. no_PC_history    move.l    array_size,d0
  194.         move.l    opcode_list,d1
  195.         beq    no_opc_list
  196.         move.l    d1,a1
  197.         EXEC    FreeMem            ;free opcodes array if allocated
  198.  
  199. no_opc_list    move.l    #CNTS_BLOCKSIZE,d0
  200.         move.l    counters,d1
  201.         beq    no_counters
  202.         move.l    d1,a1
  203.         EXEC    FreeMem            ;free counters array if allocated
  204.  
  205. no_counters    move.l    conf_size,d0
  206.         beq    release_libs
  207.         move.l    conf_buffer,a1
  208.         EXEC    FreeMem            ;free cached conf file.
  209.  
  210. release_libs    bsr    close_libs        ;finally release our grip on libraries
  211.  
  212.         move.l    stack_level,sp        ;restore original SP (allows quit from
  213. END_ISAN:    rts                ;subroutines)
  214.  
  215. ;===================================================================================
  216. ;===================================================================================
  217. ;===============                   =================================================
  218. ;===============  END OF PROGRAM   =================================================
  219. ;===============                   =================================================
  220. ;===================================================================================
  221. ;===================================================================================
  222.  
  223. ;-----------------------------------------------
  224. ; Parse argument line according to:
  225. ;
  226. ; TASK/K,PROCESS/K,SPEED/K,MODE/K,REGS/S,TOTAL/S,GRAFMAP/S,FILE/K,PROFILE/S
  227. ;
  228. ; e.g. 1> ISAN TASK $7d0432C SPEED 1 MODE 2 TOTAL
  229. ;-----------------------------------------------
  230.  
  231. check_args    bsr    clear_results        ;set default results for ReadArgs
  232.  
  233.         move.l    #ISAN_template,d1    ;our argument template
  234.         move.l    #rda_results,d2
  235.         bsr    ReadArgs        ;parse command line (2.0 style)
  236.         beq    give_syntax        ;malformed arguments ? -> give help
  237.  
  238.         move.l    task_arg,d0        ;if task AND process args are given:
  239.         and.l    process_arg,d0        ;sorry, need exactly one.
  240.         bne    task_or_proc_please
  241.  
  242.         move.l    task_arg,d0        ;if NEITHER task OR process args are
  243.         or.l    process_arg,d0        ;given: sorry need one.
  244.         beq    give_syntax
  245. ;---------------
  246.         tst.l    profile_flag        ;user wants branching/loop profiling ?
  247.         beq    which_mode
  248.         move.l    #1,trace_mode        ;force trace mode to MODE 2
  249.         bra    which_speed        ;skip user's mode selection
  250. ;---------------
  251. which_mode    move.l    trace_mode,a0        ;check out the trace mode argument
  252.         moveq    #0,d0
  253.         move.b    (a0),d0
  254.         cmp.b    #'1',d0            ;trace all instructions (MODE 1) ?
  255.         beq    good_mode
  256.  
  257.         cmp.b    #'2',d0            ;or trace program flow changes (MODE 2)
  258.         bne    wrong_mode
  259. good_mode    sub.b    #'1',d0
  260.         move.l    d0,trace_mode        ;store 0 or 1 (MODE 1 or 2 resp.)
  261. ;---------------
  262. which_speed    move.l    update_speed,a0
  263.         move.l    a0,a4
  264.         bsr    DEC_TO_BIN        ;get SPEED <decimal> argument
  265.         cmp.l    a0,a4            ;if argument wasn't decimal
  266.         beq    invalid_update_sp    ;error!
  267.         tst.l    d1            ;or delay is 0
  268.         beq    invalid_update_sp
  269.  
  270.         move.l    #50*10,d0        ;check that user doesn't give a huge
  271.         cmp.l    d0,d1            ;delay factor coz that would freeze
  272.         bcs    decent_speed        ;our IDCMP loop too !
  273.         move.l    d0,d1
  274. decent_speed    move.l    d1,update_speed        ;else use user value as speed
  275. ;---------------
  276.         move.l    task_arg,d0        ;look for a Task or a Process?
  277.         beq    get_Process
  278.  
  279. get_Task    move.l    d0,a0            ;check task address syntax
  280.         cmp.b    #'$',(a0)+
  281.         bne    want_dollar_hex
  282.  
  283.         bsr    hex_to_bin        ;convert Task hex address to bin
  284.         move.l    d0,tcb_ptr        ;remember Task address
  285.  
  286.         bsr    check_taskaddr        ;validate Task
  287.         bne    task_doesnt_exist    ;if Task exists,
  288.  
  289.         lea    window_info,a0        ;-> window title append position
  290.         move.l    #'TASK',(a0)+        ;regardless of odd allignment (68030 **!!)
  291.         move.w    #' $',(a0)+        ;append string "TASK $hhhhhhhh)",0
  292.         move.l    tcb_ptr,d0
  293.         moveq    #8,d1
  294.         bsr    bin_hex            ;(reconvert Task addr to clean 8 chars)
  295.  
  296.         lea    task_addr_str+8,a0
  297.         move.w    #')'<<8,(a0)+        ;finish off title string
  298.         rts
  299. ;---------------
  300. get_Process    move.l    process_arg,a0        ;-> decimal process number
  301.         move.l    a0,a4
  302.         bsr    DEC_TO_BIN        ;get decimal number
  303.         cmp.l    a0,a4
  304.         beq    bad_procnum
  305.  
  306.         move.l    d1,d7
  307.         bsr    check_process        ;find Process N
  308.         move.l    d2,tcb_ptr        ;if found, store its TCB addr.
  309.         beq    proc_doesnt_exist
  310.  
  311.         lea    window_info,a0        ;now add string "PROCESS N)",0
  312.         move.l    #'PROC',(a0)+        ;to end of window title
  313.         move.l    #'ESS ',(a0)+
  314.         move.l    process_arg,a1
  315.         move.b    (a1)+,(a0)+        ;copy 1st process ID decimal digit
  316.         cmp.b    #9,d7            ;was process number 2 digits ?
  317.         ble    end_title
  318.         move.b    (a1)+,(a0)+        ;copy 2nd digit
  319.  
  320. end_title    move.w    #')'<<8,(a0)+        ;finish off title string
  321.         rts
  322. ;-----------------------------------------------
  323. ; Open graphs Window (sized according to how long opcode list is).
  324. ; Set the TextFont to "topaz 8" so that any Preferences font doesn't
  325. ; screw up our neat display.
  326. ;
  327. ; Return EQ if failed.
  328. ;-----------------------------------------------
  329.  
  330. open_windows    move.l    INTUI_LIB_PTR,a6    ;using Intuition...
  331.         move.l    #MyNewWindow,a0
  332.         INTUI    OpenWindow        ;open output window (incl. slider gadg)
  333.         move.l    d0,window        ;if ISAN.conf list too big then window
  334.         req                ;won't be able to open (too high)
  335.  
  336.         move.l    d0,a0
  337.         move.l    wd_UserPort(a0),msgport    ;also find Window's IDCMP msg port
  338.         move.l    wd_RPort(a0),rastport    ;and graphics RastPort
  339.  
  340.         move.l    GFX_LIB_PTR,a6        ;using graphics.library...
  341.         lea    textattr,a0
  342.         GFX    OpenFont        ;get Topaz 8 ROM font
  343.         move.l    d0,font_ptr
  344.         req
  345.  
  346.         move.l    d0,a0
  347.         GFXR    SetFont            ;use this font for our Window
  348. ;---------------
  349.         tst.l    show_regs        ;should we also open a register info
  350.         beq    no_regswin
  351.  
  352.         move.l    INTUI_LIB_PTR,a6    ;using Intuition again...
  353.  
  354.         move.l    #MyNewWindow,a0        ;modify initial NewWindow struct
  355.         add.w    #(WINDOW_WIDTH-386)/2,nw_LeftEdge(a0)
  356.         move.w    #386,nw_Width(a0)
  357.         move.w    #55,nw_Height(a0)
  358.         move.w    #50,nw_TopEdge(a0)
  359.         clr.l    nw_FirstGadget(a0)
  360.         clr.l    nw_IDCMPFlags(a0)    ;window generates NO messages
  361.         and.l    #~WINDOWCLOSE,nw_Flags(a0)    ;no close gadget on this win.
  362.         
  363.         move.l    #regswin_title,nw_Title(a0)
  364.         INTUI    OpenWindow        ;open output window (incl. slider gadg)
  365.         move.l    d0,regs_window        ;if ISAN.conf list too big then window
  366.         req                ;won't be able to open (too high)
  367.  
  368.         move.l    d0,a0
  369.         move.l    wd_RPort(a0),regswin_rp
  370.  
  371.         move.l    GFX_LIB_PTR,a6        ;switch to graphics library
  372.         move.l    font_ptr,a0
  373.         move.l    regswin_rp,a1
  374.         GFX    SetFont            ;use 8*8 font for our Window
  375.  
  376.         bsr    draw_regswin_txt
  377. ;---------------
  378. no_regswin    tst.l    profile_flag        ;should we also open a PC stats win?
  379.         beq    no_profile_win
  380.  
  381.         move.l    INTUI_LIB_PTR,a6    ;using Intuition again...
  382.         move.l    #MyNewWindow,a0
  383.         move.w    #512,nw_Height(a0)
  384.         move.w    #640,nw_Width(a0)
  385.         clr.w    nw_LeftEdge(a0)
  386.         clr.w    nw_TopEdge(a0)
  387.         clr.l    nw_FirstGadget(a0)
  388.         clr.l    nw_IDCMPFlags(a0)    ;window generates NO messages
  389.         and.l    #~WINDOWCLOSE,nw_Flags(a0)    ;no close gadget on this win.
  390.         
  391.         move.l    #prof_win_title,nw_Title(a0)
  392.         INTUI    OpenWindow        ;open output window (incl. slider gadg)
  393.         move.l    d0,prof_window        ;if ISAN.conf list too big then window
  394.         req                ;won't be able to open (too high)
  395.  
  396.         move.l    d0,a0
  397.         move.l    wd_RPort(a0),profwin_rp ;init its RastPort ptr
  398.  
  399.         move.l    GFX_LIB_PTR,a6        ;switch to graphics library
  400.         move.l    font_ptr,a0
  401.         move.l    profwin_rp,a1
  402.         GFX    SetFont            ;use 8*8 font for our Window
  403.  
  404.         move.l    profwin_rp,a1
  405.         moveq    #1,d0            ;use Black for text
  406.         GFX    SetAPen
  407. ;---------------
  408. no_profile_win    moveq    #-1,d0            ;NE = OK!
  409.         rts
  410. ;-----------------------------------------------
  411. ; Draw some static text in the freshly opened REGISTERS window.
  412. ;-----------------------------------------------
  413. draw_regswin_txt:
  414.         move.l    regswin_rp,a1
  415.         moveq    #1,d0            ;use Black for text
  416.         GFX    SetAPen
  417.  
  418.         lea    regstrings,a3        ;-> strings to print
  419.         moveq    #4-1,d7            ;print 4 lines of 4 registers
  420.         moveq    #PANE_Y+CHAR_HEIGHT,d4
  421.  
  422. pr_regline    moveq    #4-1,d6
  423.         moveq    #PANE_X,d3        ;reset cursor X
  424.  
  425. pr_reg        move.l    regswin_rp,a1
  426.         move.w    d3,d0
  427.         move.w    d4,d1
  428.         GFX    Move
  429.  
  430.         moveq    #3,d0
  431.         move.l    a3,a0
  432.         move.l    regswin_rp,a1
  433.         GFX    Text            ;print a string "Rn="
  434.  
  435.         lea    3(a3),a3        ;point to next string
  436.         add.w    #12*CHAR_WIDTH,d3
  437.         dbra    d6,pr_reg
  438.     
  439.         add.w    #CHAR_HEIGHT,d4        ;go down a line
  440.         dbra    d7,pr_regline
  441. ;---------------
  442.         move.l    regswin_rp,a1
  443.         moveq    #PANE_X,d0        ;reset cursor X
  444.         move.w    d4,d1
  445.         GFX    Move
  446.  
  447.         moveq    #3,d0
  448.         move.l    a3,a0
  449.         move.l    regswin_rp,a1
  450.         GFX    Text            ;"PC="
  451.  
  452.         rts
  453. ;-----------------------------------------------
  454. ; If user requested the GRAFMAP command line option,
  455. ; open lo-res 256*256 screen and draw the nibble reference grid.
  456. ;
  457. ; Every single opcode used by the traced Task will light up one pixel
  458. ; corresponding to its exact opcode (0..65535 !).
  459. ;-----------------------------------------------
  460. open_screen    move.l    INTUI_LIB_PTR,a6    ;because the opcode map screen is so
  461.         move.l    ib_FirstScreen(a6),a0    ;extremely narrow (256 pixels wide),
  462.         move.w    sc_Width(a0),d0        ;find out width of Workbench (+-)
  463.         lsr.w    #1,d0            ;(convert to lores pixels)
  464.         sub.w    #256,d0            ;and center our screen on monitor...
  465.         lsr.w    #1,d0
  466.  
  467.         lea    map_newscreen,a0
  468.         move.w    d0,ns_LeftEdge(a0)
  469.  
  470.         INTUI    OpenScreen        ;open graphical opcode usage display
  471.         move.l    d0,map_screen
  472.         req
  473.  
  474.         move.l    d0,a0
  475.         lea    sc_RastPort(a0),a2
  476.         move.l    GFX_LIB_PTR,a6
  477.  
  478.         move.l    a2,a1
  479.         moveq    #2,d0            ;write reference grid in plane 1
  480.         GFX    SetAPen
  481.  
  482.         moveq    #16-1,d7        ;write 16 horizontal lines
  483.         move.w    #12,d2            ;starting Y with (0,12)-(255,12)
  484.  
  485. draw_horiz    moveq    #0,d0
  486.         move.w    d2,d1
  487.         move.l    a2,a1            ;get RastPort ptr
  488.         GFX    Move
  489.  
  490.         move.w    #255,d0
  491.         move.w    d2,d1
  492.         move.l    a2,a1
  493.         GFX    Draw
  494.  
  495.         add.w    #16,d2            ;increment Y
  496.         dbra    d7,draw_horiz
  497. ;---------------
  498.         moveq    #16-1,d7        ;write 16 vertical lines
  499.         moveq    #0,d2            ;starting with (0,12)-(0,255+12)
  500.  
  501. draw_vert    move.w    d2,d0
  502.         moveq    #12,d1
  503.         move.l    a2,a1
  504.         GFX    Move
  505.  
  506.         move.w    d2,d0
  507.         move.w    #12+255,d1
  508.         move.l    a2,a1
  509.         GFX    Draw
  510.  
  511.         add.w    #16,d2            ;increment X
  512.         dbra    d7,draw_vert
  513.  
  514.         moveq    #-1,d0            ;return OK.
  515.         rts
  516. ;-----------------------------------------------
  517. ; Error EXITS (print error, clean up and quit)
  518. ;-----------------------------------------------
  519. no_memory    lea    no_arr_mem,a0
  520.         bsr    print_error
  521.         bra    bail_out
  522. ;-----------------------------------------------
  523. want_dollar_hex    lea    dollars_please,a0
  524.         bsr    print_error
  525.         bra    bail_out
  526. ;-----------------------------------------------
  527. bad_procnum    lea    dec_procnum,a0
  528.         bsr    print_error
  529.         bra    bail_out
  530. ;-----------------------------------------------
  531. give_syntax    lea    syntax,a0
  532.         bsr    print_error
  533.         bra    bail_out
  534. ;-----------------------------------------------
  535. cant_find_conf    lea    no_conf,a0
  536.         bsr    print_error
  537.         bra    bail_out
  538. ;-----------------------------------------------
  539. task_doesnt_exist
  540.         lea    bad_task,a0
  541.         bsr    print_error
  542.         bra    bail_out
  543. ;-----------------------------------------------
  544. proc_doesnt_exist
  545.         lea    bad_proc,a0
  546.         bsr    print_error
  547.         bra    bail_out
  548. ;-----------------------------------------------
  549. wrong_mode    lea    bad_trace_mode,a0
  550.         bsr    print_error
  551.         bra    bail_out
  552. ;-----------------------------------------------
  553. invalid_update_sp
  554.         lea    bad_speed,a0
  555.         bsr    print_error
  556.         bra    bail_out
  557. ;-----------------------------------------------
  558. cant_get_window    lea    win_too_big,a0
  559.         bsr    print_error
  560.         bra    bail_out
  561. ;-----------------------------------------------
  562. task_or_proc_please
  563.         lea    plonker,a0
  564.         bsr    print_error
  565.         bra    bail_out
  566. ;-----------------------------------------------
  567. need_020    lea    wrong_machine,a0
  568.         bsr    print_error
  569.         bra    bail_out
  570. ;-----------------------------------------------
  571. bad_conf_err    lea    bad_conf_file,a0
  572.         bsr    print_error
  573.         bra    bail_out
  574. ;-----------------------------------------------
  575. no_mem_for_descr
  576.         lea    no_descr_mem,a0
  577.         bsr    print_error
  578.         bra    bail_out
  579. ;-----------------------------------------------
  580. no_screen    lea    no_screen_str,a0
  581.         bsr    print_error
  582.         bra    bail_out
  583.  
  584. ;-----------------------------------------------
  585. ; Check our Window's IDCMP MessagePort for any Intuition events.
  586. ;-----------------------------------------------
  587.  
  588. handle_IDCMP
  589. while_msgs    move.l    4.w,a6
  590.         move.l    msgport,a0
  591.         EXEC    GetMsg            ;dequeue IntuiMessage.
  592.         tst.l    d0
  593.         req                ;if no event: exit
  594.  
  595.         move.l    d0,a1            ;A1 -> IntuiMessage
  596.         move.l    im_Class(a1),imsg_class    ;copy relevant message info
  597.         move.w    im_Code(a1),imsg_code
  598.         move.l    im_IAddress(a1),imsg_iaddr
  599.         move.l    im_MouseX(a1),imsg_ratcords    ;relative to window
  600.         EXEC    ReplyMsg        ;and return msg to Intuition
  601.  
  602.         move.l    imsg_class,d0        ;now find routine to execute
  603.         lea    event_routines,a0    ;for this event
  604.         bra    wh_msg_types
  605.  
  606. possible_event    move.l    (a0)+,a1        ;assuming this type: get vector
  607.         cmp.l    d0,d1            ;is this the event type we got ?
  608.         beq    handle_event        ;yes: go exec handler for this type.
  609.  
  610. wh_msg_types    move.l    (a0)+,d1        ;get possible event type
  611.         bpl    possible_event
  612.         bra    while_msgs
  613. ;---------------
  614. handle_event    jsr    (a1)            ;yes, process event
  615.         bra    while_msgs        ;any other events queued up?
  616.  
  617. ;=======================================================================
  618.         EVEN
  619. event_routines
  620. ;        dc.l    MOUSEMOVE,follow_mouse    ;when moving about in gadget
  621. ;        dc.l    GADGETDOWN,gadget_on    ;when first clicked
  622. ;        dc.l    MENUPICK,handle_menus    ;when selecting menu items
  623. ;        dc.l    RAWKEY,keypress        ;for value entry & arrow keys
  624.  
  625.         dc.l    GADGETUP,gadget_off    ;when released
  626.         dc.l    MOUSEBUTTONS,handle_click ;any clicks in Window
  627.         dc.l    CLOSEWINDOW,kill_program
  628.  
  629.         dc.l    -1            ;end of list
  630. ;=======================================================================
  631.  
  632. ;-----------------------------------------------
  633. ; User messed around with our slider gadget and finally released it.
  634. ; Read new knob position and adjust program update speed accordingly.
  635. ;-----------------------------------------------
  636.  
  637. gadget_off    lea    GadgetSInfo,a0        ;-> PropInfo struct for our slider
  638.  
  639.         moveq    #0,d0
  640.         move.w    pi_VertPot(a0),d0    ;get new pot setting    (0..64K)
  641.         moveq    #9,d1
  642.         lsr.w    d1,d0            ;scale it down a bit    (0..127)
  643.         move.l    d0,update_speed        ;max Delay() is 2.54 secs (127)
  644.         rts
  645. ;-----------------------------------------------
  646. ; Any click inside our window resets all counters (resets graphs to zero).
  647. ;-----------------------------------------------
  648. handle_click    move.w    imsg_code,d0        ;discard release clicks
  649.         and.w    #$0080,d0
  650.         rne
  651.  
  652.         move.l    counters,a0        ;-> array of LONG counters
  653.         moveq    #-1,d0
  654.         moveq    #0,d1
  655. reset_counters    move.l    d1,(a0)+        ;wipe all 65536 counters clean
  656.         dbra    d0,reset_counters
  657.  
  658. wipe_counters    move.l    GFX_LIB_PTR,a6
  659.         moveq    #0,d0            ;switch to background color for wipe
  660.         GFXR    SetAPen
  661.  
  662.         moveq    #PANE_X,d0        ;top-left corner for rectfill
  663.         moveq    #PANE_Y+2,d1
  664.         add.w    label_len,d0
  665.  
  666.         move.w    d0,d2            ;calc bot-right corner coords
  667.         move.w    d1,d3
  668.         add.w    #HEXNUM_SPACE-1,d2
  669.         add.w    contents_height,d3
  670.         add.w    #1,d3
  671.         GFXR    RectFill        ;wipe previous counters
  672.  
  673.         rts
  674. ;-----------------------------------------------
  675. kill_program    st    close_me        ;signal main loop to exit.
  676.         rts
  677.  
  678. ;-----------------------------------------------
  679. ; Analyse cached "ISAN.config" file.
  680. ; Validate format and create data structures for contents, the free file.
  681. ; Each line is either a comment line or a line with three comma-separated fields:
  682. ;    OPCODE,MASK,LABEL
  683. ;
  684. ; If argument flag "TOTAL" was present, add two special entries to show TOTAL
  685. ; number of instructions counted !!
  686. ;-----------------------------------------------
  687.  
  688. read_configuration
  689.         clr.w    opcodes            ;clr # of opcodes encountered
  690.         lea    count_opcodes,a5
  691.         bsr    scan_file        ;go through file and count opcode lines
  692.  
  693.         tst.l    total_flag        ;did user ask for automatic TOTAL too?
  694.         beq    get_descr_array
  695.         addq.w    #2,opcodes        ;make room for 2 more special entries
  696.  
  697. get_descr_array    move.l    4.w,a6
  698.         move.w    opcodes,d0        ;now allocate a memory block to hold
  699.         beq    bad_conf_err        ;exactly N Opcode descriptors structs
  700.  
  701.         mulu    #opc_sizeof,d0
  702.         move.l    d0,array_size
  703.         move.l    #MEMF_CLEAR|MEMF_PUBLIC,d1
  704.         EXEC    AllocMem
  705.         move.l    d0,opcode_list        ;opcode_list -> array to fill in.
  706.         beq    no_mem_for_descr
  707.  
  708.         moveq    #0,d7            ;max label length so far..
  709.  
  710.         move.l    opcode_list,a4        ;-> descriptor array to initialise
  711.         tst.l    total_flag        ;if total flag is set add our two
  712.         beq    fill_descriptors    ;special entries at the top of list
  713. ;---------------
  714.         moveq    #5,d7            ;max label length so far...
  715.  
  716.         move.w    #1,opc_combis(a4)
  717.         move.w    #SPECIAL1,opc_base_op(a4)  ;use an A-line opcode to signal
  718.         clr.w    opc_nocare_mask(a4)       ;special TOTAL "opcode"
  719.         move.l    #total_label,opc_label(a4) ;point to built-in label
  720.         move.w    d7,opc_label_len(a4)
  721.         add.l    #opc_sizeof,a4        ;point to next free slot
  722.  
  723.         move.w    #1,opc_combis(a4)       ;do a similar thing to get an
  724.         move.w    #SPECIAL2,opc_base_op(a4)  ;"underline" entry !
  725.         clr.w    opc_nocare_mask(a4)
  726.         move.l    #underline_label,opc_label(a4)
  727.         move.w    d7,opc_label_len(a4)
  728.         add.l    #opc_sizeof,a4        ;point to next free slot
  729. ;---------------
  730. fill_descriptors
  731.         lea    get_data,a5        ;go through file again but grab data
  732.         bsr    scan_file        ;to fill in descriptors.
  733.         bne    bad_conf_err
  734.  
  735.         mulu    #CHAR_WIDTH,d7        ;calc howmany width pixels labels
  736.         move.w    d7,label_len        ;will take up.
  737.  
  738.         move.w    opcodes,d0        ;calc howmany pixels high instruction
  739.         mulu    #CHAR_HEIGHT,d0        ;list will be
  740.         sub.w    #3,d0            ; - a bit to avoid wiping window edge
  741.         move.w    d0,contents_height
  742.  
  743.         add.w    #PANE_Y+8,d0        ;and automaticaly size
  744.         move.w    d0,win_h        ;window and
  745.         sub.w    #16,d0
  746.         move.w    d0,gad_h        ;attached slider gadget.
  747. ;---------------
  748.         rts
  749. ;-----------------------------------------------
  750. ; Go through cached ISAN.config file line-by-line and execute a user routine for
  751. ; every line starting with a "$".
  752. ; 
  753. ; A4 -> Opcode descriptor array ptr
  754. ; A5 -> user routine to execute
  755. ; RETURNS (NE) if error occurred.
  756. ;-----------------------------------------------
  757. scan_file    move.l    conf_buffer,a0        ;-> cached ISAN.conf file
  758.  
  759.         bra    wh_lines
  760. ;---------------
  761. check_line    cmp.b    #'$',(a0)        ;instruction line ?
  762.         beq    handle_line        ;no, skip over entire line
  763.  
  764. skip_comment    move.b    (a0)+,d0
  765.         beq    file_eof
  766.         cmp.b    #LF,d0
  767.         bne    skip_comment
  768.         bra    wh_lines
  769. ;---------------
  770. handle_line    addq.w    #1,a0            ;skip "$"
  771.         jsr    (a5)            ;exec routine for a line starting w. $
  772.         bra    skip_comment
  773. ;---------------
  774. wh_lines    tst.b    (a0)            ;reached EOF yet ?
  775.         bne    check_line
  776. ;---------------
  777. file_eof    rts
  778.         
  779. ;-----------------------------------------------
  780. ; Initial user routine for scan_file to count opcode lines
  781. ;-----------------------------------------------
  782. count_opcodes    addq.w    #1,opcodes        ;just keep track of "$" lines
  783.         rts
  784. ;-----------------------------------------------
  785. ; Decode a $XXXX,$MMMM,"label" line
  786. ;
  787. ; A0 -> start of current line
  788. ; A4 -> next free Opcode descriptor slot
  789. ; D7 = maximum label length
  790. ;-----------------------------------------------
  791.  
  792. get_data    bsr    hex_to_bin        ;get basic opcode pattern
  793.         move.w    d0,opc_base_op(a4)
  794.  
  795.         cmp.b    #COMMA,(a0)+        ;need delimiter
  796.         bne    bad_conf_err
  797.         cmp.b    #'$',(a0)+        ;need hex number qualifier
  798.         bne    bad_conf_err
  799.  
  800.         bsr    hex_to_bin        ;get dont care mask
  801.         move.w    d0,opc_nocare_mask(a4)
  802.  
  803.         bsr    count_ones_in_D0    ;calc howmany opcode combinations
  804.         moveq    #0,d1            ;dont care mask means !
  805.         bset    d0,d1
  806.         move.w    d1,opc_combis(a4)
  807.  
  808.         cmp.b    #COMMA,(a0)+        ;need delimiter
  809.         bne    bad_conf_err
  810.         cmp.b    #DOUBLE_QUOTE,(a0)+    ;followed by start of string
  811.         bne    bad_conf_err
  812.     
  813.         move.l    a0,opc_label(a4)    ;store ptr to label string
  814.         move.l    a0,a1
  815.  
  816. calc_lab_len    cmp.b    #DOUBLE_QUOTE,(a1)+
  817.         bne    calc_lab_len        ;find end of label
  818.  
  819.         sub.l    opc_label(a4),a1    ;calc label length
  820.         sub.w    #1,a1
  821.         move.w    a1,opc_label_len(a4)
  822.  
  823.         cmp.w    d7,a1            ;label longer than all prev ones?
  824.         bcs    no_new_max
  825.         move.w    a1,d7            ;yes, update max length
  826. no_new_max    
  827.  
  828.         add.l    #opc_sizeof,a4        ;point to next free slot
  829.         rts
  830.  
  831. ;===================================================================================
  832. ; Go through opcode_list and stats array and generate list of opcode counters
  833. ; which we need to display.
  834. ; Find Maximum counter and scale all counters for clean display in window.
  835. ;
  836. ; LOOP REGISTERS:
  837. ;    D6 = maximum frequency so far
  838. ;    D7 = # of opcodes/groups to display
  839. ;    A4 -> current opcode descriptor
  840. ;    A5 -> base of counters array
  841. ;===================================================================================
  842.  
  843. scan_stats    move.l    4.w,a6            ;stop target Task (and all others!)
  844.         FORBID                ;so we can make consistent freq counts
  845.  
  846.         moveq    #0,d6            ;max freq so far
  847.         clr.l    most_frequent        ;clr ptr to slot of highest freq opc
  848.  
  849.         move.w    opcodes,d7        ;# of opcodes (groups) to scan
  850.         subq.w    #1,d7            ;-1 DBRA 
  851.         move.l    opcode_list,a4        ;-> array of opcode descriptors
  852.         move.l    counters,a5        ;-> 1 LONG for every 680x0 opcode!
  853.  
  854. ;---------------
  855. check_op_group    move.w    opc_combis(a4),d5    ;range of instructions or single ?
  856.         subq.w    #1,d5            ;(-1 DBRA)
  857.         bne    handle_range
  858.  
  859.         moveq    #0,d0            ;clear for LONG index !
  860.         move.w    opc_base_op(a4),d0    ;get opcode (all bits significant)
  861.         cmp.w    #SPECIAL1,d0
  862.         beq    calc_fast_total
  863.  
  864.         move.l    0(a5,d0.l*4),d1        ;get current cnt for this instruction
  865.         bra    update_max        ;join main flow again...
  866. ;---------------
  867. ; Here we go through counters array linearly and find total sum of instructions
  868. ; executed so far. This is faster than using the general purpose mask technique.
  869. ;---------------
  870. calc_fast_total    move.l    a5,a0
  871.         moveq    #0,d1            ;clear counter
  872.         move.w    #(65536/8)-1,d0        ;add up all 65536 LONG counters
  873. zap_through_it    add.l    (a0)+,d1        ;as quickly as possible...
  874.         add.l    (a0)+,d1
  875.         add.l    (a0)+,d1
  876.         add.l    (a0)+,d1
  877.         add.l    (a0)+,d1
  878.         add.l    (a0)+,d1
  879.         add.l    (a0)+,d1
  880.         add.l    (a0)+,d1
  881.         dbra    d0,zap_through_it
  882.  
  883. ;-- for TOTAL "opcode" we have a custom update_max which doesn't touch most_frequent
  884.         move.l    d1,opc_freq(a4)        ;remember locally
  885.         cmp.l    d6,d1            ;need to update maximum freq ?
  886.         bcs    next_opc
  887.         move.l    d1,d6            ;new max freq = current inst freq
  888.         bra    next_opc
  889.  
  890. ;---------------
  891. ; Here we have to generate ALL possible opcodes given the opcode template and
  892. ; the Don't Care bits mask.
  893. ; This isn't as straightforward as you might think.
  894. ;
  895. ; D7 = outer opcodes loop counter
  896. ; D6 = maximum frequency so far
  897. ; D5 = # of combinations in this opcode group
  898. ;---------------
  899.  
  900. handle_range    move.w    opc_nocare_mask(a4),d4    ;get dont care mask
  901.         move.w    opc_base_op(a4),d3    ;get opcode TEMPLATE
  902.  
  903.         move.w    d4,d2
  904.         not.w    d2            ;inverted dont care mask
  905.         and.w    d2,d3            ;d3 = 100% clean template mask
  906.  
  907. ; Say we have a dont care mask of $0E43. That's a mask with 3 bitfields that we
  908. ; should increment as if it were ONE contiguous bitfield.
  909. ; This is achieved by forcing all bits inbetween the bitfields to '1' and adding
  910. ; an "add mask" (the LSb '1' in the original mask); this way carry bits from a
  911. ; bitfield are transported across a 1s "bridge" to the next bitfield etc..
  912. ; The final opcode is derived from this "work" opcode and the original template by
  913. ; some ANDing and ORing.
  914.  
  915.         move.w    d4,d0            ;original don't care mask
  916.         moveq    #-1,d1            ;calc the "add mask"
  917. find_first_lsb    addq.w    #1,d1            ;(= the lowest 1 bit in the mask on
  918.         lsr.w    #1,d0            ;its own).
  919.         bcc    find_first_lsb
  920.         moveq    #0,d0
  921.         bset    d1,d0            ;D0 is add mask.
  922.  
  923.         sub.l    a0,a0            ;clr accumulated freq of opc family
  924.         moveq    #0,d1            ;FOR CNT=0 TO COMBI-1
  925. ;--------
  926. gen_codes    and.w    d4,d1            ;mask out "scattered count"
  927.         or.w    d3,d1            ;or in clean template = final opcode
  928.  
  929.         add.l    0(a5,d1.l*4),a0        ;add its freq to total group freq
  930.  
  931.         or.w    d2,d1            ;0 holes = bitfields
  932.         add.w    d0,d1            ;"add" across bitfield voids
  933.  
  934.         dbra    d5,gen_codes        ;all possible combinations generated?
  935.  
  936.         move.l    a0,d1            ;sum total of opcode group
  937. ;---------------
  938. update_max    move.l    d1,opc_freq(a4)        ;total # of ops of this type counted
  939.         cmp.l    d6,d1            ;need to update maximum freq ?
  940.         bcs    next_opc
  941.  
  942.         move.l    d1,d6            ;new max freq = current inst freq
  943.         move.l    a4,most_frequent    ;remember most freq opc slot
  944. ;---------------
  945. next_opc    add.l    #opc_sizeof,a4        ;goto next descriptor
  946.         dbra    d7,check_op_group    ;all done ?
  947.  
  948. ;-----------------------------
  949. ; We've gone through all opcodes we want to snoop on.
  950. ; From the found maximum frequency normalize all frequencies so that max = $FFFFFFFF
  951. ;-----------------------------
  952.  
  953.         or.b    #1,d6            ;force max freq to have at least one 1 bit
  954.         bfffo    d6{0:32},d0        ;find # of LEFT shifts to normalize max
  955.  
  956.         move.w    opcodes,d7        ;# of opcodes (groups) to scan
  957.         subq.w    #1,d7            ;-1 DBRA 
  958.         move.l    opcode_list,a4        ;-> array of opcode descriptors
  959.  
  960. norm_counts    move.l    opc_freq(a4),d1        ;get original frequency
  961.         lsl.l    d0,d1            ;normalize it
  962.         move.l    d1,opc_xfreq(a4)    ;store normalized frequency
  963.  
  964.         add.l    #opc_sizeof,a4        ;goto next descriptor
  965.         dbra    d7,norm_counts        ;all done ?
  966.  
  967.         move.l    4.w,a6            ;thanks for hanging around guys...!
  968.         PERMIT                ;carry on now..
  969.     
  970.         rts
  971. ;-----------------------------------------------
  972. ; Redraw ENTIRE contents of Window.    (**!! Should optimize)
  973. ;-----------------------------------------------
  974. update_windows    bsr    update_op_counters
  975.         bsr    update_registers
  976.         bsr    update_PC_counters
  977.         rts
  978. ;-----------------------------------------------
  979. ; Update the main statistics window containing opcode usage frequencies.
  980. ;-----------------------------------------------
  981. update_op_counters
  982.         move.l    GFX_LIB_PTR,a6        ;using graphics.library...
  983.         moveq    #1,d0            ;set color for labels & hex frequencies
  984.         GFXR    SetAPen
  985.  
  986.         moveq    #PANE_X,d5        ;initial cursor coords.
  987.         moveq    #PANE_Y+CHAR_HEIGHT,d6
  988.  
  989.         move.w    opcodes,d7        ;# of graphs/labels to draw
  990.         subq.w    #1,d7
  991.         move.l    opcode_list,a4        ;-> array of opcode descriptors
  992. ;---------------
  993. draw_labels    tst.b    add_labels        ;have labels already been printed ?
  994.         beq    skip_labels        ;yes, don't print again (since static)
  995.  
  996.         move.w    d5,d0
  997.         move.w    d6,d1
  998.         GFXR    Move            ;set text cursor for label
  999.  
  1000.         move.l    opc_label(a4),a0
  1001.         move.w    opc_label_len(a4),d0
  1002.         GFXR    Text            ;print label
  1003.  
  1004. skip_labels    move.l    opc_freq(a4),d0        ;create hex string from freq.
  1005.         beq    zero_cnt        ;if freq is zero then just print "0"
  1006.  
  1007.         moveq    #8,d1            ;otherwise print hex number as eight
  1008.         lea    hex_output,a0        ;full digits
  1009.         bsr    bin_hex
  1010.  
  1011.         move.w    d5,d0
  1012.         move.w    d6,d1
  1013.         add.w    label_len,d0        ;just after labels...
  1014.         GFXR    Move            ;set cursor for frequency
  1015.  
  1016.         moveq    #8,d0
  1017.         lea    hex_output,a0
  1018.         GFXR    Text            ;print hex frequency 'xxxxxxxx'
  1019.         bra    do_labels
  1020. ;--------
  1021. zero_cnt    move.w    d5,d0
  1022.         move.w    d6,d1
  1023.         add.w    label_len,d0        ;just after labels...
  1024.         add.w    #7*CHAR_WIDTH,d0    ;(strip leading zeros)
  1025.         GFXR    Move            ;set cursor for frequency
  1026.  
  1027.         moveq    #1,d0
  1028.         lea    a_zero,a0
  1029.         GFXR    Text            ;print hex frequency '       0'
  1030.  
  1031. do_labels    add.w    #CHAR_HEIGHT,d6        ;down one line
  1032.         add.l    #opc_sizeof,a4        ;goto next descriptor
  1033.         dbra    d7,draw_labels
  1034.  
  1035.         sf    add_labels        ;from now: never draw labels again
  1036. ;---------------
  1037. wipe_graph_area    moveq    #0,d0            ;switch to background color for wipe
  1038.         GFXR    SetAPen
  1039.  
  1040.         moveq    #PANE_X+HEXNUM_SPACE,d0    ;top-left corner for rectfill
  1041.         add.w    label_len,d0
  1042.         moveq    #PANE_Y+3,d1
  1043.  
  1044.         moveq    #PANE_X,d2        ;calc bot-right corner coords
  1045.         add.w    win_width,d2
  1046.         sub.w    #GADG_WIDTH,d2
  1047.         move.w    contents_height,d3
  1048.         add.w    d1,d3
  1049.         GFXR    RectFill        ;wipe previous graphs display
  1050. ;---------------
  1051.         moveq    #0,d0
  1052.         move.w    win_width,d0        ;total window width
  1053.         sub.w    label_len,d0        ;- area where labels go
  1054.         sub.w    #PANE_X+HEXNUM_SPACE+5,d0 ;= available drawing length
  1055.  
  1056.         bfffo    d0{0:32},d4        ;calc window width scale factor
  1057.         addq.w    #1,d4
  1058. ;---------------
  1059.         moveq    #PANE_Y+4,d6
  1060.         moveq    #PANE_X+HEXNUM_SPACE,d5    ;initial pen X,Y
  1061.         add.w    label_len,d5
  1062.         add.w    #2,d5
  1063.  
  1064.         move.w    opcodes,d7        ;# of graphs/labels to draw
  1065.         subq.w    #1,d7
  1066.         move.l    opcode_list,a4        ;-> array of opcode descriptors
  1067.  
  1068. draw_graph    tst.l    opc_xfreq(a4)        ;any graph to draw at all ??
  1069.         beq    skip_graph        ;yes, (freq non-zero)
  1070.  
  1071.         moveq    #2,d0            ;assume normal graph color
  1072.         cmp.l    most_frequent,a4    ;does this slot represent max freq?
  1073.         bne    draw_line        ;yes,
  1074.  
  1075.         moveq    #1,d0            ;highlight longest opcode graph
  1076.  
  1077. draw_line    GFXR    SetAPen            ;select color for graph
  1078.  
  1079.         move.w    d5,d0
  1080.         move.w    d6,d1
  1081.         GFXR    Move            ;Move to start of line
  1082.  
  1083.         move.l    opc_xfreq(a4),d0    ;get LONG normalized inst. freq.
  1084.         lsr.l    d4,d0            ;scale to fit window
  1085.         add.w    d5,d0            ;add positioning offset
  1086.         move.w    d6,d1
  1087.         GFXR    Draw            ;draw a bargraph line
  1088.  
  1089. skip_graph    add.w    #CHAR_HEIGHT,d6        ;down one line
  1090.         add.l    #opc_sizeof,a4        ;goto next descriptor
  1091.         dbra    d7,draw_graph
  1092.         rts
  1093. ;-----------------------------------------------
  1094. ;-- Now optionally dump all registers in REGISTER window
  1095. ;-----------------------------------------------
  1096. update_registers
  1097.         tst.l    regswin_rp        ;if no register window: don't
  1098.         req
  1099.  
  1100.         lea    regs_dump,a3        ;-> 16 registers to display
  1101.  
  1102.         moveq    #4-1,d7            ;print 4 lines of 4 registers
  1103.         moveq    #PANE_Y+CHAR_HEIGHT,d4
  1104.  
  1105. print_regline    moveq    #4-1,d6
  1106.         moveq    #PANE_X+3*CHAR_WIDTH,d3    ;reset cursor X
  1107.  
  1108. print_reg    move.l    regswin_rp,a1
  1109.         move.w    d3,d0
  1110.         move.w    d4,d1
  1111.         GFX    Move
  1112.  
  1113.         move.l    (a3)+,d0        ;get a register value
  1114.         moveq    #8,d1
  1115.         lea    hex_output,a0
  1116.         bsr    bin_hex            ;convert to ASCII string
  1117.  
  1118.         moveq    #8,d0
  1119.         lea    hex_output,a0
  1120.         move.l    regswin_rp,a1
  1121.         GFX    Text
  1122.  
  1123.         add.w    #12*CHAR_WIDTH,d3
  1124.         dbra    d6,print_reg
  1125.     
  1126.         add.w    #CHAR_HEIGHT,d4
  1127.         dbra    d7,print_regline
  1128. ;---------------
  1129.         move.l    (a3)+,d0        ;get PC register value
  1130.         moveq    #8,d1
  1131.         lea    hex_output,a0
  1132.         bsr    bin_hex            ;convert to ASCII string
  1133.  
  1134.         move.l    regswin_rp,a1
  1135.         moveq    #PANE_X+3*CHAR_WIDTH,d0    ;reset cursor X
  1136.         move.w    d4,d1
  1137.         GFX    Move
  1138.  
  1139.         moveq    #8,d0
  1140.         lea    hex_output,a0
  1141.         move.l    regswin_rp,a1
  1142.         GFX    Text            ;"PC=XXXXXXXX"
  1143.         rts
  1144. ;-----------------------------------------------
  1145. ; Optionally update PC counters in PC PROFILE window.
  1146. ;-----------------------------------------------
  1147. update_PC_counters
  1148.         tst.l    profwin_rp        ;if no register window: don't
  1149.         req
  1150.  
  1151.         tst.w    num_PCs            ;if any PCs trapped yet...
  1152.         req
  1153.  
  1154.         move.l    PC_history_PCs,a3    ;-> N PC statistics to display
  1155.         move.l    PC_history_cnts,a4    ;->
  1156.  
  1157.         moveq    #0,d7            ;print N lines ...
  1158.  
  1159. print_PC_line    moveq    #0,d0
  1160.         move.w    d7,d0            ;list grows like newspaper columns
  1161.         divu    #42,d0
  1162.         move.l    d0,d1            ;save quotient
  1163.         swap    d0            ;get remainder down
  1164.         mulu    #CHAR_HEIGHT,d0
  1165.         add.w    #PANE_Y+CHAR_HEIGHT,d0
  1166.  
  1167.         mulu    #20*CHAR_WIDTH,d1
  1168.         add.w    #PANE_X,d1
  1169.  
  1170.         exg    d0,d1            ;AARRGGHHH !!
  1171.  
  1172.         move.w    d0,d3
  1173.         move.w    d1,d4
  1174.  
  1175.         move.l    profwin_rp,a1
  1176.         GFX    Move
  1177.  
  1178.         move.l    (a3),d0            ;get a PC register value
  1179.         moveq    #8,d1
  1180.         lea    hex_output,a0
  1181.         bsr    bin_hex            ;convert to ASCII string
  1182.  
  1183.         moveq    #8,d0
  1184.         lea    hex_output,a0
  1185.         move.l    profwin_rp,a1
  1186.         GFX    Text
  1187. ;------
  1188. just_print_cnt    move.w    d3,d0
  1189.         add.w    #10*CHAR_WIDTH,d0
  1190.         move.w    d4,d1
  1191.         move.l    profwin_rp,a1
  1192.         GFX    Move
  1193.  
  1194.         move.l    #'    ',hex_output
  1195.         move.l    #'   0',hex_output+4
  1196.         move.l    (a4)+,d0        ;get # of times PC got here (counter)
  1197.         moveq    #8,d1
  1198.         lea    hex_output,a0
  1199.         bsr    bin_hex            ;convert to ASCII string
  1200.  
  1201.         moveq    #8,d0
  1202.         lea    hex_output,a0
  1203.         move.l    profwin_rp,a1
  1204.         GFX    Text
  1205.  
  1206.         addq.w    #4,a3            ;-> next PC value
  1207.         addq.w    #1,d7
  1208.         cmp.w    num_PCs,d7        ;done entire list ?
  1209.         bne    print_PC_line
  1210.  
  1211.         rts
  1212. ;-----------------------------------------------
  1213. ; Go through counters array and plot a pixel in the map screen for every non-zero
  1214. ; counter.
  1215. ; We don't use a pixel plot routine (much too slow), instead we check 32 opcodes
  1216. ; in one go, creating a bunch of 32 pixels in a data reg and then we write this
  1217. ; to the screen.
  1218. ;-----------------------------------------------
  1219.  
  1220. LINE_SIZE    equ    32            ;bytes for a 256 pixels line
  1221.  
  1222. update_screen    tst.l    opcode_map        ;is screen enabled ?
  1223.         req                ;yep,
  1224.  
  1225.         move.l    map_screen,a1
  1226.         lea    sc_BitMap+bm_Planes(a1),a1
  1227.         move.l    (a1),a1            ;get bitplane 0 ptr
  1228.         add.l    #12*LINE_SIZE,a1    ;skip Screen Title/Dragbar area.
  1229.  
  1230.         move.l    counters,a0        ;get base address of counters array
  1231.         move.w    #(65536/32)-1,d7    ;check all opcodes in blocks of 32
  1232.  
  1233. plot_counters    moveq    #32-1,d1        ;construct 32 pixels in register
  1234.         moveq    #0,d0            ;clear pixel line LONG
  1235.  
  1236. constr_pixline    tst.l    (a0)+            ;opcode used at all ?
  1237.         beq    unused_opcode        ;yes,
  1238.         bset    d1,d0            ;set its pixel (use DBRA counter as bit #)
  1239.  
  1240. unused_opcode    dbra    d1,constr_pixline
  1241.  
  1242.         move.l    d0,(a1)+        ;blast 32 pixels into screen at a time
  1243.         dbra    d7,plot_counters
  1244.         rts
  1245. ;-----------------------------------------------
  1246. ; Set all program parameters to defaults before parsing argument line.
  1247. ;-----------------------------------------------
  1248.  
  1249. clear_results    clr.l    task_arg        ;
  1250.         clr.l    process_arg        ;
  1251.  
  1252.         move.l    #twenty,update_speed    ;DOS Delay() factor
  1253.         move.l    #one,trace_mode        ;default TRACE mode = 1
  1254.  
  1255.         clr.l    total_flag        ;don't add total counter !
  1256.         clr.l    profile_flag        ;don't use profiling
  1257.  
  1258.         move.w    #WINDOW_WIDTH,win_width    
  1259.  
  1260.         move.l    #default_conf,conf_file
  1261.  
  1262. dummy        rts
  1263.  
  1264. ;-----------------------------------------------
  1265. ; Validate user's Process ID.
  1266. ; Return EQ if Task exists
  1267. ;
  1268. ; IN : D7.L = Process #
  1269. ;
  1270. ; OUT: D2.L = Process TCB addr or NULL
  1271. ;-----------------------------------------------
  1272.  
  1273. check_process    move.l    4.w,a6            ;-> Exec Library
  1274.  
  1275.         DISABLE                ;no list altering while we look!
  1276.         lea    TaskWait(a6),a5        ;scan TaskWait list first (most likely)
  1277.         bsr    find_process
  1278.         bne    is_process
  1279.  
  1280.         lea    TaskReady(a6),a5    ;if not on Wait list, maybe on Ready
  1281.         bsr    find_process
  1282.  
  1283. is_process    ENABLE
  1284.         rts
  1285. ;-----------------------------------------------
  1286. ; Try to find Process N on given Task list
  1287. ; A5 -> List Head
  1288. ; D7.L = Process number
  1289. ;-----------------------------------------------
  1290. find_process    move.l    (a5),d1            ;get head of list
  1291.         beq    plist_end
  1292.  
  1293.         move.l    d1,a5            ;move LN_SUCC to curr Node ptr
  1294.  
  1295.         cmp.b    #NT_PROCESS,LN_TYPE(a5)    ;is this a Process ?
  1296.         bne    find_process        ;no, goto next Task
  1297.  
  1298.         cmp.l    pr_TaskNum(a5),d7    ;ok, is this the Process we want ?
  1299.         bne    find_process
  1300.  
  1301.         move.l    a5,d2            ;yes: return tcb addr.
  1302.         rts
  1303. ;---------------
  1304. plist_end    moveq    #0,d2            ;didn't find Process (return NULL)
  1305.         rts
  1306. ;-----------------------------------------------
  1307. ; Validate user's TASK address.
  1308. ; Return EQ if Task exists
  1309. ;-----------------------------------------------
  1310.  
  1311. check_taskaddr    move.l    4.w,a6            ;-> Exec Library
  1312.         move.l    tcb_ptr,a0        ;find Task node with this start adr
  1313.  
  1314.         DISABLE                ;no list altering while we look!
  1315.         move.l    TaskWait(a6),a5        ;scan TaskWait list first (most likely)
  1316.         bsr    find_task
  1317.         beq    is_task
  1318.  
  1319.         move.l    TaskReady(a6),a5    ;maybe a CPU hog then ?
  1320.         bsr    find_task
  1321.         beq    is_task
  1322.  
  1323.         ENABLE
  1324.         moveq    #-1,d0            ;NE = nope, couldn't find Task
  1325.         rts
  1326.  
  1327. is_task        ENABLE
  1328.         moveq    #0,d0            ;EQ = yep, found Task
  1329.         rts
  1330. ;-----------------------------------------------
  1331. ; Try to find Task X on given Task list
  1332. ; A5 -> List Head
  1333. ; A0 -> Task addr
  1334. ;-----------------------------------------------
  1335. find_task    tst.l    (a5)            ;is this node the Tail of list ?
  1336.         beq    list_tail        ;nope.
  1337.  
  1338.         cmp.l    a5,a0            ;check against user input
  1339.         beq    task_present        ;if match return EQ
  1340.  
  1341.         move.l    (a5),a5
  1342.         bra    find_task
  1343.  
  1344. list_tail    moveq    #-1,d0            ;else NE
  1345. task_present    rts
  1346. ;-----------------------------------------------
  1347. ; Modify the target Task's trace bits in its SR (stored in its saved context).
  1348. ; Point its TC_TRAP vectors to our stuff to handle all those TRACE exceptions.
  1349. ;-----------------------------------------------
  1350.  
  1351. start_task_traceing
  1352.         move.l    tcb_ptr,a5        ;-> Task/Process to snoop on.
  1353.  
  1354.         move.l    counters,TC_TRAPDATA(a5)    ;tell handler where counters are
  1355.         move.l    TC_TRAPCODE(a5),old_trapcode    ;save any old trap handlers
  1356.  
  1357.         lea    default_handler,a0    ;choose which trace handler to use
  1358.  
  1359.         tst.l    profile_flag
  1360.         beq    use_regs_maybe
  1361.  
  1362.         lea    proftrace_handler,a0
  1363.         bra    curse_task
  1364.  
  1365. use_regs_maybe    tst.l    show_regs
  1366.         beq    curse_task
  1367.         lea    rgtrace_handler,a0
  1368.  
  1369. curse_task    move.l    a0,TC_TRAPCODE(a5)    ;install our TRACE handler
  1370.  
  1371.         move.b    #$80,d0            ;assume normal TRACE mode (T1=1,T0=0)
  1372.         tst.l    trace_mode
  1373.         beq    normal_trace
  1374.         move.b    #$40,d0            ;T1=0, T0=0
  1375.  
  1376. normal_trace    move.l    4.w,a6
  1377.         DISABLE
  1378.         move.l    TC_SPREG(a5),a1        ;find Task's saved context
  1379.         and.b    #$3F,8(a1)        ;clear any trace bits already set.
  1380.         or.b    d0,8(a1)        ;go set TRACE bits in saved SR reg !
  1381.         ENABLE
  1382.         rts
  1383. ;-----------------------------------------------
  1384. ; We've got enough info on traced Task. Switch it back to normal mode.
  1385. ; **!! This doesn't check whether the Task is still actually there or not !
  1386. ;-----------------------------------------------
  1387.  
  1388. stop_task_traceing
  1389.         move.l    tcb_ptr,a5        ;get Task's TCB address
  1390.  
  1391.         move.l    4.w,a6            ;using Exec..
  1392.         DISABLE                ;freeze multi-tasking while modifying
  1393.  
  1394. ;**!!        move.l    old_trapcode,TC_TRAPCODE(a5)    ;restore original handler
  1395. ;        clr.l    TC_TRAPDATA(a5)
  1396.  
  1397.         move.l    TC_SPREG(a5),a1        ;find Task's saved context
  1398.         and.b    #$3F,8(a1)        ;clear T1, T0
  1399.         ENABLE
  1400.         rts
  1401.  
  1402. ;------------------------------------------------------------------------------------
  1403. ; This EXCEPTION handler is executed after EVERY instruction of the
  1404. ; target Task/Process once we switched "its" CPU into TRACE mode.
  1405. ;
  1406. ; ** THIS IS EFFECTIVELY THE CORE OF THE ENTIRE PROGRAM **
  1407. ;
  1408. ;------------------------------------------------------------------------------------
  1409.  
  1410.  
  1411. REGS_SAVED1    equ    2            ;size of "stack frame"
  1412.  
  1413.  
  1414. default_handler:
  1415.         addq.l    #4,SP            ;discard garbage that Exec added.
  1416.  
  1417.         move.l    a0,-(sp)        ;handler has to be transparent (like IRQ)
  1418.         move.l    d0,-(sp)        ;(2 * move is faster than movem)
  1419.  
  1420.         move.l    ([4]ThisTask),a0    ;find address of Task that trapped
  1421.         move.l    TC_TRAPDATA(a0),a0    ;get ptr to array of LONG counters
  1422.  
  1423.         moveq    #0,d0            ;clear MSW for following casting...
  1424.         move.w    ([sp,8+REGS_SAVED1*4]),d0  ;get opcode (cast to LONG)
  1425.         addq.l    #1,0(a0,d0.l*4)        ;increment this opcode's counter
  1426.  
  1427.         move.l    (sp)+,d0        ;restore used registers
  1428.         move.l    (sp)+,a0
  1429.  
  1430.         rte    ;ret to Task for just ONE instruction and come back here !
  1431. ;-----------------------------------------------
  1432. ;**!! The original trace handler used to use conservative 68000 addressing modes
  1433. ;**!! By using the new 68020+ modes we're able to use one address register less
  1434. ;**!! than before which in turns means less to save/restore.
  1435.  
  1436. ; The old code looked like this:
  1437.  
  1438. ;        move.l    4.w,a0            ;find address of Task that trapped.
  1439. ;        move.l    ThisTask(a0),a0
  1440. ;        move.l    TC_TRAPDATA(a0),a1    ;get ptr to array of LONG counters
  1441.  
  1442. ;        move.l    8+12(sp),a0        ;get address of opcode that trapped
  1443. ;        move.w    (a0),d0            ;get opcode
  1444.  
  1445. ;-----------------------------------------------
  1446. ; This is an alternative (slower) handler that also dumps all 680x0 registers.
  1447. ; This handler is only used when the user specifies the REGS option.
  1448. ;-----------------------------------------------
  1449.  
  1450. REGS_SAVED2    equ    2
  1451.  
  1452.  
  1453. rgtrace_handler:addq.l    #4,SP
  1454.  
  1455.         movem.l    d0-d7/a0-a6,regs_dump    ;dump all Dn/An registers
  1456.         move.l    8(sp),regs_dump+16*4    ;and PC
  1457. ;---------------
  1458.         move.l    a0,-(sp)
  1459.         move.l    d0,-(sp)
  1460.  
  1461.         move.l    USP,a0
  1462.         move.l    a0,regs_dump+15*4
  1463.  
  1464.         move.l    ([4]ThisTask),a0
  1465.         move.l    TC_TRAPDATA(a0),a0
  1466.  
  1467.         moveq    #0,d0
  1468.         move.w    ([sp,8+REGS_SAVED2*4]),d0
  1469.         addq.l    #1,0(a0,d0.l*4)
  1470.  
  1471.         move.l    (sp)+,d0
  1472.         move.l    (sp)+,a0
  1473.         rte
  1474. ;-----------------------------------------------
  1475. ; This is another alternative handler which also some PC register statistics.
  1476. ; This handler is only used when the user specifies the PROFILE option.
  1477. ;-----------------------------------------------
  1478.  
  1479. REGS_SAVED3    equ    4
  1480.  
  1481. proftrace_handler:
  1482.         addq.l    #4,SP
  1483.  
  1484.         movem.l    d0-d7/a0-a6,regs_dump    ;dump all Dn/An registers
  1485.         move.l    8(sp),regs_dump+16*4    ;and PC
  1486. ;---------------
  1487.         movem.l    d0-d1/a0-a1,-(sp)
  1488.  
  1489.         move.l    USP,a0
  1490.         move.l    a0,regs_dump+15*4
  1491.  
  1492.         move.l    ([4]ThisTask),a0
  1493.         move.l    TC_TRAPDATA(a0),a0
  1494.  
  1495.         moveq    #0,d0
  1496.         move.w    ([sp,8+REGS_SAVED3*4]),d0
  1497.         addq.l    #1,0(a0,d0.l*4)
  1498.  
  1499.         move.l    regs_dump+16*4,d0
  1500.         cmp.l    #$00F80000,d0
  1501.         bcs    non_ROM_PC
  1502.         cmp.l    #$01000000,d0
  1503.         bcs    skip_ROM_PC
  1504.  
  1505. non_ROM_PC    bsr    update_PC_hist
  1506.  
  1507. skip_ROM_PC    movem.l    (sp)+,d0-d1/a0-a1
  1508.         rte
  1509. ;-----------------------------------------------
  1510. ; Go through PC History array and update/add
  1511. ; a PC entry.
  1512. ;-----------------------------------------------
  1513. update_PC_hist    move.l    PC_history_PCs,a0    ;-> N PC values followed by N counters
  1514.         move.l    regs_dump+16*4,d1    ;get PC value of TRACE exception
  1515.  
  1516.         move.w    num_PCs,d0        ;how long is list to check ?
  1517.         beq    add_new_PC
  1518.  
  1519.         subq.w    #1,d0
  1520.  
  1521. check_history    cmp.l    (a0)+,d1        ;does this PC already occur in list?
  1522.         dbeq    d0,check_history
  1523.         bne    add_new_PC
  1524.  
  1525. inc_PC_counter    add.l    #(MAX_PC_HIST*4)-4,a0
  1526.         addq.l    #1,(a0)            ;yes, just incr. its counter
  1527.         rts
  1528.  
  1529. add_new_PC    cmp.w    #MAX_PC_HIST,num_PCs    ;stop storing new ones when full
  1530.         rcc
  1531.  
  1532.         move.l    PC_history_PCs,a0    ;otherwise
  1533.         move.l    PC_history_cnts,a1
  1534.  
  1535.         move.w    num_PCs,d0    
  1536.         move.l    d1,(a0,d0*4)        ;add new PC to list
  1537.         moveq    #1,d1
  1538.         move.l    d1,(a1,d0*4)        ;& init its counter
  1539.  
  1540.         addq.w    #1,num_PCs        ;keep track of size of list
  1541.         rts
  1542. ;-----------------------------------------------
  1543. ; Initialize some variables
  1544. ;-----------------------------------------------
  1545. init_isan    clr.l    window            ;clr ptrs to ensure safe freeing
  1546.         clr.l    regs_window        ;in case of allocation failure
  1547.         clr.l    prof_window
  1548.  
  1549.         clr.l    map_screen
  1550.         clr.l    font_ptr
  1551.  
  1552.         clr.l    PC_history_PCs
  1553.         clr.l    opcode_list
  1554.  
  1555.         clr.w    num_PCs            ;no PCs so far.
  1556.  
  1557.         sf    close_me        ;no need to quit just now...
  1558.         st    add_labels        ;first update pass we want labels
  1559.  
  1560.         rts
  1561. ;-----------------------------------------------
  1562. ; Open Dos, Graphics and Intuition libraries.
  1563. ;-----------------------------------------------
  1564. open_libs    move.l    4.w,a6            ;using Exec..
  1565.         lea    dosname,a1
  1566.         moveq    #0,d0
  1567.         EXEC    OpenLibrary        ;open DOS
  1568.         move.l    d0,DOS_LIB_PTR
  1569.         beq    beg_your_pardon
  1570.  
  1571.         lea    gfxname,a1
  1572.         moveq    #0,d0
  1573.         EXEC    OpenLibrary
  1574.         move.l    d0,GFX_LIB_PTR        ;open GFX
  1575.         beq    beg_your_pardon
  1576.  
  1577.         lea    intuiname,a1
  1578.         moveq    #0,d0
  1579.         EXEC    OpenLibrary        ;open Intuition
  1580.         move.l    d0,INTUI_LIB_PTR
  1581.  
  1582.         move.l    DOS_LIB_PTR,a6        ;and using DOS
  1583.         DOS    Output            ;get standard output filehandle
  1584.         move.l    d0,stdout
  1585.  
  1586. beg_your_pardon    rts
  1587. ;-----------------------------------------------
  1588. close_libs    move.l    4.w,a6            ;using Exec..
  1589.         move.l    DOS_LIB_PTR,d0
  1590.         beq    no_dos
  1591.         move.l    d0,a1
  1592.         EXEC    CloseLibrary        ;close DOS
  1593.  
  1594. no_dos        move.l    GFX_LIB_PTR,d0
  1595.         beq    no_gfx
  1596.         move.l    d0,a1
  1597.         EXEC    CloseLibrary        ;close GFX
  1598.  
  1599. no_gfx        move.l    INTUI_LIB_PTR,d0
  1600.         beq    done_lib_closures
  1601.         move.l    d0,a1
  1602.         EXEC    CloseLibrary        ;close Intuition
  1603. done_lib_closures
  1604.         rts
  1605. ;-----------------------------------------------
  1606. ; Convert hex string pointed to by A0 into binary.
  1607. ; Return in D0.L
  1608. ;-----------------------------------------------
  1609. hex_to_bin    moveq    #0,d0            ;clear accumulator
  1610.         bra    wh_nibbles
  1611.  
  1612. add_nibble    lsl.l    #4,d0
  1613.         add.b    d1,d0
  1614.  
  1615. wh_nibbles    moveq    #0,d1            ;(clear high byte of index reg)
  1616.         move.b    (a0)+,d1        ;get char
  1617.  
  1618.         sub.b    #'0',d1            ;make sure char is in set of legal
  1619.         bcs    not_hex            ;hex chars
  1620.         cmp.b    #'f'-'0',d1
  1621.         bhi    not_hex
  1622.  
  1623.         move.b    h2bin(PC,d1.w),d1    ;use char as index into lookup table
  1624.         bpl    add_nibble        ;if lookup gives valid nibble
  1625. ;---------------
  1626. not_hex        subq.w    #1,a0            ;backtrack to first non-hex char
  1627.         rts
  1628.  
  1629. h2bin        dc.b    0,1,2,3,4,5,6,7,8,9,-1,-1,-1,-1,-1,-1
  1630.         dc.b    -1,10,11,12,13,14,15,-1,-1,-1,-1,-1,-1,-1,-1,-1    ;@..'O'
  1631.         dc.b    -1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1    ;'P'.._
  1632.         dc.b    -1,10,11,12,13,14,15
  1633. ;-----------------------------------------------
  1634. ; Count number of '1' bits in D0.L
  1635. ; Return in D0.L
  1636. ;-----------------------------------------------
  1637.         EVEN
  1638. count_ones_in_D0
  1639.         moveq    #0,d1            ;zero count.
  1640.         moveq    #0,d2            ;dummy addition operand for ADDX
  1641.  
  1642. count_ones    add.l    d0,d0            ;shift a '0' or a '1' out in Carry
  1643.         addx.l    d2,d1            ;add 1 to count if C=1
  1644.         tst.l    d0
  1645.         bne    count_ones
  1646.  
  1647. found_all_ones    move.w    d1,d0
  1648.         rts
  1649.  
  1650. ;-----------------------------------------------
  1651. ; Leading Zero stripped BIN_HEX
  1652. ;-----------------------------------------------
  1653. bin_hex        move.l    a0,-(sp)
  1654.         move.l    d1,-(sp)
  1655.         bsr    BIN_HEX
  1656.         move.l    (sp)+,d1
  1657.         move.l    (sp)+,a0
  1658.  
  1659.         subq.w    #2,d1            ;-2 to leave at least 1 '0'
  1660. kill_leading_0    cmp.b    #'0',(a0)
  1661.         rne
  1662.         move.b    #' ',(a0)+
  1663.         dbra    d1,kill_leading_0
  1664.         rts
  1665. ;-----------------------------------------------
  1666. ; Here I IMPORT some handy MODULES
  1667. ;-----------------------------------------------
  1668.         include    SRC:UTILS/ReadArgs.s    ;argline parser (with std template)
  1669.         include    SRC:UTILS/load_file.s    ;entire file loader
  1670.         include SRC:MODULES/LIB1/BIN_HEX
  1671.         include    SRC:MODULES/LIB1/DEC_TO_BIN
  1672. ;-----------------------------------------------
  1673.         EVEN
  1674.  
  1675. MyNewWindow:
  1676.     dc.w    640-WINDOW_WIDTH-13    ;window XY origin relative to TopLeft of screen
  1677.     dc.w    0
  1678.     dc.w    WINDOW_WIDTH+13        ;window width and
  1679. win_h    dc.w    131            ;height (FILLED IN)
  1680.     dc.b    0,1            ;detail and block pens
  1681.  
  1682. ;IDCMP flags
  1683.     dc.l    CLOSEWINDOW+GADGETUP+MOUSEBUTTONS
  1684.  
  1685. ;Window flags
  1686.     dc.l    WINDOWDRAG+WINDOWDEPTH+WINDOWCLOSE+ACTIVATE+NOCAREREFRESH+REPORTMOUSE
  1687.  
  1688.     dc.l    Gadgets            ;first gadget in gadget list
  1689.     dc.l    NULL            ;custom CHECKMARK imagery
  1690.     dc.l    WindowName        ;window title
  1691.     dc.l    NULL            ;custom screen pointer
  1692.     dc.l    NULL            ;custom bitmap
  1693.     dc.w    5,5            ;minimum width and height
  1694.     dc.w    -1,-1            ;maximum width and height
  1695.     dc.w    WBENCHSCREEN        ;destination screen type
  1696.  
  1697. Gadgets    dc.l    NULL            ;next gadget
  1698.     dc.w    WINDOW_WIDTH-7        ;origin XY of hit box relative to window TopLeft
  1699.     dc.w    13
  1700.  
  1701.     dc.w    15            ;hit box width and
  1702. gad_h    dc.w    100            ;height (FILLED IN)
  1703.     dc.w    NULL            ;gadget flags
  1704.     dc.w    RELVERIFY        ;activation flags
  1705.     dc.w    PROPGADGET        ;gadget type flags
  1706.     dc.l    KnobImage        ;gadget border or image to be rendered
  1707.     dc.l    NULL            ;alternate imagery for selection
  1708.     dc.l    NULL            ;first IntuiText structure
  1709.     dc.l    NULL            ;gadget mutual-exclude long word
  1710.     dc.l    GadgetSInfo        ;SpecialInfo structure
  1711.     dc.w    NULL            ;user-definable data
  1712.     dc.l    NULL            ;pointer to user-definable data
  1713.  
  1714. GadgetSInfo:
  1715.     dc.w    AUTOKNOB+FREEVERT    ;PropInfo flags
  1716.     dc.w    0,$2800            ;horizontal and vertical pot values
  1717.     dc.w    3276,3276        ;horizontal and vertical body values
  1718.     dc.w    0,0,0,0,0,0        ;Intuition initialized and maintained variables
  1719.  
  1720. KnobImage:
  1721.     dc.w    0,$1E            ;XY origin relative to container TopLeft
  1722.     dc.w    7,5            ;Image width and height in pixels
  1723.     dc.w    0            ;number of bitplanes in Image
  1724.     dc.l    NULL            ;pointer to ImageData
  1725.     dc.b    $0000,$0000        ;PlanePick and PlaneOnOff
  1726.     dc.l    NULL            ;next Image structure
  1727.  
  1728. map_newscreen:
  1729.     dc.w    50,0            ;screen XY origin relative to View
  1730.     dc.w    256,256+12        ;screen width and height
  1731.     dc.w    2            ;screen depth (number of bitplanes)
  1732.     dc.b    0,1            ;detail and block pens
  1733.     dc.w    0            ;display modes for this screen
  1734.     dc.w    CUSTOMSCREEN        ;screen type
  1735.     dc.l    NULL            ;pointer to default screen font
  1736.     dc.l    NewScreenName        ;screen title
  1737.     dc.l    NULL            ;first in list of custom screen gadgets
  1738.     dc.l    NULL            ;pointer to custom BitMap structure
  1739.  
  1740. textattr    dc.l    topazname
  1741.         dc.w    CHAR_HEIGHT    ;ta_YSize = 8
  1742.         dc.b    0,0        ;Style and Flags = 0
  1743.  
  1744. topazname    dc.b    "topaz.font",0
  1745.  
  1746. ;-----------------------------------------------
  1747. ; Strings section
  1748. ;-----------------------------------------------
  1749.  
  1750. one        dc.b    "1",0        ;default trace mode
  1751. twenty        dc.b    "20",0        ;default trace update speed
  1752. a_zero        dc.b    "0"        ;a lonely zero char for printing a zero count
  1753. default_conf    dc.b    "S:ISAN.config",0
  1754.  
  1755. NewScreenName    dc.b    "ISAN Opcode Map (Opcode=$0000)",0
  1756.  
  1757. * Tag for VERSION command
  1758. version        dc.b    "$VER: ISAN 1.2 ©LVA 22/JAN/94",0
  1759. WindowName:    dc.b          "ISAN 1.2 ©LVA 22/JAN/94   ("
  1760. window_info    dc.b    "TASK $"
  1761. task_addr_str    dc.b    "XXYYZZQQ)",0    ;**!! Watch out that string doesn't overflow
  1762.  
  1763. regswin_title    dc.b    "Task Registers",0
  1764. prof_win_title    dc.b    "PC Profiling Info",0
  1765.  
  1766. syntax        dc.b    "Example:",LF
  1767.         dc.b    "  1> ISAN PROCESS 5 MODE 2 REGS GRAFMAP",0
  1768.  
  1769. no_arr_mem    dc.b    "Not enough contiguous RAM for statistics arrays.",0
  1770. no_descr_mem    dc.b    "No memory for instruction descriptors array (running LOW!).",0
  1771. dollars_please    dc.b    "Task addresses should have a '$' to denote hexadecimal.",0
  1772. dec_procnum    dc.b    "Process number should be a small decimal number.",0
  1773. no_conf        dc.b    "Couldn't find 'ISAN.config' file anywhere !",0
  1774. bad_conf_file    dc.b    "ISAN.config file contains garbage.",0
  1775. bad_task    dc.b    "Task not found on Waiting or Ready list.",0
  1776. bad_proc    dc.b    "Process not found on Waiting or Ready list.",0
  1777. bad_trace_mode    dc.b    "Trace mode should be 1 or 2 (1=trace all, 2=trace flow)",0
  1778. bad_speed    dc.b    "Speed must be in 1..500 range.",0
  1779. win_too_big    dc.b    "Couldn't open Window (opcode list too long?).",0
  1780. plonker        dc.b    "Please specify either a Task or a Process (not both).",0
  1781. wrong_machine    dc.b    "ISAN Only works on 68020+ machines. Sorry (better than crashing, innit ?)",0
  1782. no_screen_str    dc.b    "Couldn't open Screen for opcode bitmap display.",0
  1783.  
  1784. ISAN_template    dc.b    "TASK/K,PROCESS/K,SPEED/K,MODE/K,REGS/S,TOTAL/S,GRAFMAP/S,FILE/K,PROFILE/S",0
  1785.  
  1786.         EVEN
  1787. hex_output    dc.b    "XXXXYYYY",0
  1788. regstrings    dc.b    "D0=D1=D2=D3=D4=D5=D6=D7="
  1789.         dc.b    "A0=A1=A2=A3=A4=A5=A6=A7=PC="
  1790.  
  1791. total_label    dc.b    "TOTAL"
  1792. underline_label    dc.b    "-----"
  1793.  
  1794. dosname        DOSNAME
  1795. intuiname    INTNAME
  1796. gfxname        GRAFNAME
  1797.  
  1798. ;-----------------------------------------------
  1799. ; Variables (pointers, handles, counters, flags...)
  1800. ;-----------------------------------------------
  1801.  
  1802.         SECTION    isan_vars,BSS
  1803.  
  1804. DOS_LIB_PTR    ds.l    1
  1805. GFX_LIB_PTR    ds.l    1
  1806. INTUI_LIB_PTR    ds.l    1
  1807.  
  1808. stack_level    ds.l    1
  1809. arg_line    ds.l    1
  1810. stdout        ds.l    1
  1811.  
  1812. tcb_ptr        ds.l    1    ;TCB ptr to task we're messing with
  1813. old_trapcode    ds.l    1    ;ptr to original trap exception handler (to restore)
  1814.  
  1815. window        ds.l    1    ;pointer to our Window
  1816. regs_window    ds.l    1    ;-> Registers Window (if requested)
  1817. prof_window    ds.l    1    ;-> PC Profiling Win (if requested)
  1818.  
  1819. rastport    ds.l    1    ;and their RastPorts
  1820. regswin_rp    ds.l    1
  1821. profwin_rp    ds.l    1
  1822.  
  1823. font_ptr    ds.l    1    ;ptr to Topaz Font
  1824.  
  1825. map_screen    ds.l    1    ;ptr to opcode map screen (if asked for)
  1826.  
  1827. msgport        ds.l    1    ;Window's IDCMP Message Port
  1828. imsg_class    ds.l    1
  1829. imsg_iaddr    ds.l    1
  1830. imsg_ratcords    ds.l    1
  1831. imsg_code    ds.w    1
  1832.  
  1833. conf_size    ds.l    1    ;# of configuration file buffer
  1834. conf_buffer    ds.l    1    ;ptr to cached configuration file
  1835.  
  1836. counters    ds.l    1    ;-> 256K of LONG counters (1 long per opcode)
  1837. array_size    ds.l    1    ;szie of descriptor array
  1838. opcode_list    ds.l    1    ;array of opcode descriptors to scan each time
  1839. most_frequent    ds.l    1    ;address of slot representing most frequent opcode
  1840.  
  1841. regs_dump    ds.l    16+1    ;room for D0-D7/A0-USP, PC
  1842.  
  1843. opcodes        ds.w    1    ;# of opcodes to check.
  1844.  
  1845. win_width    ds.w    1
  1846. label_len    ds.w    1
  1847. contents_height    ds.w    1    ;height of used rectangle within window
  1848.  
  1849. close_me    ds.b    1    ;close window request flag
  1850. add_labels    ds.b    1    ;print labels first time only
  1851.  
  1852. num_PCs        ds.w    1    ;number of different non-sequential PCs so far
  1853.  
  1854. PC_history_PCs    ds.l    1    ;ptr to array of encountered PC values
  1855. PC_history_cnts    ds.l    1
  1856.  
  1857. ; Here we have the contiguous block of LONGs that ReadArgs() fills in
  1858. ;--------------------------------------------------------------------
  1859.         EVEN
  1860. rda_results
  1861. task_arg    ds.l    1    ;ptr to TASK address argument
  1862. process_arg    ds.l    1    ;ptr to PROCESS number argument
  1863. update_speed    ds.l    1    ;DOS Delay() value
  1864. trace_mode    ds.l    1    ;1 or 2 for TT=10 or TT=01
  1865. show_regs    ds.l    1    ;open extra Window to display Task's register set
  1866. total_flag    ds.l    1
  1867. opcode_map    ds.l    1    ;open opcode map screen
  1868. conf_file    ds.l    1    ;ptr to filename for configuration
  1869. profile_flag    ds.l    1    ;do PC profiling in MODE 2 tracing
  1870.  
  1871.  
  1872.         END
  1873.