home *** CD-ROM | disk | FTP | other *** search
/ Carousel Volume 2 #1 / carousel.iso / comdore / 64misc / plntrbts (.txt) < prev    next >
Commodore BASIC  |  1988-12-02  |  26KB  |  797 lines
  1. 1 IFPEEK(52016)<>32ORPEEK(52040)<>245THENLOAD"LINPUT.PR",8,1
  2. 2 REM PLANET OF THE ROBOTS
  3. 3 REM BY DANIEL TOBIAS
  4. 4 REM C64 VERSION 1.1
  5. 5 REM 6/12/84
  6. 7 NA$="[208]LANET OF THE [210]OBOTS"
  7. 8 POKE 53280,7:POKE53281,1:PRINT"[144]"
  8. 9 S=54272:FORI=.TO24:POKES+I,.:NEXT
  9. 10 PRINT"":LI=52016
  10. 15 DIM LV%(100,8),LD$(100,1),R%(100),ID$(50),IL%(50),PR(50),IW(50),L%(100)
  11. 17 DIM WD$(100),W%(100,1),FW%(1)
  12. 18 DIMV%(3),H%(2),O%(1),A(1)
  13. 20 GOSUB 18000:GOSUB 19000
  14. 60 PRINT"[147]"
  15. 100 REM START
  16. 108 XX=1
  17. 110 IFXX=1THENGOSUB1000
  18. 120 GOSUB500
  19. 125 XX=XX+1:IFXX>5THENXX=1
  20. 130 IFFW%(0)=0THENPRINT"[215]HAT?":GOTO110
  21. 140 ONFW%(0)GOSUB2000,3000,4000,5000,5500,6000,7000,8000,9000,9500
  22. 142 IFFW%(0)>10THENONFW%(0)-10GOSUB13000,13500,14500,15000,15500,16000,16500
  23. 143 IFFW%(0)=18THENGOSUB10000
  24. 145 IFFW%(0)=99THEN300
  25. 150 T=T+1
  26. 160 GOTO110
  27. 200 REM CONVERT TO LOWER CASE
  28. 220 FOR IP=1TOLEN(I$)
  29. 230 CH$=MID$(I$,IP,1)
  30. 240 IFCH$>="[193]"ANDCH$<="[218]"THENI$=LEFT$(I$,IP-1)+CHR$(ASC(CH$)-128)+MID$(I$,IP+1)
  31. 260 NEXT IP
  32. 270 RETURN
  33. 300 REM END
  34. 305 PRINT"[144]"
  35. 310 PRINT "[211]TOP AFTER"T"TURNS."
  36. 312 INPUT"PLAY AGAIN";PA$:IFPA$="Y"ORPA$="[217]"ORPA$="[183]"THENRUN
  37. 320 PRINT
  38. 330 PRINT"[147]LOAD"CHR$(34)"HELLO"CHR$(34)",8":PRINT"RUN":POKE631,13:POKE632,13
  39. 332 POKE198,2:END
  40. 500 REM HANDLE INPUT
  41. 505 FW%(0)=0:FW%(1)=0
  42. 510 PRINT"-->";:SYSLI,B$:I$=B$+"":PRINT
  43. 515 IF I$="" THEN 510
  44. 518 GOSUB 200
  45. 520 WD$="":A=1
  46. 530 IF MID$(I$,A,1)=" " THEN 600
  47. 540 WD$=WD$+MID$(I$,A,1)
  48. 550 A=A+1:IFA<=LEN(I$)THEN530
  49. 600 REM FOUND WORD
  50. 610 FORB=1TONW:IFWD$(B)=WD$THENGOSUB650
  51. 620 NEXTB:WD$="":A=A+1
  52. 630 IFA>LEN(I$)THENRETURN
  53. 640 GOTO530
  54. 650 FORC=0TO1
  55. 660 IFW%(B,C)>=0THENFW%(C)=W%(B,C)
  56. 670 NEXTC
  57. 680 RETURN
  58. 1000 REM PRINT DESCRIPTION
  59. 1002 IFLD$(L,0)="S"THENGOSUB12000
  60. 1005 PRINT
  61. 1010 PRINTLD$(L,L%(L))
  62. 1011 IFL=28ANDJ=0THENPRINT"[212]HERE IS A DOOR WITH BARS."
  63. 1012 IFL=28ANDJ<>0THENPRINT"[212]HE BARS ARE BROKEN, LEAVING A WAY OUT."
  64. 1014 PRINT
  65. 1015 L%(L)=1
  66. 1020 PRINT"[207]PEN PATHWAYS: ";:FORA=1TO8:IFLV%(L,A)<>0THENPRINTDN$(A)" ";
  67. 1025 NEXTA
  68. 1030 PRINT
  69. 1040 PRINT"[214]ISIBLE OBJECTS:"
  70. 1045 X=0
  71. 1050 FORA=1TONI
  72. 1060 IF IL%(A)=LTHENPRINT" "ID$(A);:X=1
  73. 1062 IFIL%(A)=LANDPR(A)>0ANDR%(L)=1THENPRINT" ([208]RICE $"PR(A)")";
  74. 1065 IF IL%(A)=LTHENPRINT
  75. 1070 NEXTA
  76. 1080 IFX=0THENPRINT"[212]HERE ARE NONE."
  77. 1082 IF R%(L)<>0THENPRINT
  78. 1085 IFR%(L)=1THENPRINT"[195]LERK ROBOT HERE."
  79. 1090 IFR%(L)>20ANDR%(L)<29THENPRINT"[199]UARD ROBOT HERE."
  80. 1110 IF R%(L)=3THENPRINT"[194]ERZERK ROBOT HERE!"
  81. 1120 IFT-E>=100THENPRINT"[217]OU ARE GETTING HUNGRY!"
  82. 1480 PRINT
  83. 1490 RETURN
  84. 2000 REM MOVE
  85. 2005 IFFW%(1)<101ORFW%(1)>108THENPRINT"[199]O WHERE?":RETURN
  86. 2010 X=LV%(L,FW%(1)-100)
  87. 2020 IFX<0ORX>NLTHENPRINT"[206]OT DEFINED YET.":RETURN
  88. 2025 IFL=28ANDI$="BREAK OUT"THEN15000
  89. 2030 IFX=0THENPRINT"[217]OU CAN'T GO THAT WAY.":RETURN
  90. 2035 IFR%(L)=3THENPRINT"[210]OBOT: [212]RYING TO ESCAPE, HUH?  [201]T WON'T"
  91. 2037 IFR%(L)=3THENPRINT"WORK!  [218]AP! [217]OU'RE DEAD!":GOTO300
  92. 2040 IFX=6ANDIL%(7)<>0THENPRINT"[210]OBOT: [201]'M SORRY, BUT THE DRESS CODE"
  93. 2041 IFX=6ANDIL%(7)<>0THENPRINT"  REQUIRES THAT YOU WEAR A TIE.":RETURN
  94. 2042 IFL=6ANDR<>0THENPRINT"[210]OBOT: [201]'M SORRY.  [217]OU ARE A BAD CREDIT"
  95. 2043 IFL=6ANDR<>0THENPRINT"  RISK.  [217]OU CAN'T ENTER.":RETURN
  96. 2045 IFR%(L)=20+FW%(1)-100THEN2500
  97. 2060 REM
  98. 2065 IFL=39ANDX=39ANDRND(0)<.35THENPL=1-PL:X=35:IFPL=0THENX=40
  99. 2080 IFX=17THENPRINT"[210]OBOT: [211]ORRY, THIS INFORMATION BOOTH IS   OUT OF ORDER."
  100. 2085 IFX=17THENRETURN
  101. 2087 IFLD$(X,0)="[211]"THENGOSUB12000:RETURN
  102. 2090 IFL=36ANDX=37THENINPUT"[197]NTER COMBINATION";A$
  103. 2095 IFL=36ANDX=37ANDVAL(A$)<>CM%THENPRINT"[211]ORRY. [215]RONG!":RETURN
  104. 2100 IFX=38THEN14000
  105. 2200 L=X:XX=1:RETURN
  106. 2500 REM ID CARD
  107. 2510 IFIL%(12)=0THENPRINT"[210]OBOT: [201].[196]. ACCEPTED.  [217]OU CAN PASS."
  108. 2520 IFIL%(12)=0THENPRINT"  [199]OOD DAY, [205]R. [211]MITH.":GOTO2060
  109. 2530 PRINT"[210]OBOT: [201]'M SORRY, BUT YOU CAN'T GO THAT   WAY WITHOUT AN [201].[196]. CARD."
  110. 2540 RETURN
  111. 3000 REM PICK UP
  112. 3005 IFFW%(1)=0ORFW%(1)>NITHENPRINT"[206]O SUCH THING HERE.":RETURN
  113. 3006 IFIL%(FW%(1))=0THENPRINT"[217]OU ARE ALREADY CARRYING IT!":RETURN
  114. 3007 IFIL%(FW%(1))<>LTHENPRINT"[206]O SUCH THING HERE.":RETURN
  115. 3009 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"[210]OBOT: [217]OU CAN'T TAKE THAT WITHOUT"
  116. 3010 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"  PAYING FOR IT!  [208]LEASE BUY IT IF YOU"
  117. 3011 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"  WANT IT.":RETURN
  118. 3013 HF=0
  119. 3015 IFWT+IW(FW%(1))>150ANDIW(FW%(1))<=150THEN HF=1
  120. 3017 IF HF=1 THEN PRINT "[212]OO HEAVY.  [217]OU MUST DROP SOMETHING     FIRST.":RETURN
  121. 3020 IFIW(FW%(1))>150THENPRINT"[212]OO HEAVY FOR YOU TO LIFT.":RETURN
  122. 3030 IFIW(FW%(1))<0THENPRINT"[201]T IS SECURELY FASTENED.":RETURN
  123. 3040 IL%(FW%(1))=0:WT=WT+IW(FW%(1))
  124. 3045 PRINT "[207][203]."
  125. 3050 IFFW%(1)=10THENM=ABS(M)
  126. 3060 RETURN
  127. 4000 REM DROP
  128. 4010 IFFW%(1)<1ORFW%(1)>NITHENPRINT"[217]OU ARE NOT CARRYING ONE.":RETURN
  129. 4020 IFIL%(FW%(1))<>0THENPRINT"[217]OU ARE NOT CARRYING ONE.":RETURN
  130. 4030 IL%(FW%(1))=L:WT=WT-IW(FW%(1))
  131. 4040 PRINT "[207][203]."
  132. 4042 IFL=39THENPRINT"[201]T SLIDES INTO A CREVICE IN THE RUINS   AND IS LOST."
  133. 4043 IFL=39THENIL%(FW%(1))=-1
  134. 4045 IFFW%(1)=10THENM=-ABS(M)
  135. 4050 RETURN
  136. 5000 REM LOOK
  137. 5005 IFFW%(1)>0THEN8000
  138. 5010 XX=1
  139. 5020 L%(L)=0
  140. 5030 RETURN
  141. 5500 REM INV
  142. 5505 X=0
  143. 5510 PRINT "[217]OU ARE CARRYING:"
  144. 5520 FORA=1TONI
  145. 5525 IFA=10THEN5540
  146. 5530 IFIL%(A)=0THENPRINT" "ID$(A):X=1
  147. 5540 NEXTA
  148. 5545 IFM>0THENPRINT"[160]$"M"IN CASH.":X=1
  149. 5550 IFX=0THENPRINT"[206]OTHING."
  150. 5560 RETURN
  151. 6000 REM SAVE GAME
  152. 6010 PRINT"[197]NTER FILENAME. ([196]EFAULT: PLANET.SAVE)":INPUTF$
  153. 6015 IFF$=""THENF$="PLANET.SAVE"
  154. 6017 OPEN15,8,15:PRINT#15,"S:"F$:CLOSE15
  155. 6020 OPEN2,8,2,F$+",S,W"
  156. 6040 PRINT#2,L:FORB=1TONI:PRINT#2,IL%(B):NEXTB:PRINT#2,WT:PRINT#2,T
  157. 6050 FORB=1TONL:PRINT#2,R%(B):NEXTB:PRINT#2,M:PRINT#2,E
  158. 6060 FORB=1TONI:PRINT#2,PR(B):NEXTB
  159. 6070 PRINT#2,CM%:PRINT#2,R:PRINT#2,J
  160. 6080 PRINT#2,PW:PRINT#2,RM
  161. 6090 CLOSE2
  162. 6100 PRINT "[207][203].":RETURN
  163. 6500 REM LOAD GAME
  164. 6510 PRINT"[197]NTER FILENAME. ([196]EFAULT: PLANET.SAVE)":INPUTF$
  165. 6515 IFF$=""THENF$="PLANET.SAVE"
  166. 6520 OPEN15,8,15
  167. 6530 OPEN2,8,2,F$+",S,R"
  168. 6540 GOSUB 6900
  169. 6550 INPUT#2,L:FORB=1TONI:INPUT#2,IL%(B):NEXTB:INPUT#2,WT:INPUT#2,T
  170. 6560 FORB=1TONL:INPUT#2,R%(B):NEXTB:INPUT#2,M:INPUT#2,E
  171. 6565 FORB=1TONI:INPUT#2,PR(B):NEXTB
  172. 6570 INPUT#2,CM%:INPUT#2,R:INPUT#2,J
  173. 6575 IFJ<>0THENLV%(28,8)=27
  174. 6580 INPUT#2,PW:INPUT#2,RM
  175. 6590 CLOSE2:CLOSE15
  176. 6600 RETURN
  177. 6900 INPUT#15,A$,B$,C$,D$
  178. 6910 IFVAL(A$)>0THENPRINT"[199]AME NOT FOUND.":FORA=1TO100:NEXTA:RUN
  179. 6920 RETURN
  180. 7000 REM WEIGH
  181. 7010 IFIL%(2)<>LANDIL%(2)<>0THENPRINT"[212]HERE IS NO SCALE.":RETURN
  182. 7020 IFFW%(1)=2THENPRINT"[217]OU CAN'T WEIGH IT ON ITSELF!":RETURN
  183. 7030 IFFW%(1)<1ORFW%(1)>NITHENPRINT"[212]HERE IS NO SUCH ITEM HERE.":RETURN
  184. 7040 IFIL%(FW%(1))<>LANDIL%(FW%(1))<>0THENPRINT"[212]HERE IS NO SUCH ITEM HERE.":RETURN
  185. 7050 PRINT"[201]T WEIGHS"IW(FW%(1))"POUNDS."
  186. 7060 RETURN
  187. 8000 REM READ/EXAMINE
  188. 8005 IFFW%(1)=200THENPRINT"[212]HE BARS LOOK RUSTY AND WEAK.":RETURN
  189. 8010 IFFW%(1)<1ORFW%(1)>NITHENPRINT"[206]O SUCH THING HERE.":RETURN
  190. 8020 IFIL%(FW%(1))<>LANDIL%(FW%(1))<>0THENPRINT"[206]O SUCH THING HERE.":RETURN
  191. 8030 IFFW%(1)=5THENPRINT"[212]HE SIGN SAYS: [201]NSERT $2.50.":RETURN
  192. 8050 IFFW%(1)=10THENPRINT"[212]HEY ARE MOSTLY DOLLAR COINS, BUT THERE"
  193. 8055 IFFW%(1)=10THENPRINT"ARE SOME $2.50 PIECES.":RETURN
  194. 8060 IFFW%(1)=4THENPRINT"[201]T HAS MANY PERIPHERALS, INCLUDING A    MODEM.":RETURN
  195. 8070 IFFW%(1)=8THENPRINT"[201]T IS [212]HE [193]DVENTURES OF [211]UPER[210]OBOT.":RETURN
  196. 8080 IFFW%(1)=12THENPRINT"[201]T BELONGED TO SECRET AGENT [194]ILL [211]MITH,"
  197. 8085 IFFW%(1)=12THENPRINT"WHO HAD THE HIGHEST SECURITY CLEARANCE.":RETURN
  198. 8090 IFFW%(1)=14THENPRINT"[212]HEY APPEAR TO BE THE FRAGMENTS OF A"
  199. 8095 IFFW%(1)=14THENPRINT"BUTCHER'S KNIFE.":RETURN
  200. 8100 IFFW%(1)=11THEN8200
  201. 8110 IFFW%(1)=13THEN8300
  202. 8190 PRINT"[206]OTHING INTERESTING.":RETURN
  203. 8200 PRINT"[212]ITLE: [200]OW TO [205]AKE [212]HE [205]OST OF [195]OMPUTER   [206]ETWORKS":PRINT
  204. 8210 PRINT"[217]OU CAN ACCESS THE GOVERNMENT'S PUBLIC"
  205. 8215 PRINT"INFORMATION DATA FILES THROUGH ANY"
  206. 8217 PRINT"MODEM-EQUIPPED COMPUTER.  [212]O DO THIS,   SIMPLY TYPE:"
  207. 8220 PRINT "  [204][207][193][196]"CHR$(34)"[212][197][210][205]6400"CHR$(34)",8,1"
  208. 8230 PRINT"[212]HEN, YOU SELECT THE GOVERNMENT NETWORK BY TYPING:"
  209. 8235 PRINT"  [199][207][214][212]"
  210. 8240 PRINT"[206]OW, YOU ARE ASKED THE NAME OF THE FILE"
  211. 8245 PRINT"YOU WANT.  [198]ILES YOU HAVE ACCESS TO"
  212. 8247 PRINT"INCLUDE '[208][207][208]', WHICH CONTAINS THE"
  213. 8250 PRINT"CURRENT POPULATION OF THE [213][211][193].  [200]AVE    FUN!"
  214. 8260 PRINT:RETURN
  215. 8300 PRINT"          [212][160][207][160][208][160][160][160][211][160][197][160][195][160][210][160][197][160][212]"
  216. 8310 PRINT"[212]O: [215]ORKERS ON [208]ROJECT [195]HRONOS"
  217. 8320 PRINT:PRINT"[212]HE CURRENT COMBINATION TO THE DOOR OF"
  218. 8323 PRINT"ROOM "RM" IS POSTED ON THE GOVERNMENT"
  219. 8326 PRINT"COMPUTER NETWORK IN THE FILE TITLED"
  220. 8328 PRINT"'[195][200][210][207][206][207][211]'.  [212]HE PASSWORD TO THE FILE IS":PRINT"'"PW$(PW);"'."
  221. 8330 RETURN
  222. 8500 REM TRIAL/JAIL
  223. 8510 PRINT "* [193] POLICE ROBOT ARRIVES. *"
  224. 8515 PRINT
  225. 8520 PRINT"[208]OLICE: [217]OU ARE UNDER ARREST.  [217]OU HAVE"
  226. 8530 PRINT"  A RIGHT TO REFRAIN FROM INPUTTING"
  227. 8533 PRINT"  ANYTHING; ANYTHING YOU INPUT MAY BE"
  228. 8536 PRINT"  HELD AGAINST YOU IN COURT."
  229. 8540 PRINT"[144]* [217]OU ARE TAKEN TO A COURTROOM.      *"
  230. 8545 PRINT"* [212]HE JUDGE AND JURY ARE ALL ROBOTS. *"
  231. 8550 PRINT
  232. 8560 PRINT:PRINT"[202]UDGE: [217]OU ARE CHARGED WITH ";
  233. 8580 IFCH=1THENPRINT"[193]SSAULT OF":PRINT"  A [210]OBOT. ";
  234. 8590 IFCH<>1THENPRINT"[212]HEFT OF":PRINT"  SERVICES.";
  235. 8600 PRINT"  [200]OW DO YOU PLEAD?"
  236. 8605 PRINT
  237. 8610 PRINT "[196]EFENDANT: ";:SYSLI,B$:I$=B$+"":PRINT
  238. 8615 PRINT
  239. 8620 GOSUB200:IFLEN(I$)>=6THENIFLEFT$(I$,6)="GUILTY"THEN8900
  240. 8630 PRINT"[202]UDGE: [212]HE [196]ISTRICT [193]TTORNEY WILL NOW     PRESENT HIS CASE."
  241. 8635 PRINT
  242. 8640 PRINT"* [212]HE [196].[193]. IS ALSO A ROBOT. *"
  243. 8645 PRINT
  244. 8650 PRINT"[196].[193].: [201] WILL NOW CALL UPON THE ";
  245. 8660 IFR%(L)=1THENPRINT"CLERK "
  246. 8665 IFR%(L)<>1THENPRINT"GUARD "
  247. 8670 PRINT" ROBOT, SERIAL #"INT(RND(1)*999999)" TO TESTIFY."
  248. 8672 PRINT
  249. 8677 IFCH<>1THEN8700
  250. 8680 PRINT"[210]OBOT: [212]HIS MAN ASSAULTED ME WITH A":IFIL%(9)=0THENPRINT" RAY GUN ";
  251. 8685 IF IL%(9)<>0THENPRINT" KNIFE ";
  252. 8690 PRINT"ONLY"INT(RND(1)*59)"MINUTES,"RND(1)*59:PRINT"  SECONDS AGO."
  253. 8692 PRINT
  254. 8695 PRINT"[196].[193].: [201] REST MY CASE."
  255. 8696 PRINT
  256. 8697 GOTO8800
  257. 8700 REM (null)HEFT OF (null)ERVICES
  258. 8710 PRINT"[210]OBOT: [212]HIS MAN HAD A MEAL AT THE"
  259. 8712 PRINT"  RESTAURANT IN WHICH [201] WORK, AND WOULD   NOT PAY."
  260. 8715 PRINT
  261. 8720 PRINT"[196].[193].: [215]HEN DID THIS HAPPEN?"
  262. 8725 PRINT
  263. 8730 PRINT"[210]OBOT: [202]UST"INT(RND(1)*59)" MINUTES, "RND(1)*59:PRINT"  SECONDS AGO."
  264. 8735 PRINT
  265. 8740 PRINT"[196].[193].: [201] REST MY CASE."
  266. 8745 PRINT
  267. 8800 REM YOUR REPLY
  268. 8810 PRINT"[202]UDGE: [215]HAT DOES THE DEFENDANT HAVE TO    SAY FOR HIMSELF?"
  269. 8815 PRINT
  270. 8820 PRINT"[196]EFENDANT: ";:SYSLI,B$:I$=B$+"":PRINT
  271. 8822 PRINT
  272. 8825 PRINT"[202]UDGE: [212]HE JURY WILL NOW REACH A          VERDICT."
  273. 8827 FORA=1TO1500:NEXTA:PRINT
  274. 8830 PRINT"[202]URY: [212]HE WORD OF A ROBOT IS MORE"
  275. 8833 PRINT"  RELIABLE THAN THAT OF A MERE HUMAN."
  276. 8836 PRINT"  [212]HEREFORE, WE FIND THE DEFENDANT        GUILTY AS CHARGED."
  277. 8840 PRINT
  278. 8900 REM SENTENCING
  279. 8905 SE=2
  280. 8910 IFCH=1THENPRINT"[202]UDGE: [217]OU ARE HEREBY SENTENCED TO DEATH  BY ELECTROCUTION."
  281. 8915 IFCH=1THENPRINT:PRINT"* [217]OU ARE TAKEN TO AN EXECUTION CHAMBER * AND KILLED.":GOTO300
  282. 8920 PRINT"[202]UDGE: [217]OU ARE HEREBY SENTENCED TO "
  283. 8923 PRINT" "SE"YEARS IN PRISON.  [194]AILIFF, PLEASE"
  284. 8926 PRINT"  REMOVE THE PRISONER.  [206]EXT CASE!"
  285. 8930 PRINT:L=28
  286. 8940 FORA=1TONI:IFIL%(A)=0THENIL%(A)=29
  287. 8942 NEXTA
  288. 8945 M=-ABS(M)
  289. 8950 XX=1:RETURN
  290. 9000 REM SHOOT
  291. 9010 IFIL%(9)<>0THENPRINT"[215]ITH WHAT?":RETURN
  292. 9020 IFR%(L)=0THENPRINT"[206]OTHING TO SHOOT AT.":RETURN
  293. 9030 IFR%(L)<>3THENPRINT"[212]HE ROBOT'S FORCE FIELD REPELS THE RAY.":CH=1:GOTO8500
  294. 9040 PRINT"[212]HE DEFECT WHICH CAUSED THE ROBOT TO"
  295. 9045 PRINT"MALFUNCTION ALSO AFFECTED ITS NORMALLY"
  296. 9050 PRINT"INVULNERABLE FORCE FIELD.  [217]OUR SHOT    DESTROYS IT."
  297. 9060 R%(L)=0
  298. 9070 RETURN
  299. 9500 REM BUY
  300. 9501 IFFW%(1)<1ORFW%(1)>NITHENPRINT"[206]O SUCH THING HERE.":RETURN
  301. 9503 IFIL%(FW%(1))=0THENPRINT"[217]OU ARE ALREADY CARRYING IT.":RETURN
  302. 9505 IFIL%(FW%(1))<>LTHENPRINT"[206]O SUCH THING HERE.":RETURN
  303. 9510 IFPR(FW%(1))=0THENPRINT"[212]HERE IS NO PRICE ON IT.":RETURN
  304. 9520 P=PR(FW%(1))
  305. 9525 IFM<=0THENPRINT"[217]OU DO NOT HAVE ANY MONEY!":RETURN
  306. 9530 IFP>MTHENPRINT"[217]OU DO NOT HAVE ENOUGH MONEY!":RETURN
  307. 9540 M=M-P
  308. 9550 PR(FW%(1))=0
  309. 9560 GOTO3000
  310. 10000 REM COMPUTER
  311. 10002 IFIL%(4)<>LTHENPRINT"[206]O SUCH THING HERE.":RETURN
  312. 10005 PRINT"[210]OBOT: [215]HEN YOU ARE FINISHED, TYPE        '[207][198][198]' TO SHUT IT OFF.":PRINT
  313. 10007 PRINT"[200]IT RETURN TO TURN COMPUTER ON. ";:SYSLI,B$:PRINT
  314. 10010 SYS65409
  315. 10020 PRINT"   **** COMMODORE 6400 BASIC V32 ****"
  316. 10025 PRINT"64M RAM SYSTEM 38911206 BASIC BYTES FREE":PRINT"READY."
  317. 10030 SYSLI,B$:I$=B$+"":PRINT
  318. 10035 FORA=1TOLEN(I$):IFMID$(I$,A,1)=" "THENI$=LEFT$(I$,A-1)+MID$(I$,A+1)
  319. 10037 NEXTA
  320. 10040 IF I$="LOAD"+CHR$(34)+"TERM6400"+CHR$(34)+",8,1" THEN 10100
  321. 10045 IFI$="OFF"THENXX=1:GOTO10500
  322. 10047 PRINT
  323. 10050 I=INT(RND(1)*5)+1
  324. 10055 ONIGOSUB10060,10065,10070,10075,10080:PRINT"READY.":GOTO10030
  325. 10060 PRINT"?SYNTAX  ERROR":RETURN
  326. 10065 PRINT"?UNBALANCED COORDINATE  ERROR":RETURN
  327. 10070 PRINT"?IMPROPER DELIMITER  ERROR":RETURN
  328. 10075 PRINT"?UNFORMATTED REFERENCE  ERROR":RETURN
  329. 10080 PRINT"?UNINDEXABLE ADDRESS  ERROR":RETURN
  330. 10100 REM MODEM
  331. 10110 GOTO30500
  332. 10120 PRINT"[215]ELCOME TO THE [213].[211]. [199]OVT [196]ATABASE!":PRINT"[212]YPE '[207][198][198]'[160]TO LOG OFF."
  333. 10140 INPUT"[206]AME OF FILE TO ACCESS";I$:GOSUB200:IFI$="OFF"THEN10550
  334. 10150 IFI$="POP"THEN10600
  335. 10160 IFI$="CHRONOS"THEN10200
  336. 10170 PRINT"[206]O SUCH FILE!":GOTO10140
  337. 10200 REM CHRONOS
  338. 10210 INPUT"[195]LASSIFIED!  [208]ASSWORD";I$
  339. 10220 IFI$<>PW$(PW)THENPRINT"[201]MPROPER PASSWORD!":GOTO10140
  340. 10230 PRINT"[208]ROJECT [195]HRONOS COMBINATION:"CM%"."
  341. 10240 GOTO 10140
  342. 10500 REM EXIT COMPUTER
  343. 10505 XX=1
  344. 10510 POKE53280,7:POKE53281,1:PRINT"[147]"
  345. 10517 PRINT""
  346. 10520 RETURN
  347. 10550 PRINT"[204]OGGING OFF [199][207][214][212] SYSTEM -- [200]AVE A GOOD  DAY!"
  348. 10555 FORI=1TORND(.)*10+5:PRINTCHR$(RND(.)*256);:FORP=1TORND(.)*200:NEXT:NEXT
  349. 10560 PRINT:PRINT"[195]ARRIER[160]TONE[160]LOST!"
  350. 10570 PRINT:PRINT"[158][194]ACK TO [212][197][210][205]6400.  [217]OUR CHOICES:"
  351. 10575 PRINT" (1) [193]CCESS ANOTHER SYSTEM"
  352. 10580 PRINT" (2) [197]XIT TO [194][193][211][201][195]"
  353. 10585 PRINT" (3) [197]XIT AND [212]URN [195]OMPUTER [207]FF"
  354. 10587 I$=""
  355. 10590 PRINT:INPUT"[217]OUR CHOICE";I$
  356. 10595 IFVAL(I$)=0THEN10590
  357. 10597 ONVAL(I$)GOTO30025,30200,10500
  358. 10598 GOTO10590
  359. 10600 PRINT"[212]HE CURRENT POPULATION OF THE [213].[211].[193]."
  360. 10610 PRINT"ACCORDING TO CENSUS FIGURES AS OF"
  361. 10620 PRINT"7/6/2121: [197]XACTLY 0 PERSONS,  23,241,203ROBOTS."
  362. 10630 PRINT:GOTO10120
  363. 11000 REM RESTAURANT
  364. 11010 PRINT"[210]OBOT: [200]ERE IS THE MENU:"
  365. 11020 PRINT"  (1) [205]ARSBURGER"
  366. 11025 PRINT"      $120"
  367. 11030 PRINT"  (2) [199]REEN [199]OOP ([211]PECIAL OF THE WEEK!"
  368. 11035 PRINT"      $140"
  369. 11040 PRINT"  (3) [195]AVIAR AND [195]HAMPAGNE"
  370. 11045 PRINT"      $350"
  371. 11047 PRINT"([200]IT [210][197][212][213][210][206][146] IF YOU DON'T WISH TO ORDER.)":I$=""
  372. 11050 INPUT"[217]OUR ORDER (BY NUMBER)";I$
  373. 11060 IFI$=""THENRETURN
  374. 11070 IFVAL(I$)<1ORVAL(I$)>3THEN11050
  375. 11080 PRINT:PRINT"[217]OU ARE SERVED."
  376. 11090 PRINT"[205]MM. [201]T TASTES GOOD."
  377. 11095 E=T
  378. 11100 PRINT:PRINT"[210]OBOT: [217]OUR CHECK, SIR."
  379. 11120 PRINT:PRINT"[217]OU DO NOT HAVE ENOUGH MONEY!"
  380. 11130 CH=0:GOTO8500
  381. 12000 REM SUBWAY
  382. 12005 L=LV%(L,6)
  383. 12010 PRINT"[217]OU ENTER AT THE "LD$(L,1):PRINT"STATION."
  384. 12015 PRINT
  385. 12020 IFLV%(L,1)=0THENI=2:GOTO12050
  386. 12030 IFLV%(L,2)=0THENI=1:GOTO12050
  387. 12040 PRINT"[215]HICH TRAIN ([206]ORTHBOUND OR [211]OUTHBOUND)":INPUTI$
  388. 12045 I=2:IFLEFT$(I$,1)="[206]"ORLEFT$(I$,1)="N"THENI=1
  389. 12050 L=LV%(L,I)
  390. 12060 PRINT"[206]EXT STATION: "LD$(L,1)
  391. 12065 IFLV%(L,I)=0THENPRINT"[197]ND OF THE LINE.":L=LV%(L,8):XX=1:RETURN
  392. 12070 PRINT
  393. 12080 INPUT"[196]O YOU WANT TO GET OFF HERE";I$
  394. 12085 IFLEFT$(I$,1)="[217]"ORLEFT$(I$,1)="Y"THENL=LV%(L,8):XX=1:RETURN
  395. 12090 PRINT:GOTO12050
  396. 13000 REM CALL ROBOT
  397. 13002 IFR%(L)=0THENPRINT"[206]OBODY TO CALL.":RETURN
  398. 13003 IFR%(L)<>1THEN13200
  399. 13010 IFL=6THEN11000
  400. 13020 IFL=34THEN13300
  401. 13030 IFL=36THEN13400
  402. 13040 IFL=3THENPRINT"[210]OBOT: [215]OULD YOU LIKE TO TRY OUT THE    [195]OMMODORE 6400"
  403. 13045 IFL=3THENINPUTI$:IFLEFT$(I$,1)="[217]"ORLEFT$(I$,1)="Y"THEN10000
  404. 13047 IFL=3THENRETURN
  405. 13050 PRINT"[210]OBOT: [195]AN [201] HELP YOU?"
  406. 13060 INPUTI$
  407. 13065 IFI$=""THEN13060
  408. 13070 GOSUB520
  409. 13080 IFFW%(0)=10THENGOSUB9500:RETURN
  410. 13085 IFFW%(1)=4ANDL=3THEN10000
  411. 13090 PRINT"[210]OBOT: [201] AM NOT PROGRAMMED TO HANDLE      QUERIES OF THIS TYPE."
  412. 13190 RETURN
  413. 13200 REM GUARD AND BERZERK ROBOTS
  414. 13210 IFR%(L)=3THENPRINT"[212]HE ROBOT KILLS YOU WHILE YOU ARE TRYING";
  415. 13215 IFR%(L)=3THENPRINT"TO COMMUNICATE WITH IT!":GOTO300
  416. 13220 PRINT"[210]OBOT: [217]ES?"
  417. 13230 INPUTI$
  418. 13240 PRINT"[210]OBOT: [201] AM UNAUTHORIZED TO HANDLE        QUERIES OF THIS NATURE."
  419. 13250 RETURN
  420. 13300 REM UNIVERSITY
  421. 13310 PRINT"[210]OBOT: [215]HAT ROOM NUMBER DO YOU WANT?":INPUTI$
  422. 13320 IFVAL(I$)<>RMTHENPRINT"[210]OBOT: [211]ORRY, THAT ROOM IS NOT OPEN.":RETURN
  423. 13330 PRINT:PRINT"[212]HE WALL SLIDES OPEN, AND YOU ARE"
  424. 13333 PRINT"BRISKLY CARRIED ON A PLATFORM FLOATING"
  425. 13336 PRINT"INCHES ABOVE THE FLOOR, THROUGH SEVERAL"
  426. 13338 PRINT"HALLWAYS.  [217]OU COME TO A STOP."
  427. 13340 L=36:XX=1:RETURN
  428. 13400 REM HALL
  429. 13410 PRINT"[210]OBOT: [196]O YOU WANT TO RETURN TO THE":INPUT"LOBBY";I$
  430. 13420 IFLEFT$(I$,1)="[217]"ORLEFT$(I$,1)="Y"THENL=34:XX=1
  431. 13430 RETURN
  432. 13500 REM PLAY GAME
  433. 13505 PRINT
  434. 13510 PRINT"[195]OST:[160]$2.50"
  435. 13520 IFM<2.5THENPRINT"[217]OU CAN'T AFFORD IT.":RETURN
  436. 13530 PRINT:PRINT"[212]HE MACHINE IS OUT OF ORDER.  [201]T TAKES"
  437. 13540 PRINT"YOUR MONEY, BUT DOES NOT PLAY.  [217]OU"
  438. 13550 PRINT"POUND ON IT, BUT NOTHING HAPPENS, AND   YOU DON'T GET YOUR MONEY BACK."
  439. 13560 M=M-2.5
  440. 13570 RETURN
  441. 14000 REM TIME MACHINE
  442. 14010 PRINT"[217]OU ARE IN THE TIME MACHINE!"
  443. 14020 PRINT"[206]OW, SET THE CONTROLS:"
  444. 14030 INPUT"[217]EAR";Y
  445. 14040 INPUT"[205]ONTH";I$:INPUT"[196]AY";I$:INPUT"[200]OUR";I$:INPUT"[205]INUTE";I$
  446. 14045 INPUT"[211]ECOND";I$
  447. 14050 PRINT:PRINT"[212]HE MACHINE WHIRRS..."
  448. 14060 FORA=1TO1000:NEXTA
  449. 14070 PRINT"[217]OU HAVE ARRIVED!"
  450. 14080 IFY>=1970ANDY<2001THENPRINT"[194]ACK IN THE 20TH CENTURY AT LAST!  [217]OU  WIN!"
  451. 14085 IFY>=1970ANDY<2001THEN300
  452. 14090 IFY>=2001THENPRINT"[215]HY DID YOU GO TO THE FUTURE AGAIN?  [201]"
  453. 14095 IFY>=2001THENPRINT"DIDN'T PROGRAM ANY ADVENTURE GAME FOR"
  454. 14096 IFY>=2001THENPRINT"THAT CENTURY, AND THE TIME MACHINE IS"
  455. 14098 IFY>=2000THENPRINT"OUT OF POWER.  [217]OU'RE ON YOUR OWN.":GOTO300
  456. 14100 IFY<1970ANDY>=1901THENPRINT"[215]ELL, AT LEAST YOU MADE IT TO THE 20TH"
  457. 14110 IFY<1970ANDY>1901THENPRINT"CENTURY, BUT YOU'LL HAVE TO WAIT A"
  458. 14120 IFY<1970ANDY>1901THENPRINT"WHILE FOR [195]OMMODORE COMPUTERS TO BE     INVENTED."
  459. 14130 IFY<1970ANDY>1901THEN300
  460. 14140 PRINT"[217]OU END UP IN THE YEAR"Y".  [201] DIDN'T"
  461. 14150 PRINT"PROGRAM ANY ADVENTURE FOR THAT CENTURY,"
  462. 14160 PRINT"AND THE TIME MACHINE IS OUT OF POWER,   SO YOU ARE ON YOUR OWN."
  463. 14170 GOTO300
  464. 14500 REM EAT
  465. 14502 IFFW%(1)=0ANDL=6THEN11000
  466. 14510 IFFW%(1)<1ORFW%(1)>NITHENPRINT"[197]AT WHAT?":RETURN
  467. 14520 IFIL%(FW%(1))<>0THENPRINT"[197]AT WHAT?":RETURN
  468. 14530 IFIW(FW%(1))>2THENPRINT"[196]ON'T BE RIDICULOUS!":RETURN
  469. 14540 IFFW%(1)=3THENPRINT"[205]MM. [212]HAT WAS GOOD.":E=T:GOTO14565
  470. 14545 PRINT"[195]HOMP [195]HOMP [195]HOMP"
  471. 14550 PRINT"[201]T COULD HAVE USED A LITTLE SALT."
  472. 14560 IFT-E>150THENPRINT"[206]OT VERY NUTRITIOUS.  [217]OU7RE STILL      HUNGRY."
  473. 14565 IL%(FW%(1))=-1
  474. 14567 IFFW%(1)=10THENM=0
  475. 14570 RETURN
  476. 15000 REM BREAK OUT OF JAIL
  477. 15010 IFL<>28THENPRINT"[215]HAT?":RETURN
  478. 15020 PRINT"[212]HE RUSTY, WEAKENED BARS GIVE WAY AND   THERE IS AN OPENING OUT."
  479. 15030 LV%(28,8)=27:J=1
  480. 15040 RETURN
  481. 15500 REM ATTACK
  482. 15510 IFIL%(9)=0THEN9000
  483. 15515 IFR%(L)=0THENPRINT"[206]OTHING TO ATTACK.":RETURN
  484. 15520 IFIL%(1)<>0THENPRINT"[217]OU HAVE NO HOPE OF FIGHTING A TOUGH"
  485. 15525 IFIL%(1)<>0THENPRINT"METAL ROBOT WITH YOUR BARE HANDS.":RETURN
  486. 15530 PRINT"[212]HE KNIFE SHATTERS AGAINST THE ROBOT'S  TOUGH SIDE."
  487. 15535 IL%(1)=-1:IL%(14)=L
  488. 15538 IFR%(L)=3THENPRINT"[212]HE ROBOT KILLS YOU.":GOTO300
  489. 15540 CH=1:GOTO8500
  490. 16000 REM OPEN
  491. 16010 PRINT"[193]LL THE DOORS OPEN AND CLOSE"
  492. 16020 PRINT"AUTOMATICALLY, SO THERE IS NO NEED TO   OPEN OR CLOSE THEM."
  493. 16030 RETURN
  494. 16500 REM HELP
  495. 16510 PRINT:PRINT"[211]OME AVAILABLE COMMANDS:"
  496. 16530 PRINT" [201][206][214]":PRINT" [199][197][212] [OBJECT]":PRINT" [194][213][217] [OBJECT]":PRINT" [196][210][207][208] [OBJECT]"
  497. 16540 PRINT" [197][216][193][205][201][206][197] [OBJECT]":PRINT" [195][193][204][204][160][210][207][194][207][212]":"[160][193][212][212][193][195][203][160][210][207][194][207][212]":"[160][211][200][207][207][212][160][210][207][194][207][212]"
  498. 16545 PRINT"[160][204][207][207][203]"
  499. 16550 PRINT:RETURN
  500. 18000 REM OPENING TITLES
  501. 18010 PRINT "[147]"
  502. 18020 PRINT:PRINT:PRINT:PRINT:PRINT
  503. 18030 PRINT:PRINT:PRINT"     **** [208]LANET OF THE [210]OBOTS ****"
  504. 18040 PRINT
  505. 18050 PRINT"        [195]OMMODORE 64 [214]ERSION 1.1"
  506. 18060 PRINT:PRINT"   [195]OPYRIGHT ([195]) 1984 BY [196]ANIEL [212]OBIAS"
  507. 18070 PRINT:INPUT"         [201]NSTRUCTIONS ([217]/[206]) ";I$
  508. 18080 IF LEFT$(I$,1)="[206]" OR LEFT$(I$,1)="N" THEN RETURN
  509. 18500 REM INSTRUCTIONS
  510. 18510 PRINT"[147]"
  511. 18520 PRINT"[193] TIME WARP HAS SUDDENLY TRANSPORTED":PRINT
  512. 18530 PRINT"YOU INTO THE FUTURE, WHERE A WAR USING":PRINT
  513. 18550 PRINT"NEUTRON BOMBS AND BACTERIOLOGICAL"
  514. 18560 PRINT:PRINT"WARFARE HAS COMPLETELY WIPED OUT THE":PRINT
  515. 18570 PRINT"HUMAN RACE.  [200]OWEVER, THE COMPUTERS":PRINT
  516. 18580 PRINT"AND ROBOTS DON'T KNOW THIS, AND KEEP":PRINT
  517. 18585 PRINT"GOING ABOUT THEIR BUSINESS AS IF NOTHING":PRINT"HAS HAPPENED.":PRINT
  518. 18587 PRINT"*** [200]IT RETURN TO CONTINUE ***";:SYSLI,B$:PRINT"[147]"
  519. 18590 PRINT"[217]OU EXPLORE THE WORLD YOU ARE THRUST"
  520. 18595 PRINT:PRINT"INTO USING SIMPLE SENTENCES, IN THE"
  521. 18600 PRINT:PRINT"STANDARD ADVENTURE-GAME FASHION, SUCH"
  522. 18610 PRINT:PRINT"AS [193][212][212][193][195][203][160][210][207][194][207][212][160]OR [197][216][193][205][201][206][197][160][195][207][201][206]."
  523. 18620 PRINT:PRINT"[201]F A ROBOT IS IN THE ROOM, YOU MAY"
  524. 18625 PRINT:PRINT"ATTEMPT TO TALK TO IT BY TYPING [195][193][204][204]"
  525. 18630 PRINT:PRINT"[210][207][194][207][212], BUT POSITIVE RESULTS ARE NOT":PRINT:PRINT"GUARANTEED!"
  526. 18635 PRINT:PRINT"*** [200]IT RETURN TO CONTINUE. ***";:SYSLI,B$:PRINT"[147]"
  527. 18640 PRINT"[199][207][160][206][207][210][212][200] MAY BE ABBREVIATED [206], AND THE"
  528. 18650 PRINT:PRINT"SAME MAY BE DONE WITH THE OTHER COMPASS"
  529. 18660 PRINT:PRINT"DIRECTIONS."
  530. 18670 PRINT:PRINT"[212]HE OBJECT IS TO GET BACK TO THE 20TH"
  531. 18680 PRINT:PRINT"CENTURY.  [199]OOD LUCK!"
  532. 18690 PRINT:PRINT"[211]OME UTILITY COMMANDS:"
  533. 18700 PRINT"  [209][213][201][212] EXITS GAME":PRINT"  [211][193][214][197] SAVES GAME IN PROGRESS TO DISK."
  534. 18710 PRINT:PRINT"*** [200]IT RETURN TO START. ***";:SYSLI,B$:PRINT"[147]":RETURN
  535. 18999 RETURN
  536. 19000 REM INITIALIZE
  537. 19002 PRINT"[147][208]LEASE WAIT.  [201]NITIALIZING DATA."
  538. 19005 FORA=1TO8:READDN$(A):NEXTA
  539. 19020 A=1
  540. 19025 FORB=0TO1:READLD$(A,B):NEXTB:IFLD$(A,0)<>""THENA=A+1:GOTO19025
  541. 19027 NL=A-1
  542. 19030 FORA=1TONL:FORB=1TO8:READLV%(A,B):NEXTB:READR%(A):NEXTA
  543. 19040 FORA=1TONL:L%(A)=0:NEXTA
  544. 19050 A=1
  545. 19060 READID$(A),IL%(A),IW(A),PR(A):IFIL%(A)<>-999THENA=A+1:GOTO19060
  546. 19065 NI=A-1
  547. 19067 FORA=1TO10:READPW$(A):NEXTA
  548. 19070 A=1
  549. 19075 READWD$(A),W%(A,0),W%(A,1):IFWD$(A)<>""THENA=A+1:GOTO19075
  550. 19080 NW=A-1
  551. 19085 L=1:T=1
  552. 19087 W=0:M=-119
  553. 19088 E=0:J=0:R=0
  554. 19090 PRINT "[147]":INPUT"[204]OAD GAME FROM DISK ([217]/[206]) ";I$
  555. 19093 PW=INT(RND(0)*10)+1
  556. 19096 CM%=INT(RND(0)*9999):RM=INT(RND(0)*900)+100
  557. 19100 IFLEFT$(I$,1)="[217]"ORLEFT$(I$,1)="Y"THENGOSUB6500
  558. 19110 F=.0596064645
  559. 19120 FORI=.TO3:READP:V%(I)=P/F+.5:NEXT:FORI=.TO2:READP:H%(I)=P/F+.5:NEXT
  560. 19125 FORI=.TO1:READP:O%(I)=P/F+.5:NEXT:FORI=.TO1:READP:A(I)=INT(P/F+.5):NEXT
  561. 19130 RETURN
  562. 20000 REM DATA
  563. 20005 DATA"[206][160]","[211] ","[197] ","[215] ","[213] ","[196] ","[201][206] ","[207][213][212]"
  564. 20040 DATA"[144][217]OU ARE IN THE PARKING LOT OF A SHOPPINGMALL. [193] ROAD IS TO THE EAST."
  565. 20045 DATA"[144][217]OU'RE IN PARKING LOT TO MALL."
  566. 20050 DATA"[217]OU ARE IN THE SHOPPING MALL.  [212]HERE IS A COMPUTER STORE HERE."
  567. 20055 DATA"[217]OU'RE IN MALL AT COMPUTER STORE."
  568. 20060 DATA"[217]OU ARE IN THE COMPUTER STORE.","[217]OU'RE IN COMPUTER STORE."
  569. 20070 DATA"[212]O THE WEST IS A COMIC BOOK STORE.  [212]O  THE EAST IS A RESTAURANT."
  570. 20075 DATA"[217]OU'RE BY COMIC STORE AND RESTAURANT."
  571. 20080 DATA"[212]HIS IS A STORE CATERING TO COMIC BOOK  COLLECTORS."
  572. 20085 DATA"[217]OU ARE IN COMIC STORE."
  573. 20090 DATA"[217]OU ARE IN A RESTAURANT.","[217]OU'RE IN RESTAURANT."
  574. 20100 DATA"[212]O THE WEST IS AN ARCADE, AND TO THE    EAST IS A GROCERY STORE."
  575. 20105 DATA"[217]OU'RE BY ARCADE AND GROCERY."
  576. 20110 DATA"[217]OU ARE IN AN ARCADE.","[217]OU'RE IN ARCADE."
  577. 20120 DATA"[212]O THE WEST IS A BUTCHER SHOP, AND TO   THE EAST A CLOTHING STORE."
  578. 20125 DATA"[217]OU'RE BY BUTCHER AND CLOTHING STORE."
  579. 20130 DATA"[217]OU ARE IN A BUTCHER SHOP.","[217]OU'RE IN BUTCHER SHOP."
  580. 20140 DATA"[217]OU ARE IN A CLOTHING STORE.","[217]OU'RE IN CLOTHING STORE."
  581. 20150 DATA"[217]OU ARE IN A GROCERY.","[217]OU'RE IN GROCERY."
  582. 20160 DATA"[144][217]OU ARE ON A [206]-[211] ROAD.  [212]HERE IS A      SHOPPING MALL TO THE WEST."
  583. 20165 DATA"[144][217]OU'RE ON ROAD BY MALL."
  584. 20170 DATA"[144][212]HE ROAD GOES 100 FT., THEN STOPS AT AN IMPENETRABLE PILE OF DEBRIS."
  585. 20175 DATA"[144][217]OU'RE AT DEBRIS."
  586. 20180 DATA"[144][217]OU ARE NEXT TO AN INFORMATION BOOTH,   MANNED BY A ROBOT."
  587. 20185 DATA"[144][217]OU'RE AT INFO BOOTH."
  588. 20190 DATA"[144][217]OU ARE IN A PHONE BOOTH.  [212]HE CASH BOX HAS BURST OPEN."
  589. 20195 DATA"[144][217]OU'RE IN PHONE BOOTH."
  590. 20200 DATA"[201]","[201]"
  591. 20210 DATA"[217]OU ARE IN THE LIBRARY.","[217]OU'RE IN LIBRARY."
  592. 20220 DATA"[144][212]O THE WEST IS A LIBRARY, AND THE CITY  HALL IS TO THE EAST."
  593. 20225 DATA"[144][217]OU'RE BY LIBRARY AND CITY HALL."
  594. 20230 DATA"[217]OU ARE IN THE LOBBY OF THE CITY HALL.  [212]HERE IS A STAIRWAY HERE."
  595. 20235 DATA"[217]OU'RE IN CITY HALL LOBBY."
  596. 20240 DATA"[144][212]HE ROAD ENDS HERE.  [212]HERE IS A SUBWAY  ENTRANCE HERE."
  597. 20245 DATA"[144][217]OU'RE BY SUBWAY STATION."
  598. 20247 DATA"[211]","[195]ITY [200]ALL"
  599. 20250 DATA"[217]OU ARE IN A HALLWAY LEADING TOWARDS    OFFICES TO THE EAST."
  600. 20255 DATA"[217]OU'RE IN HALLWAY."
  601. 20260 DATA"[212]HERE ARE OFFICES TO THE NORTH AND      SOUTH."
  602. 20265 DATA"[217]OU'RE BETWEEN TWO OFFICES."
  603. 20270 DATA"[217]OU ARE IN AN OFFICE","[217]OU'RE IN OFFICE."
  604. 20280 DATA"[217]OU ARE IN AN OFFICE","[217]OU'RE IN OFFICE."
  605. 20290 DATA"[217]OU ARE IN A HALLWAY IN THE JAIL.  [193]    CLOSET IS TO THE NORTH."
  606. 20295 DATA"[217]OU'RE IN JAIL HALLWAY."
  607. 20300 DATA"[217]OU ARE IN A JAIL CELL.","[217]OU'RE IN JAIL CELL."
  608. 20310 DATA"[156][217]OU ARE IN A CLOSET.","[156][217]OU'RE IN CLOSET."
  609. 20320 DATA"[211]","[205]ARKET [211]TREET"
  610. 20330 DATA"[211]","[205]ETRO [213]NIVERSITY"
  611. 20340 DATA"[211]","[197]NDSVILLE"
  612. 20350 DATA"[156][217]OU ARE ON A STREET WHICH IS BLOCKED IN BOTH DIRECTIONS BY DEBRIS."
  613. 20355 DATA"[156][217]OU'RE ON BLOCKED STREET."
  614. 20360 DATA"[156][217]OU ARE IN THE MAIN LOBBY OF THE [205]ETRO  [213]NIVERSITY BUILDING."
  615. 20365 DATA"[156][217]OU'RE IN UNIVERSITY LOBBY."
  616. 20370 DATA"[144][217]OU ARE ON A PLAIN WHERE A BOMB BLAST   HAS DESTROYED THE TOWN."
  617. 20375 DATA"[144][217]OU'RE ON PLAIN BY SUBWAY STOP."
  618. 20380 DATA"[156][217]OU ARE IN FRONT OF A DOOR.","[156][217]OU'RE IN FRONT OF DOOR."
  619. 20390 DATA"[156][217]OU ARE IN THE LABORATORY OF [208]ROJECT    [195]HRONOS.[146]"
  620. 20395 DATA"[156][217]OU'RE IN LAB.[146]"
  621. 20400 DATA"[212]","[212]"
  622. 20405 DATA"[144][217]OU ARE ON PLAIN.","[144][217]OU ARE ON PLAIN."
  623. 20410 DATA"[217]OU ARE BY A PHONE BOOTH.","[217]OU'RE BY PHONE BOOTH."
  624. 20990 DATA"",""
  625. 21000 REM MOVEMENT,ROBOTS
  626. 21010 DATA0,0,13,0,0,0,2,0,0
  627. 21020 DATA7,4,0,0,0,0,3,1,0
  628. 21030 DATA0,0,0,0,0,0,0,2,1
  629. 21040 DATA2,0,6,5,0,0,0,0,0
  630. 21050 DATA0,0,0,0,0,0,0,4,1
  631. 21060 DATA0,0,0,0,0,0,0,4,1
  632. 21070 DATA9,2,12,8,0,0,0,0,0
  633. 21080 DATA0,0,0,0,0,0,0,7,0
  634. 21090 DATA0,7,11,10,0,0,0,0,0
  635. 21100 DATA0,0,0,0,0,0,0,9,0
  636. 21110 DATA0,0,0,0,0,0,0,9,1
  637. 21120 DATA0,0,0,0,0,0,0,7,1
  638. 21130 DATA14,15,0,1,0,0,0,0,0
  639. 21140 DATA0,13,0,0,0,0,0,0,0
  640. 21150 DATA13,19,0,0,0,0,17,0,0
  641. 21160 DATA0,0,0,0,0,0,0,40,0
  642. 21170 DATA0,0,0,0,0,0,0,15,1
  643. 21180 DATA0,0,0,0,0,0,0,19,0
  644. 21190 DATA15,21,20,18,0,0,0,0,0
  645. 21200 DATA0,0,0,0,23,27,0,19,26
  646. 21210 DATA19,0,0,0,0,22,0,0,3
  647. 21215 DATA0,30,0,0,0,0,0,21,0
  648. 21220 DATA0,0,24,0,0,20,0,0,23
  649. 21230 DATA26,25,0,23,0,0,0,0,0
  650. 21240 DATA0,0,0,0,0,0,0,24,3
  651. 21245 DATA0,0,0,0,0,0,0,24,0
  652. 21250 DATA29,28,0,0,20,0,0,0,25
  653. 21260 DATA0,0,0,0,0,0,0,0,0
  654. 21270 DATA0,0,0,0,0,0,0,27,0
  655. 21280 DATA22,31,0,0,0,0,0,33,0
  656. 21290 DATA30,32,0,0,0,0,0,34,0
  657. 21300 DATA31,0,0,0,0,0,0,35,0
  658. 21310 DATA0,0,0,0,0,30,0,0,0
  659. 21320 DATA0,0,0,0,0,31,0,0,1
  660. 21330 DATA39,39,39,39,0,32,0,0,0
  661. 21340 DATA0,0,0,0,0,0,37,0,1
  662. 21350 DATA0,0,0,0,0,0,38,36,0
  663. 21360 DATA0,0,0,0,0,0,0,0,0
  664. 21370 DATA39,39,39,39,0,0,0,0,0
  665. 21380 DATA39,39,39,39,0,0,16,0,0
  666. 23000 REM ITEMS
  667. 23030 DATA"[194]UTCHER'S [203]NIFE",10,5,0
  668. 23033 DATA"[211]CALE",10,140,0
  669. 23036 DATA"[198]OOD [208]ILLS",12,.5,10
  670. 23040 DATA"[195]OMMODORE 6400 [195]OMPUTER",3,15,5000
  671. 23050 DATA"[214]IDEO GAME MACHINE",8,-1,0
  672. 23060 DATA"[211]UIT OF CLOTHES",11,2,995
  673. 23070 DATA"[212]IE",11,.15,20
  674. 23090 DATA"[195]OMIC",5,.3,6
  675. 23100 DATA"[210]AY [199]UN",14,1,0
  676. 23110 DATA"[195]OINS",16,2,0
  677. 23120 DATA"[194]OOK",18,1,0
  678. 23130 DATA"[201].[196]. [195]ARD",29,.05,0
  679. 23140 DATA"[204]ETTER",26,.05,0
  680. 23150 DATA"[211]HATTERED PIECES OF METAL",-1,5,0
  681. 23160 DATA"[212]IME [205]ACHINE",37,2000,0
  682. 23990 DATA"",-999,-999,-999
  683. 23995 DATASESAME,SNARK,QUARK,PEARTREE,MOONSHINE,SHOE,TURKEY,CHRISTMAS
  684. 23997 DATAHALLOWEEN,ROBOTWAR
  685. 24000 REM WORDS
  686. 24010 DATAN,1,101
  687. 24020 DATAS,1,102
  688. 24030 DATAE,1,103
  689. 24040 DATAW,1,104
  690. 24050 DATAU,1,105
  691. 24060 DATAD,1,106
  692. 24070 DATAIN,1,107
  693. 24080 DATAOUT,1,108
  694. 24090 DATAGET,2,-1
  695. 24100 DATATAKE,2,-1
  696. 24140 DATAGO,1,-1
  697. 24160 DATADROP,3,-1
  698. 24170 DATALOOK,4,-1
  699. 24180 DATAINV,5,-1
  700. 24190 DATAQUIT,99,-1
  701. 24200 DATASAVE,6,-1
  702. 24210 DATAROBOT,-1,200
  703. 24220 DATABUY,10,-1
  704. 24230 DATAWEIGH,7,-1
  705. 24240 DATAREAD,8,-1
  706. 24250 DATAEXAMINE,8,-1
  707. 24260 DATAKNIFE,-1,1
  708. 24270 DATASCALE,-1,2
  709. 24280 DATAPILLS,-1,3
  710. 24290 DATACOMMODORE,-1,4
  711. 24295 DATA6400,-1,4
  712. 24300 DATACOMPUTER,-1,4
  713. 24310 DATACALL,11,-1
  714. 24315 DATATALK,11,-1
  715. 24317 DATASPEAK,11,-1
  716. 24320 DATAGAME,-1,5
  717. 24330 DATAPLAY,12,-1
  718. 24340 DATASUIT,-1,6
  719. 24350 DATATIE,-1,7
  720. 24360 DATACOMIC,-1,8
  721. 24370 DATAEAT,13,-1
  722. 24380 DATABREAK,14,-1
  723. 24390 DATAESCAPE,14,-1
  724. 24400 DATAGUN,-1,9
  725. 24410 DATACOINS,-1,10
  726. 24420 DATAMONEY,-1,10
  727. 24425 DATACASH,-1,10
  728. 24430 DATABOOK,-1,11
  729. 24440 DATASHOOT,9,-1
  730. 24445 DATAZAP,9,-1
  731. 24450 DATAATTACK,15,-1
  732. 24455 DATAKILL,15,-1
  733. 24460 DATAI.D.,-1,12
  734. 24465 DATAID,-1,12
  735. 24470 DATACARD,-1,12
  736. 24480 DATALETTER,-1,13
  737. 24490 DATAPIECES,-1,14
  738. 24500 DATAOPEN,16,-1
  739. 24510 DATAHELP,17,-1
  740. 24515 DATAON,18,-1
  741. 24520 DATABARS,-1,200
  742. 24895 REM *****UNABBREVIATED:
  743. 24900 DATANORTH,1,101
  744. 24905 DATASOUTH,1,102
  745. 24910 DATAEAST,1,103
  746. 24915 DATAWEST,1,104
  747. 24920 DATAUP,1,105
  748. 24925 DATADOWN,1,106
  749. 24930 DATAINVENTORY,5,-1
  750. 24935 DATAENTER,1,107
  751. 24940 DATAEXIT,1,108
  752. 24990 DATA"",-999,-999
  753. 30000 POKES+5,.:POKES+6,240:POKES+12,.:POKES+13,240:POKES+3,8:POKES+10,8
  754. 30005 POKES+24,15:T$="123456789*0#"
  755. 30010 F=.059604645:POKE53280,.:POKE53281,.
  756. 30012 PRINT"[147][158][212][197][210][205]6400  300 [203]ILOBAUD [212]ERMINAL [208]ACKAGE"
  757. 30013 PRINT"[158][195]OPYRIGHT ([195])[160]2063 BY [204]OADSTAR [211]OFTWARE"
  758. 30014 PRINT"[212]YPE '[207][198][198]' TO RETURN TO [194][193][211][201][195]."
  759. 30025 P$="1-800-555-0749":GOTO30150
  760. 30030 PRINT"[196]IALING:  ";:GOSUB30135:POKES+24,8
  761. 30035 FORI=1TOLEN(P$):A$=MID$(P$,I,1):PRINTA$;:FORJ=1TOLEN(T$)
  762. 30040 IFA$<>MID$(T$,J,1)THENNEXT:NEXT:GOTO30025
  763. 30045 P=J-1:J=LEN(T$):NEXT:V%=P/3:H%=P-3*V%:P1%=H%(H%):P2%=V%(V%):GOSUB30080:NEXT
  764. 30050 POKES+24,15:GOSUB30090:GOSUB30115
  765. 30055 PRINT:PRINT"300 [203]ILOBAUD [195]ONNECT[154]":FORI=1TO500:NEXT:GOTO10120
  766. 30060 DATA697,770,852,941:REM VERTICAL TOUCH-TONE PITCHES
  767. 30065 DATA1209,1336,1477:REM HORIZONTAL TOUCH-TONE PITCHES
  768. 30070 DATA1070,1270:REM ORIGINATE MODEM SPACE, MARK
  769. 30075 DATA2025,2225:REM ANSWER MODEM SPACE, MARK
  770. 30080 POKES,P1%AND255:POKES+1,P1%/256:POKES+7,P2%AND255:POKES+8,P2%/256
  771. 30085 POKES+4,65:POKES+11,65:FORP=1TO50:NEXT:POKES+4,.:POKES+11,.:RETURN
  772. 30090 T1%=7430:T2%=7000:POKES+24,.:POKES+24,15::FORP=1TO2:POKES+4,17:FORI=1TO60
  773. 30095 POKES,T1%AND255:POKES+1,T1%/256
  774. 30100 POKES,T2%AND255:POKES+1,T2%/256:NEXT
  775. 30105 POKES+4,.:FORI=1TO1000-2500*(P=1):NEXT:NEXT:POKES+24,.:POKES+24,15
  776. 30110 POKES+24,.:FORI=1TO20:NEXT:POKES+24,15:POKES+24,.:POKES+24,15:RETURN
  777. 30115 T1=A(.):T2%=O%(.):POKES+24,4
  778. 30120 POKES,T1-256*INT(T1/256):POKES+1,T1/256:POKES+4,65:FORI=1TO800:NEXT
  779. 30125 POKES+7,T2%AND255:POKES+8,T2%/256:POKES+11,65:FORI=1TO500:NEXT:POKES+24,.
  780. 30130 POKES+4,.:POKES+11,.:RETURN
  781. 30135 T%=7217:POKES+24,.:POKES+24,15:POKES+24,.:POKES+24,15
  782. 30140 POKES,T%AND255:POKES+1,T%/256:FORP=1TO200:POKES+4,16:POKES+4,17:NEXT
  783. 30145 POKES+4,16:RETURN
  784. 30150 INPUT"[211]YSTEM TO ACCESS";I$:GOSUB200:IFI$="OFF"THEN30200
  785. 30155 FORI=1TO1000:NEXT:IFI$<>"GOVT"THENPRINT"[213]NKNOWN SYSTEM":GOTO30150
  786. 30160 PRINT"[156][199][207][214][212]:  [213].[211]. [199]OVT. [196]ATABASE":PRINT"[208]HONE [206]UMBER:  "P$
  787. 30165 PRINT"[129][201]S THIS CORRECT ([217]/[206])?[160]";
  788. 30170 POKE198,.:WAIT198,1:GETI$:IFI$="[206]"ORI$="N"THENPRINT"[206]OPE.":PRINT"":GOTO30150
  789. 30175 IFI$<>"[217]"ANDI$<>"Y"THEN30165
  790. 30180 PRINT"[217]EAH!":GOTO30030
  791. 30200 POKE53270,4:FORI=1TO2000:NEXT:GOTO10010
  792. 30500 PRINT:PRINT"SEARCHING FOR TERM6400":CLOSE8:CLOSE15:OPEN8,8,8,"#"
  793. 30502 OPEN15,8,15,"U1:8 0 18 0":PRINT#15,"U1:8 0 18 0"
  794. 30505 FORI=1TO1000:NEXT:PRINT"LOADING"
  795. 30510 FORI=1TO4:PRINT#15,"U1:8 0 "INT(RND(1)*30+3);.:FORJ=1TORND(1)*2000+1000
  796. 30515 NEXT:NEXT:CLOSE8:CLOSE15:GOTO30000
  797.