home *** CD-ROM | disk | FTP | other *** search
/ Carousel Volume 2 #1 / carousel.iso / comdore / 64misc / gdump / GMOVE.SRC (.txt) < prev    next >
Commodore BASIC  |  1989-05-26  |  4KB  |  151 lines
  1. 1000 ;SUPPORT PROGRAM FOR GDUMP
  2. 1010 ;     M.J.KERYAN  3-25-84
  3. 1020 ;
  4. 1030 *      = $5530
  5. 1040 ;
  6. 1050 GOSIMN JMP GDSIMN
  7. 1060 ;FOR SIMON'S BASIC SCREEN DUMP
  8. 1070 ;  A TRADEMARK OF COMMODORE ELECTRONICS
  9. 1080 GOULTR JMP GDULTR
  10. 1090 ;FOR ULTRABASIC-64 SCREEN DUMP
  11. 1100 ;  A TRADEMARK OF ABACUS SOFTWARE
  12. 1110 GODOOD JMP GDDOOD
  13. 1120 ;FOR **DOODLE** SCREEN DUMP
  14. 1130 ;  A TRADEMARK OF OMNI UNLIMITED
  15. 1140 GOKOAL JMP GDKOAL
  16. 1150 ;FOR KOALAPAINTER SCREEN DUMP
  17. 1160 ;  A TRADEMARK OF AUDIO LIGHT
  18. 1170 GOSLID JMP GDSLID
  19. 1180 ;FOR SCREEN DUMP OF PICTURES IN
  20. 1190 ;  SLIDESHOW FORMAT (TPUG)
  21. 1200 ;
  22. 1210 GDSIMN JSR ROMOUT ;SWITCH OUT ROMS
  23. 1220        JSR GD1    ;MOVE MEMORY
  24. 1230        JSR ROMIN  ;ROMS BACK IN
  25. 1240        LDA #$C0
  26. 1250        STA $5009
  27. 1260        RTS
  28. 1270 ;
  29. 1280 ROMOUT SEI        ;IGNORE INTER.
  30. 1290        LDA #$34   ;ROMS OUT
  31. 1300        STA $01
  32. 1310        RTS
  33. 1320 ;
  34. 1330 ROMIN  LDA #$37   ;ROMS BACK IN
  35. 1340        STA $01
  36. 1350        CLI        ;RESTORE INTER.
  37. 1360        RTS
  38. 1370 ;
  39. 1380 GD1    LDA #$E0   ;SET UP
  40. 1390 GD2    STA FROM+2
  41. 1400 GD3    LDA #$20
  42. 1410        STA TO+2
  43. 1420        LDY #$20   ;32 BLOCKS
  44. 1430 GD4    LDX #$00
  45. 1440        STX FROM+1
  46. 1450        STX TO+1
  47. 1460 FROM   LDA $E000,X ;MOVE DATA
  48. 1470 TO     STA $2000,X
  49. 1480        INX
  50. 1490        BNE FROM
  51. 1500        INC FROM+2
  52. 1510        INC TO+2
  53. 1520        DEY
  54. 1530        BNE FROM
  55. 1540        RTS
  56. 1550 GD5    LDA #$84    ;SET UP
  57. 1560 GD6    STA FROM+2
  58. 1570 GD7    LDA #$04
  59. 1580        STA TO+2
  60. 1590 GD8    LDY #$04    ;4 BLOCKS
  61. 1600        BNE GD4     ;BRANCH ALWAYS
  62. 1610 ;
  63. 1620 GDULTR JSR ROMOUT  ;ROMS OUT
  64. 1630        LDA #$A0
  65. 1640        JSR GD2
  66. 1650        JSR ROMIN   ;ROMS BACK IN
  67. 1660        JSR GD5
  68. 1670        LDA #$88
  69. 1680        STA FROM+2
  70. 1690        LDA #$D8
  71. 1700        STA TO+2
  72. 1710        JSR GD8
  73. 1720        LDA $83E0   ;BORDER COLOR
  74. 1730        STA $D020
  75. 1740        LDA $83E1   ;BACKGROUND
  76. 1750        STA $D021
  77. 1760        JSR BITON   ;BIT-MAP ON
  78. 1770        LDA $83D6
  79. 1780        STA $D016   ;HIRES OR M-C
  80. 1790        RTS
  81. 1800 ;
  82. 1810 BITON  LDA $D011
  83. 1820        ORA #$30
  84. 1830        STA $D011   ;BIT MAP ON
  85. 1840        LDA $D018
  86. 1850        ORA #$08    ;LOCATED AT
  87. 1860        STA $D018   ; $2000
  88. 1870        RTS
  89. 1880 ;
  90. 1890 GDDOOD LDA #$60
  91. 1900        JSR GD2     ;MOVE BIT-MAP
  92. 1910        LDA #$5C
  93. 1920        JSR GD6     ;MOVE SCREEN
  94. 1930        JSR BITON   ;BIT MAP ON
  95. 1940        JSR MCOFF   ;MULTI COLOR OFF
  96. 1950        RTS
  97. 1960 ;
  98. 1970 MCOFF  LDA $D016   ;TURN OFF
  99. 1980        AND #$CF    ;MULTI-COLOR
  100. 1990        STA $D016   ;MODE
  101. 2000        RTS
  102. 2010 ;
  103. 2020 MCON   LDA $D016   ;TURN ON
  104. 2030        AND #$DF    ;MULTI-COLOR
  105. 2040        ORA #$10    ;MODE
  106. 2050        STA $D016
  107. 2060        RTS
  108. 2070 ;
  109. 2080 GDKOAL LDA #$60    ;MOVE BIT-MAP
  110. 2090        JSR GD2
  111. 2100        LDX #$00
  112. 2110        STX TO+1
  113. 2120        LDY #$04
  114. 2130        STY TO+2
  115. 2140        LDA #$40
  116. 2150        STA FROM+1
  117. 2160        LDA #$7F
  118. 2170        STA FROM+2
  119. 2180        JSR FROM    ;MOVE SCREEN
  120. 2190        LDX #$00
  121. 2200        STX TO+1
  122. 2210        LDY #$04
  123. 2220        LDA #$D8
  124. 2230        STA TO+2
  125. 2240        LDA #$28
  126. 2250        STA FROM+1
  127. 2260        LDA #$83
  128. 2270        STA FROM+2
  129. 2280        JSR FROM    ;MOVE COLOR MEM
  130. 2290        LDA $8710
  131. 2300        STA $D021   ;BACKGROUND
  132. 2310        JSR BITON   ;BIT-MAP ON
  133. 2320        JSR MCON    ;MULTI-COLOR ON
  134. 2330        RTS
  135. 2340 ;
  136. 2350 GDSLID LDY #$04
  137. 2360        STY GSL+2
  138. 2370        LDX #$00
  139. 2380        STX GSL+1
  140. 2390        LDA #$10    ;SCREEN COLORS
  141. 2400 GSL    STA $0400,X ;SET TO BLACK
  142. 2410        INX         ;AND WHITE
  143. 2420        BNE GSL
  144. 2430        INC GSL+2
  145. 2440        DEY
  146. 2450        BNE GSL
  147. 2460        JSR BITON   ;BIT-MAP ON
  148. 2470        JSR MCOFF   ;MULTI COLOR OFF
  149. 2480        RTS
  150. 2490 .END
  151.