home *** CD-ROM | disk | FTP | other *** search
/ Carousel Volume 2 #1 / carousel.iso / comdore / 64utils / seq (.txt) < prev    next >
Commodore BASIC  |  1988-11-16  |  2KB  |  47 lines
  1. 1 PRINT"[144][147][211][197][209][213][197][206][212][201][193][204] [198][201][204][197] [210][197][193][196][146]":PRINT"[195][207][208][217][210][201][199][200][212] 1983 [194][217] [210][193][217][205][207][206][196] [211][146]":PRINT"[200][201][212] [193] [203][197][217]"
  2. 2 R$=CHR$(13):POKE808,239:FORB=1TO16:FORC=1TO50
  3. 3 POKE53281,B:GETA$:IFA$=""THENNEXT:NEXT:GOTO2
  4. 4 PRINT"[208]LEASE ENTER FILE NAME, OR <RETURN> FOR":PRINT"'LISTING'":INPUT B$
  5. 5 IFB$=""THENB$="LISTING"
  6. 10 PRINT"[147][217]OUR OPTIONS:"R$;R$;R$" <[211]>CREEN"R$;R$" <[208]>RINTER"R$;R$" <?>[200]ELP"R$;
  7. 15 PRINTR$" <[209]>UIT"
  8. 25 GETG$:IFG$=""THEN25
  9. 27 IFG$="Q"THEN1140
  10. 30 IFG$="S"GOTO60
  11. 33 IFG$="?"THEN1000
  12. 40 IFG$<>"P"THEN25
  13. 50 OPEN1,4,7:Q=1
  14. 60 OPEN5,8,5,B$+",S,R":GOSUB500
  15. 62 PRINT"[147][208]RESS ANY KEY TO PAUSE,":PRINT"PRESS AGAIN TO CO";
  16. 65 PRINT"NTINUE.":PRINT"'Q' ENDS PROGRAM"R$
  17. 100 GET#5,F$
  18. 110 IFST=0THEN130
  19. 120 IFST=64THEN300
  20. 130 IFQ<>1THENPRINTF$;:GOTO136
  21. 135 PRINT#1,F$;
  22. 136 GETA$
  23. 137 IFA$<>""THENGOSUB199
  24. 140 GOTO100
  25. 199 IFA$="Q"THEN1100
  26. 200 GETA$:IFA$=""THEN200
  27. 205 IFA$="Q"THEN1100
  28. 210 RETURN
  29. 300 GOTO1100
  30. 500 CLOSE15:OPEN15,8,15:INPUT#15,D,E$,F,G
  31. 510 IFD>0THENPRINT"[212]HERE IS A FILE ACCESS PROBLEM:"R$;D;E$:CLOSE15:GOTO1100
  32. 520 RETURN
  33. 1000 PRINT"[147][212]HIS PROGRAM IS A DISK FILE READ PROGRAM"R$"IT WILL READ A";
  34. 1010 PRINT"NY SEQUENTIAL[146] FILE ON ANY"R$"DISK FORMATTED FOR THE C-64 OR VIC-20."
  35. 1020 PRINTR$"TO USE, SIMPLY TYPE IN THE NAME OF THE"R$"FILE YOU WISH TO SEE. THEN";
  36. 1030 PRINT" CHOOSE"R$"WHETHER YOU WANT THE FILE SENT TO THE"R$"PRINTER OR SCREEN."
  37. 1040 PRINTR$R$"WHILE THE FILE IS BEING SHOWN, YOU MAY"R$"PRESS ANY KEY (EXCEPT 'Q";
  38. 1050 PRINT"') TO FREEZE THE DISPLAY (OR PRINTER)."R$"PRESSING 'Q' WILL END THE PR";
  39. 1060 PRINT"OGRAM."
  40. 1070 PRINT"PRESS ANY KEY TO CONTINUE[146]"
  41. 1080 GETA$:IFA$=""THEN1080
  42. 1090 GOTO10
  43. 1100 Q=0:CLOSE1:CLOSE5:PRINTR$"[196]O YOU WISH TO READ"R$"ANOTHER FILE (Y/N)?"
  44. 1110 FORA=1TO1500:GETA$:IFA$=""THENNEXT
  45. 1120 IFA$="Y"THENPRINTCHR$(147):B$="":GOTO4
  46. 1140 POKE808,237:PRINT"    [145]":END
  47.