home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / basic / el-e.bas < prev    next >
BASIC Source File  |  1994-07-13  |  21KB  |  566 lines
  1.    PRINT "          *** ELECTRICAL ENGENEERING & DESIGN ***"
  2.    PRINT "                 J. Schrabal, April 1979"
  3.    PRINT
  4.    PRINT "File cleaned up of typos and put somewhat of a structure"
  5.    PRINT "in it: 8/25/82 by S. Kluger"
  6.    PRINT
  7.    pi = 3.141592654      REM pi constant
  8. 10 PRINT "To select one of the programs just type it's number"
  9.    PRINT "and hit 'RETURN' key. Enter all alphabetic answers in UPPER CASE!"
  10.    PRINT
  11. 20 PRINT "Select from the following routines (0 to quit) :"
  12.    PRINT "     1. Ohm's law (DC)"
  13.    PRINT "     2. Zener stabilized DC supply"
  14.    PRINT "     3. DC power supply design"
  15.    PRINT "     4. Low pass 2-pole Butterworth filter"
  16.    PRINT "     5. Series resonant frequency circuit"
  17.    PRINT "     6. Passive band-pass filter"
  18.    PRINT "     7. Small coil design & inductance calculations"
  19.    PRINT "     8. Long wire antenna"
  20.    PRINT "     9. Dipole or half wave antenna"
  21.    PRINT "    10. Time constant calculation"
  22.    PRINT "    11. Resistance of wire"
  23.    PRINT "    12. Crystal (rec./tr.) frequency calculations"
  24.    PRINT
  25.    INPUT "What routine do you wish to select";SELECTION
  26.      IF SELECTION>0 AND SELECTION<13 THEN 30
  27.        IF SELECTION=0 THEN 9999
  28.    PRINT "Please answer with number fom 0 to 12":GOTO 20
  29. 30 ON SELECTION GO TO 100,200,250,300,400,500,600,700,800,900,1000,1200
  30.  
  31.      REM PART 1 (100)
  32.  
  33. 100 PRINT
  34.     PRINT "          *** OHM's LAW (DC) ***"
  35. 110 PRINT
  36.     PRINT " ENTER values for 2 (two) known"
  37.     PRINT " ENTER 0 (zero) for unknown values to be calculated"
  38.     PRINT
  39.     INPUT "Potential in volts ";E
  40.     INPUT "Current flow in amperes ";I
  41.       IF E>0 AND I>0 THEN 111
  42.     INPUT "Resistance in ohms";R
  43.       IF I>0 AND R>0 AND E=0 THEN 120
  44.       IF E>0 AND R>0 AND I=0 THEN 130
  45.     INPUT "Power in watts ";P
  46.       IF E>0 AND I=0 AND R=0 THEN 141
  47.       IF I>0 AND E=0 AND R=0 THEN 142
  48.       IF R>0 AND E=0 AND I=0 THEN 143
  49. 111 R=E/I
  50.     GOTO 140
  51. 120 E=I*R
  52.     GOTO 140
  53. 130 I=E/R
  54. 140 P=E*I
  55.     GOTO 150
  56. 141 I=P/E
  57.     R=(E^2)/P
  58.     GOTO 150
  59. 142 E=P/I
  60.     R=E/I
  61.     GOTO 150
  62. 143 E=(P*R)^.5
  63.     I=E/R
  64. 150 PRINT
  65.     PRINT "Potential = ";E;" volts"
  66.     PRINT "Current flow = ";I;" amperes"
  67.     PRINT "Resistance = ";R;" ohms"
  68.     PRINT "Power = ";P;" watts"
  69.     PRINT
  70.     INPUT "MORE CALCULATIONS? (YES/NO)";ANS$
  71.       IF ANS$="YES" THEN GOTO 110 ELSE GOTO 20
  72.  
  73.               REM   Part 2   (200)
  74.  
  75. 200 PRINT
  76.     PRINT "      *** ZENER STABILIZED CIRCUIT DESIGN ***"
  77. 210  PRINT
  78.     INPUT "Voltage rating of zener diode";A
  79.     INPUT "Wattage rating of zener diode";W
  80.     INPUT "Maximum DC voltage of power supply";B
  81.     R=((B-A)^2)/W
  82.     I=(W/R)^.5     REM in amperes
  83.     PRINT "For an open circuit, or for load up to ";I*1000;" miliamperes"
  84.     PRINT "Use ";R;"ohms ";W;" watt resistor"
  85.     PRINT
  86.     PRINT "Will the load (device) you use have larger than ";
  87.     PRINT W;"watts consumption?"
  88.     INPUT "(YES/NO)";A$
  89.       IF A$="NO" THEN 220
  90.     INPUT "What is the maximum wattage of the device you use:";C
  91.     X=((B-A)^2)/((W/2)+C)
  92.     PRINT "Use ";X; "ohms ";W+C;" watts resistor"
  93.     PRINT "WARNING: Zener diode will probably burn out if the load"
  94.     PRINT "         should be removed and circuit left open."
  95.     PRINT
  96. 220 INPUT "More calculations? (YES/NO)";ANS$
  97.       IF ANS$="YES" THEN GOTO 210 ELSE GOTO 20
  98.  
  99. 250    REM Part 2.1
  100.  
  101.     PRINT "          *** POWER SUPPLY DESIGN ***"
  102.     PRINT
  103.     INPUT "What is LINE AC voltage supplied by utility";A
  104. 251 INPUT "What is transformer's primary rating (or tap)";B
  105. 252 INPUT "What is RMS voltage of secondary winding";C
  106.     D=(C*A)/B        REM  D is max.RMS
  107.     P=D*1.4          REM  P is peak voltage
  108.     M=P+(P/4)      REM  M is maximum peak
  109. 256 INPUT "What is the needed (desired) DC voltage";O
  110.       IF C>(2*O) THEN 267
  111.       IF O>C THEN 268
  112.     PRINT "What is the voltage rating of REGULATORS"
  113.     INPUT "                  used with the power supply";Z
  114.       IF ((Z+2.5)+(Z*.1))>O THEN 269
  115.       IF ((Z+3.5)+(Z*.25))<O THEN 271
  116. 255 PRINT "Presuming that you use full wave, will the rectifying bridge"
  117.     INPUT "consist of four (4) or two (2) diodes (as in centertap sec)";F
  118.       IF F=4 OR F=2 THEN 260
  119.     PRINT:PRINT "Answer whether 2 or 4 diodes will be used":PRINT:GOTO 255
  120. 260 IF F=2 THEN S=.75
  121.       IF F=4 THEN S=1.5
  122.     G=(D-S)*1.4        REM G is pulsating DC peak
  123.     R=G-O              REM R is ripple
  124.     INPUT "What is the load to be used in amperes? (if unknown type 0)";H
  125.       IF H=0 THEN 280
  126. 261 I=(H*83)/R*100
  127.     I=I+(I/10)
  128.     PRINT
  129.     PRINT "Line = ";A;" volts AC (max).Transformer primary (tap) = ";B;" volts AC"
  130.     PRINT "Secondary = ";D;" volts RMS. Peak sec.voltage = ";P
  131.     PRINT "For desired ";O;" volts DC use rectifying bridge of ";F
  132.     PRINT "diodes rated at ";M;" volts (minimum) and ";4*H; "amps (min.)"
  133.     PRINT "Filter capacitor should be rated ";I;" microfarads (minimum)"
  134.     PRINT "and ";G; "volts DC (min).Permissible ripple = ";R;" volts"
  135.     PRINT
  136.     PRINT "NOTE:Use ohm-law to calculate bleeder-resistor."
  137.     INPUT "More calculation for another secondary (YES/NO)";ANS$
  138.       IF ANS$="YES" THEN 252
  139.     INPUT "More calculation for another transformer (or tap)";ANS$
  140.       IF ANS$="YES" THEN GOTO 251 ELSE GOTO 20
  141. 267 PRINT "Your secondary winding has overly high rating for this"
  142.     PRINT "power requirement":PRINT:GOTO 252
  143. 268 PRINT "Your secondary winding has low voltage rating for this"
  144.     PRINT "power requirement":PRINT:GOTO 252
  145. 269 PRINT "Power supply DC voltage must be more than 2.5 volts higher"
  146.     PRINT "     than voltage of REGULATOR.":PRINT:GOTO 256
  147. 271 PRINT "Your supply voltage is overly high and will cause the regulator"
  148.     PRINT "to overheat. Reduce your voltage to ";Z+4;" volts"
  149.     PRINT "One way to do this is to insert series of diodes with rating"
  150.     PRINT "which will be printed below, each such diode reducing the"
  151.     PRINT "supply DC voltage by .7 volts (two diodes reduce 1.4 v)"
  152.     PRINT "Then add this voltage to regulators when answering Q."
  153.     PRINT:GOTO 256
  154. 280 INPUT "How many TAB-type regulators will be used";T
  155.     INPUT "         K-type regulators";K
  156.     INPUT "Any other load (in ampers)";Y
  157.     H=T+(K*1.5)+Y:GOTO 261
  158.  
  159.        REM   Part 3  (300)
  160.  
  161. 300 PRINT "         *** LOW PASS FILTER ***"
  162.     PRINT "This program is based on OPERATIONAL AMPLIFIERS DESIGNS"
  163.     PRINT "& APPLICATIONS by Graeme & Tobey, McGraw, 1971."
  164.     PRINT
  165. 310 INPUT "Cut off frequency (in Hertz)";F
  166. 320 INPUT "Desired pass-band gain (H)";H
  167.     PRINT "Peaking factor: 0(zero) for standard 2-pole Butterworth"
  168.     INPUT "(alpha)         value for non-standard filter";A
  169.     IF A=0 THEN A=2^.5
  170.     IF (H/A)>100 THEN 330
  171.     PRINT "Value of C2 in mF (microFarads)"
  172.     INPUT "Note: 0.02 mF = 0.000 000 02 F     ";C
  173.     R=A/(4*pi*F*C/1000000)
  174.     PRINT
  175.     PRINT "          .---------.                C1 = ";(4*(1+H)*C)/(A^2)
  176.     PRINT "          X         :                C2 = ";C
  177.     PRINT "          X R2      = C2             R1 = ";R/H
  178.     PRINT "          X         :                R2 = ";R
  179.     PRINT "    R1    :    R3   : - o            R3 = ";R/(H+1)
  180.     PRINT "--XXXXXX--:--XXXXXX-:---o  o"
  181.     PRINT "          :             o    o"
  182.     PRINT " E-in     :             o      o---------------"
  183.     PRINT "          = C1        + o    o"
  184.     PRINT "          :          ---o  o" 
  185.     PRINT "          :          :  o           E-out"
  186.     PRINT "          :          :"
  187.     PRINT "----------:----------:--------------------------"
  188.     INPUT "Another gain/alpha ratio? (YES/NO)";ANS$
  189.       IF ANS$="YES" THEN 320
  190.     INPUT "Another filter configuration (YES/NO)";B$
  191.       IF B$="YES" THEN GOTO 310 ELSE GOTO 20
  192. 330 PRINT"Because operational amplifiers are non-ideal, pass-"
  193.     PRINT "band gain should be chosen to be less than 10 when peaking"
  194.     PRINT "factor Alpha = 0-1"
  195.     PRINT "Gain of 100 with peaking factor=1 is acceptable for "
  196.     PRINT "for peaking gain 80 dB in 2-pole Batterworth config-"
  197.     PRINT "uration."
  198.     PRINT
  199.     GOTO 320
  200.  
  201.       REM   Part 4 (400)
  202.  
  203. 400 PRINT
  204.     PRINT "          *** SERIES RESONANT FREQUENCY CIRCUITS ***"
  205. 410 PRINT
  206.     INPUT "Inductance in MH (Milli-Henrys)";L
  207.     INPUT "Capacitance in NF (Nano-Farads)";C
  208.     PRINT
  209.     PRINT "Series L/C resonant frequency is ";\
  210.            1000/(6.283185307*((L*C)^0.5));" KHz (Kilo Hertz)"
  211.     PRINT "Note: this frequency is not affected by resistance in the circuit"
  212.     PRINT
  213.     INPUT "More calculations? (YES/NO)";ANS$
  214.       IF ANS$="YES" THEN 410
  215.     GOTO 20
  216.  
  217.      REM Part 5 (500)
  218.  
  219. 500 PRINT
  220.     PRINT "      *** PASSIVE BANDPASS FILTER DESIGN ***"
  221.     PRINT
  222.     PRINT"   This program is based on ELECTRICAL ENGINEERING &"
  223.     PRINT "CIRCUITS DESIGN by Skilling, Willey, 1961."
  224.     PRINT "   It will calculate ideal component values for the"
  225.     PRINT "T-section and PI-Section filters, given F1, F2,and R"
  226. 510 PRINT
  227.     INPUT "What is F1, low cut-off frequency (in Hertz)";L
  228.     INPUT "What is F2, high cut-off frequency (in Hertz)";H
  229.       IF L>H THEN 560
  230.     INPUT "What is R, image impedance in mid-frequency (in ohms)";R
  231.       IF L<0 THEN 581
  232.       IF H<0 THEN 581
  233.       IF R<0 THEN 581
  234.     X=H-L
  235.     Y=12.56637061*L*H
  236.     Z=pi
  237. 520 INPUT "If you want T-section type 'T'";T$
  238.       IF T$<>"T" THEN 550
  239.     PRINT
  240.     PRINT "2Ca=";X/Y*R*2,"  Cb=";1/Z*R,"  R=";R
  241.     PRINT "La/2=";R/Z/2,"  Lb=";R*X/Y
  242.     PRINT
  243.     PRINT "    2Ca     La/2                La/2     2Ca"
  244.     PRINT "o----!!----mmmmmmm---:-----:---mmmmmmm---!!-....."
  245.     PRINT "                     :     :                    :"
  246.     PRINT "                     :     m                    X"
  247.     PRINT "                  Cb =     m  Lb             R  X"
  248.     PRINT "                     :     m                    X"
  249.     PRINT "                     :     :                    :"
  250.     PRINT "o--------------------:-----:----------------....:"
  251. 550 PRINT
  252.     INPUT "If you want PI-section type 'P'";P$
  253.       IF P$<>"P" THEN 582
  254.     PRINT
  255.     PRINT "La=";R/Z,"  2Lb=";2*R*X/Y,"  R=";R
  256.     PRINT "Ca=";X/Y*R,"  Cb/2=";1/Z*R/2
  257.     PRINT
  258.     PRINT "                 La       Ca"
  259.     PRINT "o-------:----:-mmmmmmm----!!-----:----:..........:"
  260.     PRINT "        :    :                   :    :          :"
  261.     PRINT "        m    :                   :    m          X"
  262.     PRINT "    2Lb m    = Cb/2        Cb/2  =    m 2Lb    R X"
  263.     PRINT "        m    :                   :    m          X"
  264.     PRINT "        :    :                   :    :          :"
  265.     PRINT "o-------:----:-------------------:----:..........:"
  266.     PRINT
  267.     INPUT "Another passive filter calculation (YES/NO)";A$
  268.       IF A$="YES" THEN GOTO 510 ELSE GOTO 20
  269. 560 PRINT "High cut-off frequency must be higher than low-"
  270.     PRINT "cut-off frequency":GOTO 510
  271. 581 PRINT "This value must be larger than 0 (zero)":GOTO 510  
  272. 582 PRINT "Answer 'P' or 'T' only":GOTO 510
  273.  
  274.      REM Part 6
  275.  
  276. 600 PRINT "        *** SMALL COIL DESIGN ***"
  277.     PRINT
  278.     PRINT "Program limitations:"
  279.     PRINT "        Inductance = 100 microhenries MAXIMUM"
  280.     PRINT "        Wire size  =  12 size MAXIMUM"
  281.     PRINT "                      40 gage MINIMUM"
  282.     PRINT "        (resistors used as form must be of composite type)"
  283. 610 PRINT
  284.     PRINT "PROGRAMS:"
  285.     PRINT "     1. INDUCTANCE"
  286.     PRINT "     2. INDUCTIVE REACTANCE"
  287.     PRINT
  288.     INPUT " WHICH ONE OF THE TWO PROGRAMS ABOVE YOU WANT COMPUTED";A
  289.       IF A=1 THEN 650
  290.       IF A>2 THEN 610
  291.       IF A<0 THEN 610
  292. 620 INPUT "WHAT IS THE DESIRED INDUCTIVE REACTANCE IN OHMS";I
  293.     INPUT "AT WHAT FREQUENCY IN MHZ";F
  294.     H=I/(2*3.14159*F)
  295.     PRINT "INDUCTANCE = ";H;" MICROHENRIES"
  296.     IF H<100 THEN 660
  297. 640 PRINT "Program limitation is 100 microhenries MAXIMUM"
  298.     GOTO 610
  299. 650 INPUT "What is the desired coil inductance in microhenries";H
  300.       IF H>100 THEN 640
  301. 660 PRINT "Coil forms:"
  302.     PRINT "   A = 1/4 WATT RESISTOR"
  303.     PRINT "   B = 1/2 WATT RESISTOR"
  304.     PRINT "   C = 1 WATT RESISTOR"
  305.     PRINT "   D = 2 WATT RESISTOR"
  306.     PRINT "   E = OTHER FORM"
  307.     INPUT " SELECT COIL FORM FROM ABOVE (A,B,C,D,E)";FORM$
  308.       IF FORM$="A" THEN D=.09
  309.       IF FORM$="B" THEN D= .14
  310.       IF FORM$="C" THEN D= .22
  311.       IF FORM$="D" THEN D= .312
  312.       IF FORM$="E" THEN GOTO 601 ELSE GOTO 602
  313. 601 INPUT "What is the diameter of the coil in inches";D
  314. 602 PRINT "What gage enameled wire will be used:"
  315.     INPUT "                (gage 12 to 40)";G
  316.       IF G=12 THEN W=.081
  317.       IF G=13 THEN W=.072
  318.       IF G=14 THEN W=.064
  319.       IF G=15 THEN W=.057
  320.       IF G=16 THEN W=.051
  321.       IF G=17 THEN W=.045
  322.       IF G=18 THEN W=.040
  323.       IF G=19 THEN W=.036
  324.       IF G=20 THEN W=.32
  325.       IF G=21 THEN W=.0285
  326.       IF G=22 THEN W=.0253
  327.       IF G=23 THEN W=.0226
  328.       IF G=24 THEN W=.0201
  329.       IF G=25 THEN W=.0179
  330.       IF G=26 THEN W=.0159
  331.       IF G=27 THEN W=.0142
  332.       IF G=28 THEN W=.0126
  333.       IF G=29 THEN W=.0113
  334.       IF G=30 THEN W=.01
  335.       IF G=31 THEN W=.0089
  336.       IF G=32 THEN W=.008
  337.       IF G=33 THEN W=.0071
  338.       IF G=34 THEN W=.0063
  339.       IF G=35 THEN W=.0056
  340.       IF G=36 THEN W=.005
  341.       IF G=37 THEN W=.0045
  342.       IF G=38 THEN W=.004
  343.       IF G=39 THEN W=.0035
  344.       IF G=40 THEN W=.0031
  345.       IF G<12 OR G>40 THEN 602
  346.     N=((40*H*W)+SQR (((4*H*W)*(4*H*W))+(4*D*D*D*18*H)))/(2*D*D)
  347.     N1=((40*H*W)-SQR (((4*H*W)*(4*H*W))+(4*D*D*D*18*H)))/(2*D*D)
  348.       IF N>N1 THEN N2=N ELSE N2=N1
  349.     N2=(INT(N2*10))/10
  350.     PRINT:PRINT "Wire size = ";G;" gage"
  351.     PRINT "Coil diameter = ";D;" inches"
  352.     PRINT "Number of turns = ";N2
  353.     PRINT "Coil length = ";(INT(N2*W*100))/100;" inches"
  354.     INPUT "More calculations? (YES/NO)";ANS$
  355.       IF ANS$="YES" THEN GOTO 610 ELSE GOTO 20
  356.  
  357.      REM   Part 7 (700)
  358.  
  359. 700 PRINT
  360.     PRINT "          *** LONG WIRE ANTENNA ***"
  361.     PRINT
  362.     PRINT "    When an antenna is more than half wavelength long"
  363.     PRINT "it is called 'long wire' or 'harmonic' antenna."
  364.     PRINT
  365. 710 INPUT "What frequency in MHz (Mega Hertz)";F
  366.     INPUT "How many half-waves long";N
  367.     L=492*(N-0.05)/F
  368.     PRINT "Length = ";L;" Feet"
  369.     PRINT "Note: If this antenna is fed in exact center at ";L/2;" ft."
  370.     PRINT "no unbalance will occur on any harmonic frequency."
  371.     PRINT
  372.     INPUT "More calculations? (YES/NO)";ANS$
  373.       IF ANS$="YES" THEN 710
  374.     GOTO 20
  375.  
  376.      REM    Part 8  (800)
  377.  
  378. 800 PRINT
  379.     PRINT "      *** DIPOLE OR HALF WAVE ANTENNA ***"
  380.     PRINT
  381. 810 INPUT "Frequency in MHz (Mega Hertz)";F
  382.     L=492/F
  383.     PRINT:PRINT "Actual half-wave lenght is ";L;" feet"
  384.       IF F<30 THEN L=L*.95
  385.       IF F<150 THEN L=L*.97
  386.       IF F>149.9 THEN L=L*.98
  387.     PRINT "Lenght corrected to free space factor and to capacitance"
  388.     PRINT "of insulators is ";L;" feet"
  389.     PRINT
  390.     C=118/F
  391.     E=148/F
  392.     PRINT "<----------";L;" ft-------->"
  393.     PRINT "         <-";C;"ft->"
  394.     PRINT "o----------o-------o----------o"
  395.     PRINT "            o     o     ^"
  396.     PRINT "             o   o      E = ";E;" ft"
  397.     PRINT "              o=o  <- 600 ohms line 3.75 in spaced #16 wire"
  398.     PRINT "              o o                   5 in spaced #14 wire"
  399.     PRINT "              o o                   6 in spaced #12 wire"
  400.     PRINT
  401.     INPUT "More calculations (YES/NO)";ANS$
  402.       IF ANS$="YES" THEN 810
  403.     GOTO 20 
  404.  
  405.      REM       Part 9
  406.  
  407. 900 PRINT
  408.     PRINT "          *** TIME CONSTANT CALCULATIONS ***"
  409.     PRINT
  410. 910 PRINT "NOTE: If you wish to substitute Farads by MICROfarads then you"
  411.     PRINT "    must use resistance in MEGohms in order to get result"
  412.     PRINT "    in seconds."
  413.     INPUT "What is the resistance in ohms";R
  414.     INPUT "What is the capacitance in farads";C
  415.     PRINT "Time constant = ";R*C;"seconds"
  416.     INPUT "More calculations? (YES/NO)";ANS$
  417.       IF ANS$="YES" THEN GOTO 910 ELSE GOTO 20
  418.  
  419.      REM  Part 10
  420.  
  421. 1000 PRINT
  422.      PRINT "          *** RESISTANCE OF WIRE ***"
  423.      PRINT
  424. 1010 INPUT "What is the desired resistance in ohms";R
  425.      PRINT "What A.W.G.(B&S) size wire NO. is available?"
  426.      INPUT "                     (if unknown, enter '0')";WN
  427.        IF WN=0 THEN 1050
  428.        IF WN=1 THEN RW=.1264
  429.        IF WN=2 THEN RW=.1593
  430.        IF WN=3 THEN RW=.2009
  431.        IF WN=4 THEN RW=.2533
  432.        IF WN=5 THEN RW=.3195
  433.        IF WN=6 THEN RW=.4028
  434.        IF WN=7 THEN RW=.5080
  435.        IF WN=8 THEN RW=.6405
  436.        IF WN=9 THEN RW=.8077
  437.        IF WN=10 THEN RW=1.018
  438.        IF WN=11 THEN RW=1.284
  439.        IF WN=12 THEN RW=1.619
  440.        IF WN=13 THEN RW=2.042
  441.        IF WN=14 THEN RW=2.575
  442.        IF WN=15 THEN RW=3.247
  443.        IF WN=16 THEN RW=4.094
  444.        IF WN=17 THEN RW=5.163
  445.        IF WN=18 THEN RW=6.51
  446.        IF WN=19 THEN RW=8.21
  447.        IF WN=20 THEN RW=10.35
  448.        IF WN=21 THEN RW=13.05
  449.        IF WN=22 THEN RW=16.46
  450.        IF WN=23 THEN RW=20.76
  451.        IF WN=24 THEN RW=26.17
  452.        IF WN=25 THEN RW=33
  453.        IF WN=26 THEN RW=41.62
  454.        IF WN=27 THEN RW=52.48
  455.        IF WN=28 THEN RW=66.17
  456.        IF WN=29 THEN RW=83.44
  457.        IF WN=30 THEN RW=105.2
  458.        IF WN=31 THEN RW=132.7
  459.        IF WN=32 THEN RW=167.3
  460.        IF WN=33 THEN RW=211
  461.        IF WN=34 THEN RW=266
  462.        IF WN=35 THEN RW=335
  463.        IF WN=36 THEN RW=423
  464.        IF WN=37 THEN RW=533
  465.        IF WN=38 THEN RW=672.6
  466.        IF WN=39 THEN RW=848.1
  467.        IF WN=40 THEN RW=1069
  468. 1040 INPUT "Of what MATERIAL is the wire";MATERIAL$
  469.      MAT$=LEFT$(MATERIAL$,3)
  470.      TEST = RW  REM set up test for illegal entry
  471.        IF MAT$="COP" THEN RW=RW*1
  472.        IF MAT$="ALU" THEN RW=RW*1.6
  473.        IF MAT$="BRA" THEN RW=RW*4
  474.        IF MAT$="CAD" THEN RW=RW*4.4
  475.        IF MAT$="CHR" THEN RW=RW*1.8
  476.        IF MAT$="GOL" THEN RW=RW*1.4
  477.        IF MAT$="IRO" THEN RW=RW*5.68
  478.        IF MAT$="LEA" THEN RW=RW*12.8
  479.        IF MAT$="NIC" THEN RW=RW*5.1
  480.        IF MAT$="BRO" THEN RW=RW*4
  481.        IF MAT$="SIL" THEN RW=RW*.94
  482.        IF MAT$="STE" THEN RW=RW*11
  483.        IF MAT$="TIN" THEN RW=RW*6.7
  484.        IF MAT$="ZIN" THEN RW=RW*3.4
  485.          IF (RW=TEST) AND (MAT$<>"COP") THEN 1040
  486.      L=1000*R/RW
  487.      PRINT "For ";R;"ohms use ";L;" feet of No.";WN;MATERIAL$;" wire"
  488.      GOTO 1090
  489. 1050 INPUT "What is distance in feet";D
  490.      RX=R*1000/D
  491.        IF RX>.1264 THEN W=1
  492.        IF RX>.1593 THEN W=2
  493.        IF RX>.2009 THEN W=3
  494.        IF RX>.2533 THEN W=4
  495.        IF RX>.3195 THEN W=5
  496.        IF RX>.4028 THEN W=6
  497.        IF RX>.5080 THEN W=7
  498.        IF RX>.6405 THEN W=8
  499.        IF RX>.8077 THEN W=9
  500.        IF RX>1.018 THEN W=10
  501.        IF RX>1.284 THEN W=11
  502.        IF RX>1.619 THEN W=12
  503.        IF RX>2.042 THEN W=13
  504.        IF RX>2.575 THEN W=14
  505.        IF RX>3.247 THEN W=15
  506.        IF RX>4.094 THEN W=16
  507.        IF RX>5.163 THEN W=17
  508.        IF RX>6.51 THEN W=18
  509.        IF RX>8.21 THEN W=19
  510.        IF RX>10.35 THEN W=20
  511.        IF RX>13.05 THEN W=21
  512.        IF RX>16.46 THEN W=22
  513.        IF RX>20.76 THEN W=23
  514.        IF RX>26.17 THEN W=24
  515.        IF RX>33 THEN W=25
  516.        IF RX>41.62 THEN W=26
  517.        IF RX>52.48 THEN W=27
  518.        IF RX>66.17 THEN W=28
  519.        IF RX>83.44 THEN W=29
  520.        IF RX>105.2 THEN W=30
  521.        IF RX>132.7 THEN W=31
  522.        IF RX>167.3 THEN W=32
  523.        IF RX>211 THEN W=33
  524.        IF RX>266 THEN W=34
  525.        IF RX>335 THEN W=35
  526.        IF RX>423 THEN W=36
  527.        IF RX>533 THEN W=37
  528.        IF RX>672.6 THEN W=38
  529.        IF RX>848.1 THEN W=39
  530.        IF RX>1069 THEN W=40
  531.      PRINT "The smallest copper wire for ";R;" ohms at distance of ";D;" feet"
  532.      PRINT "   that can be safely used is No.";W;" A.W.G.(B&S)"
  533. 1090 INPUT "More calculations? (YES/NO)";ANS$
  534.      IF ANS$="YES" THEN GOTO 1010 ELSE GOTO 20
  535.  
  536. 1200    REM  Part 12 tr/rec. crystals
  537.  
  538.      PRINT
  539.      PRINT " ***RECEIVING & TRANSMITTING CRYSTAL CALCULATIONS***  "
  540.      PRINT
  541. 1221 INPUT "What is the receiving frequency? (in MHz)";R
  542.      INPUT "What is the transmitting frequency? (in MHz)";T
  543.      GOTO 1250
  544. 1222 INPUT "What is 1st IF freq.(in MHz) of rec.";I
  545.      INPUT "What is RECEIVING crystal divider";RD
  546.      INPUT "What is TRANSMITTING crystal multiplier";TD
  547. 1230 PRINT
  548.      PRINT "For receiving on ";R;" MHz (with ";I;" MHz IF) & ";RD;" divider"
  549.      PRINT "    ORDER ";(R-I)/RD*1000;"KHz receiving crystal"
  550.      PRINT "For transmitting on ";T;" MHz (tranmit multiplier=";TD;")"
  551.      PRINT "ORDER ";T/TD*1000;" KHz transmitting crystal"
  552.      PRINT
  553.      INPUT "More crystal freq. calculations? (YES/NO)";ANS$
  554.        IF ANS$="YES" THEN GOTO 1221 ELSE GOTO 20
  555. 1250 PRINT "What make and model transceiver?"
  556.      PRINT "    STANDARD 146A - MOTOROLA 80D - VOICECOMMANDER";
  557.      INPUT RADIO$
  558.      RADIO$ = LEFT$(RADIO$,3)
  559.        IF RADIO$="STA" THEN 1260
  560.        IF RADIO$="MOT" THEN I=5.5:RD=5:TD=24:GOTO 1230
  561.        IF RADIO$="VOI" THEN I=8.7:RD=3:TD=8:GOTO 1230
  562.      GOTO 1222
  563. 1260 I=11.7:RD=9:TD=18:GOTO 1230
  564.  
  565. 9999 END
  566.