home *** CD-ROM | disk | FTP | other *** search
/ C/C++ Interactive Guide / c-cplusplus-interactive-guide.iso / c_ref / csource3 / 147_01 / daytim.csm < prev    next >
Text File  |  1985-03-11  |  11KB  |  479 lines
  1. ;
  2. ;
  3. ;
  4. ; Contains:
  5. ;
  6. ;    timdif        a generic time difference routine
  7. ;                       originally written by Sigi Kluger, and
  8. ;                       modified to work as a .CSM for BDS-C.
  9. ;
  10. ;    daytim        returns in HL, a pointer a
  11. ;                       null-terminated string of the form:
  12. ;
  13. ;            dd mmm yy hh:mm:ss
  14. ;
  15. ;            uses CPM+ and MPM function #105
  16. ;
  17. ; Note: this module should work with the following operating systems:
  18. ;
  19. ;    CPM 3.x  (aka "CPM+")
  20. ;    MP/M 2.x and higher
  21. ;    TurboDOS 1.2x, 1.3x, and, presumably, higher
  22. ;    Not (of course) CPM 1.x and 2.x, which have no real-time functions
  23. ;
  24. ; Note that it has only been tested with CP/M 3.1.      --Ron Fowler
  25. ;    
  26. ;
  27.     INCLUDE "a:bds.lib"
  28.  
  29. ;
  30. ;TIMEDIF.ASM v1.10
  31. ;12/28/83
  32. ;By S. Kluger
  33. ;
  34. ;Converted to CSM file by FJW 12/31/83
  35. ;
  36. ;
  37. ; Purpose:
  38. ; Evaluate two ASCII character strings in HH:MM:SS format and
  39. ; return their difference.
  40. ;
  41. ; Entry point:    TIMDIF
  42. ; Externals:    STTIME
  43. ;        ENTIME
  44. ;        ELAPTM
  45. ;
  46. ; Input parameters:
  47. ; STTIME holds a time string of HH:MM:SS format. STTIME must point
  48. ; to the tens hours digit. The time string must be in 24 hour format.
  49. ; The time stored there should be the beginning time of an event.
  50. ;
  51. ; ENTIME holds a string with the same format. The time stored there
  52. ; should be the end of an event.
  53. ;
  54. ; On return, ELAPTM will be filled with the elapsed time in
  55. ; hours and minutes and the accumulator will be cleared with the
  56. ; ZERO flag SET. If either entry parameter contained an illegal
  57. ; quantity, the CARRY flag will be SET and ELAPTM will be undefined.
  58. ; NOTE: TIMDIF will not place delimiters into ELAPTM!
  59. ;
  60. ; Only the first 8 characters of the strings are processed and checked
  61. ; for proper range. Be sure to zero the seconds field if not needed!
  62. ;
  63. ; NOTE:
  64. ; If ENTIME is smaller than STTIME, then 24 hours are added to ENTIME.
  65. ;
  66. ; This routine is intended for application where the event time will
  67. ; never be greater than 23:59:59 (RCPM and BBS use mainly).
  68. ;
  69. ;    PUBLIC    TIMDIF        ;entry point
  70. ;    EXTRN    STTIME        ;start time field
  71. ;    EXTRN    ENTIME        ;end time field
  72. ;    EXTRN    ELAPTM        ;elapsed time field
  73. ;
  74. ;    cseg
  75. ;
  76. ; Entry point. All registers meet their doom...
  77. ;
  78.     FUNCTION    timdif
  79.  
  80. timdif:    call    arghak
  81.     push    b
  82.     lhld    arg1        ;point to start time (sttime)
  83.     call    chform        ;check proper format
  84.     jc    exit        ;return if error
  85.     lhld    arg2        ;point to end time (entime)
  86.     call    chform        ;check that too
  87.     jc    exit
  88. ;
  89. ; The stage is set - let's get down to business...
  90. ;
  91.     lhld    arg1
  92.     lxi    d,6
  93.     dad    d        ;point to seconds start (sttime+6)
  94.     call    getbin        ;get binary
  95.     mov    d,a        ;save it
  96.     push    d
  97.     lhld    arg2
  98.     lxi    d,6
  99.     dad    d        ;seconds end (entime+6)
  100.     pop    d
  101.     call    getbin        ;get binary
  102.     mvi    e,0        ;reset our private borrow flag
  103.     sub    d        ;subtract
  104.     jnc    skbs        ;skip if no borrow
  105.     dcr    e        ;set our borrow flag
  106.     adi    60        ;make mod 60
  107. skbs:    push    d
  108.     lhld    arg3
  109.     lxi    d,7
  110.     dad    d
  111.     pop    d        ;store as result (elaptm+7)
  112.     call    stora
  113. ;
  114. ; Do the same stuff for minutes
  115. ;
  116.     push    d
  117.     lhld    arg1
  118.     lxi    d,3
  119.     dad    d        ;minutes start (sttime+3)
  120.     pop    d
  121.     call    getbin        ;get binary
  122.     mov    d,a        ;save binary
  123.     push    d
  124.     lhld    arg2
  125.     lxi    d,3
  126.     dad    d        ;minutes end (entime+3)
  127.     pop    d
  128.     call    getbin        ;get binary
  129.     inr    e        ;if not borrow...
  130.     jnz    skbm1        ;then skip...
  131.     inr    d        ;...else add borrowed value
  132. skbm1:    mvi    e,0        ;make sure borrow flag reset
  133.     sub    d        ;subtract
  134.     jnc    skbm2        ;skip if no borrow
  135.     dcr    e        ;set borrow
  136.     adi    60        ;make mod 60
  137. skbm2:    push    d
  138.     lhld    arg3
  139.     lxi    d,4
  140.     dad    d        ;store elapsed minutes (elaptm+4)
  141.     pop    d
  142.     call    stora
  143. ;
  144. ; Finally, here go the hours.
  145. ;
  146.     lhld    arg1        ;hours start (sttime)
  147.     call    getbin        ;get 'em
  148.     mov    d,a        ;save start hours
  149.     lhld    arg2        ;hours end (entime)
  150.     call    getbin        ;get binary
  151.     inr    e        ;if not borrow...
  152.     jnz    skbh1        ;...then skip...
  153.     inr    d        ;...else add borrowed hour
  154. skbh1:    sub    d        ;subtract
  155.     jnc    skbh2        ;jump if no borrow
  156.     adi    24        ;else add 24 hours
  157. skbh2:    lhld    arg3
  158.     inx    h        ;save as hours (elaptm+1)
  159.     call    stora
  160.     xra    a        ;make sure error is reset
  161. exit:    pop    b
  162.     ret            ;end of execution, back to caller.
  163. ;
  164. ; Get the ASCII value at HL as a binary into A
  165. ;
  166. getbin:    mov    a,m        ;get tens
  167.     ani    0fh        ;strip ASCII offset
  168.     mov    b,a        ;save tens
  169.     xra    a        ;set accumulator
  170.     mvi    c,10        ;set up cheap multiplier
  171. mul:    add    c
  172.     dcr    b
  173.     jnz    mul
  174.     mov    b,a        ;save tens
  175.     inx    h        ;point to units
  176.     mov    a,m        ;get units
  177.     ani    0fh        ;same treatment
  178.     add    b        ;add the tens
  179.     ret
  180. ;
  181. ; Check format of HH:MM:SS string. Checks all digits for presence
  182. ; and validity.
  183. ;
  184. chform:    mov    a,m        ;get 10s H
  185.     cpi    '0'
  186.     rc
  187.     cpi    '3'
  188.     cmc
  189.     rc
  190.     inx    h
  191.     mov    a,m        ;get 1s H
  192.     call    ck10        ;check decimal
  193.     rc
  194.     inx    h        ;get colon
  195.     mov    a,m
  196.     cpi    ':'
  197.     stc
  198.     rnz
  199.     inx    h        ;point to 10s M
  200.     mov    a,m
  201.     call    ck6        ;check hex
  202.     rc
  203.     inx    h
  204.     mov    a,m        ;1s M
  205.     call    ck10
  206.     rc
  207.     inx    h
  208.     mov    a,m        ;get delimiter
  209.     cpi    ':'
  210.     stc
  211.     rnz
  212.     inx    h
  213.     mov    a,m        ;get 10s S
  214.     call    ck6
  215.     rc
  216.     inx    h
  217.     mov    a,m
  218. ck10:    cpi    '0'
  219.     rc
  220.     cpi    '9'+1
  221.     cmc
  222.     ret
  223. ;
  224. ck6:    cpi    '0'
  225.     rc
  226.     cpi    '7'
  227.     cmc
  228.     ret
  229. ;
  230. ; Store accumulator as ASCII digits at HL and HL+1
  231. ;
  232. stora:    mvi    b,0ffh        ;-1
  233. tlp:    inr    b
  234.     sui    10        ;subtract 10
  235.     jnc    tlp        ;until borrow
  236.     adi    10        ;make mod 10
  237.     ori    '0'        ;make ASCII
  238.     mov    m,a
  239.     dcx    h
  240.     mvi    a,'0'
  241.     add    b
  242.     mov    m,a
  243.     ret
  244. ;
  245.     ENDFUNC
  246. ;
  247.     FUNCTION    daytim
  248. ;
  249.     push    b
  250.     lxi    d,jdate        ;pointer to date/time bufr
  251.     mvi    c,105        ;C=return date/time function
  252.     call    0005h        ;get date/time
  253.     sta    secs        ;cpm3 returns seconds in a
  254.     lxi    d,datbuf    ;get date buffer
  255.     lhld    jdate        ;fetch julian date
  256.     call    dspdat        ;display date in date buffer
  257.     call    dsptim        ;display time in time buffer
  258.     lxi    h,datbuf    ;get date buffer
  259.     xra    a
  260.     pop    b
  261.     ret
  262. ;
  263. ; Function 'dspdat' converts a Julian Date to ASCII.
  264. ;
  265. ; Call dspdat with address of ASCII string return buffer (9 bytes long)
  266. ; in DE, and Julian date to be converted in HL.
  267. ;
  268. ;
  269. ; Registers AF-BC-DE-HL-IX are destroyed.
  270. ;
  271. dspdat:    push    d        ;save return address
  272.     lxi    d,yyear        ;pass buffer to fmjul
  273.     call    fmjul        ;calculate y-m-d
  274.     pop    h        ;return address to hl
  275.     lda    yday        ;check for error
  276.     ora    a
  277.     jz    err
  278.     call    decmem        ;convert to decimal
  279.     mvi    m,' '        ;move in a space
  280.     inx    h
  281.     push    h        ;save pointer
  282.     lhld    ymonth        ;get month number
  283.     mvi    h,0        ;make double length
  284.     dcx    h        ;make base 0
  285.     mov    d,h        ;multiply by 3
  286.     mov    e,l
  287.     dad    d
  288.     dad    d
  289.     lxi    d,months    ;calculate month table address
  290.     dad    d
  291.     pop    d        ;recover pointer
  292.     lxi    b,3        ;length of move
  293.     db    0edh,0b0h    ;LDIR        ;move month into string
  294.     xchg            ;pointer back to hl
  295.     mvi    m,' '        ;move in a space
  296.     inx    h
  297.     lda    yyear        ;get year
  298.     call    decmem        ;convert to decimal
  299.     jmp    x        ;done
  300. err:    mvi    b,9        ;error, return 9 *'s
  301. erl:    mvi    m,'*'
  302.     inx    h
  303.     db    010h,0fbh    ;DJNZ    erl
  304. x:    mvi    m,' '        ;insert delimeter
  305.     ret            ;done
  306. ;
  307. ;
  308. ; Function 'dsptim' converts a bcd hours, minutes, and seconds to ASCII.
  309. ;
  310. dsptim:    lxi    h,timbuf    ;get time buffer
  311.     lxi    d,hours        ;get hours/minutes/seconds
  312.     ldax    d        ;get hours
  313.     inx    d        ;advance pointer
  314.     call    bcdout        ;convert hours to ascii
  315.     mvi    m,':'        ;inset colon
  316.     inx    h
  317.     ldax    d        ;get minutes
  318.     inx    d        ;advance pointer
  319.     call    bcdout        ;convert minutes to ascii
  320.     mvi    m,':'        ;insert colon
  321.     inx    h
  322.     ldax    d        ;get seconds
  323.     call    bcdout        ;convert seconds to ascii
  324.     mvi    m,0        ;insert delimeter
  325.     ret            ;done
  326. ;
  327. decmem:    mvi    b,'0'-1        ;convert a-reg to decimal
  328. dec:    inr    b
  329.     sui    10
  330.     jp    dec
  331.     mov    m,b
  332.     inx    h
  333.     adi    10+'0'
  334.     mov    m,a
  335.     inx    h
  336.     ret
  337. ;
  338. bcdout:    push    psw        ;convert a-reg (bcd) to decimal
  339.     rrc            ;hi nybble
  340.     rrc
  341.     rrc
  342.     rrc
  343.     call    bcd1        ;process hi nybble
  344.     pop    psw        ;then lo
  345. bcd1:    ani    0fh        ;4 bits only
  346.     adi    '0'        ;add ascii bias
  347.     mov    m,a        ;store it
  348.     inx    h
  349.     ret
  350. ;
  351. ; routine to convert modified julian date  passed in hl to
  352. ; yy/mm/dd form, into buffer passed in de. passed buffer
  353. ; looks like this:
  354. ;
  355. ;    db    year  (bcd)
  356. ;    db    month    "
  357. ;    db    date    "
  358. ;
  359. ; returned julian date is the day number using a base date
  360. ; of jan 1 of "baseyr" (defined below)
  361. ;
  362. ;
  363. baseyr    equ    78        ;base year of date system (1978)
  364. ;
  365. ; we begin...
  366. ;
  367. fmjul:    push    d        ;save buffer pointer (for later)
  368.     mvi    b,baseyr     ;base year in b
  369. ;
  370. ; scan through years starting at baseyr
  371. ; subtracting days from our current date
  372. ;
  373. julp:    mov    a,b        ;fetch current year
  374.