home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 317b.lha / RCS_Sources / rsbx.lib / xc.asm < prev   
Assembly Source File  |  1989-12-05  |  8KB  |  352 lines
  1. *
  2. * This is a copy of c.a, distributed with the Lattice 5.04 compiler, that has
  3. *    been hacked to support my LaunchChild calls. There is no WorkBench
  4. *    support in this startup.
  5. *
  6. *                    Ray
  7. *
  8. *
  9. * C initial startup procedure under AmigaDOS
  10. * 
  11. * Use the following command line to make c.o
  12. * asm -u -iINCLUDE: c.a
  13. *
  14. * Use the following command line to make cres.o
  15. * asm -u -dRESIDENT -iINCLUDE: -ocres.o c.a
  16. *
  17.     INCLUDE    "exec/types.i"
  18.     INCLUDE    "exec/alerts.i"
  19.     INCLUDE    "exec/nodes.i"
  20.     INCLUDE    "exec/lists.i"
  21.     INCLUDE    "exec/ports.i"
  22.     INCLUDE    "exec/libraries.i"
  23.     INCLUDE    "exec/tasks.i"
  24.     INCLUDE    "exec/memory.i"
  25.     INCLUDE    "exec/execbase.i"
  26.     INCLUDE    "libraries/dos.i"
  27.     INCLUDE    "libraries/dosextens.i"
  28.     INCLUDE    "exec/funcdef.i"
  29.     INCLUDE    "exec/exec_lib.i"
  30.     INCLUDE    "libraries/dos_lib.i"
  31.  
  32. MEMFLAGS    EQU    MEMF_CLEAR+MEMF_PUBLIC
  33. AbsExecBase    EQU    4
  34.  
  35. ; some usefull macros:
  36.  
  37. callsys macro
  38.     CALLLIB _LVO\1
  39.     endm
  40.     
  41.     xdef    _XCEXIT        * exit(code) is standard way to leave C.
  42.     xdef    _@XCEXIT
  43.     
  44.     xref    _LinkerDB    * linker defined base value
  45.     xref    __BSSBAS    * linker defined base of BSS
  46.     xref    __BSSLEN    * linker defined length of BSS
  47.     IFD    RESIDENT
  48.     xref    _RESLEN
  49.     xref    _RESBASE
  50.     xref    _NEWDATAL
  51.     xref    __stack
  52.     ENDC
  53.     
  54. *    library references
  55.  
  56.     section text,code
  57.  
  58.     xref    __xmain            * Name of C program to start with.
  59.     xref    _MemCleanup        * Free all allocated memory
  60.     xref    ___fpinit        * initialize floating point
  61.     xref    ___fpterm        * terminate floating point
  62.     
  63. start:
  64.     movem.l d1-d6/a0-a6,-(a7)
  65.  
  66.     move.l    a0,a2            * save command pointer
  67.     move.l    d0,d2            * and command length
  68.     lea    _LinkerDB,a4        * load base register
  69.     move.l    AbsExecBase.W,a6
  70.  
  71. *------ are we running as a son of Workbench?
  72.     move.l    ThisTask(a6),A3
  73.     tst.l    pr_CLI(A3)
  74.     bne.s    fromCLI
  75.     
  76. *=======================================================================
  77. *====== Workbench Startup Code =========================================
  78. *=======================================================================
  79.  
  80. fromWorkbench:
  81.  
  82.     lea    pr_MsgPort(A3),a0    * our process base
  83.     callsys WaitPort
  84.     lea    pr_MsgPort(A3),a0    * our process base
  85.     callsys GetMsg
  86.     move.l    d0,a2
  87.  
  88. *$* should put recoverable alert here
  89.  
  90. *------    return the startup message to our parent
  91. *    we forbid so workbench can't UnLoadSeg() us
  92. *    before we are done:
  93.     callsys    Forbid
  94.     move.l    a2,a1
  95.     callsys    ReplyMsg
  96.  
  97.     moveq.l    #-1,D0
  98.     
  99.     movem.l (a7)+,d1-d6/a0-a6
  100.     rts
  101.     
  102. *=======================================================================
  103. *====== CLI Startup Code ===============================================
  104. *=======================================================================
  105.  
  106. fromCLI:
  107.     IFND    RESIDENT
  108.         lea    __BSSBAS,a3        * get base of BSS
  109.         moveq    #0,d1
  110.         move.l    #__BSSLEN,d0        * get length of BSS in longwords
  111.         bra.s    clr_lp            * and clear for length given
  112. clr_bss        move.l    d1,(a3)+
  113. clr_lp        dbf    d0,clr_bss
  114.         move.l    a7,__StackPtr(A4)    * Save stack ptr
  115.         move.l    a6,_SysBase(A4)
  116.     ENDC
  117.     
  118.  
  119.     IFD    RESIDENT
  120.         movem.l    d2,-(a7)
  121.         movem.l a0-a2,-(a7)
  122.  
  123. *------        get the size of the stack, if CLI use cli_DefaultStack
  124.  
  125.         move.l    ThisTask(a6),A3
  126.         move.l    pr_CLI(A3),d1
  127.         lsl.l    #2,d1
  128.         move.l    d1,a0
  129.         move.l    cli_DefaultStack(a0),d1
  130.         lsl.l    #2,d1            * # longwords -> # bytes
  131.  
  132. dostack:
  133.         moveq    #0,d2            * use d2 as flag for newstack or not
  134.         move.l    #RESLEN,d0
  135.         cmp.l    __stack(a4),d1        * This a4 is in the original 
  136.                         * set of data
  137.         bcc.s    nochange    
  138.         move.l    __stack(a4),d1
  139.         add.l    d1,d0            * increase size of mem for new stack
  140.         moveq    #1,d2            * set flag
  141.         
  142. nochange:
  143.         move.l    d1,a3            * save stacksize to set up stack checking
  144.         move.l    #MEMFLAGS,d1
  145.         callsys AllocMem
  146.         tst.l    d0
  147.         bne.s    ok1
  148.         movem.l    (a7)+,d2/a0-a2
  149. *$* ACK!!!
  150. *$*        rts
  151. *$* ACK!!!
  152.  
  153. ok1:        move.l    d0,a0
  154.         move.l    d0,a2
  155.  
  156.     ;a2 now has difference
  157.         move.l    d0,a1
  158.         move.l    #NEWDATAL,d0
  159.         sub.l    #RESBASE,a4
  160.     ;copy data over
  161. cpy:        move.l    (a4)+,(a0)+
  162.         subq.l    #1,d0
  163.         bne.s    cpy
  164.     ;a4 now points at number of relocs
  165.         move.l    (a4)+,d0
  166. reloc:        beq.s    nreloc
  167.         move.l    a1,a0
  168.         add.l    (a4)+,a0        * a0 now has add of reloc
  169.         add.l    (a0),a2
  170.         move.l    a2,(a0) 
  171.         move.l    a1,a2            * restore offset
  172.         subq.l    #1,d0
  173.         bra.s    reloc
  174.  
  175. nreloc:        move.l    a1,a4            * set up new base register
  176.         add.l    #RESBASE,a4
  177.  
  178.         move.l    #RESLEN,realdatasize(a4)
  179.         movem.l (a7)+,a0-a2
  180.  
  181.         move.l    a6,_SysBase(A4)
  182.         tst.b    d2
  183.         movem.l    (a7)+,d2        * restore d2 
  184.         movem.l a7,__StackPtr(A4)    * Save stack ptr (movem doesn't
  185.                         * change flags
  186.         beq.s    nochg2
  187.  
  188. *------        set up new stack
  189.         move.l    a4,d0
  190.         sub.l    #RESBASE,d0
  191.         add.l    #RESLEN,d0
  192.         add.l    __stack(a4),d0        * here a4 will be pointing at the
  193.                         * new data, but _stack will be the
  194.                         * same if all goes well
  195.  
  196.         sub.l    #128,d0            * 128 down for good measure
  197.         move.l    d0,a7
  198.         move.l    __stack(a4),d0
  199.         move.l    d0,4(a7)        * fill in size of new stack    
  200.         add.l    d0,_realdatasize(a4)     * need to know how much to free later
  201.  
  202. nochg2:
  203. *------        Set _base for stack checking
  204.         move.l    a7,d1
  205.         sub.l    a3,d1            * get top of stack
  206.         add.l    #128,D1            * allow for parms overflow
  207.         move.l    D1,__base(A4)        * save for stack checking
  208.  
  209.     ENDC
  210.  
  211. clrwb:
  212.     clr.l    _WBenchMsg(A4)
  213.  
  214. *-----    clear any pending signals
  215.     moveq    #0,d0
  216.     move.l    #$00003000,d1
  217.     callsys    SetSignal
  218.     
  219.  
  220. *------ attempt to open DOS library:
  221.     lea    DOSName(PC),A1
  222.     moveq.l #0,D0
  223.     callsys OpenLibrary
  224.     move.l    D0,_DOSBase(A4)
  225.     bne.s    ok2
  226.     moveq.l #100,d0
  227.     bra.w    exit2
  228.  
  229. ok2:
  230. *=======================================================================
  231. *
  232. * Entry: D2 = command length
  233. *    A2 = Command pointer
  234.  
  235.     ifnd    RESIDENT        * we need to set _base if not resident
  236.         move.l    a7,D0        * get top of stack
  237.         sub.l    4(a7),D0    * compute bottom 
  238.         add.l    #128,D0        * allow for parms overflow
  239.         move.l    D0,__base(A4)    * save for stack checking
  240.     endc
  241.     
  242. *------ find command name:
  243.     move.l    ThisTask(a6),A3
  244.     move.l    pr_CLI(a3),a0
  245.     add.l    a0,a0        * bcpl pointer conversion
  246.     add.l    a0,a0
  247.     move.l    cli_CommandName(a0),a1
  248.     add.l    a1,a1        * bcpl pointer conversion
  249.     add.l    a1,a1
  250.  
  251. *------ collect parameters:
  252.     move.b    (a1)+,d0
  253.     move.l    a1,__ProgramName(A4)
  254.  
  255.  
  256.     move.l    d2,-(A7)        * push command line length
  257.     move.l    a2,-(A7)        * push command line address
  258.  
  259. *=============================================
  260. *------ common code --------
  261. *=============================================
  262.  
  263. main    jsr    ___fpinit(PC)        * Initialize floating point
  264.     jsr    __xmain(PC)        * call C entrypoint
  265.     moveq.l    #0,d0            * set successful status
  266.     bra.s    exit2
  267. *
  268.  
  269. _XCEXIT:
  270.     move.l    4(SP),d0        * extract return code
  271. _@XCEXIT:
  272. exit2:
  273.     move.l    d0,-(a7)
  274.     move.l    __ONEXIT(A4),d0        * exit trap function?
  275.     beq.s     exit3
  276.     move.l    d0,a0
  277.     jsr    (a0)
  278. exit3    move.l    __Children(a4),d0    * if we have any children
  279.     beq.s    exit4            *    orphan them
  280.     move.l    d0,a0
  281.     move.l    (a0),a0
  282.     jsr    (a0)
  283. exit4    jsr    _MemCleanup(PC)        * cleanup leftover memory alloc.
  284.     move.l    AbsExecBase.W,a6
  285.     move.l    _DOSBase(A4),a1
  286.     callsys CloseLibrary        * close Dos library
  287.  
  288.     jsr    ___fpterm(PC)        * clean up any floating point
  289.  
  290. *------ this rts sends us back to DOS:
  291. exitToDOS:
  292.     IFD    RESIDENT
  293.         move.l    realdatasize(a4),d0
  294.         move.l    a4,a1
  295.         sub.l    #RESBASE,a1
  296.         move.l    AbsExecBase.W,a6
  297.         move.l    (A7)+,d6
  298.         movea.l    __StackPtr(a4),a5
  299.         callsys    FreeMem
  300.         move.l    d6,d0
  301.         movea.l    a5,sp
  302.     ELSE
  303.         move.l    (A7)+,D0
  304.         movea.l    __StackPtr(a4),SP    * restore stack ptr
  305.     ENDC
  306.     
  307.     movem.l (a7)+,d1-d6/a0-a6
  308.     rts
  309.  
  310.  
  311. DOSName     dc.b    'dos.library',0
  312.  
  313.     section __MERGED,BSS
  314. *
  315.     xref    _DOSBase
  316.  
  317.     xdef    _NULL,_SysBase,_WBenchMsg
  318.     xdef    _curdir,__mbase,__mnext,__msize,__tsize
  319.     xdef    __oserr,__OSERR,__FPERR,__SIGFPE,__ONERR,__ONEXIT,__ONBREAK
  320.     xdef    __SIGINT
  321.     xdef    __ProgramName,__StackPtr,__base
  322.     xdef    __Children
  323.  
  324. *
  325.     ifd    RESIDENT
  326. realdatasize    ds.l    1    * size of memory allocated for data +
  327.                 * possible stack
  328.     endc
  329.     
  330. _NULL        ds.l    1    *
  331. __base        ds.l    1    * base of stack
  332. __mbase        ds.l    1    * base of memory pool
  333. __mnext        ds.l    1    * next available memory location
  334. __msize        ds.l    1    * size of memory pool
  335. __tsize        ds.l    1    * total size?
  336. __oserr        equ    *
  337. __OSERR        ds.l    1
  338. __FPERR        ds.l    1
  339. __SIGFPE    ds.l    1
  340. __SIGINT    ds.l    1
  341. __ONERR        ds.l    1
  342. __ONEXIT    ds.l    1
  343. __ONBREAK    ds.l    1
  344. _curdir         ds.l    1
  345. _SysBase    ds.l    1
  346. _WBenchMsg    ds.l    1
  347. __StackPtr    ds.l    1
  348. stdin        ds.l    1
  349. __ProgramName    ds.l    1
  350. __Children    ds.l    1
  351.         END
  352.